source: trunk/NEMOGCM/NEMO/SAS_SRC/daymod.F90 @ 5518

Last change on this file since 5518 was 5518, checked in by clem, 5 years ago

Restarting date issue ⇒ allow SAS to read the date in the ocean restart (if it exists)

  • Property svn:keywords set to Id
File size: 18.6 KB
Line 
1MODULE daymod
2   !!======================================================================
3   !!                       ***  MODULE  daymod  ***
4   !! Ocean        :  calendar
5   !!=====================================================================
6   !! History :  OPA  ! 1994-09  (M. Pontaud M. Imbard)  Original code
7   !!                 ! 1997-03  (O. Marti)
8   !!                 ! 1997-05  (G. Madec)
9   !!                 ! 1997-08  (M. Imbard)
10   !!   NEMO     1.0  ! 2003-09  (G. Madec)  F90 + nyear, nmonth, nday
11   !!                 ! 2004-01  (A.M. Treguier) new calculation based on adatrj
12   !!                 ! 2006-08  (G. Madec)  surface module major update
13   !!----------------------------------------------------------------------     
14
15   !!----------------------------------------------------------------------
16   !!   day        : calendar
17   !! 
18   !!           -------------------------------
19   !!           ----------- WARNING -----------
20   !!
21   !!   we suppose that the time step is deviding the number of second of in a day
22   !!             ---> MOD( rday, rdttra(1) ) == 0
23   !!
24   !!           ----------- WARNING -----------
25   !!           -------------------------------
26   !! 
27   !!----------------------------------------------------------------------
28   USE dom_oce         ! ocean space and time domain
29   USE phycst          ! physical constants
30   USE in_out_manager  ! I/O manager
31   USE iom             !
32   USE ioipsl, ONLY :   ymds2ju   ! for calendar
33   USE prtctl          ! Print control
34   USE restart         !
35   USE timing          ! Timing
36
37   IMPLICIT NONE
38   PRIVATE
39
40   PUBLIC   day        ! called by step.F90
41   PUBLIC   day_init   ! called by istate.F90
42
43   INTEGER ::   nsecd, nsecd05, ndt, ndt05
44
45   !!----------------------------------------------------------------------
46   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
47   !! $Id$
48   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
49   !!----------------------------------------------------------------------
50CONTAINS
51
52   SUBROUTINE day_init
53      !!----------------------------------------------------------------------
54      !!                   ***  ROUTINE day_init  ***
55      !!
56      !! ** Purpose :   Initialization of the calendar values to their values 1 time step before nit000
57      !!                because day will be called at the beginning of step
58      !!
59      !! ** Action  : - nyear        : current year
60      !!              - nmonth       : current month of the year nyear
61      !!              - nday         : current day of the month nmonth
62      !!              - nday_year    : current day of the year nyear
63      !!              - nsec_year    : current time step counted in second since 00h jan 1st of the current year
64      !!              - nsec_month   : current time step counted in second since 00h 1st day of the current month
65      !!              - nsec_day     : current time step counted in second since 00h of the current day
66      !!              - nsec1jan000  : second since Jan. 1st 00h of nit000 year and Jan. 1st 00h of the current year
67      !!              - nmonth_len, nyear_len, nmonth_half, nmonth_end through day_mth
68      !!----------------------------------------------------------------------
69      INTEGER  ::   inbday, idweek
70      REAL(wp) ::   zjul
71      !!----------------------------------------------------------------------
72      !
73      ! all calendar staff is based on the fact that MOD( rday, rdttra(1) ) == 0
74      IF( MOD( rday     , rdttra(1) ) /= 0. )   CALL ctl_stop( 'the time step must devide the number of second of in a day' )
75      IF( MOD( rday     , 2.        ) /= 0. )   CALL ctl_stop( 'the number of second of in a day must be an even number'    )
76      IF( MOD( rdttra(1), 2.        ) /= 0. )   CALL ctl_stop( 'the time step (in second) must be an even number'           )
77      nsecd   = NINT(rday           )
78      nsecd05 = NINT(0.5 * rday     )
79      ndt     = NINT(      rdttra(1))
80      ndt05   = NINT(0.5 * rdttra(1))
81
82      ! ==> clem: here we read the ocean restart for the date (only if it exists)
83      !           It is not clean and another solution should be found
84      CALL day_rst( nit000, 'READ' )
85      ! ==>
86
87      ! set the calendar from ndastp (read in restart file and namelist)
88
89      nyear   =   ndastp / 10000
90      nmonth  = ( ndastp - (nyear * 10000) ) / 100
91      nday    =   ndastp - (nyear * 10000) - ( nmonth * 100 ) 
92
93      CALL ymds2ju( nyear, nmonth, nday, 0.0, fjulday )  ! we assume that we start run at 00:00
94      IF( ABS(fjulday - REAL(NINT(fjulday),wp)) < 0.1 / rday )   fjulday = REAL(NINT(fjulday),wp)   ! avoid truncation error
95      fjulday = fjulday + 1.                             ! move back to the day at nit000 (and not at nit000 - 1)
96
97      nsec1jan000 = 0
98      CALL day_mth
99     
100      IF ( nday == 0 ) THEN     !   for ex if ndastp = ndate0 - 1
101         nmonth = nmonth - 1 
102         nday = nmonth_len(nmonth)
103      ENDIF
104      IF ( nmonth == 0 ) THEN   ! go at the end of previous year
105         nmonth = 12
106         nyear = nyear - 1
107         nsec1jan000 = nsec1jan000 - nsecd * nyear_len(0)
108         IF( nleapy == 1 )   CALL day_mth
109      ENDIF
110     
111      ! day since january 1st
112      nday_year = nday + SUM( nmonth_len(1:nmonth - 1) )
113
114      !compute number of days between last monday and today     
115      CALL ymds2ju( 1900, 01, 01, 0.0, zjul )  ! compute julian day value of 01.01.1900 (our reference that was a Monday)
116      inbday = NINT(fjulday - zjul)            ! compute nb day between  01.01.1900 and current day 
117      idweek = MOD(inbday, 7)                  ! compute nb day between last monday and current day 
118
119      ! number of seconds since the beginning of current year/month/week/day at the middle of the time-step
120      nsec_year  = nday_year * nsecd - ndt05   ! 1 time step before the middle of the first time step
121      nsec_month = nday      * nsecd - ndt05   ! because day will be called at the beginning of step
122      nsec_week  = idweek    * nsecd - ndt05
123      nsec_day   =             nsecd - ndt05
124
125      ! control print
126      IF(lwp) WRITE(numout,'(a,i6,a,i2,a,i2,a,i8,a,i8)')' =======>> 1/2 time step before the start of the run DATE Y/M/D = ',   &
127           &                   nyear, '/', nmonth, '/', nday, '  nsec_day:', nsec_day, '  nsec_week:', nsec_week
128
129      ! Up to now, calendar parameters are related to the end of previous run (nit000-1)
130      ! call day to set the calendar parameters at the begining of the current simulaton. needed by iom_init
131      CALL day( nit000 )
132      !
133   END SUBROUTINE day_init
134
135
136   SUBROUTINE day_mth
137      !!----------------------------------------------------------------------
138      !!                   ***  ROUTINE day_init  ***
139      !!
140      !! ** Purpose :   calendar values related to the months
141      !!
142      !! ** Action  : - nmonth_len    : length in days of the months of the current year
143      !!              - nyear_len     : length in days of the previous/current year
144      !!              - nmonth_half   : second since the beginning of the year and the halft of the months
145      !!              - nmonth_end    : second since the beginning of the year and the end of the months
146      !!----------------------------------------------------------------------
147      INTEGER  ::   jm               ! dummy loop indice
148      !!----------------------------------------------------------------------
149
150      ! length of the month of the current year (from nleapy, read in namelist)
151      IF ( nleapy < 2 ) THEN
152         nmonth_len(:) = (/ 31, 31, 28, 31, 30, 31, 30, 31, 31, 30, 31, 30, 31, 31 /)
153         nyear_len(:) = 365
154         IF ( nleapy == 1 ) THEN   ! we are using calandar with leap years
155            IF ( MOD(nyear-1, 4) == 0 .AND. ( MOD(nyear-1, 400) == 0 .OR. MOD(nyear-1, 100) /= 0 ) ) THEN
156               nyear_len(0)  = 366
157            ENDIF
158            IF ( MOD(nyear  , 4) == 0 .AND. ( MOD(nyear  , 400) == 0 .OR. MOD(nyear  , 100) /= 0 ) ) THEN
159               nmonth_len(2) = 29
160               nyear_len(1)  = 366
161            ENDIF
162            IF ( MOD(nyear+1, 4) == 0 .AND. ( MOD(nyear+1, 400) == 0 .OR. MOD(nyear+1, 100) /= 0 ) ) THEN
163               nyear_len(2)  = 366
164            ENDIF
165         ENDIF
166      ELSE
167         nmonth_len(:) = nleapy   ! all months with nleapy days per year
168         nyear_len(:) = 12 * nleapy
169      ENDIF
170
171      ! half month in second since the begining of the year:
172      ! time since Jan 1st   0     1     2    ...    11    12    13
173      !          ---------*--|--*--|--*--| ... |--*--|--*--|--*--|--------------------------------------
174      !                 <---> <---> <--->  ...  <---> <---> <--->       
175      ! month number      0     1     2    ...    11    12    13
176      !
177      ! nmonth_half(jm) = rday * REAL( 0.5 * nmonth_len(jm) + SUM(nmonth_len(1:jm-1)) )
178      nmonth_half(0) = - nsecd05 * nmonth_len(0)
179      DO jm = 1, 13
180         nmonth_half(jm) = nmonth_half(jm-1) + nsecd05 * ( nmonth_len(jm-1) + nmonth_len(jm) )
181      END DO
182
183      nmonth_end(0) = 0
184      DO jm = 1, 13
185         nmonth_end(jm) = nmonth_end(jm-1) + nsecd * nmonth_len(jm)
186      END DO
187      !           
188   END SUBROUTINE
189
190
191   SUBROUTINE day( kt )
192      !!----------------------------------------------------------------------
193      !!                      ***  ROUTINE day  ***
194      !!
195      !! ** Purpose :   Compute the date with a day iteration IF necessary.
196      !!
197      !! ** Method  : - ???
198      !!
199      !! ** Action  : - nyear     : current year
200      !!              - nmonth    : current month of the year nyear
201      !!              - nday      : current day of the month nmonth
202      !!              - nday_year : current day of the year nyear
203      !!              - ndastp    : = nyear*10000 + nmonth*100 + nday
204      !!              - adatrj    : date in days since the beginning of the run
205      !!              - nsec_year : current time of the year (in second since 00h, jan 1st)
206      !!----------------------------------------------------------------------     
207      INTEGER, INTENT(in) ::   kt        ! ocean time-step indices
208      !
209      CHARACTER (len=25) ::   charout
210      REAL(wp)           ::   zprec      ! fraction of day corresponding to 0.1 second
211      !!----------------------------------------------------------------------
212      !
213      IF( nn_timing == 1 )  CALL timing_start('day')
214      !
215      zprec = 0.1 / rday
216      !                                                 ! New time-step
217      nsec_year  = nsec_year  + ndt 
218      nsec_month = nsec_month + ndt                 
219      nsec_week  = nsec_week  + ndt
220      nsec_day   = nsec_day   + ndt               
221      adatrj  = adatrj  + rdttra(1) / rday
222      fjulday = fjulday + rdttra(1) / rday
223      IF( ABS(fjulday - REAL(NINT(fjulday),wp)) < zprec )   fjulday = REAL(NINT(fjulday),wp)   ! avoid truncation error
224      IF( ABS(adatrj  - REAL(NINT(adatrj ),wp)) < zprec )   adatrj  = REAL(NINT(adatrj ),wp)   ! avoid truncation error
225     
226      IF( nsec_day > nsecd ) THEN                       ! New day
227         !
228         nday      = nday + 1
229         nday_year = nday_year + 1
230         nsec_day  = ndt05
231         !
232         IF( nday == nmonth_len(nmonth) + 1 ) THEN      ! New month
233            nday   = 1
234            nmonth = nmonth + 1
235            nsec_month = ndt05
236            IF( nmonth == 13 ) THEN                     ! New year
237               nyear     = nyear + 1
238               nmonth    = 1
239               nday_year = 1
240               nsec_year = ndt05
241               IF( nsec1jan000 >= 2 * (2**30 - nsecd * nyear_len(1) / 2 ) ) THEN   ! test integer 4 max value
242                  CALL ctl_stop( 'The number of seconds between Jan. 1st 00h of nit000 year and Jan. 1st 00h ',   &
243                     &           'of the current year is exceeding the INTEGER 4 max VALUE: 2^31-1 -> 68.09 years in seconds', &
244                     & 'You must do a restart at higher frequency (or remove this STOP and recompile everything in I8)' )
245               ENDIF
246               nsec1jan000 = nsec1jan000 + nsecd * nyear_len(1)
247               IF( nleapy == 1 )   CALL day_mth
248            ENDIF
249         ENDIF
250         !
251         ndastp = nyear * 10000 + nmonth * 100 + nday   ! New date
252         !
253         !compute first day of the year in julian days
254         CALL ymds2ju( nyear, 01, 01, 0.0, fjulstartyear )
255         !
256         IF(lwp) WRITE(numout,'(a,i8,a,i4.4,a,i2.2,a,i2.2,a,i3.3)') '======>> time-step =', kt,   &
257              &   '      New day, DATE Y/M/D = ', nyear, '/', nmonth, '/', nday, '      nday_year = ', nday_year
258         IF(lwp) WRITE(numout,'(a,i8,a,i7,a,i5)') '         nsec_year = ', nsec_year,   &
259              &   '   nsec_month = ', nsec_month, '   nsec_day = ', nsec_day, '   nsec_week = ', nsec_week
260      ENDIF
261
262      IF( nsec_week > 7*nsecd )   nsec_week = ndt05     ! New week
263     
264      IF(ln_ctl) THEN
265         WRITE(charout,FMT="('kt =', I4,'  d/m/y =',I2,I2,I4)") kt, nday, nmonth, nyear
266         CALL prt_ctl_info(charout)
267      ENDIF
268
269      ! since we no longer call rst_opn, need to define nitrst here, used by ice restart routine
270      IF( kt == nit000 ) nitrst = nitend
271      IF( MOD( kt - 1, nstock ) == 0 ) THEN
272         ! we use kt - 1 and not kt - nit000 to keep the same periodicity from the beginning of the experiment
273         nitrst = kt + nstock - 1                  ! define the next value of nitrst for restart writing
274         IF( nitrst > nitend )   nitrst = nitend   ! make sure we write a restart at the end of the run
275      ENDIF
276
277      IF( nn_timing == 1 )  CALL timing_stop('day')
278      !
279   END SUBROUTINE day
280
281
282   SUBROUTINE day_rst( kt, cdrw )
283      !!---------------------------------------------------------------------
284      !!                   ***  ROUTINE ts_rst  ***
285      !!
286      !!  ** Purpose : Read or write calendar in restart file:
287      !!
288      !!  WRITE(READ) mode:
289      !!       kt        : number of time step since the begining of the experiment at the
290      !!                   end of the current(previous) run
291      !!       adatrj(0) : number of elapsed days since the begining of the experiment at the
292      !!                   end of the current(previous) run (REAL -> keep fractions of day)
293      !!       ndastp    : date at the end of the current(previous) run (coded as yyyymmdd integer)
294      !!
295      !!   According to namelist parameter nrstdt,
296      !!       nrstdt = 0  no control on the date (nit000 is  arbitrary).
297      !!       nrstdt = 1  we verify that nit000 is equal to the last
298      !!                   time step of previous run + 1.
299      !!       In both those options, the  exact duration of the experiment
300      !!       since the beginning (cumulated duration of all previous restart runs)
301      !!       is not stored in the restart and is assumed to be (nit000-1)*rdt.
302      !!       This is valid is the time step has remained constant.
303      !!
304      !!       nrstdt = 2  the duration of the experiment in days (adatrj)
305      !!                    has been stored in the restart file.
306      !!----------------------------------------------------------------------
307      INTEGER         , INTENT(in) ::   kt         ! ocean time-step
308      CHARACTER(len=*), INTENT(in) ::   cdrw       ! "READ"/"WRITE" flag
309      !
310      REAL(wp) ::   zkt, zndastp
311      !!----------------------------------------------------------------------
312
313      IF( TRIM(cdrw) == 'READ' ) THEN
314
315         IF( iom_varid( numror, 'kt', ldstop = .FALSE. ) > 0 ) THEN
316            ! Get Calendar informations
317            CALL iom_get( numror, 'kt', zkt )   ! last time-step of previous run
318            IF(lwp) THEN
319               WRITE(numout,*) ' *** Info read in restart : '
320               WRITE(numout,*) '   previous time-step                               : ', NINT( zkt )
321               WRITE(numout,*) ' *** restart option'
322               SELECT CASE ( nrstdt )
323               CASE ( 0 )   ;   WRITE(numout,*) ' nrstdt = 0 : no control of nit000'
324               CASE ( 1 )   ;   WRITE(numout,*) ' nrstdt = 1 : no control the date at nit000 (use ndate0 read in the namelist)'
325               CASE ( 2 )   ;   WRITE(numout,*) ' nrstdt = 2 : calendar parameters read in restart'
326               END SELECT
327               WRITE(numout,*)
328            ENDIF
329            ! Control of date
330            IF( nit000 - NINT( zkt ) /= 1 .AND. nrstdt /= 0 )                                         &
331                 &   CALL ctl_stop( ' ===>>>> : problem with nit000 for the restart',                 &
332                 &                  ' verify the restart file or rerun with nrstdt = 0 (namelist)' )
333            ! define ndastp and adatrj
334            IF ( nrstdt == 2 ) THEN
335               ! read the parameters correspondting to nit000 - 1 (last time step of previous run)
336               CALL iom_get( numror, 'ndastp', zndastp )
337               ndastp = NINT( zndastp )
338               CALL iom_get( numror, 'adatrj', adatrj  )
339            ELSE
340               ! parameters correspondting to nit000 - 1 (as we start the step loop with a call to day)
341               ndastp = ndate0 - 1     ! ndate0 read in the namelist in dom_nam, we assume that we start run at 00:00
342               adatrj = ( REAL( nit000-1, wp ) * rdttra(1) ) / rday
343               ! note this is wrong if time step has changed during run
344            ENDIF
345         ELSE
346            ! parameters correspondting to nit000 - 1 (as we start the step loop with a call to day)
347            ndastp = ndate0 - 1        ! ndate0 read in the namelist in dom_nam, we assume that we start run at 00:00
348            adatrj = ( REAL( nit000-1, wp ) * rdttra(1) ) / rday
349         ENDIF
350         IF( ABS(adatrj  - REAL(NINT(adatrj),wp)) < 0.1 / rday )   adatrj = REAL(NINT(adatrj),wp)   ! avoid truncation error
351         !
352         IF(lwp) THEN
353            WRITE(numout,*) ' *** Info used values : '
354            WRITE(numout,*) '   date ndastp                                      : ', ndastp
355            WRITE(numout,*) '   number of elapsed days since the begining of run : ', adatrj
356            WRITE(numout,*)
357         ENDIF
358         !
359      ELSEIF( TRIM(cdrw) == 'WRITE' ) THEN
360         !
361         IF( kt == nitrst ) THEN
362            IF(lwp) WRITE(numout,*)
363            IF(lwp) WRITE(numout,*) 'rst_write : write oce restart file  kt =', kt
364            IF(lwp) WRITE(numout,*) '~~~~~~~'
365         ENDIF
366         ! calendar control
367         CALL iom_rstput( kt, nitrst, numrow, 'kt'     , REAL( kt    , wp) )   ! time-step
368         CALL iom_rstput( kt, nitrst, numrow, 'ndastp' , REAL( ndastp, wp) )   ! date
369         CALL iom_rstput( kt, nitrst, numrow, 'adatrj' , adatrj            )   ! number of elapsed days since
370         !                                                                     ! the begining of the run [s]
371      ENDIF
372      !
373   END SUBROUTINE day_rst
374   !!======================================================================
375END MODULE daymod
Note: See TracBrowser for help on using the repository browser.