New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trazdf.F90 in trunk/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: trunk/NEMOGCM/NEMO/OPA_SRC/TRA/trazdf.F90 @ 3294

Last change on this file since 3294 was 3294, checked in by rblod, 12 years ago

Merge of 3.4beta into the trunk
  • Property svn:keywords set to Id
File size: 7.7 KB
Line 
1MODULE trazdf
2   !!==============================================================================
3   !!                 ***  MODULE  trazdf  ***
4   !! Ocean active tracers:  vertical component of the tracer mixing trend
5   !!==============================================================================
6   !! History :  1.0  ! 2005-11  (G. Madec)  Original code
7   !!            3.0  ! 2008-01  (C. Ethe, G. Madec)  merge TRC-TRA
8   !!----------------------------------------------------------------------
9
10   !!----------------------------------------------------------------------
11   !!   tra_zdf      : Update the tracer trend with the vertical diffusion
12   !!   tra_zdf_init : initialisation of the computation
13   !!----------------------------------------------------------------------
14   USE oce             ! ocean dynamics and tracers variables
15   USE dom_oce         ! ocean space and time domain variables
16   USE domvvl          ! variable volume
17   USE phycst          ! physical constant
18   USE zdf_oce         ! ocean vertical physics variables
19   USE sbc_oce         ! surface boundary condition: ocean
20   USE dynspg_oce
21
22   USE trazdf_exp      ! vertical diffusion: explicit (tra_zdf_exp     routine)
23   USE trazdf_imp      ! vertical diffusion: implicit (tra_zdf_imp     routine)
24
25   USE ldftra_oce      ! ocean active tracers: lateral physics
26   USE trdmod_oce      ! ocean active tracers: lateral physics
27   USE trdtra      ! ocean tracers trends
28   USE in_out_manager  ! I/O manager
29   USE prtctl          ! Print control
30   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
31   USE lib_mpp         ! MPP library
32   USE wrk_nemo        ! Memory allocation
33   USE timing          ! Timing
34
35
36   IMPLICIT NONE
37   PRIVATE
38
39   PUBLIC   tra_zdf        ! routine called by step.F90
40   PUBLIC   tra_zdf_init   ! routine called by nemogcm.F90
41
42   INTEGER ::   nzdf = 0   ! type vertical diffusion algorithm used (defined from ln_zdf...  namlist logicals)
43
44   !! * Substitutions
45#  include "domzgr_substitute.h90"
46#  include "zdfddm_substitute.h90"
47#  include "vectopt_loop_substitute.h90"
48   !!----------------------------------------------------------------------
49   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
50   !! $Id$
51   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
52   !!----------------------------------------------------------------------
53CONTAINS
54
55   SUBROUTINE tra_zdf( kt )
56      !!----------------------------------------------------------------------
57      !!                  ***  ROUTINE tra_zdf  ***
58      !!
59      !! ** Purpose :   compute the vertical ocean tracer physics.
60      !!---------------------------------------------------------------------
61      INTEGER, INTENT( in ) ::   kt      ! ocean time-step index
62      !!
63      INTEGER  ::   jk                   ! Dummy loop indices
64      REAL(wp), POINTER, DIMENSION(:,:,:) ::   ztrdt, ztrds   ! 3D workspace
65      !!---------------------------------------------------------------------
66      !
67      IF( nn_timing == 1 )  CALL timing_start('tra_zdf')
68      !
69      IF( neuler == 0 .AND. kt == nit000 ) THEN     ! at nit000
70         r2dtra(:) =  rdttra(:)                          ! = rdtra (restarting with Euler time stepping)
71      ELSEIF( kt <= nit000 + 1) THEN                ! at nit000 or nit000+1
72         r2dtra(:) = 2. * rdttra(:)                      ! = 2 rdttra (leapfrog)
73      ENDIF
74
75      IF( l_trdtra )   THEN                    !* Save ta and sa trends
76         CALL wrk_alloc( jpi, jpj, jpk, ztrdt, ztrds )
77         ztrdt(:,:,:) = tsa(:,:,:,jp_tem)
78         ztrds(:,:,:) = tsa(:,:,:,jp_sal)
79      ENDIF
80
81      SELECT CASE ( nzdf )                       ! compute lateral mixing trend and add it to the general trend
82      CASE ( 0 )    ;    CALL tra_zdf_exp( kt, nit000, 'TRA', r2dtra, nn_zdfexp, tsb, tsa, jpts )  !   explicit scheme
83      CASE ( 1 )    ;    CALL tra_zdf_imp( kt, nit000, 'TRA', r2dtra,            tsb, tsa, jpts )  !   implicit scheme
84      CASE ( -1 )                                       ! esopa: test all possibility with control print
85         CALL tra_zdf_exp( kt, nit000, 'TRA', r2dtra, nn_zdfexp, tsb, tsa, jpts )
86         CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' zdf0 - Ta: ', mask1=tmask,               &
87         &             tab3d_2=tsa(:,:,:,jp_sal), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
88         CALL tra_zdf_imp( kt, nit000, 'TRA', r2dtra,            tsb, tsa, jpts ) 
89         CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' zdf1 - Ta: ', mask1=tmask,               &
90         &             tab3d_2=tsa(:,:,:,jp_sal), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
91      END SELECT
92
93      IF( l_trdtra )   THEN                      ! save the vertical diffusive trends for further diagnostics
94         DO jk = 1, jpkm1
95            ztrdt(:,:,jk) = ( ( tsa(:,:,jk,jp_tem) - tsb(:,:,jk,jp_tem) ) / r2dtra(jk) ) - ztrdt(:,:,jk)
96            ztrds(:,:,jk) = ( ( tsa(:,:,jk,jp_sal) - tsb(:,:,jk,jp_sal) ) / r2dtra(jk) ) - ztrds(:,:,jk)
97         END DO
98         CALL trd_tra( kt, 'TRA', jp_tem, jptra_trd_zdf, ztrdt )
99         CALL trd_tra( kt, 'TRA', jp_sal, jptra_trd_zdf, ztrds )
100         CALL wrk_dealloc( jpi, jpj, jpk, ztrdt, ztrds )
101      ENDIF
102
103      !                                          ! print mean trends (used for debugging)
104      IF(ln_ctl)   CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' zdf  - Ta: ', mask1=tmask,               &
105         &                       tab3d_2=tsa(:,:,:,jp_sal), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
106      !
107      IF( nn_timing == 1 )  CALL timing_stop('tra_zdf')
108      !
109   END SUBROUTINE tra_zdf
110
111
112   SUBROUTINE tra_zdf_init
113      !!----------------------------------------------------------------------
114      !!                 ***  ROUTINE tra_zdf_init  ***
115      !!
116      !! ** Purpose :   Choose the vertical mixing scheme
117      !!
118      !! ** Method  :   Set nzdf from ln_zdfexp
119      !!      nzdf = 0   explicit (time-splitting) scheme (ln_zdfexp=T)
120      !!           = 1   implicit (euler backward) scheme (ln_zdfexp=F)
121      !!      NB: rotation of lateral mixing operator or TKE or KPP scheme,
122      !!      the implicit scheme is required.
123      !!----------------------------------------------------------------------
124      USE zdftke
125      USE zdfgls
126      USE zdfkpp
127      !!----------------------------------------------------------------------
128
129      ! Choice from ln_zdfexp already read in namelist in zdfini module
130      IF( ln_zdfexp ) THEN   ;   nzdf = 0           ! use explicit scheme
131      ELSE                   ;   nzdf = 1           ! use implicit scheme
132      ENDIF
133
134      ! Force implicit schemes
135      IF( lk_zdftke .OR. lk_zdfgls .OR. lk_zdfkpp )   nzdf = 1      ! TKE, GLS or KPP physics
136      IF( ln_traldf_iso                           )   nzdf = 1      ! iso-neutral lateral physics
137      IF( ln_traldf_hor .AND. ln_sco              )   nzdf = 1      ! horizontal lateral physics in s-coordinate
138      IF( ln_zdfexp .AND. nzdf == 1 )   CALL ctl_stop( 'tra_zdf : If using the rotation of lateral mixing operator',   &
139            &                         ' TKE or KPP scheme, the implicit scheme is required, set ln_zdfexp = .false.' )
140
141      ! Test: esopa
142      IF( lk_esopa )    nzdf = -1                      ! All schemes used
143
144      IF(lwp) THEN
145         WRITE(numout,*)
146         WRITE(numout,*) 'tra_zdf_init : vertical tracer physics scheme'
147         WRITE(numout,*) '~~~~~~~~~~~'
148         IF( nzdf == -1 )   WRITE(numout,*) '              ESOPA test All scheme used'
149         IF( nzdf ==  0 )   WRITE(numout,*) '              Explicit time-splitting scheme'
150         IF( nzdf ==  1 )   WRITE(numout,*) '              Implicit (euler backward) scheme'
151      ENDIF
152      !
153   END SUBROUTINE tra_zdf_init
154
155   !!==============================================================================
156END MODULE trazdf
Note: See TracBrowser for help on using the repository browser.