New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
zdfbfr.F90 in trunk/NEMOGCM/NEMO/OPA_SRC/ZDF – NEMO

source: trunk/NEMOGCM/NEMO/OPA_SRC/ZDF/zdfbfr.F90 @ 2715

Last change on this file since 2715 was 2715, checked in by rblod, 13 years ago

First attempt to put dynamic allocation on the trunk
  • Property svn:keywords set to Id
File size: 12.4 KB
Line 
1MODULE zdfbfr
2   !!======================================================================
3   !!                       ***  MODULE  zdfbfr  ***
4   !! Ocean physics: Bottom friction
5   !!======================================================================
6   !! History :  OPA  ! 1997-06  (G. Madec, A.-M. Treguier)  Original code
7   !!   NEMO     1.0  ! 2002-06  (G. Madec)  F90: Free form and module
8   !!            3.2  ! 2009-09  (A.C.Coward)  Correction to include barotropic contribution
9   !!            3.3  ! 2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
10   !!----------------------------------------------------------------------
11
12   !!----------------------------------------------------------------------
13   !!   zdf_bfr      : update momentum Kz at the ocean bottom due to the type of bottom friction chosen
14   !!   zdf_bfr_init : read in namelist and control the bottom friction parameters.
15   !!   zdf_bfr_2d   : read in namelist and control the bottom friction parameters.
16   !!----------------------------------------------------------------------
17   USE oce             ! ocean dynamics and tracers variables
18   USE dom_oce         ! ocean space and time domain variables
19   USE zdf_oce         ! ocean vertical physics variables
20   USE in_out_manager  ! I/O manager
21   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
22   USE lib_mpp         ! distributed memory computing
23   USE prtctl          ! Print control
24
25   IMPLICIT NONE
26   PRIVATE
27
28   PUBLIC   zdf_bfr         ! called by step.F90
29   PUBLIC   zdf_bfr_init    ! called by opa.F90
30
31   !                                    !!* Namelist nambfr: bottom friction namelist *
32   INTEGER  ::   nn_bfr    = 0           ! = 0/1/2/3 type of bottom friction
33   REAL(wp) ::   rn_bfri1  = 4.0e-4_wp   ! bottom drag coefficient (linear case)
34   REAL(wp) ::   rn_bfri2  = 1.0e-3_wp   ! bottom drag coefficient (non linear case)
35   REAL(wp) ::   rn_bfeb2  = 2.5e-3_wp   ! background bottom turbulent kinetic energy  [m2/s2]
36   REAL(wp) ::   rn_bfrien = 30._wp      ! local factor to enhance coefficient bfri
37   LOGICAL  ::   ln_bfr2d  = .false.     ! logical switch for 2D enhancement
38   
39   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) ::  bfrcoef2d   ! 2D bottom drag coefficient
40
41   !! * Substitutions
42#  include "vectopt_loop_substitute.h90"
43#  include "domzgr_substitute.h90"
44   !!----------------------------------------------------------------------
45   !! NEMO/OPA 4.0 , NEMO Consortium (2011)
46   !! $Id$
47   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
48   !!----------------------------------------------------------------------
49CONTAINS
50
51   INTEGER FUNCTION zdf_bfr_alloc()
52      !!----------------------------------------------------------------------
53      !!                ***  FUNCTION zdf_bfr_alloc  ***
54      !!----------------------------------------------------------------------
55      ALLOCATE( bfrcoef2d(jpi,jpj), STAT=zdf_bfr_alloc )
56      !
57      IF( lk_mpp             )   CALL mpp_sum ( zdf_bfr_alloc )
58      IF( zdf_bfr_alloc /= 0 )   CALL ctl_warn('zdf_bfr_alloc: failed to allocate arrays.')
59   END FUNCTION zdf_bfr_alloc
60
61
62   SUBROUTINE zdf_bfr( kt )
63      !!----------------------------------------------------------------------
64      !!                   ***  ROUTINE zdf_bfr  ***
65      !!                 
66      !! ** Purpose :   compute the bottom friction coefficient.
67      !!
68      !! ** Method  :   Calculate and store part of the momentum trend due   
69      !!              to bottom friction following the chosen friction type
70      !!              (free-slip, linear, or quadratic). The component
71      !!              calculated here is multiplied by the bottom velocity in
72      !!              dyn_bfr to provide the trend term.
73      !!                The coefficients are updated at each time step only
74      !!              in the quadratic case.
75      !!
76      !! ** Action  :   bfrua , bfrva   bottom friction coefficients
77      !!----------------------------------------------------------------------
78      INTEGER, INTENT( in ) ::   kt   ! ocean time-step index
79      !!
80      INTEGER  ::   ji, jj       ! dummy loop indices
81      INTEGER  ::   ikbu, ikbv   ! local integers
82      REAL(wp) ::   zvu, zuv, zecu, zecv   ! temporary scalars
83      !!----------------------------------------------------------------------
84
85      IF( nn_bfr == 2 ) THEN                 ! quadratic botton friction
86         ! Calculate and store the quadratic bottom friction coefficient bfrua and bfrva
87         ! where bfrUa = C_d*SQRT(u_bot^2 + v_bot^2 + e_b) {U=[u,v]}
88         ! from these the trend due to bottom friction:  -F_h/e3U  can be calculated
89         ! where -F_h/e3U_bot = bfrUa*Ub/e3U_bot {U=[u,v]}
90         !
91# if defined key_vectopt_loop
92         DO jj = 1, 1
93!CDIR NOVERRCHK
94            DO ji = jpi+2, jpij-jpi-1   ! vector opt. (forced unrolling)
95# else
96!CDIR NOVERRCHK
97         DO jj = 2, jpjm1
98!CDIR NOVERRCHK
99            DO ji = 2, jpim1
100# endif
101               ikbu = mbku(ji,jj)         ! ocean bottom level at u- and v-points
102               ikbv = mbkv(ji,jj)         ! (deepest ocean u- and v-points)
103               !
104               zvu  = 0.25 * (  vn(ji,jj  ,ikbu) + vn(ji+1,jj  ,ikbu)     &
105                  &           + vn(ji,jj-1,ikbu) + vn(ji+1,jj-1,ikbu)  )
106               zuv  = 0.25 * (  un(ji,jj  ,ikbv) + un(ji-1,jj  ,ikbv)     &
107                  &           + un(ji,jj+1,ikbv) + un(ji-1,jj+1,ikbv)  )
108               !
109               zecu = SQRT(  un(ji,jj,ikbu) * un(ji,jj,ikbu) + zvu*zvu + rn_bfeb2  )
110               zecv = SQRT(  vn(ji,jj,ikbv) * vn(ji,jj,ikbv) + zuv*zuv + rn_bfeb2  )
111               !
112               bfrua(ji,jj) = - 0.5_wp * ( bfrcoef2d(ji,jj) + bfrcoef2d(ji+1,jj  ) ) * zecu 
113               bfrva(ji,jj) = - 0.5_wp * ( bfrcoef2d(ji,jj) + bfrcoef2d(ji  ,jj+1) ) * zecv
114            END DO
115         END DO
116         !
117         CALL lbc_lnk( bfrua, 'U', 1. )   ;   CALL lbc_lnk( bfrva, 'V', 1. )      ! Lateral boundary condition
118         !
119         IF(ln_ctl)   CALL prt_ctl( tab2d_1=bfrua, clinfo1=' bfr  - u: ', mask1=umask,        &
120            &                       tab2d_2=bfrva, clinfo2=       ' v: ', mask2=vmask,ovlap=1 )
121      ENDIF
122      !
123   END SUBROUTINE zdf_bfr
124
125
126   SUBROUTINE zdf_bfr_init
127      !!----------------------------------------------------------------------
128      !!                  ***  ROUTINE zdf_bfr_init  ***
129      !!                   
130      !! ** Purpose :   Initialization of the bottom friction
131      !!
132      !! ** Method  :   Read the nammbf namelist and check their consistency
133      !!              called at the first timestep (nit000)
134      !!----------------------------------------------------------------------
135      USE iom   ! I/O module for ehanced bottom friction file
136      !!
137      INTEGER ::   inum         ! logical unit for enhanced bottom friction file
138      INTEGER ::   ji, jj       ! dummy loop indexes
139      INTEGER ::   ikbu, ikbv   ! temporary integers
140      INTEGER ::   ictu, ictv   !    -          -
141      REAL(wp) ::  zminbfr, zmaxbfr   ! temporary scalars
142      REAL(wp) ::  zfru, zfrv         !    -         -
143      !!
144      NAMELIST/nambfr/ nn_bfr, rn_bfri1, rn_bfri2, rn_bfeb2, ln_bfr2d, rn_bfrien
145      !!----------------------------------------------------------------------
146
147      REWIND ( numnam )               !* Read Namelist nam_bfr : bottom momentum boundary condition
148      READ   ( numnam, nambfr )
149
150      !                               !* Parameter control and print
151      IF(lwp) WRITE(numout,*)
152      IF(lwp) WRITE(numout,*) 'zdf_bfr : momentum bottom friction'
153      IF(lwp) WRITE(numout,*) '~~~~~~~'
154      IF(lwp) WRITE(numout,*) '   Namelist nam_bfr : set bottom friction parameters'
155
156      !                              ! allocate zdfbfr arrays
157      IF( zdf_bfr_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'zdf_bfr_init : unable to allocate arrays' )
158
159      SELECT CASE (nn_bfr)
160      !
161      CASE( 0 )
162         IF(lwp) WRITE(numout,*) '      free-slip '
163         bfrua(:,:) = 0.e0
164         bfrva(:,:) = 0.e0
165         !
166      CASE( 1 )
167         IF(lwp) WRITE(numout,*) '      linear botton friction'
168         IF(lwp) WRITE(numout,*) '      friction coef.   rn_bfri1  = ', rn_bfri1
169         IF( ln_bfr2d ) THEN
170            IF(lwp) WRITE(numout,*) '      read coef. enhancement distribution from file   ln_bfr2d  = ', ln_bfr2d
171            IF(lwp) WRITE(numout,*) '      coef rn_bfri2 enhancement factor                rn_bfrien  = ',rn_bfrien
172         ENDIF
173         !
174         bfrcoef2d(:,:) = rn_bfri1  ! initialize bfrcoef2d to the namelist variable
175         !
176         IF(ln_bfr2d) THEN 
177            ! bfr_coef is a coefficient in [0,1] giving the mask where to apply the bfr enhancement
178            CALL iom_open('bfr_coef.nc',inum)
179            CALL iom_get (inum, jpdom_data, 'bfr_coef',bfrcoef2d,1) ! bfrcoef2d is used as tmp array
180            CALL iom_close(inum)
181            bfrcoef2d(:,:) = rn_bfri1 * ( 1 + rn_bfrien * bfrcoef2d(:,:) )
182         ENDIF
183         bfrua(:,:) = - bfrcoef2d(:,:)
184         bfrva(:,:) = - bfrcoef2d(:,:)
185         !
186      CASE( 2 )
187         IF(lwp) WRITE(numout,*) '      quadratic botton friction'
188         IF(lwp) WRITE(numout,*) '      friction coef.   rn_bfri2  = ', rn_bfri2
189         IF(lwp) WRITE(numout,*) '      background tke   rn_bfeb2  = ', rn_bfeb2
190         IF( ln_bfr2d ) THEN
191            IF(lwp) WRITE(numout,*) '      read coef. enhancement distribution from file   ln_bfr2d  = ', ln_bfr2d
192            IF(lwp) WRITE(numout,*) '      coef rn_bfri2 enhancement factor                rn_bfrien  = ',rn_bfrien
193         ENDIF
194         bfrcoef2d(:,:) = rn_bfri2  ! initialize bfrcoef2d to the namelist variable
195         !
196         IF(ln_bfr2d) THEN 
197            ! bfr_coef is a coefficient in [0,1] giving the mask where to apply the bfr enhancement
198            CALL iom_open('bfr_coef.nc',inum)
199            CALL iom_get (inum, jpdom_data, 'bfr_coef',bfrcoef2d,1) ! bfrcoef2d is used as tmp array
200            CALL iom_close(inum)
201            bfrcoef2d(:,:)= rn_bfri2 * ( 1 + rn_bfrien * bfrcoef2d(:,:) )
202         ENDIF
203         !
204      CASE DEFAULT
205         IF(lwp) WRITE(ctmp1,*) '         bad flag value for nn_bfr = ', nn_bfr
206         CALL ctl_stop( ctmp1 )
207         !
208      END SELECT
209      !
210      ! Basic stability check on bottom friction coefficient
211      !
212      ictu = 0               ! counter for stability criterion breaches at U-pts
213      ictv = 0               ! counter for stability criterion breaches at V-pts
214      zminbfr =  1.e10_wp    ! initialise tracker for minimum of bottom friction coefficient
215      zmaxbfr = -1.e10_wp    ! initialise tracker for maximum of bottom friction coefficient
216      !
217#  if defined key_vectopt_loop
218      DO jj = 1, 1
219!CDIR NOVERRCHK
220         DO ji = jpi+2, jpij-jpi-1   ! vector opt. (forced unrolling)
221#  else
222!CDIR NOVERRCHK
223      DO jj = 2, jpjm1
224!CDIR NOVERRCHK
225         DO ji = 2, jpim1
226#  endif
227             ikbu = mbku(ji,jj)       ! deepest ocean level at u- and v-points
228             ikbv = mbkv(ji,jj)
229             zfru = 0.5 * fse3u(ji,jj,ikbu) / rdt
230             zfrv = 0.5 * fse3v(ji,jj,ikbv) / rdt
231             IF( ABS( bfrcoef2d(ji,jj) ) > zfru ) THEN
232                IF( ln_ctl ) THEN
233                   WRITE(numout,*) 'BFR ', narea, nimpp+ji, njmpp+jj, ikbu
234                   WRITE(numout,*) 'BFR ', ABS( bfrcoef2d(ji,jj) ), zfru
235                ENDIF
236                ictu = ictu + 1
237             ENDIF
238             IF( ABS( bfrcoef2d(ji,jj) ) > zfrv ) THEN
239                 IF( ln_ctl ) THEN
240                     WRITE(numout,*) 'BFR ', narea, nimpp+ji, njmpp+jj, ikbv
241                     WRITE(numout,*) 'BFR ', bfrcoef2d(ji,jj), zfrv
242                 ENDIF
243                 ictv = ictv + 1
244             ENDIF
245             zminbfr = MIN(  zminbfr, MIN( zfru, ABS( bfrcoef2d(ji,jj) ) )  )
246             zmaxbfr = MAX(  zmaxbfr, MIN( zfrv, ABS( bfrcoef2d(ji,jj) ) )  )
247         END DO
248      END DO
249      IF( lk_mpp ) THEN
250         CALL mpp_sum( ictu )
251         CALL mpp_sum( ictv )
252         CALL mpp_min( zminbfr )
253         CALL mpp_max( zmaxbfr )
254      ENDIF
255      IF( lwp .AND. ictu + ictv > 0 ) THEN
256         WRITE(numout,*) ' Bottom friction stability check failed at ', ictu, ' U-points '
257         WRITE(numout,*) ' Bottom friction stability check failed at ', ictv, ' V-points '
258         WRITE(numout,*) ' Bottom friction coefficient now ranges from: ', zminbfr, ' to ', zmaxbfr
259         WRITE(numout,*) ' Bottom friction coefficient will be reduced where necessary'
260      ENDIF
261      !
262   END SUBROUTINE zdf_bfr_init
263
264   !!======================================================================
265END MODULE zdfbfr
Note: See TracBrowser for help on using the repository browser.