New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trcopt.F90 in trunk/NEMOGCM/NEMO/TOP_SRC/LOBSTER – NEMO

source: trunk/NEMOGCM/NEMO/TOP_SRC/LOBSTER/trcopt.F90 @ 2715

Last change on this file since 2715 was 2715, checked in by rblod, 13 years ago

First attempt to put dynamic allocation on the trunk
  • Property svn:keywords set to Id
File size: 7.0 KB
Line 
1MODULE trcopt
2   !!======================================================================
3   !!                         ***  MODULE trcopt  ***
4   !! TOP :   LOBSTER Compute the light availability in the water column
5   !!======================================================================
6   !! History :    -   !  1995-05  (M. Levy) Original code
7   !!              -   !  1999-09  (J.-M. Andre, M. Levy)
8   !!              -   !  1999-11  (C. Menkes, M.-A. Foujols) itabe initial
9   !!              -   !  2000-02  (M.A. Foujols) change x**y par exp(y*log(x))
10   !!   NEMO      2.0  !  2007-12  (C. Deltel, G. Madec)  F90
11   !!             3.2  !  2009-04  (C. Ethe, G. Madec)  minor optimisation + style
12   !!----------------------------------------------------------------------
13#if defined key_lobster
14   !!----------------------------------------------------------------------
15   !!   'key_lobster'                                     LOBSTER bio-model
16   !!----------------------------------------------------------------------
17   !!   trc_opt        :   Compute the light availability in the water column
18   !!----------------------------------------------------------------------
19   USE oce_trc         !
20   USE trc
21   USE sms_lobster
22   USE prtctl_trc      ! Print control for debbuging
23
24   IMPLICIT NONE
25   PRIVATE
26
27   PUBLIC   trc_opt   ! called in trcprg.F90
28
29   !!* Substitution
30#  include "top_substitute.h90"
31   !!----------------------------------------------------------------------
32   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
33   !! $Id$
34   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
35   !!----------------------------------------------------------------------
36
37CONTAINS
38
39   SUBROUTINE trc_opt( kt )
40      !!---------------------------------------------------------------------
41      !!                     ***  ROUTINE trc_opt  ***
42      !!
43      !! ** Purpose :   computes the light propagation in the water column
44      !!              and the euphotic layer depth
45      !!
46      !! ** Method  :   local par is computed in w layers using light propagation
47      !!              mean par in t layers are computed by integration
48      !!
49!!gm please remplace the '???' by true comments
50      !! ** Action  :   xpar   ???
51      !!                neln   ???
52      !!                xze    ???
53      !!---------------------------------------------------------------------
54      USE wrk_nemo, ONLY: wrk_in_use, wrk_not_released
55      USE wrk_nemo, ONLY: zpar100 => wrk_2d_1, & ! irradiance at euphotic layer depth
56                          zpar0m  => wrk_2d_2    ! irradiance just below the surface
57      USE wrk_nemo, ONLY: zparr => wrk_3d_2, &   ! red and green compound of par
58                          zparg => wrk_3d_3
59      !!
60      INTEGER, INTENT( in ) ::   kt   ! index of the time stepping
61      !!
62      INTEGER  ::   ji, jj, jk          ! dummy loop indices
63      CHARACTER (len=25) ::   charout   ! temporary character
64      REAL(wp) ::   zpig                ! log of the total pigment
65      REAL(wp) ::   zkr, zkg            ! total absorption coefficient in red and green
66      REAL(wp) ::   zcoef               ! temporary scalar
67
68      !!---------------------------------------------------------------------
69
70      IF( ( wrk_in_use(2, 1,2)) .OR. ( wrk_in_use(3, 2,3)) )THEN
71         CALL ctl_stop('trc_opt : requested workspace arrays unavailable')   ;   RETURN
72      END IF
73
74      IF( kt == nit000 ) THEN
75         IF(lwp) WRITE(numout,*)
76         IF(lwp) WRITE(numout,*) ' trc_opt : LOBSTER optic-model'
77         IF(lwp) WRITE(numout,*) ' ~~~~~~~ '
78      ENDIF
79
80      !                                          ! surface irradiance
81      zpar0m (:,:)   = qsr   (:,:) * 0.43        ! ------------------
82      zpar100(:,:)   = zpar0m(:,:) * 0.01
83      xpar   (:,:,1) = zpar0m(:,:)
84      zparr  (:,:,1) = zpar0m(:,:) * 0.5
85      zparg  (:,:,1) = zpar0m(:,:) * 0.5
86
87      !                                          ! Photosynthetically Available Radiation (PAR)
88      zcoef = 12 * redf / rcchl / rpig           ! --------------------------------------
89      DO jk = 2, jpk                                  ! local par at w-levels
90         DO jj = 1, jpj
91            DO ji = 1, jpi
92               zpig = LOG(  MAX( TINY(0.), trn(ji,jj,jk-1,jp_lob_phy) ) * zcoef  )
93               zkr  = xkr0 + xkrp * EXP( xlr * zpig )
94               zkg  = xkg0 + xkgp * EXP( xlg * zpig )
95               zparr(ji,jj,jk) = zparr(ji,jj,jk-1) * EXP( -zkr * fse3t(ji,jj,jk-1) )
96               zparg(ji,jj,jk) = zparg(ji,jj,jk-1) * EXP( -zkg * fse3t(ji,jj,jk-1) )
97            END DO
98        END DO
99      END DO
100      DO jk = 1, jpkm1                                ! mean par at t-levels
101         DO jj = 1, jpj
102            DO ji = 1, jpi
103               zpig = LOG(  MAX( TINY(0.), trn(ji,jj,jk,jp_lob_phy) ) * zcoef  )
104               zkr  = xkr0 + xkrp * EXP( xlr * zpig )
105               zkg  = xkg0 + xkgp * EXP( xlg * zpig )
106               zparr(ji,jj,jk) = zparr(ji,jj,jk) / ( zkr * fse3t(ji,jj,jk) ) * ( 1 - EXP( -zkr * fse3t(ji,jj,jk) ) )
107               zparg(ji,jj,jk) = zparg(ji,jj,jk) / ( zkg * fse3t(ji,jj,jk) ) * ( 1 - EXP( -zkg * fse3t(ji,jj,jk) ) )
108               xpar (ji,jj,jk) = MAX( zparr(ji,jj,jk) + zparg(ji,jj,jk), 1.e-15 )
109            END DO
110         END DO
111      END DO
112
113      !                                          ! Euphotic layer
114      !                                          ! --------------
115      neln(:,:) = 1                                   ! euphotic layer level
116      DO jk = 1, jpk                                  ! (i.e. 1rst T-level strictly below EL bottom)
117         DO jj = 1, jpj
118           DO ji = 1, jpi
119              IF( xpar(ji,jj,jk) >= zpar100(ji,jj) )   neln(ji,jj) = jk + 1 
120              !                                       ! nb. this is to ensure compatibility with
121              !                                       ! nmld_trc definition in trd_mld_trc_zint
122           END DO
123         END DO
124      END DO
125      !                                               ! Euphotic layer depth
126      DO jj = 1, jpj
127         DO ji = 1, jpi
128            xze(ji,jj) = fsdepw(ji,jj,neln(ji,jj))
129         END DO
130      END DO
131
132
133      IF(ln_ctl) THEN      ! print mean trends (used for debugging)
134         WRITE(charout, FMT="('opt')")
135         CALL prt_ctl_trc_info( charout )
136         CALL prt_ctl_trc( tab4d=trn, mask=tmask, clinfo=ctrcnm )
137      ENDIF
138      !
139      IF( wrk_not_released(2, 1,2)  .OR.  wrk_not_released(3, 2,3)  )   &
140          CALL ctl_stop('trc_opt : failed to release workspace arrays')
141      !
142   END SUBROUTINE trc_opt
143
144#else
145   !!======================================================================
146   !!  Dummy module :                                   No PISCES bio-model
147   !!======================================================================
148CONTAINS
149   SUBROUTINE trc_opt( kt )                   ! Empty routine
150      INTEGER, INTENT( in ) ::   kt
151      WRITE(*,*) 'trc_opt: You should not have seen this print! error?', kt
152   END SUBROUTINE trc_opt
153#endif 
154
155   !!======================================================================
156END MODULE  trcopt
Note: See TracBrowser for help on using the repository browser.