| 1 | MODULE traqsr |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE traqsr *** |
|---|
| 4 | !! Ocean physics: solar radiation penetration in the top ocean levels |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : OPA ! 1990-10 (B. Blanke) Original code |
|---|
| 7 | !! 7.0 ! 1991-11 (G. Madec) |
|---|
| 8 | !! ! 1996-01 (G. Madec) s-coordinates |
|---|
| 9 | !! NEMO 1.0 ! 2002-06 (G. Madec) F90: Free form and module |
|---|
| 10 | !! - ! 2005-11 (G. Madec) zco, zps, sco coordinate |
|---|
| 11 | !! 3.2 ! 2009-04 (G. Madec & NEMO team) |
|---|
| 12 | !! 4.0 ! 2012-05 (C. Rousset) store attenuation coef for use in ice model |
|---|
| 13 | !!---------------------------------------------------------------------- |
|---|
| 14 | |
|---|
| 15 | !!---------------------------------------------------------------------- |
|---|
| 16 | !! tra_qsr : trend due to the solar radiation penetration |
|---|
| 17 | !! tra_qsr_init : solar radiation penetration initialization |
|---|
| 18 | !!---------------------------------------------------------------------- |
|---|
| 19 | USE oce ! ocean dynamics and active tracers |
|---|
| 20 | USE dom_oce ! ocean space and time domain |
|---|
| 21 | USE sbc_oce ! surface boundary condition: ocean |
|---|
| 22 | USE trc_oce ! share SMS/Ocean variables |
|---|
| 23 | USE trdmod_oce ! ocean variables trends |
|---|
| 24 | USE trdtra ! ocean active tracers trends |
|---|
| 25 | USE in_out_manager ! I/O manager |
|---|
| 26 | USE phycst ! physical constants |
|---|
| 27 | USE prtctl ! Print control |
|---|
| 28 | USE iom ! I/O manager |
|---|
| 29 | USE fldread ! read input fields |
|---|
| 30 | USE restart ! ocean restart |
|---|
| 31 | USE lib_mpp ! MPP library |
|---|
| 32 | USE wrk_nemo ! Memory Allocation |
|---|
| 33 | USE timing ! Timing |
|---|
| 34 | USE sbc_ice, ONLY : lk_lim3 |
|---|
| 35 | |
|---|
| 36 | IMPLICIT NONE |
|---|
| 37 | PRIVATE |
|---|
| 38 | |
|---|
| 39 | PUBLIC tra_qsr ! routine called by step.F90 (ln_traqsr=T) |
|---|
| 40 | PUBLIC tra_qsr_init ! routine called by opa.F90 |
|---|
| 41 | |
|---|
| 42 | ! !!* Namelist namtra_qsr: penetrative solar radiation |
|---|
| 43 | LOGICAL , PUBLIC :: ln_traqsr !: light absorption (qsr) flag |
|---|
| 44 | LOGICAL , PUBLIC :: ln_qsr_rgb !: Red-Green-Blue light absorption flag |
|---|
| 45 | LOGICAL , PUBLIC :: ln_qsr_2bd !: 2 band light absorption flag |
|---|
| 46 | LOGICAL , PUBLIC :: ln_qsr_bio !: bio-model light absorption flag |
|---|
| 47 | LOGICAL , PUBLIC :: ln_qsr_ice !: light penetration for ice-model LIM3 (clem) |
|---|
| 48 | INTEGER , PUBLIC :: nn_chldta !: use Chlorophyll data (=1) or not (=0) |
|---|
| 49 | REAL(wp), PUBLIC :: rn_abs !: fraction absorbed in the very near surface (RGB & 2 bands) |
|---|
| 50 | REAL(wp), PUBLIC :: rn_si0 !: very near surface depth of extinction (RGB & 2 bands) |
|---|
| 51 | REAL(wp), PUBLIC :: rn_si1 !: deepest depth of extinction (water type I) (2 bands) |
|---|
| 52 | |
|---|
| 53 | ! Module variables |
|---|
| 54 | REAL(wp) :: xsi0r !: inverse of rn_si0 |
|---|
| 55 | REAL(wp) :: xsi1r !: inverse of rn_si1 |
|---|
| 56 | TYPE(FLD), ALLOCATABLE, DIMENSION(:) :: sf_chl ! structure of input Chl (file informations, fields read) |
|---|
| 57 | INTEGER, PUBLIC :: nksr ! levels below which the light cannot penetrate ( depth larger than 391 m) |
|---|
| 58 | REAL(wp), DIMENSION(3,61) :: rkrgb !: tabulated attenuation coefficients for RGB absorption |
|---|
| 59 | |
|---|
| 60 | !! * Substitutions |
|---|
| 61 | # include "domzgr_substitute.h90" |
|---|
| 62 | # include "vectopt_loop_substitute.h90" |
|---|
| 63 | !!---------------------------------------------------------------------- |
|---|
| 64 | !! NEMO/OPA 3.3 , NEMO Consortium (2010) |
|---|
| 65 | !! $Id$ |
|---|
| 66 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 67 | !!---------------------------------------------------------------------- |
|---|
| 68 | CONTAINS |
|---|
| 69 | |
|---|
| 70 | SUBROUTINE tra_qsr( kt ) |
|---|
| 71 | !!---------------------------------------------------------------------- |
|---|
| 72 | !! *** ROUTINE tra_qsr *** |
|---|
| 73 | !! |
|---|
| 74 | !! ** Purpose : Compute the temperature trend due to the solar radiation |
|---|
| 75 | !! penetration and add it to the general temperature trend. |
|---|
| 76 | !! |
|---|
| 77 | !! ** Method : The profile of the solar radiation within the ocean is defined |
|---|
| 78 | !! through 2 wavebands (rn_si0,rn_si1) or 3 wavebands (RGB) and a ratio rn_abs |
|---|
| 79 | !! Considering the 2 wavebands case: |
|---|
| 80 | !! I(k) = Qsr*( rn_abs*EXP(z(k)/rn_si0) + (1.-rn_abs)*EXP(z(k)/rn_si1) ) |
|---|
| 81 | !! The temperature trend associated with the solar radiation penetration |
|---|
| 82 | !! is given by : zta = 1/e3t dk[ I ] / (rau0*Cp) |
|---|
| 83 | !! At the bottom, boudary condition for the radiation is no flux : |
|---|
| 84 | !! all heat which has not been absorbed in the above levels is put |
|---|
| 85 | !! in the last ocean level. |
|---|
| 86 | !! In z-coordinate case, the computation is only done down to the |
|---|
| 87 | !! level where I(k) < 1.e-15 W/m2. In addition, the coefficients |
|---|
| 88 | !! used for the computation are calculated one for once as they |
|---|
| 89 | !! depends on k only. |
|---|
| 90 | !! |
|---|
| 91 | !! ** Action : - update ta with the penetrative solar radiation trend |
|---|
| 92 | !! - save the trend in ttrd ('key_trdtra') |
|---|
| 93 | !! |
|---|
| 94 | !! Reference : Jerlov, N. G., 1968 Optical Oceanography, Elsevier, 194pp. |
|---|
| 95 | !! Lengaigne et al. 2007, Clim. Dyn., V28, 5, 503-516. |
|---|
| 96 | !!---------------------------------------------------------------------- |
|---|
| 97 | ! |
|---|
| 98 | INTEGER, INTENT(in) :: kt ! ocean time-step |
|---|
| 99 | ! |
|---|
| 100 | INTEGER :: ji, jj, jk ! dummy loop indices |
|---|
| 101 | INTEGER :: irgb ! local integers |
|---|
| 102 | REAL(wp) :: zchl, zcoef, zfact ! local scalars |
|---|
| 103 | REAL(wp) :: zc0, zc1, zc2, zc3 ! - - |
|---|
| 104 | REAL(wp) :: zzc0, zzc1, zzc2, zzc3 ! - - |
|---|
| 105 | REAL(wp) :: zz0, zz1, z1_e3t ! - - |
|---|
| 106 | REAL(wp), POINTER, DIMENSION(:,: ) :: zekb, zekg, zekr |
|---|
| 107 | REAL(wp), POINTER, DIMENSION(:,:,:) :: ze0, ze1, ze2, ze3, zea, ztrdt |
|---|
| 108 | !!---------------------------------------------------------------------- |
|---|
| 109 | ! |
|---|
| 110 | IF( nn_timing == 1 ) CALL timing_start('tra_qsr') |
|---|
| 111 | ! |
|---|
| 112 | CALL wrk_alloc( jpi, jpj, zekb, zekg, zekr ) |
|---|
| 113 | CALL wrk_alloc( jpi, jpj, jpk, ze0, ze1, ze2, ze3, zea ) |
|---|
| 114 | ! |
|---|
| 115 | IF( kt == nit000 ) THEN |
|---|
| 116 | IF(lwp) WRITE(numout,*) |
|---|
| 117 | IF(lwp) WRITE(numout,*) 'tra_qsr : penetration of the surface solar radiation' |
|---|
| 118 | IF(lwp) WRITE(numout,*) '~~~~~~~' |
|---|
| 119 | IF( .NOT.ln_traqsr ) RETURN |
|---|
| 120 | ENDIF |
|---|
| 121 | |
|---|
| 122 | IF( l_trdtra ) THEN ! Save ta and sa trends |
|---|
| 123 | CALL wrk_alloc( jpi, jpj, jpk, ztrdt ) |
|---|
| 124 | ztrdt(:,:,:) = tsa(:,:,:,jp_tem) |
|---|
| 125 | ENDIF |
|---|
| 126 | |
|---|
| 127 | ! Set before qsr tracer content field |
|---|
| 128 | ! *********************************** |
|---|
| 129 | IF( kt == nit000 ) THEN ! Set the forcing field at nit000 - 1 |
|---|
| 130 | ! ! ----------------------------------- |
|---|
| 131 | qsr_hc(:,:,:) = 0.e0 |
|---|
| 132 | ! |
|---|
| 133 | IF( ln_rstart .AND. & ! Restart: read in restart file |
|---|
| 134 | & iom_varid( numror, 'qsr_hc_b', ldstop = .FALSE. ) > 0 ) THEN |
|---|
| 135 | IF(lwp) WRITE(numout,*) ' nit000-1 qsr tracer content forcing field red in the restart file' |
|---|
| 136 | zfact = 0.5e0 |
|---|
| 137 | CALL iom_get( numror, jpdom_autoglo, 'qsr_hc_b', qsr_hc_b ) ! before heat content trend due to Qsr flux |
|---|
| 138 | ELSE ! No restart or restart not found: Euler forward time stepping |
|---|
| 139 | zfact = 1.e0 |
|---|
| 140 | qsr_hc_b(:,:,:) = 0.e0 |
|---|
| 141 | ENDIF |
|---|
| 142 | ELSE ! Swap of forcing field |
|---|
| 143 | ! ! --------------------- |
|---|
| 144 | zfact = 0.5e0 |
|---|
| 145 | qsr_hc_b(:,:,:) = qsr_hc(:,:,:) |
|---|
| 146 | ENDIF |
|---|
| 147 | ! Compute now qsr tracer content field |
|---|
| 148 | ! ************************************ |
|---|
| 149 | |
|---|
| 150 | ! ! ============================================== ! |
|---|
| 151 | IF( lk_qsr_bio .AND. ln_qsr_bio ) THEN ! bio-model fluxes : all vertical coordinates ! |
|---|
| 152 | ! ! ============================================== ! |
|---|
| 153 | DO jk = 1, jpkm1 |
|---|
| 154 | qsr_hc(:,:,jk) = r1_rau0_rcp * ( etot3(:,:,jk) - etot3(:,:,jk+1) ) |
|---|
| 155 | END DO |
|---|
| 156 | ! Add to the general trend |
|---|
| 157 | DO jk = 1, jpkm1 |
|---|
| 158 | DO jj = 2, jpjm1 |
|---|
| 159 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 160 | z1_e3t = zfact / fse3t(ji,jj,jk) |
|---|
| 161 | tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem) + ( qsr_hc_b(ji,jj,jk) + qsr_hc(ji,jj,jk) ) * z1_e3t |
|---|
| 162 | END DO |
|---|
| 163 | END DO |
|---|
| 164 | END DO |
|---|
| 165 | CALL iom_put( 'qsr3d', etot3 ) ! Shortwave Radiation 3D distribution |
|---|
| 166 | ! clem: store attenuation coefficient of the first ocean level |
|---|
| 167 | IF ( lk_lim3 .AND. ln_qsr_ice ) THEN |
|---|
| 168 | DO jj = 1, jpj |
|---|
| 169 | DO ji = 1, jpi |
|---|
| 170 | IF ( qsr(ji,jj) /= 0._wp ) THEN |
|---|
| 171 | oatte(ji,jj) = ( qsr_hc(ji,jj,1) / ( r1_rau0_rcp * qsr(ji,jj) ) ) |
|---|
| 172 | iatte(ji,jj) = oatte(ji,jj) |
|---|
| 173 | ENDIF |
|---|
| 174 | END DO |
|---|
| 175 | END DO |
|---|
| 176 | ENDIF |
|---|
| 177 | ! ! ============================================== ! |
|---|
| 178 | ELSE ! Ocean alone : |
|---|
| 179 | ! ! ============================================== ! |
|---|
| 180 | ! |
|---|
| 181 | ! ! ------------------------- ! |
|---|
| 182 | IF( ln_qsr_rgb) THEN ! R-G-B light penetration ! |
|---|
| 183 | ! ! ------------------------- ! |
|---|
| 184 | ! Set chlorophyl concentration |
|---|
| 185 | IF( nn_chldta == 1 .OR. lk_vvl ) THEN !* Variable Chlorophyll or ocean volume |
|---|
| 186 | ! |
|---|
| 187 | IF( nn_chldta == 1 ) THEN !* Variable Chlorophyll |
|---|
| 188 | ! |
|---|
| 189 | CALL fld_read( kt, 1, sf_chl ) ! Read Chl data and provides it at the current time step |
|---|
| 190 | ! |
|---|
| 191 | !CDIR COLLAPSE |
|---|
| 192 | !CDIR NOVERRCHK |
|---|
| 193 | DO jj = 1, jpj ! Separation in R-G-B depending of the surface Chl |
|---|
| 194 | !CDIR NOVERRCHK |
|---|
| 195 | DO ji = 1, jpi |
|---|
| 196 | zchl = MIN( 10. , MAX( 0.03, sf_chl(1)%fnow(ji,jj,1) ) ) |
|---|
| 197 | irgb = NINT( 41 + 20.*LOG10(zchl) + 1.e-15 ) |
|---|
| 198 | zekb(ji,jj) = rkrgb(1,irgb) |
|---|
| 199 | zekg(ji,jj) = rkrgb(2,irgb) |
|---|
| 200 | zekr(ji,jj) = rkrgb(3,irgb) |
|---|
| 201 | END DO |
|---|
| 202 | END DO |
|---|
| 203 | ELSE ! Variable ocean volume but constant chrlorophyll |
|---|
| 204 | zchl = 0.05 ! constant chlorophyll |
|---|
| 205 | irgb = NINT( 41 + 20.*LOG10( zchl ) + 1.e-15 ) |
|---|
| 206 | zekb(:,:) = rkrgb(1,irgb) ! Separation in R-G-B depending of the chlorophyll |
|---|
| 207 | zekg(:,:) = rkrgb(2,irgb) |
|---|
| 208 | zekr(:,:) = rkrgb(3,irgb) |
|---|
| 209 | ENDIF |
|---|
| 210 | ! |
|---|
| 211 | zcoef = ( 1. - rn_abs ) / 3.e0 ! equi-partition in R-G-B |
|---|
| 212 | ze0(:,:,1) = rn_abs * qsr(:,:) |
|---|
| 213 | ze1(:,:,1) = zcoef * qsr(:,:) |
|---|
| 214 | ze2(:,:,1) = zcoef * qsr(:,:) |
|---|
| 215 | ze3(:,:,1) = zcoef * qsr(:,:) |
|---|
| 216 | zea(:,:,1) = qsr(:,:) |
|---|
| 217 | ! |
|---|
| 218 | DO jk = 2, nksr+1 |
|---|
| 219 | !CDIR NOVERRCHK |
|---|
| 220 | DO jj = 1, jpj |
|---|
| 221 | !CDIR NOVERRCHK |
|---|
| 222 | DO ji = 1, jpi |
|---|
| 223 | zc0 = ze0(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * xsi0r ) |
|---|
| 224 | zc1 = ze1(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekb(ji,jj) ) |
|---|
| 225 | zc2 = ze2(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekg(ji,jj) ) |
|---|
| 226 | zc3 = ze3(ji,jj,jk-1) * EXP( - fse3t(ji,jj,jk-1) * zekr(ji,jj) ) |
|---|
| 227 | ze0(ji,jj,jk) = zc0 |
|---|
| 228 | ze1(ji,jj,jk) = zc1 |
|---|
| 229 | ze2(ji,jj,jk) = zc2 |
|---|
| 230 | ze3(ji,jj,jk) = zc3 |
|---|
| 231 | zea(ji,jj,jk) = ( zc0 + zc1 + zc2 + zc3 ) * tmask(ji,jj,jk) |
|---|
| 232 | END DO |
|---|
| 233 | END DO |
|---|
| 234 | END DO |
|---|
| 235 | ! clem: store attenuation coefficient of the first ocean level |
|---|
| 236 | IF ( lk_lim3 .AND. ln_qsr_ice ) THEN |
|---|
| 237 | DO jj = 1, jpj |
|---|
| 238 | DO ji = 1, jpi |
|---|
| 239 | zzc0 = rn_abs * EXP( - fse3t(ji,jj,1) * xsi0r ) |
|---|
| 240 | zzc1 = zcoef * EXP( - fse3t(ji,jj,1) * zekb(ji,jj) ) |
|---|
| 241 | zzc2 = zcoef * EXP( - fse3t(ji,jj,1) * zekg(ji,jj) ) |
|---|
| 242 | zzc3 = zcoef * EXP( - fse3t(ji,jj,1) * zekr(ji,jj) ) |
|---|
| 243 | oatte(ji,jj) = 1.0 - ( zzc0 + zzc1 + zzc2 + zzc3 ) * tmask(ji,jj,2) |
|---|
| 244 | iatte(ji,jj) = 1.0 - ( zzc0 + zzc1 + zcoef + zcoef ) * tmask(ji,jj,2) |
|---|
| 245 | END DO |
|---|
| 246 | END DO |
|---|
| 247 | ENDIF |
|---|
| 248 | ! |
|---|
| 249 | DO jk = 1, nksr ! compute and add qsr trend to ta |
|---|
| 250 | qsr_hc(:,:,jk) = r1_rau0_rcp * ( zea(:,:,jk) - zea(:,:,jk+1) ) |
|---|
| 251 | END DO |
|---|
| 252 | zea(:,:,nksr+1:jpk) = 0.e0 ! below 400m set to zero |
|---|
| 253 | CALL iom_put( 'qsr3d', zea ) ! Shortwave Radiation 3D distribution |
|---|
| 254 | ! |
|---|
| 255 | ELSE !* Constant Chlorophyll |
|---|
| 256 | DO jk = 1, nksr |
|---|
| 257 | qsr_hc(:,:,jk) = etot3(:,:,jk) * qsr(:,:) |
|---|
| 258 | END DO |
|---|
| 259 | ! clem: store attenuation coefficient of the first ocean level |
|---|
| 260 | IF ( lk_lim3 .AND. ln_qsr_ice ) THEN |
|---|
| 261 | oatte(:,:) = etot3(:,:,1) / r1_rau0_rcp |
|---|
| 262 | iatte(:,:) = oatte(:,:) |
|---|
| 263 | ENDIF |
|---|
| 264 | ENDIF |
|---|
| 265 | |
|---|
| 266 | ENDIF |
|---|
| 267 | ! ! ------------------------- ! |
|---|
| 268 | IF( ln_qsr_2bd ) THEN ! 2 band light penetration ! |
|---|
| 269 | ! ! ------------------------- ! |
|---|
| 270 | ! |
|---|
| 271 | IF( lk_vvl ) THEN !* variable volume |
|---|
| 272 | zz0 = rn_abs * r1_rau0_rcp |
|---|
| 273 | zz1 = ( 1. - rn_abs ) * r1_rau0_rcp |
|---|
| 274 | DO jk = 1, nksr ! solar heat absorbed at T-point in the top 400m |
|---|
| 275 | DO jj = 1, jpj |
|---|
| 276 | DO ji = 1, jpi |
|---|
| 277 | zc0 = zz0 * EXP( -fsdepw(ji,jj,jk )*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,jk )*xsi1r ) |
|---|
| 278 | zc1 = zz0 * EXP( -fsdepw(ji,jj,jk+1)*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,jk+1)*xsi1r ) |
|---|
| 279 | qsr_hc(ji,jj,jk) = qsr(ji,jj) * ( zc0*tmask(ji,jj,jk) - zc1*tmask(ji,jj,jk+1) ) |
|---|
| 280 | END DO |
|---|
| 281 | END DO |
|---|
| 282 | END DO |
|---|
| 283 | ! clem: store attenuation coefficient of the first ocean level |
|---|
| 284 | IF ( lk_lim3 .AND. ln_qsr_ice ) THEN |
|---|
| 285 | DO jj = 1, jpj |
|---|
| 286 | DO ji = 1, jpi |
|---|
| 287 | zc0 = zz0 * EXP( -fsdepw(ji,jj,1)*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,1)*xsi1r ) |
|---|
| 288 | zc1 = zz0 * EXP( -fsdepw(ji,jj,2)*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,2)*xsi1r ) |
|---|
| 289 | oatte(ji,jj) = ( zc0*tmask(ji,jj,1) - zc1*tmask(ji,jj,2) ) / r1_rau0_rcp |
|---|
| 290 | iatte(ji,jj) = oatte(ji,jj) |
|---|
| 291 | END DO |
|---|
| 292 | END DO |
|---|
| 293 | ENDIF |
|---|
| 294 | ELSE !* constant volume: coef. computed one for all |
|---|
| 295 | DO jk = 1, nksr |
|---|
| 296 | DO jj = 2, jpjm1 |
|---|
| 297 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 298 | qsr_hc(ji,jj,jk) = etot3(ji,jj,jk) * qsr(ji,jj) |
|---|
| 299 | END DO |
|---|
| 300 | END DO |
|---|
| 301 | END DO |
|---|
| 302 | ! clem: store attenuation coefficient of the first ocean level |
|---|
| 303 | IF ( lk_lim3 .AND. ln_qsr_ice ) THEN |
|---|
| 304 | oatte(:,:) = etot3(:,:,1) / r1_rau0_rcp |
|---|
| 305 | iatte(:,:) = oatte(:,:) |
|---|
| 306 | ENDIF |
|---|
| 307 | ! |
|---|
| 308 | ENDIF |
|---|
| 309 | ! |
|---|
| 310 | ENDIF |
|---|
| 311 | ! |
|---|
| 312 | ! Add to the general trend |
|---|
| 313 | DO jk = 1, nksr |
|---|
| 314 | DO jj = 2, jpjm1 |
|---|
| 315 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 316 | z1_e3t = zfact / fse3t(ji,jj,jk) |
|---|
| 317 | tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem) + ( qsr_hc_b(ji,jj,jk) + qsr_hc(ji,jj,jk) ) * z1_e3t |
|---|
| 318 | END DO |
|---|
| 319 | END DO |
|---|
| 320 | END DO |
|---|
| 321 | ! |
|---|
| 322 | ENDIF |
|---|
| 323 | ! |
|---|
| 324 | IF( lrst_oce ) THEN ! Write in the ocean restart file |
|---|
| 325 | ! ******************************* |
|---|
| 326 | IF(lwp) WRITE(numout,*) |
|---|
| 327 | IF(lwp) WRITE(numout,*) 'qsr tracer content forcing field written in ocean restart file ', & |
|---|
| 328 | & 'at it= ', kt,' date= ', ndastp |
|---|
| 329 | IF(lwp) WRITE(numout,*) '~~~~' |
|---|
| 330 | CALL iom_rstput( kt, nitrst, numrow, 'qsr_hc_b', qsr_hc ) |
|---|
| 331 | ! |
|---|
| 332 | ENDIF |
|---|
| 333 | |
|---|
| 334 | IF( l_trdtra ) THEN ! qsr tracers trends saved for diagnostics |
|---|
| 335 | ztrdt(:,:,:) = tsa(:,:,:,jp_tem) - ztrdt(:,:,:) |
|---|
| 336 | CALL trd_tra( kt, 'TRA', jp_tem, jptra_trd_qsr, ztrdt ) |
|---|
| 337 | CALL wrk_dealloc( jpi, jpj, jpk, ztrdt ) |
|---|
| 338 | ENDIF |
|---|
| 339 | ! ! print mean trends (used for debugging) |
|---|
| 340 | IF(ln_ctl) CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' qsr - Ta: ', mask1=tmask, clinfo3='tra-ta' ) |
|---|
| 341 | ! |
|---|
| 342 | CALL wrk_dealloc( jpi, jpj, zekb, zekg, zekr ) |
|---|
| 343 | CALL wrk_dealloc( jpi, jpj, jpk, ze0, ze1, ze2, ze3, zea ) |
|---|
| 344 | ! |
|---|
| 345 | IF( nn_timing == 1 ) CALL timing_stop('tra_qsr') |
|---|
| 346 | ! |
|---|
| 347 | END SUBROUTINE tra_qsr |
|---|
| 348 | |
|---|
| 349 | |
|---|
| 350 | SUBROUTINE tra_qsr_init |
|---|
| 351 | !!---------------------------------------------------------------------- |
|---|
| 352 | !! *** ROUTINE tra_qsr_init *** |
|---|
| 353 | !! |
|---|
| 354 | !! ** Purpose : Initialization for the penetrative solar radiation |
|---|
| 355 | !! |
|---|
| 356 | !! ** Method : The profile of solar radiation within the ocean is set |
|---|
| 357 | !! from two length scale of penetration (rn_si0,rn_si1) and a ratio |
|---|
| 358 | !! (rn_abs). These parameters are read in the namtra_qsr namelist. The |
|---|
| 359 | !! default values correspond to clear water (type I in Jerlov' |
|---|
| 360 | !! (1968) classification. |
|---|
| 361 | !! called by tra_qsr at the first timestep (nit000) |
|---|
| 362 | !! |
|---|
| 363 | !! ** Action : - initialize rn_si0, rn_si1 and rn_abs |
|---|
| 364 | !! |
|---|
| 365 | !! Reference : Jerlov, N. G., 1968 Optical Oceanography, Elsevier, 194pp. |
|---|
| 366 | !!---------------------------------------------------------------------- |
|---|
| 367 | ! |
|---|
| 368 | INTEGER :: ji, jj, jk ! dummy loop indices |
|---|
| 369 | INTEGER :: irgb, ierror, ioptio, nqsr ! local integer |
|---|
| 370 | INTEGER :: ios ! Local integer output status for namelist read |
|---|
| 371 | REAL(wp) :: zz0, zc0 , zc1, zcoef ! local scalars |
|---|
| 372 | REAL(wp) :: zz1, zc2 , zc3, zchl ! - - |
|---|
| 373 | REAL(wp), POINTER, DIMENSION(:,: ) :: zekb, zekg, zekr |
|---|
| 374 | REAL(wp), POINTER, DIMENSION(:,:,:) :: ze0, ze1, ze2, ze3, zea |
|---|
| 375 | ! |
|---|
| 376 | CHARACTER(len=100) :: cn_dir ! Root directory for location of ssr files |
|---|
| 377 | TYPE(FLD_N) :: sn_chl ! informations about the chlorofyl field to be read |
|---|
| 378 | !! |
|---|
| 379 | NAMELIST/namtra_qsr/ sn_chl, cn_dir, ln_traqsr, ln_qsr_rgb, ln_qsr_2bd, ln_qsr_bio, ln_qsr_ice, & |
|---|
| 380 | & nn_chldta, rn_abs, rn_si0, rn_si1 |
|---|
| 381 | !!---------------------------------------------------------------------- |
|---|
| 382 | |
|---|
| 383 | ! |
|---|
| 384 | IF( nn_timing == 1 ) CALL timing_start('tra_qsr_init') |
|---|
| 385 | ! |
|---|
| 386 | ! clem init for oatte and iatte |
|---|
| 387 | IF( .NOT. ln_rstart ) THEN |
|---|
| 388 | oatte(:,:) = 1._wp |
|---|
| 389 | iatte(:,:) = 1._wp |
|---|
| 390 | ENDIF |
|---|
| 391 | ! |
|---|
| 392 | CALL wrk_alloc( jpi, jpj, zekb, zekg, zekr ) |
|---|
| 393 | CALL wrk_alloc( jpi, jpj, jpk, ze0, ze1, ze2, ze3, zea ) |
|---|
| 394 | ! |
|---|
| 395 | |
|---|
| 396 | REWIND( numnam_ref ) ! Namelist namtra_qsr in reference namelist : Ratio and length of penetration |
|---|
| 397 | READ ( numnam_ref, namtra_qsr, IOSTAT = ios, ERR = 901) |
|---|
| 398 | 901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtra_qsr in reference namelist', lwp ) |
|---|
| 399 | |
|---|
| 400 | REWIND( numnam_cfg ) ! Namelist namtra_qsr in configuration namelist : Ratio and length of penetration |
|---|
| 401 | READ ( numnam_cfg, namtra_qsr, IOSTAT = ios, ERR = 902 ) |
|---|
| 402 | 902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtra_qsr in configuration namelist', lwp ) |
|---|
| 403 | IF(lwm) WRITE ( numond, namtra_qsr ) |
|---|
| 404 | ! |
|---|
| 405 | IF(lwp) THEN ! control print |
|---|
| 406 | WRITE(numout,*) |
|---|
| 407 | WRITE(numout,*) 'tra_qsr_init : penetration of the surface solar radiation' |
|---|
| 408 | WRITE(numout,*) '~~~~~~~~~~~~' |
|---|
| 409 | WRITE(numout,*) ' Namelist namtra_qsr : set the parameter of penetration' |
|---|
| 410 | WRITE(numout,*) ' Light penetration (T) or not (F) ln_traqsr = ', ln_traqsr |
|---|
| 411 | WRITE(numout,*) ' RGB (Red-Green-Blue) light penetration ln_qsr_rgb = ', ln_qsr_rgb |
|---|
| 412 | WRITE(numout,*) ' 2 band light penetration ln_qsr_2bd = ', ln_qsr_2bd |
|---|
| 413 | WRITE(numout,*) ' bio-model light penetration ln_qsr_bio = ', ln_qsr_bio |
|---|
| 414 | WRITE(numout,*) ' light penetration for ice-model LIM3 ln_qsr_ice = ', ln_qsr_ice |
|---|
| 415 | WRITE(numout,*) ' RGB : Chl data (=1) or cst value (=0) nn_chldta = ', nn_chldta |
|---|
| 416 | WRITE(numout,*) ' RGB & 2 bands: fraction of light (rn_si1) rn_abs = ', rn_abs |
|---|
| 417 | WRITE(numout,*) ' RGB & 2 bands: shortess depth of extinction rn_si0 = ', rn_si0 |
|---|
| 418 | WRITE(numout,*) ' 2 bands: longest depth of extinction rn_si1 = ', rn_si1 |
|---|
| 419 | WRITE(numout,*) ' light penetration for ice-model LIM3 ln_qsr_ice = ', ln_qsr_ice |
|---|
| 420 | ENDIF |
|---|
| 421 | |
|---|
| 422 | IF( ln_traqsr ) THEN ! control consistency |
|---|
| 423 | ! |
|---|
| 424 | IF( .NOT.lk_qsr_bio .AND. ln_qsr_bio ) THEN |
|---|
| 425 | CALL ctl_warn( 'No bio model : force ln_qsr_bio = FALSE ' ) |
|---|
| 426 | ln_qsr_bio = .FALSE. |
|---|
| 427 | ENDIF |
|---|
| 428 | ! |
|---|
| 429 | ioptio = 0 ! Parameter control |
|---|
| 430 | IF( ln_qsr_rgb ) ioptio = ioptio + 1 |
|---|
| 431 | IF( ln_qsr_2bd ) ioptio = ioptio + 1 |
|---|
| 432 | IF( ln_qsr_bio ) ioptio = ioptio + 1 |
|---|
| 433 | ! |
|---|
| 434 | IF( ioptio /= 1 ) & |
|---|
| 435 | CALL ctl_stop( ' Choose ONE type of light penetration in namelist namtra_qsr', & |
|---|
| 436 | & ' 2 bands, 3 RGB bands or bio-model light penetration' ) |
|---|
| 437 | ! |
|---|
| 438 | IF( ln_qsr_rgb .AND. nn_chldta == 0 ) nqsr = 1 |
|---|
| 439 | IF( ln_qsr_rgb .AND. nn_chldta == 1 ) nqsr = 2 |
|---|
| 440 | IF( ln_qsr_2bd ) nqsr = 3 |
|---|
| 441 | IF( ln_qsr_bio ) nqsr = 4 |
|---|
| 442 | ! |
|---|
| 443 | IF(lwp) THEN ! Print the choice |
|---|
| 444 | WRITE(numout,*) |
|---|
| 445 | IF( nqsr == 1 ) WRITE(numout,*) ' R-G-B light penetration - Constant Chlorophyll' |
|---|
| 446 | IF( nqsr == 2 ) WRITE(numout,*) ' R-G-B light penetration - Chl data ' |
|---|
| 447 | IF( nqsr == 3 ) WRITE(numout,*) ' 2 bands light penetration' |
|---|
| 448 | IF( nqsr == 4 ) WRITE(numout,*) ' bio-model light penetration' |
|---|
| 449 | ENDIF |
|---|
| 450 | ! |
|---|
| 451 | ENDIF |
|---|
| 452 | ! ! ===================================== ! |
|---|
| 453 | IF( ln_traqsr ) THEN ! Initialisation of Light Penetration ! |
|---|
| 454 | ! ! ===================================== ! |
|---|
| 455 | ! |
|---|
| 456 | xsi0r = 1.e0 / rn_si0 |
|---|
| 457 | xsi1r = 1.e0 / rn_si1 |
|---|
| 458 | ! ! ---------------------------------- ! |
|---|
| 459 | IF( ln_qsr_rgb ) THEN ! Red-Green-Blue light penetration ! |
|---|
| 460 | ! ! ---------------------------------- ! |
|---|
| 461 | ! |
|---|
| 462 | CALL trc_oce_rgb( rkrgb ) !* tabulated attenuation coef. |
|---|
| 463 | ! |
|---|
| 464 | ! !* level of light extinction |
|---|
| 465 | IF( ln_sco ) THEN ; nksr = jpkm1 |
|---|
| 466 | ELSE ; nksr = trc_oce_ext_lev( r_si2, 0.33e2 ) |
|---|
| 467 | ENDIF |
|---|
| 468 | |
|---|
| 469 | IF(lwp) WRITE(numout,*) ' level of light extinction = ', nksr, ' ref depth = ', gdepw_1d(nksr+1), ' m' |
|---|
| 470 | ! |
|---|
| 471 | IF( nn_chldta == 1 ) THEN !* Chl data : set sf_chl structure |
|---|
| 472 | IF(lwp) WRITE(numout,*) |
|---|
| 473 | IF(lwp) WRITE(numout,*) ' Chlorophyll read in a file' |
|---|
| 474 | ALLOCATE( sf_chl(1), STAT=ierror ) |
|---|
| 475 | IF( ierror > 0 ) THEN |
|---|
| 476 | CALL ctl_stop( 'tra_qsr_init: unable to allocate sf_chl structure' ) ; RETURN |
|---|
| 477 | ENDIF |
|---|
| 478 | ALLOCATE( sf_chl(1)%fnow(jpi,jpj,1) ) |
|---|
| 479 | IF( sn_chl%ln_tint )ALLOCATE( sf_chl(1)%fdta(jpi,jpj,1,2) ) |
|---|
| 480 | ! ! fill sf_chl with sn_chl and control print |
|---|
| 481 | CALL fld_fill( sf_chl, (/ sn_chl /), cn_dir, 'tra_qsr_init', & |
|---|
| 482 | & 'Solar penetration function of read chlorophyll', 'namtra_qsr' ) |
|---|
| 483 | ! |
|---|
| 484 | ELSE !* constant Chl : compute once for all the distribution of light (etot3) |
|---|
| 485 | IF(lwp) WRITE(numout,*) |
|---|
| 486 | IF(lwp) WRITE(numout,*) ' Constant Chlorophyll concentration = 0.05' |
|---|
| 487 | IF( lk_vvl ) THEN ! variable volume |
|---|
| 488 | IF(lwp) WRITE(numout,*) ' key_vvl: light distribution will be computed at each time step' |
|---|
| 489 | ELSE ! constant volume: computes one for all |
|---|
| 490 | IF(lwp) WRITE(numout,*) ' fixed volume: light distribution computed one for all' |
|---|
| 491 | ! |
|---|
| 492 | zchl = 0.05 ! constant chlorophyll |
|---|
| 493 | irgb = NINT( 41 + 20.*LOG10(zchl) + 1.e-15 ) |
|---|
| 494 | zekb(:,:) = rkrgb(1,irgb) ! Separation in R-G-B depending of the chlorophyll |
|---|
| 495 | zekg(:,:) = rkrgb(2,irgb) |
|---|
| 496 | zekr(:,:) = rkrgb(3,irgb) |
|---|
| 497 | ! |
|---|
| 498 | zcoef = ( 1. - rn_abs ) / 3.e0 ! equi-partition in R-G-B |
|---|
| 499 | ze0(:,:,1) = rn_abs |
|---|
| 500 | ze1(:,:,1) = zcoef |
|---|
| 501 | ze2(:,:,1) = zcoef |
|---|
| 502 | ze3(:,:,1) = zcoef |
|---|
| 503 | zea(:,:,1) = tmask(:,:,1) ! = ( ze0+ze1+z2+ze3 ) * tmask |
|---|
| 504 | |
|---|
| 505 | DO jk = 2, nksr+1 |
|---|
| 506 | !CDIR NOVERRCHK |
|---|
| 507 | DO jj = 1, jpj |
|---|
| 508 | !CDIR NOVERRCHK |
|---|
| 509 | DO ji = 1, jpi |
|---|
| 510 | zc0 = ze0(ji,jj,jk-1) * EXP( - e3t_0(ji,jj,jk-1) * xsi0r ) |
|---|
| 511 | zc1 = ze1(ji,jj,jk-1) * EXP( - e3t_0(ji,jj,jk-1) * zekb(ji,jj) ) |
|---|
| 512 | zc2 = ze2(ji,jj,jk-1) * EXP( - e3t_0(ji,jj,jk-1) * zekg(ji,jj) ) |
|---|
| 513 | zc3 = ze3(ji,jj,jk-1) * EXP( - e3t_0(ji,jj,jk-1) * zekr(ji,jj) ) |
|---|
| 514 | ze0(ji,jj,jk) = zc0 |
|---|
| 515 | ze1(ji,jj,jk) = zc1 |
|---|
| 516 | ze2(ji,jj,jk) = zc2 |
|---|
| 517 | ze3(ji,jj,jk) = zc3 |
|---|
| 518 | zea(ji,jj,jk) = ( zc0 + zc1 + zc2 + zc3 ) * tmask(ji,jj,jk) |
|---|
| 519 | END DO |
|---|
| 520 | END DO |
|---|
| 521 | END DO |
|---|
| 522 | ! |
|---|
| 523 | DO jk = 1, nksr |
|---|
| 524 | etot3(:,:,jk) = r1_rau0_rcp * ( zea(:,:,jk) - zea(:,:,jk+1) ) |
|---|
| 525 | END DO |
|---|
| 526 | etot3(:,:,nksr+1:jpk) = 0.e0 ! below 400m set to zero |
|---|
| 527 | ENDIF |
|---|
| 528 | ENDIF |
|---|
| 529 | ! |
|---|
| 530 | ENDIF |
|---|
| 531 | ! ! ---------------------------------- ! |
|---|
| 532 | IF( ln_qsr_2bd ) THEN ! 2 bands light penetration ! |
|---|
| 533 | ! ! ---------------------------------- ! |
|---|
| 534 | ! |
|---|
| 535 | ! ! level of light extinction |
|---|
| 536 | nksr = trc_oce_ext_lev( rn_si1, 1.e2 ) |
|---|
| 537 | IF(lwp) THEN |
|---|
| 538 | WRITE(numout,*) |
|---|
| 539 | IF(lwp) WRITE(numout,*) ' level of light extinction = ', nksr, ' ref depth = ', gdepw_1d(nksr+1), ' m' |
|---|
| 540 | ENDIF |
|---|
| 541 | ! |
|---|
| 542 | IF( lk_vvl ) THEN ! variable volume |
|---|
| 543 | IF(lwp) WRITE(numout,*) ' key_vvl: light distribution will be computed at each time step' |
|---|
| 544 | ELSE ! constant volume: computes one for all |
|---|
| 545 | zz0 = rn_abs * r1_rau0_rcp |
|---|
| 546 | zz1 = ( 1. - rn_abs ) * r1_rau0_rcp |
|---|
| 547 | DO jk = 1, nksr !* solar heat absorbed at T-point computed once for all |
|---|
| 548 | DO jj = 1, jpj ! top 400 meters |
|---|
| 549 | DO ji = 1, jpi |
|---|
| 550 | zc0 = zz0 * EXP( -fsdepw(ji,jj,jk )*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,jk )*xsi1r ) |
|---|
| 551 | zc1 = zz0 * EXP( -fsdepw(ji,jj,jk+1)*xsi0r ) + zz1 * EXP( -fsdepw(ji,jj,jk+1)*xsi1r ) |
|---|
| 552 | etot3(ji,jj,jk) = ( zc0 * tmask(ji,jj,jk) - zc1 * tmask(ji,jj,jk+1) ) |
|---|
| 553 | END DO |
|---|
| 554 | END DO |
|---|
| 555 | END DO |
|---|
| 556 | etot3(:,:,nksr+1:jpk) = 0.e0 ! below 400m set to zero |
|---|
| 557 | ! |
|---|
| 558 | ENDIF |
|---|
| 559 | ENDIF |
|---|
| 560 | ! ! ===================================== ! |
|---|
| 561 | ELSE ! No light penetration ! |
|---|
| 562 | ! ! ===================================== ! |
|---|
| 563 | IF(lwp) THEN |
|---|
| 564 | WRITE(numout,*) |
|---|
| 565 | WRITE(numout,*) 'tra_qsr_init : NO solar flux penetration' |
|---|
| 566 | WRITE(numout,*) '~~~~~~~~~~~~' |
|---|
| 567 | ENDIF |
|---|
| 568 | ENDIF |
|---|
| 569 | ! |
|---|
| 570 | CALL wrk_dealloc( jpi, jpj, zekb, zekg, zekr ) |
|---|
| 571 | CALL wrk_dealloc( jpi, jpj, jpk, ze0, ze1, ze2, ze3, zea ) |
|---|
| 572 | ! |
|---|
| 573 | IF( nn_timing == 1 ) CALL timing_stop('tra_qsr_init') |
|---|
| 574 | ! |
|---|
| 575 | END SUBROUTINE tra_qsr_init |
|---|
| 576 | |
|---|
| 577 | !!====================================================================== |
|---|
| 578 | END MODULE traqsr |
|---|
