| 1 | MODULE sbcrnf |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE sbcrnf *** |
|---|
| 4 | !! Ocean forcing: river runoff |
|---|
| 5 | !!===================================================================== |
|---|
| 6 | !! History : OPA ! 2000-11 (R. Hordoir, E. Durand) NetCDF FORMAT |
|---|
| 7 | !! NEMO 1.0 ! 2002-09 (G. Madec) F90: Free form and module |
|---|
| 8 | !! 3.0 ! 2006-07 (G. Madec) Surface module |
|---|
| 9 | !! 3.2 ! 2009-04 (B. Lemaire) Introduce iom_put |
|---|
| 10 | !! 3.3 ! 2010-10 (R. Furner, G. Madec) runoff distributed over ocean levels |
|---|
| 11 | !!---------------------------------------------------------------------- |
|---|
| 12 | |
|---|
| 13 | !!---------------------------------------------------------------------- |
|---|
| 14 | !! sbc_rnf : monthly runoffs read in a NetCDF file |
|---|
| 15 | !! sbc_rnf_init : runoffs initialisation |
|---|
| 16 | !! rnf_mouth : set river mouth mask |
|---|
| 17 | !!---------------------------------------------------------------------- |
|---|
| 18 | USE dom_oce ! ocean space and time domain |
|---|
| 19 | USE phycst ! physical constants |
|---|
| 20 | USE sbc_oce ! surface boundary condition variables |
|---|
| 21 | USE closea ! closed seas |
|---|
| 22 | USE fldread ! read input field at current time step |
|---|
| 23 | USE restart ! restart |
|---|
| 24 | USE in_out_manager ! I/O manager |
|---|
| 25 | USE iom ! I/O module |
|---|
| 26 | USE lib_mpp ! MPP library |
|---|
| 27 | |
|---|
| 28 | IMPLICIT NONE |
|---|
| 29 | PRIVATE |
|---|
| 30 | |
|---|
| 31 | PUBLIC sbc_rnf ! routine call in sbcmod module |
|---|
| 32 | PUBLIC sbc_rnf_div ! routine called in sshwzv module |
|---|
| 33 | PUBLIC sbc_rnf_alloc ! routine call in sbcmod module |
|---|
| 34 | PUBLIC sbc_rnf_init ! (PUBLIC for TAM) |
|---|
| 35 | ! !!* namsbc_rnf namelist * |
|---|
| 36 | CHARACTER(len=100), PUBLIC :: cn_dir = './' !: Root directory for location of ssr files |
|---|
| 37 | LOGICAL , PUBLIC :: ln_rnf_depth = .false. !: depth river runoffs attribute specified in a file |
|---|
| 38 | LOGICAL , PUBLIC :: ln_rnf_tem = .false. !: temperature river runoffs attribute specified in a file |
|---|
| 39 | LOGICAL , PUBLIC :: ln_rnf_sal = .false. !: salinity river runoffs attribute specified in a file |
|---|
| 40 | LOGICAL , PUBLIC :: ln_rnf_emp = .false. !: runoffs into a file to be read or already into precipitation |
|---|
| 41 | TYPE(FLD_N) , PUBLIC :: sn_rnf !: information about the runoff file to be read |
|---|
| 42 | TYPE(FLD_N) , PUBLIC :: sn_cnf !: information about the runoff mouth file to be read |
|---|
| 43 | TYPE(FLD_N) :: sn_s_rnf !: information about the salinities of runoff file to be read |
|---|
| 44 | TYPE(FLD_N) :: sn_t_rnf !: information about the temperatures of runoff file to be read |
|---|
| 45 | TYPE(FLD_N) :: sn_dep_rnf !: information about the depth which river inflow affects |
|---|
| 46 | LOGICAL , PUBLIC :: ln_rnf_mouth = .false. !: specific treatment in mouths vicinity |
|---|
| 47 | REAL(wp) , PUBLIC :: rn_hrnf = 0._wp !: runoffs, depth over which enhanced vertical mixing is used |
|---|
| 48 | REAL(wp) , PUBLIC :: rn_avt_rnf = 0._wp !: runoffs, value of the additional vertical mixing coef. [m2/s] |
|---|
| 49 | REAL(wp) , PUBLIC :: rn_rfact = 1._wp !: multiplicative factor for runoff |
|---|
| 50 | |
|---|
| 51 | INTEGER , PUBLIC :: nkrnf = 0 !: nb of levels over which Kz is increased at river mouths |
|---|
| 52 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) :: rnfmsk !: river mouth mask (hori.) |
|---|
| 53 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:) :: rnfmsk_z !: river mouth mask (vert.) |
|---|
| 54 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) :: h_rnf !: depth of runoff in m |
|---|
| 55 | INTEGER, PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) :: nk_rnf !: depth of runoff in model levels |
|---|
| 56 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: rnf_tsc_b, rnf_tsc !: before and now T & S runoff contents [K.m/s & PSU.m/s] |
|---|
| 57 | |
|---|
| 58 | REAL(wp) :: r1_rau0 ! = 1 / rau0 |
|---|
| 59 | |
|---|
| 60 | TYPE(FLD), PUBLIC, ALLOCATABLE, DIMENSION(:) :: sf_rnf ! structure: river runoff (file information, fields read) (PUBLIC for TAM) |
|---|
| 61 | TYPE(FLD), PUBLIC, ALLOCATABLE, DIMENSION(:) :: sf_s_rnf ! structure: river runoff salinity (file information, fields read) (PUBLIC for TAM) |
|---|
| 62 | TYPE(FLD), PUBLIC, ALLOCATABLE, DIMENSION(:) :: sf_t_rnf ! structure: river runoff temperature (file information, fields read) (PUBLIC for TAM) |
|---|
| 63 | |
|---|
| 64 | !! * Substitutions |
|---|
| 65 | # include "domzgr_substitute.h90" |
|---|
| 66 | !!---------------------------------------------------------------------- |
|---|
| 67 | !! NEMO/OPA 3.3 , NEMO Consortium (2010) |
|---|
| 68 | !! $Id$ |
|---|
| 69 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 70 | !!---------------------------------------------------------------------- |
|---|
| 71 | CONTAINS |
|---|
| 72 | |
|---|
| 73 | INTEGER FUNCTION sbc_rnf_alloc() |
|---|
| 74 | !!---------------------------------------------------------------------- |
|---|
| 75 | !! *** ROUTINE sbc_rnf_alloc *** |
|---|
| 76 | !!---------------------------------------------------------------------- |
|---|
| 77 | ALLOCATE( rnfmsk(jpi,jpj) , rnfmsk_z(jpk) , & |
|---|
| 78 | & h_rnf (jpi,jpj) , nk_rnf (jpi,jpj) , & |
|---|
| 79 | & rnf_tsc_b(jpi,jpj,jpts) , rnf_tsc (jpi,jpj,jpts) , STAT=sbc_rnf_alloc ) |
|---|
| 80 | ! |
|---|
| 81 | IF( lk_mpp ) CALL mpp_sum ( sbc_rnf_alloc ) |
|---|
| 82 | IF( sbc_rnf_alloc > 0 ) CALL ctl_warn('sbc_rnf_alloc: allocation of arrays failed') |
|---|
| 83 | END FUNCTION sbc_rnf_alloc |
|---|
| 84 | |
|---|
| 85 | SUBROUTINE sbc_rnf( kt ) |
|---|
| 86 | !!---------------------------------------------------------------------- |
|---|
| 87 | !! *** ROUTINE sbc_rnf *** |
|---|
| 88 | !! |
|---|
| 89 | !! ** Purpose : Introduce a climatological run off forcing |
|---|
| 90 | !! |
|---|
| 91 | !! ** Method : Set each river mouth with a monthly climatology |
|---|
| 92 | !! provided from different data. |
|---|
| 93 | !! CAUTION : upward water flux, runoff forced to be < 0 |
|---|
| 94 | !! |
|---|
| 95 | !! ** Action : runoff updated runoff field at time-step kt |
|---|
| 96 | !!---------------------------------------------------------------------- |
|---|
| 97 | INTEGER, INTENT(in) :: kt ! ocean time step |
|---|
| 98 | !! |
|---|
| 99 | INTEGER :: ji, jj ! dummy loop indices |
|---|
| 100 | INTEGER :: z_err = 0 ! dummy integer for error handling |
|---|
| 101 | !!---------------------------------------------------------------------- |
|---|
| 102 | ! |
|---|
| 103 | IF( kt == nit000 ) CALL sbc_rnf_init ! Read namelist and allocate structures |
|---|
| 104 | |
|---|
| 105 | ! ! ---------------------------------------- ! |
|---|
| 106 | IF( kt /= nit000 ) THEN ! Swap of forcing fields ! |
|---|
| 107 | ! ! ---------------------------------------- ! |
|---|
| 108 | rnf_b (:,: ) = rnf (:,: ) ! Swap the ocean forcing fields except at nit000 |
|---|
| 109 | rnf_tsc_b(:,:,:) = rnf_tsc(:,:,:) ! where before fields are set at the end of the routine |
|---|
| 110 | ! |
|---|
| 111 | ENDIF |
|---|
| 112 | |
|---|
| 113 | ! !-------------------! |
|---|
| 114 | IF( .NOT. ln_rnf_emp ) THEN ! Update runoff ! |
|---|
| 115 | ! !-------------------! |
|---|
| 116 | ! |
|---|
| 117 | CALL fld_read ( kt, nn_fsbc, sf_rnf ) ! Read Runoffs data and provide it at kt |
|---|
| 118 | IF( ln_rnf_tem ) CALL fld_read ( kt, nn_fsbc, sf_t_rnf ) ! idem for runoffs temperature if required |
|---|
| 119 | IF( ln_rnf_sal ) CALL fld_read ( kt, nn_fsbc, sf_s_rnf ) ! idem for runoffs salinity if required |
|---|
| 120 | ! |
|---|
| 121 | ! Runoff reduction only associated to the ORCA2_LIM configuration |
|---|
| 122 | ! when reading the NetCDF file runoff_1m_nomask.nc |
|---|
| 123 | IF( cp_cfg == 'orca' .AND. jp_cfg == 2 ) THEN |
|---|
| 124 | WHERE( 40._wp < gphit(:,:) .AND. gphit(:,:) < 65._wp ) |
|---|
| 125 | sf_rnf(1)%fnow(:,:,1) = 0.85 * sf_rnf(1)%fnow(:,:,1) |
|---|
| 126 | END WHERE |
|---|
| 127 | ENDIF |
|---|
| 128 | ! |
|---|
| 129 | IF( MOD( kt - 1, nn_fsbc ) == 0 ) THEN |
|---|
| 130 | rnf(:,:) = rn_rfact * ( sf_rnf(1)%fnow(:,:,1) ) |
|---|
| 131 | ! |
|---|
| 132 | r1_rau0 = 1._wp / rau0 |
|---|
| 133 | ! ! set temperature & salinity content of runoffs |
|---|
| 134 | IF( ln_rnf_tem ) THEN ! use runoffs temperature data |
|---|
| 135 | rnf_tsc(:,:,jp_tem) = ( sf_t_rnf(1)%fnow(:,:,1) ) * rnf(:,:) * r1_rau0 |
|---|
| 136 | WHERE( sf_t_rnf(1)%fnow(:,:,1) == -999 ) ! if missing data value use SST as runoffs temperature |
|---|
| 137 | rnf_tsc(:,:,jp_tem) = sst_m(:,:) * rnf(:,:) * r1_rau0 |
|---|
| 138 | END WHERE |
|---|
| 139 | ELSE ! use SST as runoffs temperature |
|---|
| 140 | rnf_tsc(:,:,jp_tem) = sst_m(:,:) * rnf(:,:) * r1_rau0 |
|---|
| 141 | ENDIF |
|---|
| 142 | ! ! use runoffs salinity data |
|---|
| 143 | IF( ln_rnf_sal ) rnf_tsc(:,:,jp_sal) = ( sf_s_rnf(1)%fnow(:,:,1) ) * rnf(:,:) * r1_rau0 |
|---|
| 144 | ! ! else use S=0 for runoffs (done one for all in the init) |
|---|
| 145 | ! |
|---|
| 146 | IF ( ANY( rnf(:,:) < 0._wp ) ) z_err=1 |
|---|
| 147 | IF( lk_mpp) CALL mpp_sum(z_err) |
|---|
| 148 | IF ( z_err > 0 ) CALL ctl_stop( 'sbc_rnf : negative runnoff values exist' ) |
|---|
| 149 | ! |
|---|
| 150 | CALL iom_put( "runoffs", rnf ) ! output runoffs arrays |
|---|
| 151 | ENDIF |
|---|
| 152 | ! |
|---|
| 153 | ENDIF |
|---|
| 154 | ! |
|---|
| 155 | IF( kt == nit000 ) THEN ! set the forcing field at nit000 - 1 ! |
|---|
| 156 | ! ! ---------------------------------------- ! |
|---|
| 157 | IF( ln_rstart .AND. & !* Restart: read in restart file |
|---|
| 158 | & iom_varid( numror, 'rnf_b', ldstop = .FALSE. ) > 0 ) THEN |
|---|
| 159 | IF(lwp) WRITE(numout,*) ' nit000-1 runoff forcing fields red in the restart file' |
|---|
| 160 | CALL iom_get( numror, jpdom_autoglo, 'rnf_b', rnf_b ) ! before runoff |
|---|
| 161 | CALL iom_get( numror, jpdom_autoglo, 'rnf_hc_b', rnf_tsc_b(:,:,jp_tem) ) ! before heat content of runoff |
|---|
| 162 | CALL iom_get( numror, jpdom_autoglo, 'rnf_sc_b', rnf_tsc_b(:,:,jp_sal) ) ! before salinity content of runoff |
|---|
| 163 | ELSE !* no restart: set from nit000 values |
|---|
| 164 | IF(lwp) WRITE(numout,*) ' nit000-1 runoff forcing fields set to nit000' |
|---|
| 165 | rnf_b (:,: ) = rnf (:,: ) |
|---|
| 166 | rnf_tsc_b(:,:,:) = rnf_tsc(:,:,:) |
|---|
| 167 | ENDIF |
|---|
| 168 | ENDIF |
|---|
| 169 | ! ! ---------------------------------------- ! |
|---|
| 170 | IF( lrst_oce ) THEN ! Write in the ocean restart file ! |
|---|
| 171 | ! ! ---------------------------------------- ! |
|---|
| 172 | IF(lwp) WRITE(numout,*) |
|---|
| 173 | IF(lwp) WRITE(numout,*) 'sbcrnf : runoff forcing fields written in ocean restart file ', & |
|---|
| 174 | & 'at it= ', kt,' date= ', ndastp |
|---|
| 175 | IF(lwp) WRITE(numout,*) '~~~~' |
|---|
| 176 | CALL iom_rstput( kt, nitrst, numrow, 'rnf_b' , rnf ) |
|---|
| 177 | CALL iom_rstput( kt, nitrst, numrow, 'rnf_hc_b', rnf_tsc(:,:,jp_tem) ) |
|---|
| 178 | CALL iom_rstput( kt, nitrst, numrow, 'rnf_sc_b', rnf_tsc(:,:,jp_sal) ) |
|---|
| 179 | ENDIF |
|---|
| 180 | ! |
|---|
| 181 | END SUBROUTINE sbc_rnf |
|---|
| 182 | |
|---|
| 183 | |
|---|
| 184 | SUBROUTINE sbc_rnf_div( phdivn ) |
|---|
| 185 | !!---------------------------------------------------------------------- |
|---|
| 186 | !! *** ROUTINE sbc_rnf *** |
|---|
| 187 | !! |
|---|
| 188 | !! ** Purpose : update the horizontal divergence with the runoff inflow |
|---|
| 189 | !! |
|---|
| 190 | !! ** Method : |
|---|
| 191 | !! CAUTION : rnf is positive (inflow) decreasing the |
|---|
| 192 | !! divergence and expressed in m/s |
|---|
| 193 | !! |
|---|
| 194 | !! ** Action : phdivn decreased by the runoff inflow |
|---|
| 195 | !!---------------------------------------------------------------------- |
|---|
| 196 | REAL(wp), DIMENSION(:,:,:), INTENT(inout) :: phdivn ! horizontal divergence |
|---|
| 197 | !! |
|---|
| 198 | INTEGER :: ji, jj, jk ! dummy loop indices |
|---|
| 199 | REAL(wp) :: r1_rau0 ! local scalar |
|---|
| 200 | REAL(wp) :: zfact ! local scalar |
|---|
| 201 | !!---------------------------------------------------------------------- |
|---|
| 202 | ! |
|---|
| 203 | zfact = 0.5_wp |
|---|
| 204 | ! |
|---|
| 205 | r1_rau0 = 1._wp / rau0 |
|---|
| 206 | IF( ln_rnf_depth ) THEN !== runoff distributed over several levels ==! |
|---|
| 207 | IF( lk_vvl ) THEN ! variable volume case |
|---|
| 208 | DO jj = 1, jpj ! update the depth over which runoffs are distributed |
|---|
| 209 | DO ji = 1, jpi |
|---|
| 210 | h_rnf(ji,jj) = 0._wp |
|---|
| 211 | DO jk = 1, nk_rnf(ji,jj) ! recalculates h_rnf to be the depth in metres |
|---|
| 212 | h_rnf(ji,jj) = h_rnf(ji,jj) + fse3t(ji,jj,jk) ! to the bottom of the relevant grid box |
|---|
| 213 | END DO |
|---|
| 214 | ! ! apply the runoff input flow |
|---|
| 215 | DO jk = 1, nk_rnf(ji,jj) |
|---|
| 216 | phdivn(ji,jj,jk) = phdivn(ji,jj,jk) - ( rnf(ji,jj) + rnf_b(ji,jj) ) * zfact * r1_rau0 / h_rnf(ji,jj) |
|---|
| 217 | END DO |
|---|
| 218 | END DO |
|---|
| 219 | END DO |
|---|
| 220 | ELSE ! constant volume case : just apply the runoff input flow |
|---|
| 221 | DO jj = 1, jpj |
|---|
| 222 | DO ji = 1, jpi |
|---|
| 223 | DO jk = 1, nk_rnf(ji,jj) |
|---|
| 224 | phdivn(ji,jj,jk) = phdivn(ji,jj,jk) - ( rnf(ji,jj) + rnf_b(ji,jj) ) * zfact * r1_rau0 / h_rnf(ji,jj) |
|---|
| 225 | END DO |
|---|
| 226 | END DO |
|---|
| 227 | END DO |
|---|
| 228 | ENDIF |
|---|
| 229 | ELSE !== runoff put only at the surface ==! |
|---|
| 230 | IF( lk_vvl ) THEN ! variable volume case |
|---|
| 231 | h_rnf(:,:) = fse3t(:,:,1) ! recalculate h_rnf to be depth of top box |
|---|
| 232 | ENDIF |
|---|
| 233 | phdivn(:,:,1) = phdivn(:,:,1) - ( rnf(:,:) + rnf_b(:,:) ) * zfact * r1_rau0 / fse3t(:,:,1) |
|---|
| 234 | ENDIF |
|---|
| 235 | ! |
|---|
| 236 | END SUBROUTINE sbc_rnf_div |
|---|
| 237 | |
|---|
| 238 | |
|---|
| 239 | SUBROUTINE sbc_rnf_init |
|---|
| 240 | !!---------------------------------------------------------------------- |
|---|
| 241 | !! *** ROUTINE sbc_rnf_init *** |
|---|
| 242 | !! |
|---|
| 243 | !! ** Purpose : Initialisation of the runoffs if (ln_rnf=T) |
|---|
| 244 | !! |
|---|
| 245 | !! ** Method : - read the runoff namsbc_rnf namelist |
|---|
| 246 | !! |
|---|
| 247 | !! ** Action : - read parameters |
|---|
| 248 | !!---------------------------------------------------------------------- |
|---|
| 249 | CHARACTER(len=32) :: rn_dep_file ! runoff file name |
|---|
| 250 | INTEGER :: ji, jj, jk ! dummy loop indices |
|---|
| 251 | INTEGER :: ierror, inum ! temporary integer |
|---|
| 252 | !! |
|---|
| 253 | NAMELIST/namsbc_rnf/ cn_dir, ln_rnf_emp, ln_rnf_depth, ln_rnf_tem, ln_rnf_sal, & |
|---|
| 254 | & sn_rnf, sn_cnf , sn_s_rnf , sn_t_rnf , sn_dep_rnf, & |
|---|
| 255 | & ln_rnf_mouth , rn_hrnf , rn_avt_rnf, rn_rfact |
|---|
| 256 | !!---------------------------------------------------------------------- |
|---|
| 257 | |
|---|
| 258 | ! ! ============ |
|---|
| 259 | ! ! Namelist |
|---|
| 260 | ! ! ============ |
|---|
| 261 | ! (NB: frequency positive => hours, negative => months) |
|---|
| 262 | ! ! file ! frequency ! variable ! time intep ! clim ! 'yearly' or ! weights ! rotation ! |
|---|
| 263 | ! ! name ! (hours) ! name ! (T/F) ! (T/F) ! 'monthly' ! filename ! pairs ! |
|---|
| 264 | sn_rnf = FLD_N( 'runoffs', -1 , 'sorunoff' , .TRUE. , .true. , 'yearly' , '' , '' ) |
|---|
| 265 | sn_cnf = FLD_N( 'runoffs', 0 , 'sorunoff' , .FALSE. , .true. , 'yearly' , '' , '' ) |
|---|
| 266 | |
|---|
| 267 | sn_s_rnf = FLD_N( 'runoffs', 24. , 'rosaline' , .TRUE. , .true. , 'yearly' , '' , '' ) |
|---|
| 268 | sn_t_rnf = FLD_N( 'runoffs', 24. , 'rotemper' , .TRUE. , .true. , 'yearly' , '' , '' ) |
|---|
| 269 | sn_dep_rnf = FLD_N( 'runoffs', 0. , 'rodepth' , .FALSE. , .true. , 'yearly' , '' , '' ) |
|---|
| 270 | ! |
|---|
| 271 | REWIND ( numnam ) ! Read Namelist namsbc_rnf |
|---|
| 272 | READ ( numnam, namsbc_rnf ) |
|---|
| 273 | |
|---|
| 274 | ! ! Control print |
|---|
| 275 | IF(lwp) THEN |
|---|
| 276 | WRITE(numout,*) |
|---|
| 277 | WRITE(numout,*) 'sbc_rnf : runoff ' |
|---|
| 278 | WRITE(numout,*) '~~~~~~~ ' |
|---|
| 279 | WRITE(numout,*) ' Namelist namsbc_rnf' |
|---|
| 280 | WRITE(numout,*) ' runoff in a file to be read ln_rnf_emp = ', ln_rnf_emp |
|---|
| 281 | WRITE(numout,*) ' specific river mouths treatment ln_rnf_mouth = ', ln_rnf_mouth |
|---|
| 282 | WRITE(numout,*) ' river mouth additional Kz rn_avt_rnf = ', rn_avt_rnf |
|---|
| 283 | WRITE(numout,*) ' depth of river mouth additional mixing rn_hrnf = ', rn_hrnf |
|---|
| 284 | WRITE(numout,*) ' multiplicative factor for runoff rn_rfact = ', rn_rfact |
|---|
| 285 | ENDIF |
|---|
| 286 | |
|---|
| 287 | ! ! ================== |
|---|
| 288 | ! ! Type of runoff |
|---|
| 289 | ! ! ================== |
|---|
| 290 | ! !== allocate runoff arrays |
|---|
| 291 | IF( sbc_rnf_alloc() /= 0 ) CALL ctl_stop( 'STOP', 'sbc_rnf_alloc : unable to allocate arrays' ) |
|---|
| 292 | ! |
|---|
| 293 | IF( ln_rnf_emp ) THEN !== runoffs directly provided in the precipitations ==! |
|---|
| 294 | IF(lwp) WRITE(numout,*) |
|---|
| 295 | IF(lwp) WRITE(numout,*) ' runoffs directly provided in the precipitations' |
|---|
| 296 | IF( ln_rnf_depth .OR. ln_rnf_tem .OR. ln_rnf_sal ) THEN |
|---|
| 297 | CALL ctl_warn( 'runoffs already included in precipitations, so runoff (T,S, depth) attributes will not be used' ) |
|---|
| 298 | ln_rnf_depth = .FALSE. ; ln_rnf_tem = .FALSE. ; ln_rnf_sal = .FALSE. |
|---|
| 299 | ENDIF |
|---|
| 300 | ! |
|---|
| 301 | ELSE !== runoffs read in a file : set sf_rnf structure ==! |
|---|
| 302 | ! |
|---|
| 303 | ALLOCATE( sf_rnf(1), STAT=ierror ) ! Create sf_rnf structure (runoff inflow) |
|---|
| 304 | IF(lwp) WRITE(numout,*) |
|---|
| 305 | IF(lwp) WRITE(numout,*) ' runoffs inflow read in a file' |
|---|
| 306 | IF( ierror > 0 ) THEN |
|---|
| 307 | CALL ctl_stop( 'sbc_rnf: unable to allocate sf_rnf structure' ) ; RETURN |
|---|
| 308 | ENDIF |
|---|
| 309 | ALLOCATE( sf_rnf(1)%fnow(jpi,jpj,1) ) |
|---|
| 310 | IF( sn_rnf%ln_tint ) ALLOCATE( sf_rnf(1)%fdta(jpi,jpj,1,2) ) |
|---|
| 311 | ! ! fill sf_rnf with the namelist (sn_rnf) and control print |
|---|
| 312 | CALL fld_fill( sf_rnf, (/ sn_rnf /), cn_dir, 'sbc_rnf_init', 'read runoffs data', 'namsbc_rnf' ) |
|---|
| 313 | ! |
|---|
| 314 | IF( ln_rnf_tem ) THEN ! Create (if required) sf_t_rnf structure |
|---|
| 315 | IF(lwp) WRITE(numout,*) |
|---|
| 316 | IF(lwp) WRITE(numout,*) ' runoffs temperatures read in a file' |
|---|
| 317 | ALLOCATE( sf_t_rnf(1), STAT=ierror ) |
|---|
| 318 | IF( ierror > 0 ) THEN |
|---|
| 319 | CALL ctl_stop( 'sbc_rnf_init: unable to allocate sf_t_rnf structure' ) ; RETURN |
|---|
| 320 | ENDIF |
|---|
| 321 | ALLOCATE( sf_t_rnf(1)%fnow(jpi,jpj,1) ) |
|---|
| 322 | IF( sn_t_rnf%ln_tint ) ALLOCATE( sf_t_rnf(1)%fdta(jpi,jpj,1,2) ) |
|---|
| 323 | CALL fld_fill (sf_t_rnf, (/ sn_t_rnf /), cn_dir, 'sbc_rnf_init', 'read runoff temperature data', 'namsbc_rnf' ) |
|---|
| 324 | ENDIF |
|---|
| 325 | ! |
|---|
| 326 | IF( ln_rnf_sal ) THEN ! Create (if required) sf_s_rnf and sf_t_rnf structures |
|---|
| 327 | IF(lwp) WRITE(numout,*) |
|---|
| 328 | IF(lwp) WRITE(numout,*) ' runoffs salinities read in a file' |
|---|
| 329 | ALLOCATE( sf_s_rnf(1), STAT=ierror ) |
|---|
| 330 | IF( ierror > 0 ) THEN |
|---|
| 331 | CALL ctl_stop( 'sbc_rnf_init: unable to allocate sf_s_rnf structure' ) ; RETURN |
|---|
| 332 | ENDIF |
|---|
| 333 | ALLOCATE( sf_s_rnf(1)%fnow(jpi,jpj,1) ) |
|---|
| 334 | IF( sn_s_rnf%ln_tint ) ALLOCATE( sf_s_rnf(1)%fdta(jpi,jpj,1,2) ) |
|---|
| 335 | CALL fld_fill (sf_s_rnf, (/ sn_s_rnf /), cn_dir, 'sbc_rnf_init', 'read runoff salinity data', 'namsbc_rnf' ) |
|---|
| 336 | ENDIF |
|---|
| 337 | ! |
|---|
| 338 | IF( ln_rnf_depth ) THEN ! depth of runoffs set from a file |
|---|
| 339 | IF(lwp) WRITE(numout,*) |
|---|
| 340 | IF(lwp) WRITE(numout,*) ' runoffs depth read in a file' |
|---|
| 341 | rn_dep_file = TRIM( cn_dir )//TRIM( sn_dep_rnf%clname ) |
|---|
| 342 | IF( .NOT. sn_dep_rnf%ln_clim ) THEN ; WRITE(rn_dep_file, '(a,"_y",i4)' ) TRIM( rn_dep_file ), nyear ! add year |
|---|
| 343 | IF( sn_dep_rnf%cltype == 'monthly' ) WRITE(rn_dep_file, '(a,"m",i2)' ) TRIM( rn_dep_file ), nmonth ! add month |
|---|
| 344 | ENDIF |
|---|
| 345 | CALL iom_open ( rn_dep_file, inum ) ! open file |
|---|
| 346 | CALL iom_get ( inum, jpdom_data, sn_dep_rnf%clvar, h_rnf ) ! read the river mouth array |
|---|
| 347 | CALL iom_close( inum ) ! close file |
|---|
| 348 | ! |
|---|
| 349 | nk_rnf(:,:) = 0 ! set the number of level over which river runoffs are applied |
|---|
| 350 | DO jj = 1, jpj |
|---|
| 351 | DO ji = 1, jpi |
|---|
| 352 | IF( h_rnf(ji,jj) > 0._wp ) THEN |
|---|
| 353 | jk = 2 |
|---|
| 354 | DO WHILE ( jk /= mbkt(ji,jj) .AND. fsdept(ji,jj,jk) < h_rnf(ji,jj) ) ; jk = jk + 1 ; END DO |
|---|
| 355 | nk_rnf(ji,jj) = jk |
|---|
| 356 | ELSEIF( h_rnf(ji,jj) == -1._wp ) THEN ; nk_rnf(ji,jj) = 1 |
|---|
| 357 | ELSEIF( h_rnf(ji,jj) == -999._wp ) THEN ; nk_rnf(ji,jj) = mbkt(ji,jj) |
|---|
| 358 | ELSE |
|---|
| 359 | CALL ctl_stop( 'sbc_rnf_init: runoff depth not positive, and not -999 or -1, rnf value in file fort.999' ) |
|---|
| 360 | WRITE(999,*) 'ji, jj, h_rnf(ji,jj) :', ji, jj, h_rnf(ji,jj) |
|---|
| 361 | ENDIF |
|---|
| 362 | END DO |
|---|
| 363 | END DO |
|---|
| 364 | DO jj = 1, jpj ! set the associated depth |
|---|
| 365 | DO ji = 1, jpi |
|---|
| 366 | h_rnf(ji,jj) = 0._wp |
|---|
| 367 | DO jk = 1, nk_rnf(ji,jj) |
|---|
| 368 | h_rnf(ji,jj) = h_rnf(ji,jj) + fse3t(ji,jj,jk) |
|---|
| 369 | END DO |
|---|
| 370 | END DO |
|---|
| 371 | END DO |
|---|
| 372 | ELSE ! runoffs applied at the surface |
|---|
| 373 | nk_rnf(:,:) = 1 |
|---|
| 374 | h_rnf (:,:) = fse3t(:,:,1) |
|---|
| 375 | ENDIF |
|---|
| 376 | ! |
|---|
| 377 | ENDIF |
|---|
| 378 | ! |
|---|
| 379 | rnf(:,:) = 0._wp ! runoff initialisation |
|---|
| 380 | rnf_tsc(:,:,:) = 0._wp ! runoffs temperature & salinty contents initilisation |
|---|
| 381 | ! |
|---|
| 382 | ! ! ======================== |
|---|
| 383 | ! ! River mouth vicinity |
|---|
| 384 | ! ! ======================== |
|---|
| 385 | ! |
|---|
| 386 | IF( ln_rnf_mouth ) THEN ! Specific treatment in vicinity of river mouths : |
|---|
| 387 | ! ! - Increase Kz in surface layers ( rn_hrnf > 0 ) |
|---|
| 388 | ! ! - set to zero SSS damping (ln_ssr=T) |
|---|
| 389 | ! ! - mixed upstream-centered (ln_traadv_cen2=T) |
|---|
| 390 | ! |
|---|
| 391 | IF ( ln_rnf_depth ) CALL ctl_warn( 'sbc_rnf_init: increased mixing turned on but effects may already', & |
|---|
| 392 | & 'be spread through depth by ln_rnf_depth' ) |
|---|
| 393 | ! |
|---|
| 394 | nkrnf = 0 ! Number of level over which Kz increase |
|---|
| 395 | IF( rn_hrnf > 0._wp ) THEN |
|---|
| 396 | nkrnf = 2 |
|---|
| 397 | DO WHILE( nkrnf /= jpkm1 .AND. gdepw_0(nkrnf+1) < rn_hrnf ) ; nkrnf = nkrnf + 1 ; END DO |
|---|
| 398 | IF( ln_sco ) & |
|---|
| 399 | CALL ctl_warn( 'sbc_rnf: number of levels over which Kz is increased is computed for zco...' ) |
|---|
| 400 | ENDIF |
|---|
| 401 | IF(lwp) WRITE(numout,*) |
|---|
| 402 | IF(lwp) WRITE(numout,*) ' Specific treatment used in vicinity of river mouths :' |
|---|
| 403 | IF(lwp) WRITE(numout,*) ' - Increase Kz in surface layers (if rn_hrnf > 0 )' |
|---|
| 404 | IF(lwp) WRITE(numout,*) ' by ', rn_avt_rnf,' m2/s over ', nkrnf, ' w-levels' |
|---|
| 405 | IF(lwp) WRITE(numout,*) ' - set to zero SSS damping (if ln_ssr=T)' |
|---|
| 406 | IF(lwp) WRITE(numout,*) ' - mixed upstream-centered (if ln_traadv_cen2=T)' |
|---|
| 407 | ! |
|---|
| 408 | CALL rnf_mouth ! set river mouth mask |
|---|
| 409 | ! |
|---|
| 410 | ELSE ! No treatment at river mouths |
|---|
| 411 | IF(lwp) WRITE(numout,*) |
|---|
| 412 | IF(lwp) WRITE(numout,*) ' No specific treatment at river mouths' |
|---|
| 413 | rnfmsk (:,:) = 0._wp |
|---|
| 414 | rnfmsk_z(:) = 0._wp |
|---|
| 415 | nkrnf = 0 |
|---|
| 416 | ENDIF |
|---|
| 417 | |
|---|
| 418 | END SUBROUTINE sbc_rnf_init |
|---|
| 419 | |
|---|
| 420 | |
|---|
| 421 | SUBROUTINE rnf_mouth |
|---|
| 422 | !!---------------------------------------------------------------------- |
|---|
| 423 | !! *** ROUTINE rnf_mouth *** |
|---|
| 424 | !! |
|---|
| 425 | !! ** Purpose : define the river mouths mask |
|---|
| 426 | !! |
|---|
| 427 | !! ** Method : read the river mouth mask (=0/1) in the river runoff |
|---|
| 428 | !! climatological file. Defined a given vertical structure. |
|---|
| 429 | !! CAUTION, the vertical structure is hard coded on the |
|---|
| 430 | !! first 5 levels. |
|---|
| 431 | !! This fields can be used to: |
|---|
| 432 | !! - set an upstream advection scheme |
|---|
| 433 | !! (ln_rnf_mouth=T and ln_traadv_cen2=T) |
|---|
| 434 | !! - increase vertical on the top nn_krnf vertical levels |
|---|
| 435 | !! at river runoff input grid point (nn_krnf>=2, see step.F90) |
|---|
| 436 | !! - set to zero SSS restoring flux at river mouth grid points |
|---|
| 437 | !! |
|---|
| 438 | !! ** Action : rnfmsk set to 1 at river runoff input, 0 elsewhere |
|---|
| 439 | !! rnfmsk_z vertical structure |
|---|
| 440 | !!---------------------------------------------------------------------- |
|---|
| 441 | ! |
|---|
| 442 | INTEGER :: inum ! temporary integers |
|---|
| 443 | CHARACTER(len=140) :: cl_rnfile ! runoff file name |
|---|
| 444 | !!---------------------------------------------------------------------- |
|---|
| 445 | ! |
|---|
| 446 | IF(lwp) WRITE(numout,*) |
|---|
| 447 | IF(lwp) WRITE(numout,*) 'rnf_mouth : river mouth mask' |
|---|
| 448 | IF(lwp) WRITE(numout,*) '~~~~~~~~~ ' |
|---|
| 449 | |
|---|
| 450 | cl_rnfile = TRIM( cn_dir )//TRIM( sn_cnf%clname ) |
|---|
| 451 | IF( .NOT. sn_cnf%ln_clim ) THEN ; WRITE(cl_rnfile, '(a,"_y",i4)' ) TRIM( cl_rnfile ), nyear ! add year |
|---|
| 452 | IF( sn_cnf%cltype == 'monthly' ) WRITE(cl_rnfile, '(a,"m",i2)' ) TRIM( cl_rnfile ), nmonth ! add month |
|---|
| 453 | ENDIF |
|---|
| 454 | |
|---|
| 455 | ! horizontal mask (read in NetCDF file) |
|---|
| 456 | CALL iom_open ( cl_rnfile, inum ) ! open file |
|---|
| 457 | CALL iom_get ( inum, jpdom_data, sn_cnf%clvar, rnfmsk ) ! read the river mouth array |
|---|
| 458 | CALL iom_close( inum ) ! close file |
|---|
| 459 | |
|---|
| 460 | IF( nn_closea == 1 ) CALL clo_rnf( rnfmsk ) ! closed sea inflow set as ruver mouth |
|---|
| 461 | |
|---|
| 462 | rnfmsk_z(:) = 0._wp ! vertical structure |
|---|
| 463 | rnfmsk_z(1) = 1.0 |
|---|
| 464 | rnfmsk_z(2) = 1.0 ! ********** |
|---|
| 465 | rnfmsk_z(3) = 0.5 ! HARD CODED on the 5 first levels |
|---|
| 466 | rnfmsk_z(4) = 0.25 ! ********** |
|---|
| 467 | rnfmsk_z(5) = 0.125 |
|---|
| 468 | ! |
|---|
| 469 | END SUBROUTINE rnf_mouth |
|---|
| 470 | |
|---|
| 471 | !!====================================================================== |
|---|
| 472 | END MODULE sbcrnf |
|---|
