source: trunk/NEMOGCM/NEMO/SAS_SRC/daymod.F90 @ 7881

Last change on this file since 7881 was 7761, checked in by clem, 4 years ago

make AGRIF and LIM3 fully compatible

  • Property svn:keywords set to Id
File size: 18.5 KB
Line 
1MODULE daymod
2   !!======================================================================
3   !!                       ***  MODULE  daymod  ***
4   !! Ocean        :  calendar
5   !!=====================================================================
6   !! History :  OPA  ! 1994-09  (M. Pontaud M. Imbard)  Original code
7   !!                 ! 1997-03  (O. Marti)
8   !!                 ! 1997-05  (G. Madec)
9   !!                 ! 1997-08  (M. Imbard)
10   !!   NEMO     1.0  ! 2003-09  (G. Madec)  F90 + nyear, nmonth, nday
11   !!                 ! 2004-01  (A.M. Treguier) new calculation based on adatrj
12   !!                 ! 2006-08  (G. Madec)  surface module major update
13   !!----------------------------------------------------------------------     
14
15   !!----------------------------------------------------------------------
16   !!   day        : calendar
17   !! 
18   !!           -------------------------------
19   !!           ----------- WARNING -----------
20   !!
21   !!   we suppose that the time step is deviding the number of second of in a day
22   !!             ---> MOD( rday, rdt ) == 0
23   !!
24   !!           ----------- WARNING -----------
25   !!           -------------------------------
26   !! 
27   !!----------------------------------------------------------------------
28   USE dom_oce         ! ocean space and time domain
29   USE phycst          ! physical constants
30   USE in_out_manager  ! I/O manager
31   USE iom             !
32   USE ioipsl, ONLY :   ymds2ju   ! for calendar
33   USE prtctl          ! Print control
34   USE restart         !
35   USE timing          ! Timing
36
37   IMPLICIT NONE
38   PRIVATE
39
40   PUBLIC   day        ! called by step.F90
41   PUBLIC   day_init   ! called by istate.F90
42
43   INTEGER ::   nsecd, nsecd05, ndt, ndt05
44
45   !!----------------------------------------------------------------------
46   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
47   !! $Id$
48   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
49   !!----------------------------------------------------------------------
50CONTAINS
51
52   SUBROUTINE day_init
53      !!----------------------------------------------------------------------
54      !!                   ***  ROUTINE day_init  ***
55      !!
56      !! ** Purpose :   Initialization of the calendar values to their values 1 time step before nit000
57      !!                because day will be called at the beginning of step
58      !!
59      !! ** Action  : - nyear        : current year
60      !!              - nmonth       : current month of the year nyear
61      !!              - nday         : current day of the month nmonth
62      !!              - nday_year    : current day of the year nyear
63      !!              - nsec_year    : current time step counted in second since 00h jan 1st of the current year
64      !!              - nsec_month   : current time step counted in second since 00h 1st day of the current month
65      !!              - nsec_day     : current time step counted in second since 00h of the current day
66      !!              - nsec1jan000  : second since Jan. 1st 00h of nit000 year and Jan. 1st 00h of the current year
67      !!              - nmonth_len, nyear_len, nmonth_half, nmonth_end through day_mth
68      !!----------------------------------------------------------------------
69      INTEGER  ::   inbday, idweek
70      REAL(wp) ::   zjul
71      !!----------------------------------------------------------------------
72      !
73      ! max number of seconds between each restart
74      IF( REAL( nitend - nit000 + 1 ) * rdt > REAL( HUGE( nsec1jan000 ) ) ) THEN
75         CALL ctl_stop( 'The number of seconds between each restart exceeds the integer 4 max value: 2^31-1. ',   &
76            &           'You must do a restart at higher frequency (or remove this stop and recompile the code in I8)' )
77      ENDIF
78      ! all calendar staff is based on the fact that MOD( rday, rdt ) == 0
79      IF( MOD( rday , rdt ) /= 0. )   CALL ctl_stop( 'the time step must devide the number of second of in a day' )
80      IF( MOD( rday , 2.  ) /= 0. )   CALL ctl_stop( 'the number of second of in a day must be an even number'    )
81      IF( MOD( rdt  , 2.  ) /= 0. )   CALL ctl_stop( 'the time step (in second) must be an even number'           )
82      nsecd   = NINT(rday       )
83      nsecd05 = NINT(0.5 * rday )
84      ndt     = NINT(      rdt  )
85      ndt05   = NINT(0.5 * rdt  )
86
87      ! ==> clem: here we read the ocean restart for the date (only if it exists)
88      !           It is not clean and another solution should be found
89      CALL day_rst( nit000, 'READ' )
90      ! ==>
91
92      ! set the calendar from ndastp (read in restart file and namelist)
93
94      nyear   =   ndastp / 10000
95      nmonth  = ( ndastp - (nyear * 10000) ) / 100
96      nday    =   ndastp - (nyear * 10000) - ( nmonth * 100 ) 
97
98      CALL ymds2ju( nyear, nmonth, nday, 0.0, fjulday )  ! we assume that we start run at 00:00
99      IF( ABS(fjulday - REAL(NINT(fjulday),wp)) < 0.1 / rday )   fjulday = REAL(NINT(fjulday),wp)   ! avoid truncation error
100      fjulday = fjulday + 1.                             ! move back to the day at nit000 (and not at nit000 - 1)
101
102      nsec1jan000 = 0
103      CALL day_mth
104     
105      IF ( nday == 0 ) THEN     !   for ex if ndastp = ndate0 - 1
106         nmonth = nmonth - 1 
107         nday = nmonth_len(nmonth)
108      ENDIF
109      IF ( nmonth == 0 ) THEN   ! go at the end of previous year
110         nmonth = 12
111         nyear = nyear - 1
112         nsec1jan000 = nsec1jan000 - nsecd * nyear_len(0)
113         IF( nleapy == 1 )   CALL day_mth
114      ENDIF
115     
116      ! day since january 1st
117      nday_year = nday + SUM( nmonth_len(1:nmonth - 1) )
118
119      !compute number of days between last monday and today     
120      CALL ymds2ju( 1900, 01, 01, 0.0, zjul )  ! compute julian day value of 01.01.1900 (our reference that was a Monday)
121      inbday = NINT(fjulday - zjul)            ! compute nb day between  01.01.1900 and current day 
122      idweek = MOD(inbday, 7)                  ! compute nb day between last monday and current day 
123
124      ! number of seconds since the beginning of current year/month/week/day at the middle of the time-step
125      nsec_year  = nday_year * nsecd - ndt05   ! 1 time step before the middle of the first time step
126      nsec_month = nday      * nsecd - ndt05   ! because day will be called at the beginning of step
127      nsec_week  = idweek    * nsecd - ndt05
128      nsec_day   =             nsecd - ndt05
129
130      ! control print
131      IF(lwp) WRITE(numout,'(a,i6,a,i2,a,i2,a,i8,a,i8)')' =======>> 1/2 time step before the start of the run DATE Y/M/D = ',   &
132           &                   nyear, '/', nmonth, '/', nday, '  nsec_day:', nsec_day, '  nsec_week:', nsec_week
133
134      ! Up to now, calendar parameters are related to the end of previous run (nit000-1)
135      ! call day to set the calendar parameters at the begining of the current simulaton. needed by iom_init
136      CALL day( nit000 )
137      !
138   END SUBROUTINE day_init
139
140
141   SUBROUTINE day_mth
142      !!----------------------------------------------------------------------
143      !!                   ***  ROUTINE day_init  ***
144      !!
145      !! ** Purpose :   calendar values related to the months
146      !!
147      !! ** Action  : - nmonth_len    : length in days of the months of the current year
148      !!              - nyear_len     : length in days of the previous/current year
149      !!              - nmonth_half   : second since the beginning of the year and the halft of the months
150      !!              - nmonth_end    : second since the beginning of the year and the end of the months
151      !!----------------------------------------------------------------------
152      INTEGER  ::   jm               ! dummy loop indice
153      !!----------------------------------------------------------------------
154
155      ! length of the month of the current year (from nleapy, read in namelist)
156      IF ( nleapy < 2 ) THEN
157         nmonth_len(:) = (/ 31, 31, 28, 31, 30, 31, 30, 31, 31, 30, 31, 30, 31, 31 /)
158         nyear_len(:) = 365
159         IF ( nleapy == 1 ) THEN   ! we are using calandar with leap years
160            IF ( MOD(nyear-1, 4) == 0 .AND. ( MOD(nyear-1, 400) == 0 .OR. MOD(nyear-1, 100) /= 0 ) ) THEN
161               nyear_len(0)  = 366
162            ENDIF
163            IF ( MOD(nyear  , 4) == 0 .AND. ( MOD(nyear  , 400) == 0 .OR. MOD(nyear  , 100) /= 0 ) ) THEN
164               nmonth_len(2) = 29
165               nyear_len(1)  = 366
166            ENDIF
167            IF ( MOD(nyear+1, 4) == 0 .AND. ( MOD(nyear+1, 400) == 0 .OR. MOD(nyear+1, 100) /= 0 ) ) THEN
168               nyear_len(2)  = 366
169            ENDIF
170         ENDIF
171      ELSE
172         nmonth_len(:) = nleapy   ! all months with nleapy days per year
173         nyear_len(:) = 12 * nleapy
174      ENDIF
175
176      ! half month in second since the begining of the year:
177      ! time since Jan 1st   0     1     2    ...    11    12    13
178      !          ---------*--|--*--|--*--| ... |--*--|--*--|--*--|--------------------------------------
179      !                 <---> <---> <--->  ...  <---> <---> <--->       
180      ! month number      0     1     2    ...    11    12    13
181      !
182      ! nmonth_half(jm) = rday * REAL( 0.5 * nmonth_len(jm) + SUM(nmonth_len(1:jm-1)) )
183      nmonth_half(0) = - nsecd05 * nmonth_len(0)
184      DO jm = 1, 13
185         nmonth_half(jm) = nmonth_half(jm-1) + nsecd05 * ( nmonth_len(jm-1) + nmonth_len(jm) )
186      END DO
187
188      nmonth_end(0) = 0
189      DO jm = 1, 13
190         nmonth_end(jm) = nmonth_end(jm-1) + nsecd * nmonth_len(jm)
191      END DO
192      !           
193   END SUBROUTINE
194
195
196   SUBROUTINE day( kt )
197      !!----------------------------------------------------------------------
198      !!                      ***  ROUTINE day  ***
199      !!
200      !! ** Purpose :   Compute the date with a day iteration IF necessary.
201      !!
202      !! ** Method  : - ???
203      !!
204      !! ** Action  : - nyear     : current year
205      !!              - nmonth    : current month of the year nyear
206      !!              - nday      : current day of the month nmonth
207      !!              - nday_year : current day of the year nyear
208      !!              - ndastp    : = nyear*10000 + nmonth*100 + nday
209      !!              - adatrj    : date in days since the beginning of the run
210      !!              - nsec_year : current time of the year (in second since 00h, jan 1st)
211      !!----------------------------------------------------------------------     
212      INTEGER, INTENT(in) ::   kt        ! ocean time-step indices
213      !
214      CHARACTER (len=25) ::   charout
215      REAL(wp)           ::   zprec      ! fraction of day corresponding to 0.1 second
216      !!----------------------------------------------------------------------
217      !
218      IF( nn_timing == 1 )  CALL timing_start('day')
219      !
220      zprec = 0.1 / rday
221      !                                                 ! New time-step
222      nsec_year  = nsec_year  + ndt 
223      nsec_month = nsec_month + ndt                 
224      nsec_week  = nsec_week  + ndt
225      nsec_day   = nsec_day   + ndt               
226      adatrj  = adatrj  + rdt / rday
227      fjulday = fjulday + rdt / rday
228      IF( ABS(fjulday - REAL(NINT(fjulday),wp)) < zprec )   fjulday = REAL(NINT(fjulday),wp)   ! avoid truncation error
229      IF( ABS(adatrj  - REAL(NINT(adatrj ),wp)) < zprec )   adatrj  = REAL(NINT(adatrj ),wp)   ! avoid truncation error
230     
231      IF( nsec_day > nsecd ) THEN                       ! New day
232         !
233         nday      = nday + 1
234         nday_year = nday_year + 1
235         nsec_day  = ndt05
236         !
237         IF( nday == nmonth_len(nmonth) + 1 ) THEN      ! New month
238            nday   = 1
239            nmonth = nmonth + 1
240            nsec_month = ndt05
241            IF( nmonth == 13 ) THEN                     ! New year
242               nyear     = nyear + 1
243               nmonth    = 1
244               nday_year = 1
245               nsec_year = ndt05
246               nsec1jan000 = nsec1jan000 + nsecd * nyear_len(1)
247               IF( nleapy == 1 )   CALL day_mth
248            ENDIF
249         ENDIF
250         !
251         ndastp = nyear * 10000 + nmonth * 100 + nday   ! New date
252         !
253         !compute first day of the year in julian days
254         CALL ymds2ju( nyear, 01, 01, 0.0, fjulstartyear )
255         !
256         IF(lwp) WRITE(numout,'(a,i8,a,i4.4,a,i2.2,a,i2.2,a,i3.3)') '======>> time-step =', kt,   &
257              &   '      New day, DATE Y/M/D = ', nyear, '/', nmonth, '/', nday, '      nday_year = ', nday_year
258         IF(lwp) WRITE(numout,'(a,i8,a,i7,a,i5)') '         nsec_year = ', nsec_year,   &
259              &   '   nsec_month = ', nsec_month, '   nsec_day = ', nsec_day, '   nsec_week = ', nsec_week
260      ENDIF
261
262      IF( nsec_week > 7*nsecd )   nsec_week = ndt05     ! New week
263     
264      IF(ln_ctl) THEN
265         WRITE(charout,FMT="('kt =', I4,'  d/m/y =',I2,I2,I4)") kt, nday, nmonth, nyear
266         CALL prt_ctl_info(charout)
267      ENDIF
268
269      ! since we no longer call rst_opn, need to define nitrst here, used by ice restart routine
270      IF( kt == nit000 )  THEN
271         nitrst = nitend
272         lrst_oce = .FALSE.  ! init restart ocean (done in rst_opn when not SAS)
273      ENDIF
274
275      IF( MOD( kt - 1, nstock ) == 0 ) THEN
276         ! we use kt - 1 and not kt - nit000 to keep the same periodicity from the beginning of the experiment
277         nitrst = kt + nstock - 1                  ! define the next value of nitrst for restart writing
278         IF( nitrst > nitend )   nitrst = nitend   ! make sure we write a restart at the end of the run
279      ENDIF
280
281      IF( nn_timing == 1 )  CALL timing_stop('day')
282      !
283   END SUBROUTINE day
284
285
286   SUBROUTINE day_rst( kt, cdrw )
287      !!---------------------------------------------------------------------
288      !!                   ***  ROUTINE ts_rst  ***
289      !!
290      !!  ** Purpose : Read or write calendar in restart file:
291      !!
292      !!  WRITE(READ) mode:
293      !!       kt        : number of time step since the begining of the experiment at the
294      !!                   end of the current(previous) run
295      !!       adatrj(0) : number of elapsed days since the begining of the experiment at the
296      !!                   end of the current(previous) run (REAL -> keep fractions of day)
297      !!       ndastp    : date at the end of the current(previous) run (coded as yyyymmdd integer)
298      !!
299      !!   According to namelist parameter nrstdt,
300      !!       nrstdt = 0  no control on the date (nit000 is  arbitrary).
301      !!       nrstdt = 1  we verify that nit000 is equal to the last
302      !!                   time step of previous run + 1.
303      !!       In both those options, the  exact duration of the experiment
304      !!       since the beginning (cumulated duration of all previous restart runs)
305      !!       is not stored in the restart and is assumed to be (nit000-1)*rdt.
306      !!       This is valid is the time step has remained constant.
307      !!
308      !!       nrstdt = 2  the duration of the experiment in days (adatrj)
309      !!                    has been stored in the restart file.
310      !!----------------------------------------------------------------------
311      INTEGER         , INTENT(in) ::   kt         ! ocean time-step
312      CHARACTER(len=*), INTENT(in) ::   cdrw       ! "READ"/"WRITE" flag
313      !
314      REAL(wp) ::   zkt, zndastp
315      !!----------------------------------------------------------------------
316
317      IF( TRIM(cdrw) == 'READ' ) THEN
318
319         IF( iom_varid( numror, 'kt', ldstop = .FALSE. ) > 0 ) THEN
320            ! Get Calendar informations
321            CALL iom_get( numror, 'kt', zkt )   ! last time-step of previous run
322            IF(lwp) THEN
323               WRITE(numout,*) ' *** Info read in restart : '
324               WRITE(numout,*) '   previous time-step                               : ', NINT( zkt )
325               WRITE(numout,*) ' *** restart option'
326               SELECT CASE ( nrstdt )
327               CASE ( 0 )   ;   WRITE(numout,*) ' nrstdt = 0 : no control of nit000'
328               CASE ( 1 )   ;   WRITE(numout,*) ' nrstdt = 1 : no control the date at nit000 (use ndate0 read in the namelist)'
329               CASE ( 2 )   ;   WRITE(numout,*) ' nrstdt = 2 : calendar parameters read in restart'
330               END SELECT
331               WRITE(numout,*)
332            ENDIF
333            ! Control of date
334            IF( nit000 - NINT( zkt ) /= 1 .AND. nrstdt /= 0 )                                         &
335                 &   CALL ctl_stop( ' ===>>>> : problem with nit000 for the restart',                 &
336                 &                  ' verify the restart file or rerun with nrstdt = 0 (namelist)' )
337            ! define ndastp and adatrj
338            IF ( nrstdt == 2 ) THEN
339               ! read the parameters correspondting to nit000 - 1 (last time step of previous run)
340               CALL iom_get( numror, 'ndastp', zndastp )
341               ndastp = NINT( zndastp )
342               CALL iom_get( numror, 'adatrj', adatrj  )
343            ELSE
344               ! parameters correspondting to nit000 - 1 (as we start the step loop with a call to day)
345               ndastp = ndate0 - 1     ! ndate0 read in the namelist in dom_nam, we assume that we start run at 00:00
346               adatrj = ( REAL( nit000-1, wp ) * rdt ) / rday
347               ! note this is wrong if time step has changed during run
348            ENDIF
349         ELSE
350            ! parameters correspondting to nit000 - 1 (as we start the step loop with a call to day)
351            ndastp = ndate0 - 1        ! ndate0 read in the namelist in dom_nam, we assume that we start run at 00:00
352            adatrj = ( REAL( nit000-1, wp ) * rdt ) / rday
353         ENDIF
354         IF( ABS(adatrj  - REAL(NINT(adatrj),wp)) < 0.1 / rday )   adatrj = REAL(NINT(adatrj),wp)   ! avoid truncation error
355         !
356         IF(lwp) THEN
357            WRITE(numout,*) ' *** Info used values : '
358            WRITE(numout,*) '   date ndastp                                      : ', ndastp
359            WRITE(numout,*) '   number of elapsed days since the begining of run : ', adatrj
360            WRITE(numout,*)
361         ENDIF
362         !
363      ELSEIF( TRIM(cdrw) == 'WRITE' ) THEN
364         !
365         IF( kt == nitrst ) THEN
366            IF(lwp) WRITE(numout,*)
367            IF(lwp) WRITE(numout,*) 'rst_write : write oce restart file  kt =', kt
368            IF(lwp) WRITE(numout,*) '~~~~~~~'
369         ENDIF
370         ! calendar control
371         CALL iom_rstput( kt, nitrst, numrow, 'kt'     , REAL( kt    , wp) )   ! time-step
372         CALL iom_rstput( kt, nitrst, numrow, 'ndastp' , REAL( ndastp, wp) )   ! date
373         CALL iom_rstput( kt, nitrst, numrow, 'adatrj' , adatrj            )   ! number of elapsed days since
374         !                                                                     ! the begining of the run [s]
375      ENDIF
376      !
377   END SUBROUTINE day_rst
378   !!======================================================================
379END MODULE daymod
Note: See TracBrowser for help on using the repository browser.