New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcssm.F90 in trunk/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

source: trunk/NEMOGCM/NEMO/OPA_SRC/SBC/sbcssm.F90 @ 7698

Last change on this file since 7698 was 7698, checked in by mocavero, 7 years ago

update trunk with OpenMP parallelization

  • Property svn:keywords set to Id
File size: 17.4 KB
Line 
1MODULE sbcssm
2   !!======================================================================
3   !!                       ***  MODULE  sbcssm  ***
4   !! Surface module :  provide time-mean ocean surface variables
5   !!======================================================================
6   !! History :  9.0  ! 2006-07  (G. Madec)  Original code
7   !!            3.3  ! 2010-10  (C. Bricaud, G. Madec)  add the Patm forcing for sea-ice
8   !!            3.7  ! 2015-11  (G. Madec)  non linear free surface by default: e3t_m always computed
9   !!----------------------------------------------------------------------
10
11   !!----------------------------------------------------------------------
12   !!   sbc_ssm       : calculate sea surface mean currents, temperature, 
13   !!                   and salinity over nn_fsbc time-step
14   !!----------------------------------------------------------------------
15   USE oce            ! ocean dynamics and tracers
16   USE dom_oce        ! ocean space and time domain
17   USE sbc_oce        ! surface boundary condition: ocean fields
18   USE sbcapr         ! surface boundary condition: atmospheric pressure
19   USE eosbn2         ! equation of state and related derivatives
20   !
21   USE in_out_manager ! I/O manager
22   USE prtctl         ! Print control
23   USE iom            ! IOM library
24
25   IMPLICIT NONE
26   PRIVATE
27
28   PUBLIC   sbc_ssm        ! routine called by step.F90
29   PUBLIC   sbc_ssm_init   ! routine called by sbcmod.F90
30
31   LOGICAL, SAVE ::   l_ssm_mean = .FALSE.   ! keep track of whether means have been read from restart file
32   
33   !!----------------------------------------------------------------------
34   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
35   !! $Id$
36   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
37   !!----------------------------------------------------------------------
38CONTAINS
39
40   SUBROUTINE sbc_ssm( kt )
41      !!---------------------------------------------------------------------
42      !!                     ***  ROUTINE sbc_oce  ***
43      !!                     
44      !! ** Purpose :   provide ocean surface variable to sea-surface boundary
45      !!                condition computation
46      !!               
47      !! ** Method  :   compute mean surface velocity (2 components at U and
48      !!      V-points) [m/s], temperature [Celsius] and salinity [psu] over
49      !!      the periode (kt - nn_fsbc) to kt
50      !!         Note that the inverse barometer ssh (i.e. ssh associated with Patm)
51      !!      is add to ssh_m when ln_apr_dyn = T. Required for sea-ice dynamics.
52      !!---------------------------------------------------------------------
53      INTEGER, INTENT(in) ::   kt   ! ocean time step
54      !
55      INTEGER  ::   ji, jj               ! loop index
56      REAL(wp) ::   zcoef, zf_sbc       ! local scalar
57      REAL(wp), DIMENSION(jpi,jpj,jpts) :: zts
58      !!---------------------------------------------------------------------
59      !
60      !                                        !* surface T-, U-, V- ocean level variables (T, S, depth, velocity)
61!$OMP PARALLEL DO schedule(static) private(jj, ji)
62      DO jj = 1, jpj
63         DO ji = 1, jpi
64            zts(ji,jj,jp_tem) = tsn(ji,jj,mikt(ji,jj),jp_tem)
65            zts(ji,jj,jp_sal) = tsn(ji,jj,mikt(ji,jj),jp_sal)
66         END DO
67      END DO
68      !
69      IF( nn_fsbc == 1 ) THEN                             !   Instantaneous surface fields        !
70         !                                                ! ---------------------------------------- !
71!$OMP PARALLEL DO schedule(static) private(jj, ji)
72         DO jj = 1, jpj
73            DO ji = 1, jpi
74               ssu_m(ji,jj) = ub(ji,jj,1)
75               ssv_m(ji,jj) = vb(ji,jj,1)
76            END DO
77         END DO
78         IF( l_useCT )  THEN
79           sst_m(:,:) = eos_pt_from_ct( zts(:,:,jp_tem), zts(:,:,jp_sal) )
80         ELSE                   
81!$OMP PARALLEL DO schedule(static) private(jj, ji)
82            DO jj = 1, jpj
83               DO ji = 1, jpi
84                  sst_m(ji,jj) = zts(ji,jj,jp_tem)
85               END DO
86            END DO
87         ENDIF
88!$OMP PARALLEL DO schedule(static) private(jj, ji)
89         DO jj = 1, jpj
90            DO ji = 1, jpi
91               sss_m(ji,jj) = zts(ji,jj,jp_sal)
92            END DO
93         END DO
94         !                          ! removed inverse barometer ssh when Patm forcing is used (for sea-ice dynamics)
95         IF( ln_apr_dyn ) THEN 
96!$OMP PARALLEL DO schedule(static) private(jj, ji)
97            DO jj = 1, jpj
98               DO ji = 1, jpi
99                  ssh_m(ji,jj) = sshn(ji,jj) - 0.5 * ( ssh_ib(ji,jj) + ssh_ibb(ji,jj) )
100               END DO
101            END DO
102         ELSE                   
103!$OMP PARALLEL DO schedule(static) private(jj, ji)
104            DO jj = 1, jpj
105               DO ji = 1, jpi
106                  ssh_m(ji,jj) = sshn(ji,jj)
107               END DO
108            END DO
109         ENDIF
110         !
111!$OMP PARALLEL DO schedule(static) private(jj, ji)
112         DO jj = 1, jpj
113            DO ji = 1, jpi
114               e3t_m(ji,jj) = e3t_n(ji,jj,1)
115         !
116               frq_m(ji,jj) = fraqsr_1lev(ji,jj)
117            END DO
118         END DO
119         !
120      ELSE
121         !                                                ! ----------------------------------------------- !
122         IF( kt == nit000 .AND. .NOT. l_ssm_mean ) THEN   !   Initialisation: 1st time-step, no input means !
123            !                                             ! ----------------------------------------------- !
124            IF(lwp) WRITE(numout,*)
125            IF(lwp) WRITE(numout,*) 'sbc_ssm : mean fields initialised to instantaneous values'
126            IF(lwp) WRITE(numout,*) '~~~~~~~   '
127            zcoef = REAL( nn_fsbc - 1, wp )
128!$OMP PARALLEL DO schedule(static) private(jj, ji)
129            DO jj = 1, jpj
130               DO ji = 1, jpi
131                  ssu_m(ji,jj) = zcoef * ub(ji,jj,1)
132                  ssv_m(ji,jj) = zcoef * vb(ji,jj,1)
133               END DO
134            END DO
135            IF( l_useCT )  THEN
136              sst_m(:,:) = zcoef * eos_pt_from_ct( zts(:,:,jp_tem), zts(:,:,jp_sal) )
137            ELSE                   
138!$OMP PARALLEL DO schedule(static) private(jj, ji)
139              DO jj = 1, jpj
140                 DO ji = 1, jpi
141                    sst_m(ji,jj) = zcoef * zts(ji,jj,jp_tem)
142                 END DO
143              END DO
144            ENDIF
145!$OMP PARALLEL DO schedule(static) private(jj, ji)
146            DO jj = 1, jpj
147               DO ji = 1, jpi
148                  sss_m(ji,jj) = zcoef * zts(ji,jj,jp_sal)
149               END DO
150            END DO
151            !                          ! removed inverse barometer ssh when Patm forcing is used (for sea-ice dynamics)
152            IF( ln_apr_dyn ) THEN   
153!$OMP PARALLEL DO schedule(static) private(jj, ji)
154               DO jj = 1, jpj
155                  DO ji = 1, jpi
156                     ssh_m(ji,jj) = zcoef * ( sshn(ji,jj) - 0.5 * ( ssh_ib(ji,jj) + ssh_ibb(ji,jj) ) )
157                  END DO
158               END DO
159            ELSE                   
160!$OMP PARALLEL DO schedule(static) private(jj, ji)
161               DO jj = 1, jpj
162                  DO ji = 1, jpi
163                     ssh_m(ji,jj) = zcoef * sshn(ji,jj)
164                  END DO
165               END DO
166            ENDIF
167            !
168!$OMP PARALLEL DO schedule(static) private(jj, ji)
169            DO jj = 1, jpj
170               DO ji = 1, jpi
171                  e3t_m(ji,jj) = zcoef * e3t_n(ji,jj,1)
172                  !
173                  frq_m(ji,jj) = zcoef * fraqsr_1lev(ji,jj)
174               END DO
175            END DO
176            !                                             ! ---------------------------------------- !
177         ELSEIF( MOD( kt - 2 , nn_fsbc ) == 0 ) THEN      !   Initialisation: New mean computation   !
178            !                                             ! ---------------------------------------- !
179!$OMP PARALLEL DO schedule(static) private(jj, ji)
180            DO jj = 1, jpj
181               DO ji = 1, jpi
182                  ssu_m(ji,jj) = 0._wp     ! reset to zero ocean mean sbc fields
183                  ssv_m(ji,jj) = 0._wp
184                  sst_m(ji,jj) = 0._wp
185                  sss_m(ji,jj) = 0._wp
186                  ssh_m(ji,jj) = 0._wp
187                  e3t_m(ji,jj) = 0._wp
188                  frq_m(ji,jj) = 0._wp
189               END DO
190            END DO
191         ENDIF
192         !                                                ! ---------------------------------------- !
193         !                                                !        Cumulate at each time step        !
194         !                                                ! ---------------------------------------- !
195!$OMP PARALLEL DO schedule(static) private(jj, ji)
196         DO jj = 1, jpj
197            DO ji = 1, jpi
198               ssu_m(ji,jj) = ssu_m(ji,jj) + ub(ji,jj,1)
199               ssv_m(ji,jj) = ssv_m(ji,jj) + vb(ji,jj,1)
200            END DO
201         END DO
202         IF( l_useCT )  THEN   
203           sst_m(:,:) = sst_m(:,:) + eos_pt_from_ct( zts(:,:,jp_tem), zts(:,:,jp_sal) )
204         ELSE                   
205!$OMP PARALLEL DO schedule(static) private(jj, ji)
206           DO jj = 1, jpj
207              DO ji = 1, jpi
208                 sst_m(ji,jj) = sst_m(ji,jj) + zts(ji,jj,jp_tem)
209              END DO
210           END DO
211         ENDIF
212!$OMP PARALLEL DO schedule(static) private(jj, ji)
213         DO jj = 1, jpj
214            DO ji = 1, jpi
215               sss_m(ji,jj) = sss_m(ji,jj) + zts(ji,jj,jp_sal)
216            END DO
217         END DO
218         !                          ! removed inverse barometer ssh when Patm forcing is used (for sea-ice dynamics)
219         IF( ln_apr_dyn ) THEN   
220!$OMP PARALLEL DO schedule(static) private(jj, ji)
221            DO jj = 1, jpj
222               DO ji = 1, jpi
223                  ssh_m(ji,jj) = ssh_m(ji,jj) + sshn(ji,jj) - 0.5 * ( ssh_ib(ji,jj) + ssh_ibb(ji,jj) )
224               END DO
225            END DO
226         ELSE                   
227!$OMP PARALLEL DO schedule(static) private(jj, ji)
228           DO jj = 1, jpj
229              DO ji = 1, jpi
230                 ssh_m(ji,jj) = ssh_m(ji,jj) + sshn(ji,jj)
231              END DO
232           END DO
233         ENDIF
234         !
235!$OMP PARALLEL DO schedule(static) private(jj, ji)
236         DO jj = 1, jpj
237            DO ji = 1, jpi
238               e3t_m(ji,jj) = e3t_m(ji,jj) + e3t_n(ji,jj,1)
239               !
240               frq_m(ji,jj) = frq_m(ji,jj) + fraqsr_1lev(ji,jj)
241            END DO
242         END DO
243
244         !                                                ! ---------------------------------------- !
245         IF( MOD( kt - 1 , nn_fsbc ) == 0 ) THEN          !   Mean value at each nn_fsbc time-step   !
246            !                                             ! ---------------------------------------- !
247            zcoef = 1. / REAL( nn_fsbc, wp )
248!$OMP PARALLEL DO schedule(static) private(jj, ji)
249            DO jj = 1, jpj
250               DO ji = 1, jpi
251                  sst_m(ji,jj) = sst_m(ji,jj) * zcoef     ! mean SST             [Celsius]
252                  sss_m(ji,jj) = sss_m(ji,jj) * zcoef     ! mean SSS             [psu]
253                  ssu_m(ji,jj) = ssu_m(ji,jj) * zcoef     ! mean suface current  [m/s]
254                  ssv_m(ji,jj) = ssv_m(ji,jj) * zcoef     !
255                  ssh_m(ji,jj) = ssh_m(ji,jj) * zcoef     ! mean SSH             [m]
256                  e3t_m(ji,jj) = e3t_m(ji,jj) * zcoef     ! mean vertical scale factor [m]
257                  frq_m(ji,jj) = frq_m(ji,jj) * zcoef     ! mean fraction of solar net radiation absorbed in the 1st T level [-]
258               END DO
259            END DO
260            !
261         ENDIF
262         !                                                ! ---------------------------------------- !
263         IF( lrst_oce ) THEN                              !      Write in the ocean restart file     !
264            !                                             ! ---------------------------------------- !
265            IF(lwp) WRITE(numout,*)
266            IF(lwp) WRITE(numout,*) 'sbc_ssm : sea surface mean fields written in ocean restart file ',   &
267               &                    'at it= ', kt,' date= ', ndastp
268            IF(lwp) WRITE(numout,*) '~~~~~~~'
269            zf_sbc = REAL( nn_fsbc, wp )
270            CALL iom_rstput( kt, nitrst, numrow, 'nn_fsbc', zf_sbc )    ! sbc frequency
271            CALL iom_rstput( kt, nitrst, numrow, 'ssu_m'  , ssu_m  )    ! sea surface mean fields
272            CALL iom_rstput( kt, nitrst, numrow, 'ssv_m'  , ssv_m  )
273            CALL iom_rstput( kt, nitrst, numrow, 'sst_m'  , sst_m  )
274            CALL iom_rstput( kt, nitrst, numrow, 'sss_m'  , sss_m  )
275            CALL iom_rstput( kt, nitrst, numrow, 'ssh_m'  , ssh_m  )
276            CALL iom_rstput( kt, nitrst, numrow, 'e3t_m'  , e3t_m  )
277            CALL iom_rstput( kt, nitrst, numrow, 'frq_m'  , frq_m  )
278            !
279         ENDIF
280         !
281      ENDIF
282      !
283      IF( MOD( kt - 1 , nn_fsbc ) == 0 ) THEN          !   Mean value at each nn_fsbc time-step   !
284         CALL iom_put( 'ssu_m', ssu_m )
285         CALL iom_put( 'ssv_m', ssv_m )
286         CALL iom_put( 'sst_m', sst_m )
287         CALL iom_put( 'sss_m', sss_m )
288         CALL iom_put( 'ssh_m', ssh_m )
289         CALL iom_put( 'e3t_m', e3t_m )
290         CALL iom_put( 'frq_m', frq_m )
291      ENDIF
292      !
293   END SUBROUTINE sbc_ssm
294
295
296   SUBROUTINE sbc_ssm_init
297      !!----------------------------------------------------------------------
298      !!                  ***  ROUTINE sbc_ssm_init  ***
299      !!
300      !! ** Purpose :   Initialisation of the sbc data
301      !!
302      !! ** Action  : - read parameters
303      !!----------------------------------------------------------------------
304      REAL(wp) ::   zcoef, zf_sbc   ! local scalar
305      INTEGER  ::   ji, jj          ! loop index
306      !!----------------------------------------------------------------------
307      !
308      IF( nn_fsbc == 1 ) THEN
309         !
310         IF(lwp) WRITE(numout,*)
311         IF(lwp) WRITE(numout,*) 'sbc_ssm_init : sea surface mean fields, nn_fsbc=1 : instantaneous values'
312         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ '
313         !
314      ELSE
315         !               
316         IF(lwp) WRITE(numout,*)
317         IF(lwp) WRITE(numout,*) 'sbc_ssm_init : sea surface mean fields'
318         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~ '
319         !
320         IF( ln_rstart .AND. iom_varid( numror, 'nn_fsbc', ldstop = .FALSE. ) > 0 ) THEN
321            l_ssm_mean = .TRUE.
322            CALL iom_get( numror               , 'nn_fsbc', zf_sbc )    ! sbc frequency of previous run
323            CALL iom_get( numror, jpdom_autoglo, 'ssu_m'  , ssu_m  )    ! sea surface mean velocity    (U-point)
324            CALL iom_get( numror, jpdom_autoglo, 'ssv_m'  , ssv_m  )    !   "         "    velocity    (V-point)
325            CALL iom_get( numror, jpdom_autoglo, 'sst_m'  , sst_m  )    !   "         "    temperature (T-point)
326            CALL iom_get( numror, jpdom_autoglo, 'sss_m'  , sss_m  )    !   "         "    salinity    (T-point)
327            CALL iom_get( numror, jpdom_autoglo, 'ssh_m'  , ssh_m  )    !   "         "    height      (T-point)
328            CALL iom_get( numror, jpdom_autoglo, 'e3t_m'  , e3t_m  )    ! 1st level thickness          (T-point)
329            ! fraction of solar net radiation absorbed in 1st T level
330            IF( iom_varid( numror, 'frq_m', ldstop = .FALSE. ) > 0 ) THEN
331               CALL iom_get( numror, jpdom_autoglo, 'frq_m'  , frq_m  )
332            ELSE
333!$OMP PARALLEL DO schedule(static) private(jj, ji)
334               DO jj = 1, jpj
335                  DO ji = 1, jpi
336                     frq_m(ji,jj) = 1._wp   ! default definition
337                  END DO
338               END DO
339            ENDIF
340            !
341            IF( zf_sbc /= REAL( nn_fsbc, wp ) ) THEN      ! nn_fsbc has changed between 2 runs
342               IF(lwp) WRITE(numout,*) '   restart with a change in the frequency of mean from ', zf_sbc, ' to ', nn_fsbc 
343               zcoef = REAL( nn_fsbc - 1, wp ) / zf_sbc 
344!$OMP PARALLEL DO schedule(static) private(jj, ji)
345               DO jj = 1, jpj
346                  DO ji = 1, jpi
347                     ssu_m(ji,jj) = zcoef * ssu_m(ji,jj) 
348                     ssv_m(ji,jj) = zcoef * ssv_m(ji,jj)
349                     sst_m(ji,jj) = zcoef * sst_m(ji,jj)
350                     sss_m(ji,jj) = zcoef * sss_m(ji,jj)
351                     ssh_m(ji,jj) = zcoef * ssh_m(ji,jj)
352                     e3t_m(ji,jj) = zcoef * e3t_m(ji,jj)
353                     frq_m(ji,jj) = zcoef * frq_m(ji,jj)
354                  END DO
355               END DO
356            ELSE
357               IF(lwp) WRITE(numout,*) '   mean fields read in the ocean restart file'
358            ENDIF
359         ENDIF
360      ENDIF
361      !
362      IF( .NOT. l_ssm_mean ) THEN   ! default initialisation. needed by lim_istate
363         !
364         IF(lwp) WRITE(numout,*) '   default initialisation of ss._m arrays'
365!$OMP PARALLEL DO schedule(static) private(jj, ji)
366            DO jj = 1, jpj
367               DO ji = 1, jpi
368                  ssu_m(ji,jj) = ub(ji,jj,1)
369                  ssv_m(ji,jj) = vb(ji,jj,1)
370               END DO
371            END DO
372         IF( l_useCT )  THEN    ;   sst_m(:,:) = eos_pt_from_ct( tsn(:,:,1,jp_tem), tsn(:,:,1,jp_sal) )
373         ELSE                   ;   sst_m(:,:) = tsn(:,:,1,jp_tem)
374         ENDIF
375!$OMP PARALLEL DO schedule(static) private(jj, ji)
376         DO jj = 1, jpj
377            DO ji = 1, jpi
378               sss_m(ji,jj) = tsn  (ji,jj,1,jp_sal)
379               ssh_m(ji,jj) = sshn (ji,jj)
380               e3t_m(ji,jj) = e3t_n(ji,jj,1)
381               frq_m(ji,jj) = 1._wp
382            END DO
383         END DO
384         !
385      ENDIF
386      !
387   END SUBROUTINE sbc_ssm_init
388
389   !!======================================================================
390END MODULE sbcssm
Note: See TracBrowser for help on using the repository browser.