New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv_mus.F90 in trunk/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: trunk/NEMOGCM/NEMO/OPA_SRC/TRA/traadv_mus.F90 @ 7698

Last change on this file since 7698 was 7698, checked in by mocavero, 7 years ago

update trunk with OpenMP parallelization

  • Property svn:keywords set to Id
File size: 17.5 KB
Line 
1MODULE traadv_mus
2   !!======================================================================
3   !!                       ***  MODULE  traadv_mus  ***
4   !! Ocean  tracers:  horizontal & vertical advective trend
5   !!======================================================================
6   !! History :       !  2000-06  (A.Estublier)  for passive tracers
7   !!                 !  2001-08  (E.Durand, G.Madec)  adapted for T & S
8   !!   NEMO     1.0  !  2002-06  (G. Madec)  F90: Free form and module
9   !!            3.2  !  2010-05  (C. Ethe, G. Madec)  merge TRC-TRA + switch from velocity to transport
10   !!            3.4  !  2012-06  (P. Oddo, M. Vichi) include the upstream where needed
11   !!            3.7  !  2015-09  (G. Madec) add the ice-shelf cavities boundary condition
12   !!----------------------------------------------------------------------
13
14   !!----------------------------------------------------------------------
15   !!   tra_adv_mus   : update the tracer trend with the horizontal
16   !!                   and vertical advection trends using MUSCL scheme
17   !!----------------------------------------------------------------------
18   USE oce            ! ocean dynamics and active tracers
19   USE trc_oce        ! share passive tracers/Ocean variables
20   USE dom_oce        ! ocean space and time domain
21   USE trd_oce        ! trends: ocean variables
22   USE trdtra         ! tracers trends manager
23   USE sbcrnf         ! river runoffs
24   USE diaptr         ! poleward transport diagnostics
25   USE diaar5         ! AR5 diagnostics
26
27   !
28   USE iom
29   USE wrk_nemo       ! Memory Allocation
30   USE timing         ! Timing
31   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
32   USE in_out_manager ! I/O manager
33   USE lib_mpp        ! distribued memory computing
34   USE lbclnk         ! ocean lateral boundary condition (or mpp link)
35
36   IMPLICIT NONE
37   PRIVATE
38
39   PUBLIC   tra_adv_mus   ! routine called by traadv.F90
40   
41   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   upsmsk   !: mixed upstream/centered scheme near some straits
42   !                                                           !  and in closed seas (orca 2 and 1 configurations)
43   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   xind     !: mixed upstream/centered index
44   
45   LOGICAL  ::   l_trd   ! flag to compute trends
46   LOGICAL  ::   l_ptr   ! flag to compute poleward transport
47   LOGICAL  ::   l_hst   ! flag to compute heat/salt transport
48
49   !! * Substitutions
50#  include "vectopt_loop_substitute.h90"
51   !!----------------------------------------------------------------------
52   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
53   !! $Id$
54   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
55   !!----------------------------------------------------------------------
56CONTAINS
57
58   SUBROUTINE tra_adv_mus( kt, kit000, cdtype, p2dt, pun, pvn, pwn,             &
59      &                                              ptb, pta, kjpt, ld_msc_ups )
60      !!----------------------------------------------------------------------
61      !!                    ***  ROUTINE tra_adv_mus  ***
62      !!
63      !! ** Purpose :   Compute the now trend due to total advection of tracers
64      !!              using a MUSCL scheme (Monotone Upstream-centered Scheme for
65      !!              Conservation Laws) and add it to the general tracer trend.
66      !!
67      !! ** Method  : MUSCL scheme plus centered scheme at ocean boundaries
68      !!              ld_msc_ups=T :
69      !!
70      !! ** Action : - update pta  with the now advective tracer trends
71      !!             - send trends to trdtra module for further diagnostcs (l_trdtra=T)
72      !!             - htr_adv, str_adv : poleward advective heat and salt transport (ln_diaptr=T)
73      !!
74      !! References : Estubier, A., and M. Levy, Notes Techn. Pole de Modelisation
75      !!              IPSL, Sept. 2000 (http://www.lodyc.jussieu.fr/opa)
76      !!----------------------------------------------------------------------
77      INTEGER                              , INTENT(in   ) ::   kt              ! ocean time-step index
78      INTEGER                              , INTENT(in   ) ::   kit000          ! first time step index
79      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
80      INTEGER                              , INTENT(in   ) ::   kjpt            ! number of tracers
81      LOGICAL                              , INTENT(in   ) ::   ld_msc_ups      ! use upstream scheme within muscl
82      REAL(wp)                             , INTENT(in   ) ::   p2dt            ! tracer time-step
83      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ) ::   pun, pvn, pwn   ! 3 ocean velocity components
84      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb             ! before tracer field
85      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta             ! tracer trend
86      !
87      INTEGER  ::   ji, jj, jk, jn       ! dummy loop indices
88      INTEGER  ::   ierr                 ! local integer
89      REAL(wp) ::   zu, z0u, zzwx, zw    ! local scalars
90      REAL(wp) ::   zv, z0v, zzwy, z0w   !   -      -
91      REAL(wp) ::   zalpha               !   -      -
92      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zslpx, zslpy   ! 3D workspace
93      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zwx  , zwy     ! -      -
94      !!----------------------------------------------------------------------
95      !
96      IF( nn_timing == 1 )  CALL timing_start('tra_adv_mus')
97      !
98      CALL wrk_alloc( jpi,jpj,jpk,   zslpx, zslpy, zwx, zwy )
99      !
100      IF( kt == kit000 )  THEN
101         IF(lwp) WRITE(numout,*)
102         IF(lwp) WRITE(numout,*) 'tra_adv : MUSCL advection scheme on ', cdtype
103         IF(lwp) WRITE(numout,*) '        : mixed up-stream           ', ld_msc_ups
104         IF(lwp) WRITE(numout,*) '~~~~~~~'
105         IF(lwp) WRITE(numout,*)
106         !
107         ! Upstream / MUSCL scheme indicator
108         !
109         ALLOCATE( xind(jpi,jpj,jpk), STAT=ierr )
110!$OMP PARALLEL DO schedule(static) private(jk, jj, ji)
111         DO jk = 1, jpk
112            DO jj = 1, jpj
113               DO ji = 1, jpi
114                  xind(ji,jj,jk) = 1._wp              ! set equal to 1 where up-stream is not needed
115               END DO
116            END DO
117         END DO
118         !
119         IF( ld_msc_ups ) THEN            ! define the upstream indicator (if asked)
120            ALLOCATE( upsmsk(jpi,jpj), STAT=ierr )
121!$OMP PARALLEL
122!$OMP DO schedule(static) private(jj, ji)
123            DO jj = 1, jpj
124               DO ji = 1, jpi
125                  upsmsk(ji,jj) = 0._wp                             ! not upstream by default
126               END DO
127            END DO
128            !
129!$OMP DO schedule(static) private(jk,jj,ji)
130            DO jk = 1, jpkm1
131               DO jj = 1, jpj
132                  DO ji = 1, jpi
133                     xind(ji,jj,jk) = 1._wp                              &                   ! =>1 where up-stream is not needed
134                        &         - MAX ( rnfmsk(ji,jj) * rnfmsk_z(jk),  &                   ! =>0 near runoff mouths (& closed sea outflows)
135                        &                 upsmsk(ji,jj)                ) * tmask(ji,jj,jk)   ! =>0 in some user defined area
136                  END DO
137               END DO
138            END DO
139!$OMP END DO NOWAIT
140!$OMP END PARALLEL
141         ENDIF 
142         !
143      ENDIF 
144      !     
145      l_trd = .FALSE.
146      l_hst = .FALSE.
147      l_ptr = .FALSE.
148      IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR. ( cdtype == 'TRC' .AND. l_trdtrc ) )      l_trd = .TRUE.
149      IF(   cdtype == 'TRA' .AND. ln_diaptr )                                               l_ptr = .TRUE. 
150      IF(   cdtype == 'TRA' .AND. ( iom_use("uadv_heattr") .OR. iom_use("vadv_heattr") .OR. &
151         &                          iom_use("uadv_salttr") .OR. iom_use("vadv_salttr")  ) ) l_hst = .TRUE.
152      !
153      DO jn = 1, kjpt            !==  loop over the tracers  ==!
154         !
155         !                          !* Horizontal advective fluxes
156         !
157         !                                !-- first guess of the slopes
158!$OMP PARALLEL
159!$OMP DO schedule(static) private(jj, ji)
160         DO jj = 1, jpj
161            DO ji = 1, jpi
162               zwx(ji,jj,jpk) = 0._wp           ! bottom values
163               zwy(ji,jj,jpk) = 0._wp
164            END DO
165         END DO
166!$OMP DO schedule(static) private(jk, jj, ji)
167         DO jk = 1, jpkm1                       ! interior values
168            DO jj = 1, jpjm1     
169               DO ji = 1, fs_jpim1   ! vector opt.
170                  zwx(ji,jj,jk) = umask(ji,jj,jk) * ( ptb(ji+1,jj,jk,jn) - ptb(ji,jj,jk,jn) )
171                  zwy(ji,jj,jk) = vmask(ji,jj,jk) * ( ptb(ji,jj+1,jk,jn) - ptb(ji,jj,jk,jn) )
172               END DO
173           END DO
174         END DO
175!$OMP END DO NOWAIT
176!$OMP END PARALLEL
177         CALL lbc_lnk( zwx, 'U', -1. )          ! lateral boundary conditions   (changed sign)
178         CALL lbc_lnk( zwy, 'V', -1. )
179         !                                !-- Slopes of tracer
180!$OMP PARALLEL
181!$OMP DO schedule(static) private(jj, ji)
182         DO jj = 1, jpj
183            DO ji = 1, jpi
184               zslpx(ji,jj,jpk) = 0._wp                 ! bottom values
185               zslpy(ji,jj,jpk) = 0._wp
186            END DO
187         END DO
188!$OMP DO schedule(static) private(jk, jj, ji)
189         DO jk = 1, jpkm1                       ! interior values
190            DO jj = 2, jpj
191               DO ji = fs_2, jpi   ! vector opt.
192                  zslpx(ji,jj,jk) =                    ( zwx(ji,jj,jk) + zwx(ji-1,jj  ,jk) )   &
193                     &            * ( 0.25 + SIGN( 0.25, zwx(ji,jj,jk) * zwx(ji-1,jj  ,jk) ) )
194                  zslpy(ji,jj,jk) =                    ( zwy(ji,jj,jk) + zwy(ji  ,jj-1,jk) )   &
195                     &            * ( 0.25 + SIGN( 0.25, zwy(ji,jj,jk) * zwy(ji  ,jj-1,jk) ) )
196               END DO
197            END DO
198         END DO
199         !
200!$OMP DO schedule(static) private(jk, jj, ji)
201         DO jk = 1, jpkm1                 !-- Slopes limitation
202            DO jj = 2, jpj
203               DO ji = fs_2, jpi   ! vector opt.
204                  zslpx(ji,jj,jk) = SIGN( 1., zslpx(ji,jj,jk) ) * MIN(    ABS( zslpx(ji  ,jj,jk) ),   &
205                     &                                                 2.*ABS( zwx  (ji-1,jj,jk) ),   &
206                     &                                                 2.*ABS( zwx  (ji  ,jj,jk) ) )
207                  zslpy(ji,jj,jk) = SIGN( 1., zslpy(ji,jj,jk) ) * MIN(    ABS( zslpy(ji,jj  ,jk) ),   &
208                     &                                                 2.*ABS( zwy  (ji,jj-1,jk) ),   &
209                     &                                                 2.*ABS( zwy  (ji,jj  ,jk) ) )
210               END DO
211           END DO
212         END DO
213         !
214!$OMP DO schedule(static) private(jk, jj, ji, z0u, zalpha, zu, zv, zzwx, zzwy, z0v)
215         DO jk = 1, jpkm1                 !-- MUSCL horizontal advective fluxes
216            DO jj = 2, jpjm1
217               DO ji = fs_2, fs_jpim1   ! vector opt.
218                  ! MUSCL fluxes
219                  z0u = SIGN( 0.5, pun(ji,jj,jk) )
220                  zalpha = 0.5 - z0u
221                  zu  = z0u - 0.5 * pun(ji,jj,jk) * p2dt * r1_e1e2u(ji,jj) / e3u_n(ji,jj,jk)
222                  zzwx = ptb(ji+1,jj,jk,jn) + xind(ji,jj,jk) * zu * zslpx(ji+1,jj,jk)
223                  zzwy = ptb(ji  ,jj,jk,jn) + xind(ji,jj,jk) * zu * zslpx(ji  ,jj,jk)
224                  zwx(ji,jj,jk) = pun(ji,jj,jk) * ( zalpha * zzwx + (1.-zalpha) * zzwy )
225                  !
226                  z0v = SIGN( 0.5, pvn(ji,jj,jk) )
227                  zalpha = 0.5 - z0v
228                  zv  = z0v - 0.5 * pvn(ji,jj,jk) * p2dt * r1_e1e2v(ji,jj) / e3v_n(ji,jj,jk)
229                  zzwx = ptb(ji,jj+1,jk,jn) + xind(ji,jj,jk) * zv * zslpy(ji,jj+1,jk)
230                  zzwy = ptb(ji,jj  ,jk,jn) + xind(ji,jj,jk) * zv * zslpy(ji,jj  ,jk)
231                  zwy(ji,jj,jk) = pvn(ji,jj,jk) * ( zalpha * zzwx + (1.-zalpha) * zzwy )
232               END DO
233            END DO
234         END DO
235!$OMP END DO NOWAIT
236!$OMP END PARALLEL
237         CALL lbc_lnk( zwx, 'U', -1. )   ;   CALL lbc_lnk( zwy, 'V', -1. )   ! lateral boundary conditions   (changed sign)
238         !
239!$OMP PARALLEL DO schedule(static) private(jk, jj, ji)
240         DO jk = 1, jpkm1                 !-- Tracer advective trend
241            DO jj = 2, jpjm1     
242               DO ji = fs_2, fs_jpim1   ! vector opt.
243                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) - ( zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )       &
244                  &                                     + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  ) )     &
245                  &                                   * r1_e1e2t(ji,jj) / e3t_n(ji,jj,jk)
246               END DO
247           END DO
248         END DO       
249         !                                ! trend diagnostics
250         IF( l_trd )  THEN
251            CALL trd_tra( kt, cdtype, jn, jptra_xad, zwx, pun, ptb(:,:,:,jn) )
252            CALL trd_tra( kt, cdtype, jn, jptra_yad, zwy, pvn, ptb(:,:,:,jn) )
253         END IF
254         !                                 ! "Poleward" heat and salt transports
255         IF( l_ptr )  CALL dia_ptr_hst( jn, 'adv', zwy(:,:,:) )
256         !                                 !  heat transport
257         IF( l_hst )  CALL dia_ar5_hst( jn, 'adv', zwx(:,:,:), zwy(:,:,:) )
258         !
259         !                          !* Vertical advective fluxes
260         !
261         !                                !-- first guess of the slopes
262!$OMP PARALLEL
263!$OMP DO schedule(static) private(jj, ji)
264         DO jj = 1, jpj
265            DO ji = 1, jpi
266               zwx(ji,jj, 1 ) = 0._wp           ! surface & bottom boundary conditions
267               zwx(ji,jj,jpk) = 0._wp
268           END DO
269         END DO
270!$OMP DO schedule(static) private(jk, jj, ji)
271         DO jk = 2, jpkm1                       ! interior values
272            DO jj = 1, jpj
273               DO ji = 1, jpi
274                  zwx(ji,jj,jk) = tmask(ji,jj,jk) * ( ptb(ji,jj,jk-1,jn) - ptb(ji,jj,jk,jn) )
275              END DO
276            END DO
277         END DO
278         !                                !-- Slopes of tracer
279!$OMP END DO NOWAIT
280!$OMP DO schedule(static) private(jj, ji)
281         DO jj = 1, jpj
282            DO ji = 1, jpi
283               zslpx(ji,jj,1) = 0._wp                   ! surface values
284           END DO
285         END DO
286!$OMP DO schedule(static) private(jk, jj, ji)
287         DO jk = 2, jpkm1                       ! interior value
288            DO jj = 1, jpj
289               DO ji = 1, jpi
290                  zslpx(ji,jj,jk) =                     ( zwx(ji,jj,jk) + zwx(ji,jj,jk+1) )  &
291                     &            * (  0.25 + SIGN( 0.25, zwx(ji,jj,jk) * zwx(ji,jj,jk+1) )  )
292               END DO
293            END DO
294         END DO
295!$OMP DO schedule(static) private(jk, jj, ji)
296         DO jk = 2, jpkm1                 !-- Slopes limitation
297            DO jj = 1, jpj                      ! interior values
298               DO ji = 1, jpi
299                  zslpx(ji,jj,jk) = SIGN( 1., zslpx(ji,jj,jk) ) * MIN(    ABS( zslpx(ji,jj,jk  ) ),   &
300                     &                                                 2.*ABS( zwx  (ji,jj,jk+1) ),   &
301                     &                                                 2.*ABS( zwx  (ji,jj,jk  ) )  )
302               END DO
303            END DO
304         END DO
305!$OMP DO schedule(static) private(jk, jj, ji, z0w, zalpha, zw, zzwx, zzwy)
306         DO jk = 1, jpk-2                 !-- vertical advective flux
307            DO jj = 2, jpjm1     
308               DO ji = fs_2, fs_jpim1   ! vector opt.
309                  z0w = SIGN( 0.5, pwn(ji,jj,jk+1) )
310                  zalpha = 0.5 + z0w
311                  zw  = z0w - 0.5 * pwn(ji,jj,jk+1) * p2dt * r1_e1e2t(ji,jj) / e3w_n(ji,jj,jk+1)
312                  zzwx = ptb(ji,jj,jk+1,jn) + xind(ji,jj,jk) * zw * zslpx(ji,jj,jk+1)
313                  zzwy = ptb(ji,jj,jk  ,jn) + xind(ji,jj,jk) * zw * zslpx(ji,jj,jk  )
314                  zwx(ji,jj,jk+1) = pwn(ji,jj,jk+1) * ( zalpha * zzwx + (1.-zalpha) * zzwy ) * wmask(ji,jj,jk)
315               END DO
316            END DO
317         END DO
318!$OMP END DO NOWAIT
319!$OMP END PARALLEL
320         IF( ln_linssh ) THEN                   ! top values, linear free surface only
321            IF( ln_isfcav ) THEN                      ! ice-shelf cavities (top of the ocean)
322!$OMP PARALLEL DO schedule(static) private(jj, ji)
323               DO jj = 1, jpj
324                  DO ji = 1, jpi
325                     zwx(ji,jj, mikt(ji,jj) ) = pwn(ji,jj,mikt(ji,jj)) * ptb(ji,jj,mikt(ji,jj),jn)
326                  END DO
327               END DO   
328            ELSE                                      ! no cavities: only at the ocean surface
329!$OMP PARALLEL DO schedule(static) private(jj, ji)
330               DO jj = 1, jpj
331                  DO ji = 1, jpi
332                     zwx(ji,jj,1) = pwn(ji,jj,1) * ptb(ji,jj,1,jn)
333                  END DO
334               END DO
335            ENDIF
336         ENDIF
337         !
338!$OMP PARALLEL DO schedule(static) private(jk, jj, ji)
339         DO jk = 1, jpkm1                 !-- vertical advective trend
340            DO jj = 2, jpjm1     
341               DO ji = fs_2, fs_jpim1   ! vector opt.
342                  pta(ji,jj,jk,jn) =  pta(ji,jj,jk,jn) - ( zwx(ji,jj,jk) - zwx(ji,jj,jk+1) ) * r1_e1e2t(ji,jj) / e3t_n(ji,jj,jk)
343               END DO
344            END DO
345         END DO
346         !                                ! send trends for diagnostic
347         IF( l_trd )  CALL trd_tra( kt, cdtype, jn, jptra_zad, zwx, pwn, ptb(:,:,:,jn) )
348         !
349      END DO                     ! end of tracer loop
350      !
351      CALL wrk_dealloc( jpi,jpj,jpk,   zslpx, zslpy, zwx, zwy )
352      !
353      IF( nn_timing == 1 )  CALL timing_stop('tra_adv_mus')
354      !
355   END SUBROUTINE tra_adv_mus
356
357   !!======================================================================
358END MODULE traadv_mus
Note: See TracBrowser for help on using the repository browser.