New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
zpshde.F90 in trunk/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: trunk/NEMOGCM/NEMO/OPA_SRC/TRA/zpshde.F90 @ 2528

Last change on this file since 2528 was 2528, checked in by rblod, 13 years ago

Update NEMOGCM from branch nemo_v3_3_beta
  • Property svn:keywords set to Id
File size: 10.5 KB
Line 
1MODULE zpshde
2   !!======================================================================
3   !!                       ***  MODULE zpshde   ***
4   !! z-coordinate + partial step : Horizontal Derivative at ocean bottom level
5   !!======================================================================
6   !! History :  OPA  !  2002-04  (A. Bozec)  Original code
7   !!   NEMO     1.0  !  2002-08  (G. Madec E. Durand)  Optimization and Free form
8   !!             -   !  2004-03  (C. Ethe)  adapted for passive tracers
9   !!            3.3  !  2010-05  (C. Ethe, G. Madec)  merge TRC-TRA
10   !!======================================================================
11   
12   !!----------------------------------------------------------------------
13   !!   zps_hde      :  Horizontal DErivative of T, S and rd at the last
14   !!                   ocean level (Z-coord. with Partial Steps)
15   !!----------------------------------------------------------------------
16   USE oce             ! ocean: dynamics and tracers variables
17   USE dom_oce         ! domain: ocean variables
18   USE phycst          ! physical constants
19   USE eosbn2          ! ocean equation of state
20   USE in_out_manager  ! I/O manager
21   USE lbclnk          ! lateral boundary conditions (or mpp link)
22
23   IMPLICIT NONE
24   PRIVATE
25
26   PUBLIC   zps_hde    ! routine called by step.F90
27
28   !! * Substitutions
29#  include "domzgr_substitute.h90"
30#  include "vectopt_loop_substitute.h90"
31   !!----------------------------------------------------------------------
32   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
33   !! $Id$
34   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
35   !!----------------------------------------------------------------------
36CONTAINS
37
38   SUBROUTINE zps_hde( kt, kjpt, pta, pgtu, pgtv,   &
39                                 prd, pgru, pgrv    )
40      !!----------------------------------------------------------------------
41      !!                     ***  ROUTINE zps_hde  ***
42      !!                   
43      !! ** Purpose :   Compute the horizontal derivative of T, S and rho
44      !!      at u- and v-points with a linear interpolation for z-coordinate
45      !!      with partial steps.
46      !!
47      !! ** Method  :   In z-coord with partial steps, scale factors on last
48      !!      levels are different for each grid point, so that T, S and rd
49      !!      points are not at the same depth as in z-coord. To have horizontal
50      !!      gradients again, we interpolate T and S at the good depth :
51      !!      Linear interpolation of T, S   
52      !!         Computation of di(tb) and dj(tb) by vertical interpolation:
53      !!          di(t) = t~ - t(i,j,k) or t(i+1,j,k) - t~
54      !!          dj(t) = t~ - t(i,j,k) or t(i,j+1,k) - t~
55      !!         This formulation computes the two cases:
56      !!                 CASE 1                   CASE 2 
57      !!         k-1  ___ ___________   k-1   ___ ___________
58      !!                    Ti  T~                  T~  Ti+1
59      !!                  _____                        _____
60      !!         k        |   |Ti+1     k           Ti |   |
61      !!                  |   |____                ____|   |
62      !!              ___ |   |   |           ___  |   |   |
63      !!                 
64      !!      case 1->   e3w(i+1) >= e3w(i) ( and e3w(j+1) >= e3w(j) ) then
65      !!          t~ = t(i+1,j  ,k) + (e3w(i+1) - e3w(i)) * dk(Ti+1)/e3w(i+1)
66      !!        ( t~ = t(i  ,j+1,k) + (e3w(j+1) - e3w(j)) * dk(Tj+1)/e3w(j+1)  )
67      !!          or
68      !!      case 2->   e3w(i+1) <= e3w(i) ( and e3w(j+1) <= e3w(j) ) then
69      !!          t~ = t(i,j,k) + (e3w(i) - e3w(i+1)) * dk(Ti)/e3w(i )
70      !!        ( t~ = t(i,j,k) + (e3w(j) - e3w(j+1)) * dk(Tj)/e3w(j ) )
71      !!          Idem for di(s) and dj(s)         
72      !!
73      !!      For rho, we call eos_insitu_2d which will compute rd~(t~,s~) at
74      !!      the good depth zh from interpolated T and S for the different
75      !!      formulation of the equation of state (eos).
76      !!      Gradient formulation for rho :
77      !!          di(rho) = rd~ - rd(i,j,k) or rd(i+1,j,k) - rd~
78      !!
79      !! ** Action  : - pgtu, pgtv: horizontal gradient of tracer at u- & v-points
80      !!              - pgru, pgrv: horizontal gradient of rho (if present) at u- & v-points
81      !!----------------------------------------------------------------------
82      INTEGER                              , INTENT(in   )           ::  kt          ! ocean time-step index
83      INTEGER                              , INTENT(in   )           ::  kjpt        ! number of tracers
84      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   )           ::  pta         ! 4D tracers fields
85      REAL(wp), DIMENSION(jpi,jpj,    kjpt), INTENT(  out)           ::  pgtu, pgtv  ! hor. grad. of ptra at u- & v-pts
86      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ), OPTIONAL ::  prd         ! 3D density anomaly fields
87      REAL(wp), DIMENSION(jpi,jpj         ), INTENT(  out), OPTIONAL ::  pgru, pgrv  ! hor. grad. of prd at u- & v-pts
88      !!
89      INTEGER  ::   ji, jj, jn      ! Dummy loop indices
90      INTEGER  ::   iku, ikv, ikum1, ikvm1   ! partial step level (ocean bottom level) at u- and v-points
91      REAL(wp), DIMENSION(jpi,jpj,kjpt) ::   zti, ztj     ! interpolated value of tracer
92      REAL(wp), DIMENSION(jpi,jpj)      ::   zri, zrj     ! interpolated value of rd
93      REAL(wp), DIMENSION(jpi,jpj)      ::   zhi, zhj     ! depth of interpolation for eos2d
94      REAL(wp) ::  ze3wu, ze3wv, zmaxu, zmaxv  ! temporary scalars
95      !!----------------------------------------------------------------------
96
97      DO jn = 1, kjpt      !==   Interpolation of tracers at the last ocean level   ==!
98         !
99# if defined key_vectopt_loop
100         jj = 1
101         DO ji = 1, jpij-jpi   ! vector opt. (forced unrolled)
102# else
103         DO jj = 1, jpjm1
104            DO ji = 1, jpim1
105# endif
106               iku = mbku(ji,jj)   ;   ikum1 = MAX( iku , 1 )        ! last and before last ocean level at u- & v-points
107               ikv = mbkv(ji,jj)   ;   ikvm1 = MAX( ikv , 1 )        ! if level first is a p-step, ik.m1=1
108               ze3wu = fse3w(ji+1,jj  ,iku) - fse3w(ji,jj,iku)
109               ze3wv = fse3w(ji  ,jj+1,ikv) - fse3w(ji,jj,ikv)
110               !
111               ! i- direction
112               IF( ze3wu >= 0._wp ) THEN      ! case 1
113                  zmaxu =  ze3wu / fse3w(ji+1,jj,iku)
114                  ! interpolated values of tracers
115                  zti(ji,jj,jn) = pta(ji+1,jj,iku,jn) + zmaxu * ( pta(ji+1,jj,ikum1,jn) - pta(ji+1,jj,iku,jn) )
116                  ! gradient of  tracers
117                  pgtu(ji,jj,jn) = umask(ji,jj,1) * ( zti(ji,jj,jn) - pta(ji,jj,iku,jn) )
118               ELSE                           ! case 2
119                  zmaxu = -ze3wu / fse3w(ji,jj,iku)
120                  ! interpolated values of tracers
121                  zti(ji,jj,jn) = pta(ji,jj,iku,jn) + zmaxu * ( pta(ji,jj,ikum1,jn) - pta(ji,jj,iku,jn) )
122                  ! gradient of tracers
123                  pgtu(ji,jj,jn) = umask(ji,jj,1) * ( pta(ji+1,jj,iku,jn) - zti(ji,jj,jn) )
124               ENDIF
125               !
126               ! j- direction
127               IF( ze3wv >= 0._wp ) THEN      ! case 1
128                  zmaxv =  ze3wv / fse3w(ji,jj+1,ikv)
129                  ! interpolated values of tracers
130                  ztj(ji,jj,jn) = pta(ji,jj+1,ikv,jn) + zmaxv * ( pta(ji,jj+1,ikvm1,jn) - pta(ji,jj+1,ikv,jn) )
131                  ! gradient of tracers
132                  pgtv(ji,jj,jn) = vmask(ji,jj,1) * ( ztj(ji,jj,jn) - pta(ji,jj,ikv,jn) )
133               ELSE                           ! case 2
134                  zmaxv =  -ze3wv / fse3w(ji,jj,ikv)
135                  ! interpolated values of tracers
136                  ztj(ji,jj,jn) = pta(ji,jj,ikv,jn) + zmaxv * ( pta(ji,jj,ikvm1,jn) - pta(ji,jj,ikv,jn) )
137                  ! gradient of tracers
138                  pgtv(ji,jj,jn) = vmask(ji,jj,1) * ( pta(ji,jj+1,ikv,jn) - ztj(ji,jj,jn) )
139               ENDIF
140# if ! defined key_vectopt_loop
141            END DO
142# endif
143         END DO
144         CALL lbc_lnk( pgtu(:,:,jn), 'U', -1. )   ;   CALL lbc_lnk( pgtv(:,:,jn), 'V', -1. )   ! Lateral boundary cond.
145         !
146      END DO
147
148      ! horizontal derivative of density anomalies (rd)
149      IF( PRESENT( prd ) ) THEN         ! depth of the partial step level
150# if defined key_vectopt_loop
151         jj = 1
152         DO ji = 1, jpij-jpi   ! vector opt. (forced unrolled)
153# else
154         DO jj = 1, jpjm1
155            DO ji = 1, jpim1
156# endif
157               iku = mbku(ji,jj)
158               ikv = mbkv(ji,jj)
159               ze3wu  = fse3w(ji+1,jj  ,iku) - fse3w(ji,jj,iku)
160               ze3wv  = fse3w(ji  ,jj+1,ikv) - fse3w(ji,jj,ikv)
161               IF( ze3wu >= 0._wp ) THEN   ;   zhi(ji,jj) = fsdept(ji  ,jj,iku)     ! i-direction: case 1
162               ELSE                        ;   zhi(ji,jj) = fsdept(ji+1,jj,iku)     ! -     -      case 2
163               ENDIF
164               IF( ze3wv >= 0._wp ) THEN   ;   zhj(ji,jj) = fsdept(ji,jj  ,ikv)     ! j-direction: case 1
165               ELSE                        ;   zhj(ji,jj) = fsdept(ji,jj+1,ikv)     ! -     -      case 2
166               ENDIF
167# if ! defined key_vectopt_loop
168            END DO
169# endif
170         END DO
171
172         ! Compute interpolated rd from zti, ztj for the 2 cases at the depth of the partial
173         ! step and store it in  zri, zrj for each  case
174         CALL eos( zti, zhi, zri )   ;   CALL eos( ztj, zhj, zrj )
175
176         ! Gradient of density at the last level
177# if defined key_vectopt_loop
178         jj = 1
179         DO ji = 1, jpij-jpi   ! vector opt. (forced unrolled)
180# else
181         DO jj = 1, jpjm1
182            DO ji = 1, jpim1
183# endif
184               iku = mbku(ji,jj)
185               ikv = mbkv(ji,jj)
186               ze3wu  = fse3w(ji+1,jj  ,iku) - fse3w(ji,jj,iku)
187               ze3wv  = fse3w(ji  ,jj+1,ikv) - fse3w(ji,jj,ikv)
188               IF( ze3wu >= 0._wp ) THEN   ;   pgru(ji,jj) = umask(ji,jj,1) * ( zri(ji  ,jj) - prd(ji,jj,iku) )   ! i: 1
189               ELSE                        ;   pgru(ji,jj) = umask(ji,jj,1) * ( prd(ji+1,jj,iku) - zri(ji,jj) )   ! i: 2
190               ENDIF
191               IF( ze3wv >= 0._wp ) THEN   ;   pgrv(ji,jj) = vmask(ji,jj,1) * ( zrj(ji,jj  ) - prd(ji,jj,ikv) )   ! j: 1
192               ELSE                        ;   pgrv(ji,jj) = vmask(ji,jj,1) * ( prd(ji,jj+1,ikv) - zrj(ji,jj) )   ! j: 2
193               ENDIF
194# if ! defined key_vectopt_loop
195            END DO
196# endif
197         END DO
198         CALL lbc_lnk( pgru , 'U', -1. )   ;   CALL lbc_lnk( pgrv , 'V', -1. )   ! Lateral boundary conditions
199         !
200      END IF
201      !
202   END SUBROUTINE zps_hde
203
204   !!======================================================================
205END MODULE zpshde
Note: See TracBrowser for help on using the repository browser.