New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcrnf.F90 in trunk/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

source: trunk/NEMOGCM/NEMO/OPA_SRC/SBC/sbcrnf.F90 @ 4990

Last change on this file since 4990 was 4990, checked in by timgraham, 9 years ago

Merged branches/2014/dev_MERGE_2014 back onto the trunk as follows:

In the working copy of branch ran:
svn merge svn+ssh://forge.ipsl.jussieu.fr/ipsl/forge/projets/nemo/svn/trunk@HEAD
1 conflict in LIM_SRC_3/limdiahsb.F90
Resolved by keeping the version from dev_MERGE_2014 branch
and commited at r4989

In working copy run:
svn switch svn+ssh://forge.ipsl.jussieu.fr/ipsl/forge/projets/nemo/svn/trunk
to switch working copy

Run:
svn merge --reintegrate svn+ssh://forge.ipsl.jussieu.fr/ipsl/forge/projets/nemo/svn/branches/2014/dev_MERGE_2014
to merge the branch into the trunk - no conflicts at this stage.

  • Property svn:keywords set to Id
File size: 27.0 KB
Line 
1MODULE sbcrnf
2   !!======================================================================
3   !!                       ***  MODULE  sbcrnf  ***
4   !! Ocean forcing:  river runoff
5   !!=====================================================================
6   !! History :  OPA  ! 2000-11  (R. Hordoir, E. Durand)  NetCDF FORMAT
7   !!   NEMO     1.0  ! 2002-09  (G. Madec)  F90: Free form and module
8   !!            3.0  ! 2006-07  (G. Madec)  Surface module
9   !!            3.2  ! 2009-04  (B. Lemaire)  Introduce iom_put
10   !!            3.3  ! 2010-10  (R. Furner, G. Madec) runoff distributed over ocean levels
11   !!----------------------------------------------------------------------
12
13   !!----------------------------------------------------------------------
14   !!   sbc_rnf      : monthly runoffs read in a NetCDF file
15   !!   sbc_rnf_init : runoffs initialisation
16   !!   rnf_mouth    : set river mouth mask
17   !!----------------------------------------------------------------------
18   USE dom_oce         ! ocean space and time domain
19   USE phycst          ! physical constants
20   USE sbc_oce         ! surface boundary condition variables
21   USE sbcisf          ! PM we could remove it I think
22   USE closea          ! closed seas
23   USE fldread         ! read input field at current time step
24   USE in_out_manager  ! I/O manager
25   USE iom             ! I/O module
26   USE lib_mpp         ! MPP library
27   USE eosbn2
28   USE wrk_nemo        ! Memory allocation
29
30   IMPLICIT NONE
31   PRIVATE
32
33   PUBLIC   sbc_rnf       ! routine call in sbcmod module
34   PUBLIC   sbc_rnf_div   ! routine called in sshwzv module
35   PUBLIC   sbc_rnf_alloc ! routine call in sbcmod module
36   PUBLIC   sbc_rnf_init  ! (PUBLIC for TAM)
37   !                                                     !!* namsbc_rnf namelist *
38   CHARACTER(len=100), PUBLIC ::   cn_dir          !: Root directory for location of ssr files
39   LOGICAL           , PUBLIC ::   ln_rnf_depth    !: depth       river runoffs attribute specified in a file
40   LOGICAL           , PUBLIC ::   ln_rnf_tem      !: temperature river runoffs attribute specified in a file
41   LOGICAL           , PUBLIC ::   ln_rnf_sal      !: salinity    river runoffs attribute specified in a file
42   LOGICAL           , PUBLIC ::   ln_rnf_emp      !: runoffs into a file to be read or already into precipitation
43   TYPE(FLD_N)       , PUBLIC ::   sn_rnf          !: information about the runoff file to be read
44   TYPE(FLD_N)       , PUBLIC ::   sn_cnf          !: information about the runoff mouth file to be read
45   TYPE(FLD_N)                ::   sn_s_rnf        !: information about the salinities of runoff file to be read
46   TYPE(FLD_N)                ::   sn_t_rnf        !: information about the temperatures of runoff file to be read
47   TYPE(FLD_N)                ::   sn_dep_rnf      !: information about the depth which river inflow affects
48   LOGICAL           , PUBLIC ::   ln_rnf_mouth    !: specific treatment in mouths vicinity
49   REAL(wp)          , PUBLIC ::   rn_hrnf         !: runoffs, depth over which enhanced vertical mixing is used
50   REAL(wp)          , PUBLIC ::   rn_avt_rnf      !: runoffs, value of the additional vertical mixing coef. [m2/s]
51   REAL(wp)          , PUBLIC ::   rn_rfact        !: multiplicative factor for runoff
52
53   INTEGER , PUBLIC  ::   nkrnf = 0         !: nb of levels over which Kz is increased at river mouths
54   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   rnfmsk              !: river mouth mask (hori.)
55   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:)     ::   rnfmsk_z            !: river mouth mask (vert.)
56   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   h_rnf               !: depth of runoff in m
57   INTEGER,  PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   nk_rnf              !: depth of runoff in model levels
58   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   rnf_tsc_b, rnf_tsc  !: before and now T & S runoff contents   [K.m/s & PSU.m/s]   
59
60   TYPE(FLD), PUBLIC, ALLOCATABLE, DIMENSION(:) ::   sf_rnf       ! structure: river runoff (file information, fields read)
61   TYPE(FLD), PUBLIC, ALLOCATABLE, DIMENSION(:) ::   sf_s_rnf     ! structure: river runoff salinity (file information, fields read) 
62   TYPE(FLD), PUBLIC, ALLOCATABLE, DIMENSION(:) ::   sf_t_rnf     ! structure: river runoff temperature (file information, fields read) 
63 
64   !! * Substitutions 
65#  include "domzgr_substitute.h90" 
66   !!----------------------------------------------------------------------
67   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
68   !! $Id$
69   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
70   !!----------------------------------------------------------------------
71CONTAINS
72
73   INTEGER FUNCTION sbc_rnf_alloc()
74      !!----------------------------------------------------------------------
75      !!                ***  ROUTINE sbc_rnf_alloc  ***
76      !!----------------------------------------------------------------------
77      ALLOCATE( rnfmsk(jpi,jpj)         , rnfmsk_z(jpk)          ,     &
78         &      h_rnf (jpi,jpj)         , nk_rnf  (jpi,jpj)      ,     &
79         &      rnf_tsc_b(jpi,jpj,jpts) , rnf_tsc (jpi,jpj,jpts) , STAT=sbc_rnf_alloc )
80         !
81      IF( lk_mpp            )   CALL mpp_sum ( sbc_rnf_alloc )
82      IF( sbc_rnf_alloc > 0 )   CALL ctl_warn('sbc_rnf_alloc: allocation of arrays failed')
83   END FUNCTION sbc_rnf_alloc
84
85
86   SUBROUTINE sbc_rnf( kt )
87      !!----------------------------------------------------------------------
88      !!                  ***  ROUTINE sbc_rnf  ***
89      !!
90      !! ** Purpose :   Introduce a climatological run off forcing
91      !!
92      !! ** Method  :   Set each river mouth with a monthly climatology
93      !!                provided from different data.
94      !!                CAUTION : upward water flux, runoff forced to be < 0
95      !!
96      !! ** Action  :   runoff updated runoff field at time-step kt
97      !!----------------------------------------------------------------------
98      INTEGER, INTENT(in) ::   kt          ! ocean time step
99      !
100      INTEGER  ::   ji, jj    ! dummy loop indices
101      INTEGER  ::   z_err = 0 ! dummy integer for error handling
102      !!----------------------------------------------------------------------
103      REAL(wp), DIMENSION(:,:), POINTER       ::   ztfrz   ! freezing point used for temperature correction
104      !
105      CALL wrk_alloc( jpi,jpj, ztfrz)
106
107      !
108      IF( kt == nit000 )   CALL sbc_rnf_init                           ! Read namelist and allocate structures
109
110      !                                            ! ---------------------------------------- !
111      IF( kt /= nit000 ) THEN                      !          Swap of forcing fields          !
112         !                                         ! ---------------------------------------- !
113         rnf_b    (:,:  ) = rnf    (:,:  )               ! Swap the ocean forcing fields except at nit000
114         rnf_tsc_b(:,:,:) = rnf_tsc(:,:,:)               ! where before fields are set at the end of the routine
115         !
116      ENDIF
117
118      !                                                   !-------------------!
119      IF( .NOT. ln_rnf_emp ) THEN                         !   Update runoff   !
120         !                                                !-------------------!
121         !
122                             CALL fld_read ( kt, nn_fsbc, sf_rnf   )    ! Read Runoffs data and provide it at kt
123         IF( ln_rnf_tem  )   CALL fld_read ( kt, nn_fsbc, sf_t_rnf )    ! idem for runoffs temperature if required
124         IF( ln_rnf_sal  )   CALL fld_read ( kt, nn_fsbc, sf_s_rnf )    ! idem for runoffs salinity    if required
125         !
126         ! Runoff reduction only associated to the ORCA2_LIM configuration
127         ! when reading the NetCDF file runoff_1m_nomask.nc
128         IF( cp_cfg == 'orca' .AND. jp_cfg == 2 )   THEN
129            WHERE( 40._wp < gphit(:,:) .AND. gphit(:,:) < 65._wp )
130               sf_rnf(1)%fnow(:,:,1) = 0.85 * sf_rnf(1)%fnow(:,:,1)
131            END WHERE
132         ENDIF
133         !
134         IF( MOD( kt - 1, nn_fsbc ) == 0 ) THEN
135            !
136            rnf(:,:) = rn_rfact * ( sf_rnf(1)%fnow(:,:,1) )       ! updated runoff value at time step kt
137            !
138            !                                                     ! set temperature & salinity content of runoffs
139            IF( ln_rnf_tem ) THEN                                       ! use runoffs temperature data
140               rnf_tsc(:,:,jp_tem) = ( sf_t_rnf(1)%fnow(:,:,1) ) * rnf(:,:) * r1_rau0
141               WHERE( sf_t_rnf(1)%fnow(:,:,1) == -999._wp )             ! if missing data value use SST as runoffs temperature
142                   rnf_tsc(:,:,jp_tem) = sst_m(:,:) * rnf(:,:) * r1_rau0
143               END WHERE
144               WHERE( sf_t_rnf(1)%fnow(:,:,1) == -222._wp )             ! where fwf comes from melting of ice shelves or iceberg
145                   ztfrz(:,:) = -1.9 !tfreez( sss_m(:,:) ) !PM to be discuss (trouble if sensitivity study)
146                   rnf_tsc(:,:,jp_tem) = ztfrz(:,:) * rnf(:,:) * r1_rau0 - rnf(:,:) * lfusisf * r1_rau0_rcp
147               END WHERE
148            ELSE                                                        ! use SST as runoffs temperature
149               rnf_tsc(:,:,jp_tem) = sst_m(:,:) * rnf(:,:) * r1_rau0
150            ENDIF
151            !                                                           ! use runoffs salinity data
152            IF( ln_rnf_sal )   rnf_tsc(:,:,jp_sal) = ( sf_s_rnf(1)%fnow(:,:,1) ) * rnf(:,:) * r1_rau0
153            !                                                           ! else use S=0 for runoffs (done one for all in the init)
154            IF ( ANY( rnf(:,:) < 0._wp ) ) z_err=1
155            IF(lk_mpp) CALL mpp_sum(z_err)
156            IF( z_err > 0 ) CALL ctl_stop( 'sbc_rnf : negative runnoff values exist' )
157            !
158            CALL iom_put( "runoffs", rnf )         ! output runoffs arrays
159         ENDIF
160         !
161      ENDIF
162      !
163      IF( kt == nit000 ) THEN                          !   set the forcing field at nit000 - 1    !
164         !                                             ! ---------------------------------------- !
165         IF( ln_rstart .AND.    &                               !* Restart: read in restart file
166            & iom_varid( numror, 'rnf_b', ldstop = .FALSE. ) > 0 ) THEN
167            IF(lwp) WRITE(numout,*) '          nit000-1 runoff forcing fields red in the restart file'
168            CALL iom_get( numror, jpdom_autoglo, 'rnf_b', rnf_b )     ! before runoff
169            CALL iom_get( numror, jpdom_autoglo, 'rnf_hc_b', rnf_tsc_b(:,:,jp_tem) )   ! before heat content of runoff
170            CALL iom_get( numror, jpdom_autoglo, 'rnf_sc_b', rnf_tsc_b(:,:,jp_sal) )   ! before salinity content of runoff
171         ELSE                                                   !* no restart: set from nit000 values
172            IF(lwp) WRITE(numout,*) '          nit000-1 runoff forcing fields set to nit000'
173             rnf_b    (:,:  ) = rnf    (:,:  )
174             rnf_tsc_b(:,:,:) = rnf_tsc(:,:,:)
175         ENDIF
176      ENDIF
177      !                                                ! ---------------------------------------- !
178      IF( lrst_oce ) THEN                              !      Write in the ocean restart file     !
179         !                                             ! ---------------------------------------- !
180         IF(lwp) WRITE(numout,*)
181         IF(lwp) WRITE(numout,*) 'sbcrnf : runoff forcing fields written in ocean restart file ',   &
182            &                    'at it= ', kt,' date= ', ndastp
183         IF(lwp) WRITE(numout,*) '~~~~'
184         CALL iom_rstput( kt, nitrst, numrow, 'rnf_b' , rnf )
185         CALL iom_rstput( kt, nitrst, numrow, 'rnf_hc_b', rnf_tsc(:,:,jp_tem) )
186         CALL iom_rstput( kt, nitrst, numrow, 'rnf_sc_b', rnf_tsc(:,:,jp_sal) )
187      ENDIF
188      CALL wrk_dealloc( jpi,jpj, ztfrz)
189      !
190   END SUBROUTINE sbc_rnf
191
192
193   SUBROUTINE sbc_rnf_div( phdivn )
194      !!----------------------------------------------------------------------
195      !!                  ***  ROUTINE sbc_rnf  ***
196      !!
197      !! ** Purpose :   update the horizontal divergence with the runoff inflow
198      !!
199      !! ** Method  :
200      !!                CAUTION : rnf is positive (inflow) decreasing the
201      !!                          divergence and expressed in m/s
202      !!
203      !! ** Action  :   phdivn   decreased by the runoff inflow
204      !!----------------------------------------------------------------------
205      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   phdivn   ! horizontal divergence
206      !!
207      INTEGER  ::   ji, jj, jk   ! dummy loop indices
208      REAL(wp) ::   zfact     ! local scalar
209      !!----------------------------------------------------------------------
210      !
211      zfact = 0.5_wp
212      !
213      IF( ln_rnf_depth ) THEN      !==   runoff distributed over several levels   ==!
214         IF( lk_vvl ) THEN             ! variable volume case
215            DO jj = 1, jpj                   ! update the depth over which runoffs are distributed
216               DO ji = 1, jpi
217                  h_rnf(ji,jj) = 0._wp
218                  DO jk = 1, nk_rnf(ji,jj)                           ! recalculates h_rnf to be the depth in metres
219                     h_rnf(ji,jj) = h_rnf(ji,jj) + fse3t(ji,jj,jk)   ! to the bottom of the relevant grid box
220                  END DO
221                  !                          ! apply the runoff input flow
222                  DO jk = 1, nk_rnf(ji,jj)
223                     phdivn(ji,jj,jk) = phdivn(ji,jj,jk) - ( rnf(ji,jj) + rnf_b(ji,jj) ) * zfact * r1_rau0 / h_rnf(ji,jj)
224                  END DO
225               END DO
226            END DO
227         ELSE                          ! constant volume case : just apply the runoff input flow
228            DO jj = 1, jpj
229               DO ji = 1, jpi
230                  DO jk = 1, nk_rnf(ji,jj)
231                     phdivn(ji,jj,jk) = phdivn(ji,jj,jk) - ( rnf(ji,jj) + rnf_b(ji,jj) ) * zfact * r1_rau0 / h_rnf(ji,jj)
232                  END DO
233               END DO
234            END DO
235         ENDIF
236      ELSE                       !==   runoff put only at the surface   ==!
237         IF( lk_vvl ) THEN              ! variable volume case
238            h_rnf(:,:) = fse3t(:,:,1)   ! recalculate h_rnf to be depth of top box
239         ENDIF
240         phdivn(:,:,1) = phdivn(:,:,1) - ( rnf(:,:) + rnf_b(:,:) ) * zfact * r1_rau0 / fse3t(:,:,1)
241      ENDIF
242      !
243   END SUBROUTINE sbc_rnf_div
244
245
246   SUBROUTINE sbc_rnf_init
247      !!----------------------------------------------------------------------
248      !!                  ***  ROUTINE sbc_rnf_init  ***
249      !!
250      !! ** Purpose :   Initialisation of the runoffs if (ln_rnf=T)
251      !!
252      !! ** Method  : - read the runoff namsbc_rnf namelist
253      !!
254      !! ** Action  : - read parameters
255      !!----------------------------------------------------------------------
256      CHARACTER(len=32) ::   rn_dep_file   ! runoff file name
257      INTEGER           ::   ji, jj, jk    ! dummy loop indices
258      INTEGER           ::   ierror, inum  ! temporary integer
259      INTEGER           ::   ios           ! Local integer output status for namelist read
260      !
261      NAMELIST/namsbc_rnf/ cn_dir, ln_rnf_emp, ln_rnf_depth, ln_rnf_tem, ln_rnf_sal,   &
262         &                 sn_rnf, sn_cnf    , sn_s_rnf    , sn_t_rnf  , sn_dep_rnf,   &
263         &                 ln_rnf_mouth      , rn_hrnf     , rn_avt_rnf, rn_rfact
264      !!----------------------------------------------------------------------
265      !
266      !                                   ! ============
267      !                                   !   Namelist
268      !                                   ! ============
269      !
270      REWIND( numnam_ref )              ! Namelist namsbc_rnf in reference namelist : Runoffs
271      READ  ( numnam_ref, namsbc_rnf, IOSTAT = ios, ERR = 901)
272901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_rnf in reference namelist', lwp )
273
274      REWIND( numnam_cfg )              ! Namelist namsbc_rnf in configuration namelist : Runoffs
275      READ  ( numnam_cfg, namsbc_rnf, IOSTAT = ios, ERR = 902 )
276902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_rnf in configuration namelist', lwp )
277      IF(lwm) WRITE ( numond, namsbc_rnf )
278      !
279      !                                         ! Control print
280      IF(lwp) THEN
281         WRITE(numout,*)
282         WRITE(numout,*) 'sbc_rnf : runoff '
283         WRITE(numout,*) '~~~~~~~ '
284         WRITE(numout,*) '   Namelist namsbc_rnf'
285         WRITE(numout,*) '      runoff in a file to be read                ln_rnf_emp   = ', ln_rnf_emp
286         WRITE(numout,*) '      specific river mouths treatment            ln_rnf_mouth = ', ln_rnf_mouth
287         WRITE(numout,*) '      river mouth additional Kz                  rn_avt_rnf   = ', rn_avt_rnf
288         WRITE(numout,*) '      depth of river mouth additional mixing     rn_hrnf      = ', rn_hrnf
289         WRITE(numout,*) '      multiplicative factor for runoff           rn_rfact     = ', rn_rfact
290      ENDIF
291      !
292      !                                   ! ==================
293      !                                   !   Type of runoff
294      !                                   ! ==================
295      !                                         !==  allocate runoff arrays
296      IF( sbc_rnf_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'sbc_rnf_alloc : unable to allocate arrays' )
297      !
298      IF( ln_rnf_emp ) THEN                     !==  runoffs directly provided in the precipitations  ==!
299         IF(lwp) WRITE(numout,*)
300         IF(lwp) WRITE(numout,*) '          runoffs directly provided in the precipitations'
301         IF( ln_rnf_depth .OR. ln_rnf_tem .OR. ln_rnf_sal ) THEN
302           CALL ctl_warn( 'runoffs already included in precipitations, so runoff (T,S, depth) attributes will not be used' )
303           ln_rnf_depth = .FALSE.   ;   ln_rnf_tem = .FALSE.   ;   ln_rnf_sal = .FALSE.
304         ENDIF
305         !
306      ELSE                                      !==  runoffs read in a file : set sf_rnf structure  ==!
307         !
308         ALLOCATE( sf_rnf(1), STAT=ierror )         ! Create sf_rnf structure (runoff inflow)
309         IF(lwp) WRITE(numout,*)
310         IF(lwp) WRITE(numout,*) '          runoffs inflow read in a file'
311         IF( ierror > 0 ) THEN
312            CALL ctl_stop( 'sbc_rnf: unable to allocate sf_rnf structure' )   ;   RETURN
313         ENDIF
314         ALLOCATE( sf_rnf(1)%fnow(jpi,jpj,1)   )
315         IF( sn_rnf%ln_tint ) ALLOCATE( sf_rnf(1)%fdta(jpi,jpj,1,2) )
316         !                                          ! fill sf_rnf with the namelist (sn_rnf) and control print
317         CALL fld_fill( sf_rnf, (/ sn_rnf /), cn_dir, 'sbc_rnf_init', 'read runoffs data', 'namsbc_rnf' )
318         !
319         IF( ln_rnf_tem ) THEN                      ! Create (if required) sf_t_rnf structure
320            IF(lwp) WRITE(numout,*)
321            IF(lwp) WRITE(numout,*) '          runoffs temperatures read in a file'
322            ALLOCATE( sf_t_rnf(1), STAT=ierror  )
323            IF( ierror > 0 ) THEN
324               CALL ctl_stop( 'sbc_rnf_init: unable to allocate sf_t_rnf structure' )   ;   RETURN
325            ENDIF
326            ALLOCATE( sf_t_rnf(1)%fnow(jpi,jpj,1)   )
327            IF( sn_t_rnf%ln_tint ) ALLOCATE( sf_t_rnf(1)%fdta(jpi,jpj,1,2) )
328            CALL fld_fill (sf_t_rnf, (/ sn_t_rnf /), cn_dir, 'sbc_rnf_init', 'read runoff temperature data', 'namsbc_rnf' )
329         ENDIF
330         !
331         IF( ln_rnf_sal  ) THEN                     ! Create (if required) sf_s_rnf and sf_t_rnf structures
332            IF(lwp) WRITE(numout,*)
333            IF(lwp) WRITE(numout,*) '          runoffs salinities read in a file'
334            ALLOCATE( sf_s_rnf(1), STAT=ierror  )
335            IF( ierror > 0 ) THEN
336               CALL ctl_stop( 'sbc_rnf_init: unable to allocate sf_s_rnf structure' )   ;   RETURN
337            ENDIF
338            ALLOCATE( sf_s_rnf(1)%fnow(jpi,jpj,1)   )
339            IF( sn_s_rnf%ln_tint ) ALLOCATE( sf_s_rnf(1)%fdta(jpi,jpj,1,2) )
340            CALL fld_fill (sf_s_rnf, (/ sn_s_rnf /), cn_dir, 'sbc_rnf_init', 'read runoff salinity data', 'namsbc_rnf' )
341         ENDIF
342         !
343         IF( ln_rnf_depth ) THEN                    ! depth of runoffs set from a file
344            IF(lwp) WRITE(numout,*)
345            IF(lwp) WRITE(numout,*) '          runoffs depth read in a file'
346            rn_dep_file = TRIM( cn_dir )//TRIM( sn_dep_rnf%clname )
347            IF( .NOT. sn_dep_rnf%ln_clim ) THEN   ;   WRITE(rn_dep_file, '(a,"_y",i4)' ) TRIM( rn_dep_file ), nyear    ! add year
348               IF( sn_dep_rnf%cltype == 'monthly' )   WRITE(rn_dep_file, '(a,"m",i2)'  ) TRIM( rn_dep_file ), nmonth   ! add month
349            ENDIF
350            CALL iom_open ( rn_dep_file, inum )                           ! open file
351            CALL iom_get  ( inum, jpdom_data, sn_dep_rnf%clvar, h_rnf )   ! read the river mouth array
352            CALL iom_close( inum )                                        ! close file
353            !
354            nk_rnf(:,:) = 0                               ! set the number of level over which river runoffs are applied
355            DO jj = 1, jpj
356               DO ji = 1, jpi
357                  IF( h_rnf(ji,jj) > 0._wp ) THEN
358                     jk = 2
359                     DO WHILE ( jk /= mbkt(ji,jj) .AND. gdept_0(ji,jj,jk) < h_rnf(ji,jj) ) ;  jk = jk + 1 ;  END DO
360                     nk_rnf(ji,jj) = jk
361                  ELSEIF( h_rnf(ji,jj) == -1._wp   ) THEN   ;  nk_rnf(ji,jj) = 1
362                  ELSEIF( h_rnf(ji,jj) == -999._wp ) THEN   ;  nk_rnf(ji,jj) = mbkt(ji,jj)
363                  ELSE
364                     CALL ctl_stop( 'sbc_rnf_init: runoff depth not positive, and not -999 or -1, rnf value in file fort.999'  )
365                     WRITE(999,*) 'ji, jj, h_rnf(ji,jj) :', ji, jj, h_rnf(ji,jj)
366                  ENDIF
367               END DO
368            END DO
369            DO jj = 1, jpj                                ! set the associated depth
370               DO ji = 1, jpi
371                  h_rnf(ji,jj) = 0._wp
372                  DO jk = 1, nk_rnf(ji,jj)
373                     h_rnf(ji,jj) = h_rnf(ji,jj) + fse3t(ji,jj,jk)
374                  END DO
375               END DO
376            END DO
377         ELSE                                       ! runoffs applied at the surface
378            nk_rnf(:,:) = 1
379            h_rnf (:,:) = fse3t(:,:,1)
380         ENDIF
381         !
382      ENDIF
383      !
384      rnf(:,:) =  0._wp                         ! runoff initialisation
385      rnf_tsc(:,:,:) = 0._wp                    ! runoffs temperature & salinty contents initilisation
386      !
387      !                                   ! ========================
388      !                                   !   River mouth vicinity
389      !                                   ! ========================
390      !
391      IF( ln_rnf_mouth ) THEN                   ! Specific treatment in vicinity of river mouths :
392         !                                      !    - Increase Kz in surface layers ( rn_hrnf > 0 )
393         !                                      !    - set to zero SSS damping (ln_ssr=T)
394         !                                      !    - mixed upstream-centered (ln_traadv_cen2=T)
395         !
396         IF ( ln_rnf_depth )   CALL ctl_warn( 'sbc_rnf_init: increased mixing turned on but effects may already',   &
397            &                                              'be spread through depth by ln_rnf_depth'               )
398         !
399         nkrnf = 0                                  ! Number of level over which Kz increase
400         IF( rn_hrnf > 0._wp ) THEN
401            nkrnf = 2
402            DO WHILE( nkrnf /= jpkm1 .AND. gdepw_1d(nkrnf+1) < rn_hrnf )   ;   nkrnf = nkrnf + 1   ;   END DO
403            IF( ln_sco )   CALL ctl_warn( 'sbc_rnf: number of levels over which Kz is increased is computed for zco...' )
404         ENDIF
405         IF(lwp) WRITE(numout,*)
406         IF(lwp) WRITE(numout,*) '          Specific treatment used in vicinity of river mouths :'
407         IF(lwp) WRITE(numout,*) '             - Increase Kz in surface layers (if rn_hrnf > 0 )'
408         IF(lwp) WRITE(numout,*) '               by ', rn_avt_rnf,' m2/s  over ', nkrnf, ' w-levels'
409         IF(lwp) WRITE(numout,*) '             - set to zero SSS damping       (if ln_ssr=T)'
410         IF(lwp) WRITE(numout,*) '             - mixed upstream-centered       (if ln_traadv_cen2=T)'
411         !
412         CALL rnf_mouth                             ! set river mouth mask
413         !
414      ELSE                                      ! No treatment at river mouths
415         IF(lwp) WRITE(numout,*)
416         IF(lwp) WRITE(numout,*) '          No specific treatment at river mouths'
417         rnfmsk  (:,:) = 0._wp
418         rnfmsk_z(:)   = 0._wp
419         nkrnf = 0
420      ENDIF
421      !
422   END SUBROUTINE sbc_rnf_init
423
424
425   SUBROUTINE rnf_mouth
426      !!----------------------------------------------------------------------
427      !!                  ***  ROUTINE rnf_mouth  ***
428      !!
429      !! ** Purpose :   define the river mouths mask
430      !!
431      !! ** Method  :   read the river mouth mask (=0/1) in the river runoff
432      !!                climatological file. Defined a given vertical structure.
433      !!                CAUTION, the vertical structure is hard coded on the
434      !!                first 5 levels.
435      !!                This fields can be used to:
436      !!                 - set an upstream advection scheme
437      !!                   (ln_rnf_mouth=T and ln_traadv_cen2=T)
438      !!                 - increase vertical on the top nn_krnf vertical levels
439      !!                   at river runoff input grid point (nn_krnf>=2, see step.F90)
440      !!                 - set to zero SSS restoring flux at river mouth grid points
441      !!
442      !! ** Action  :   rnfmsk   set to 1 at river runoff input, 0 elsewhere
443      !!                rnfmsk_z vertical structure
444      !!----------------------------------------------------------------------
445      INTEGER            ::   inum        ! temporary integers
446      CHARACTER(len=140) ::   cl_rnfile   ! runoff file name
447      !!----------------------------------------------------------------------
448      !
449      IF(lwp) WRITE(numout,*)
450      IF(lwp) WRITE(numout,*) 'rnf_mouth : river mouth mask'
451      IF(lwp) WRITE(numout,*) '~~~~~~~~~ '
452      !
453      cl_rnfile = TRIM( cn_dir )//TRIM( sn_cnf%clname )
454      IF( .NOT. sn_cnf%ln_clim ) THEN   ;   WRITE(cl_rnfile, '(a,"_y",i4)' ) TRIM( cl_rnfile ), nyear    ! add year
455         IF( sn_cnf%cltype == 'monthly' )   WRITE(cl_rnfile, '(a,"m",i2)'  ) TRIM( cl_rnfile ), nmonth   ! add month
456      ENDIF
457      !
458      ! horizontal mask (read in NetCDF file)
459      CALL iom_open ( cl_rnfile, inum )                           ! open file
460      CALL iom_get  ( inum, jpdom_data, sn_cnf%clvar, rnfmsk )    ! read the river mouth array
461      CALL iom_close( inum )                                      ! close file
462      !
463      IF( nn_closea == 1 )   CALL clo_rnf( rnfmsk )               ! closed sea inflow set as ruver mouth
464      !
465      rnfmsk_z(:)   = 0._wp                                       ! vertical structure
466      rnfmsk_z(1)   = 1.0
467      rnfmsk_z(2)   = 1.0                                         ! **********
468      rnfmsk_z(3)   = 0.5                                         ! HARD CODED on the 5 first levels
469      rnfmsk_z(4)   = 0.25                                        ! **********
470      rnfmsk_z(5)   = 0.125
471      !
472   END SUBROUTINE rnf_mouth
473
474   !!======================================================================
475END MODULE sbcrnf
Note: See TracBrowser for help on using the repository browser.