New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcssm.F90 in trunk/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

source: trunk/NEMOGCM/NEMO/OPA_SRC/SBC/sbcssm.F90 @ 3294

Last change on this file since 3294 was 3294, checked in by rblod, 12 years ago

Merge of 3.4beta into the trunk
  • Property svn:keywords set to Id
File size: 9.5 KB
Line 
1MODULE sbcssm
2   !!======================================================================
3   !!                       ***  MODULE  sbcssm  ***
4   !! Surface module :  provide time-mean ocean surface variables
5   !!======================================================================
6   !! History :  9.0  ! 2006-07  (G. Madec)  Original code
7   !!            3.3  ! 2010-10  (C. Bricaud, G. Madec)  add the Patm forcing for sea-ice
8   !!----------------------------------------------------------------------
9
10   !!----------------------------------------------------------------------
11   !!   sbc_ssm        : calculate sea surface mean currents, temperature, 
12   !!                    and salinity over nn_fsbc time-step
13   !!----------------------------------------------------------------------
14   USE oce             ! ocean dynamics and tracers
15   USE dom_oce         ! ocean space and time domain
16   USE sbc_oce         ! Surface boundary condition: ocean fields
17   USE sbc_oce         ! surface boundary condition: ocean fields
18   USE sbcapr          ! surface boundary condition: atmospheric pressure
19   USE prtctl          ! Print control                    (prt_ctl routine)
20   USE restart         ! ocean restart
21   USE iom
22   USE in_out_manager  ! I/O manager
23
24   IMPLICIT NONE
25   PRIVATE
26
27   PUBLIC   sbc_ssm    ! routine called by step.F90
28   
29   !! * Substitutions
30#  include "domzgr_substitute.h90"
31   !!----------------------------------------------------------------------
32   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
33   !! $Id$
34   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
35   !!----------------------------------------------------------------------
36CONTAINS
37
38   SUBROUTINE sbc_ssm( kt )
39      !!---------------------------------------------------------------------
40      !!                     ***  ROUTINE sbc_oce  ***
41      !!                     
42      !! ** Purpose :   provide ocean surface variable to sea-surface boundary
43      !!                condition computation
44      !!               
45      !! ** Method  :   compute mean surface velocity (2 components at U and
46      !!      V-points) [m/s], temperature [Celcius] and salinity [psu] over
47      !!      the periode (kt - nn_fsbc) to kt
48      !!         Note that the inverse barometer ssh (i.e. ssh associated with Patm)
49      !!      is add to ssh_m when ln_apr_dyn = T. Required for sea-ice dynamics.
50      !!---------------------------------------------------------------------
51      INTEGER, INTENT(in) ::   kt   ! ocean time step
52      !
53      REAL(wp) ::   zcoef, zf_sbc       ! local scalar
54      !!---------------------------------------------------------------------
55      !                                                   ! ---------------------------------------- !
56      IF( nn_fsbc == 1 ) THEN                             !      Instantaneous surface fields        !
57         !                                                ! ---------------------------------------- !
58         IF( kt == nit000 ) THEN
59            IF(lwp) WRITE(numout,*)
60            IF(lwp) WRITE(numout,*) 'sbc_ssm : sea surface mean fields, nn_fsbc=1 : instantaneous values'
61            IF(lwp) WRITE(numout,*) '~~~~~~~ '
62         ENDIF
63         !
64         ssu_m(:,:) = ub(:,:,1)
65         ssv_m(:,:) = vb(:,:,1)
66         sst_m(:,:) = tsn(:,:,1,jp_tem)
67         sss_m(:,:) = tsn(:,:,1,jp_sal)
68         !                          ! removed inverse barometer ssh when Patm forcing is used (for sea-ice dynamics)
69         IF( ln_apr_dyn ) THEN   ;   ssh_m(:,:) = sshn(:,:) - 0.5 * ( ssh_ib(:,:) + ssh_ibb(:,:) )
70         ELSE                    ;   ssh_m(:,:) = sshn(:,:)
71         ENDIF
72
73         !
74      ELSE
75         !                                                ! ---------------------------------------- !
76         IF( kt == nit000) THEN                           !       Initialisation: 1st time-step      !
77            !                                             ! ---------------------------------------- !
78            IF(lwp) WRITE(numout,*)
79            IF(lwp) WRITE(numout,*) 'sbc_ssm : sea surface mean fields'
80            !
81            IF( ln_rstart .AND. iom_varid( numror, 'nn_fsbc', ldstop = .FALSE. ) > 0 ) THEN
82               CALL iom_get( numror               , 'nn_fsbc', zf_sbc )   ! sbc frequency of previous run
83               CALL iom_get( numror, jpdom_autoglo, 'ssu_m'  , ssu_m  )   ! sea surface mean velocity    (T-point)
84               CALL iom_get( numror, jpdom_autoglo, 'ssv_m'  , ssv_m  )   !   "         "    velocity    (V-point)
85               CALL iom_get( numror, jpdom_autoglo, 'sst_m'  , sst_m  )   !   "         "    temperature (T-point)
86               CALL iom_get( numror, jpdom_autoglo, 'sss_m'  , sss_m  )   !   "         "    salinity    (T-point)
87               CALL iom_get( numror, jpdom_autoglo, 'ssh_m'  , ssh_m  )   !   "         "    height      (T-point)
88               !
89               IF( zf_sbc /= REAL( nn_fsbc, wp ) ) THEN      ! nn_fsbc has changed between 2 runs
90                  IF(lwp) WRITE(numout,*) '~~~~~~~   restart with a change in the frequency of mean ',   &
91                     &                    'from ', zf_sbc, ' to ', nn_fsbc
92                  zcoef = REAL( nn_fsbc - 1, wp ) / zf_sbc
93                  ssu_m(:,:) = zcoef * ssu_m(:,:)
94                  ssv_m(:,:) = zcoef * ssv_m(:,:)
95                  sst_m(:,:) = zcoef * sst_m(:,:)
96                  sss_m(:,:) = zcoef * sss_m(:,:)
97                  ssh_m(:,:) = zcoef * ssh_m(:,:)
98               ELSE
99                  IF(lwp) WRITE(numout,*) '~~~~~~~   mean fields read in the ocean restart file'
100               ENDIF
101            ELSE
102               IF(lwp) WRITE(numout,*) '~~~~~~~   mean fields initialised to instantaneous values'
103               zcoef = REAL( nn_fsbc - 1, wp )
104               ssu_m(:,:) = zcoef * ub(:,:,1)
105               ssv_m(:,:) = zcoef * vb(:,:,1)
106               sst_m(:,:) = zcoef * tsn(:,:,1,jp_tem)
107               sss_m(:,:) = zcoef * tsn(:,:,1,jp_sal)
108               !                          ! removed inverse barometer ssh when Patm forcing is used
109               IF( ln_apr_dyn ) THEN   ;   ssh_m(:,:) = zcoef * ( sshn(:,:) - 0.5 * ( ssh_ib(:,:) + ssh_ibb(:,:) ) )
110               ELSE                    ;   ssh_m(:,:) = zcoef *   sshn(:,:)
111               ENDIF
112
113            ENDIF
114            !                                             ! ---------------------------------------- !
115         ELSEIF( MOD( kt - 2 , nn_fsbc ) == 0 ) THEN      !   Initialisation: New mean computation   !
116            !                                             ! ---------------------------------------- !
117            ssu_m(:,:) = 0.e0      ! reset to zero ocean mean sbc fields
118            ssv_m(:,:) = 0.e0
119            sst_m(:,:) = 0.e0
120            sss_m(:,:) = 0.e0
121            ssh_m(:,:) = 0.e0
122         ENDIF
123         !                                                ! ---------------------------------------- !
124         !                                                !        Cumulate at each time step        !
125         !                                                ! ---------------------------------------- !
126         ssu_m(:,:) = ssu_m(:,:) + ub(:,:,1)
127         ssv_m(:,:) = ssv_m(:,:) + vb(:,:,1)
128         sst_m(:,:) = sst_m(:,:) + tsn(:,:,1,jp_tem)
129         sss_m(:,:) = sss_m(:,:) + tsn(:,:,1,jp_sal)
130         !                          ! removed inverse barometer ssh when Patm forcing is used (for sea-ice dynamics)
131         IF( ln_apr_dyn ) THEN   ;   ssh_m(:,:) = ssh_m(:,:) + sshn(:,:) - 0.5 *  ( ssh_ib(:,:) + ssh_ibb(:,:) )
132         ELSE                    ;   ssh_m(:,:) = ssh_m(:,:) + sshn(:,:)
133         ENDIF
134
135         !                                                ! ---------------------------------------- !
136         IF( MOD( kt - 1 , nn_fsbc ) == 0 ) THEN          !   Mean value at each nn_fsbc time-step   !
137            !                                             ! ---------------------------------------- !
138            zcoef = 1. / REAL( nn_fsbc, wp )
139            sst_m(:,:) = sst_m(:,:) * zcoef           ! mean SST             [Celcius]
140            sss_m(:,:) = sss_m(:,:) * zcoef           ! mean SSS             [psu]
141            ssu_m(:,:) = ssu_m(:,:) * zcoef           ! mean suface current  [m/s]
142            ssv_m(:,:) = ssv_m(:,:) * zcoef           !
143            ssh_m(:,:) = ssh_m(:,:) * zcoef           ! mean SSH             [m]
144            !
145         ENDIF
146         !                                                ! ---------------------------------------- !
147         IF( lrst_oce ) THEN                              !      Write in the ocean restart file     !
148            !                                             ! ---------------------------------------- !
149            IF(lwp) WRITE(numout,*)
150            IF(lwp) WRITE(numout,*) 'sbc_ssm : sea surface mean fields written in ocean restart file ',   &
151               &                    'at it= ', kt,' date= ', ndastp
152            IF(lwp) WRITE(numout,*) '~~~~~~~'
153            zf_sbc = REAL( nn_fsbc, wp )
154            CALL iom_rstput( kt, nitrst, numrow, 'nn_fsbc', zf_sbc )    ! sbc frequency
155            CALL iom_rstput( kt, nitrst, numrow, 'ssu_m'  , ssu_m  )    ! sea surface mean fields
156            CALL iom_rstput( kt, nitrst, numrow, 'ssv_m'  , ssv_m  )
157            CALL iom_rstput( kt, nitrst, numrow, 'sst_m'  , sst_m  )
158            CALL iom_rstput( kt, nitrst, numrow, 'sss_m'  , sss_m  )
159            CALL iom_rstput( kt, nitrst, numrow, 'ssh_m'  , ssh_m  )
160            !
161         ENDIF
162         !
163      ENDIF
164      !
165   END SUBROUTINE sbc_ssm
166
167   !!======================================================================
168END MODULE sbcssm
Note: See TracBrowser for help on using the repository browser.