New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zlys.F90 in trunk/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z – NEMO

source: trunk/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z/p4zlys.F90 @ 7698

Last change on this file since 7698 was 7698, checked in by mocavero, 7 years ago

update trunk with OpenMP parallelization
File size: 8.9 KB
Line 
1MODULE p4zlys
2   !!======================================================================
3   !!                         ***  MODULE p4zlys  ***
4   !! TOP :   PISCES
5   !!======================================================================
6   !! History :    -   !  1988-07  (E. MAIER-REIMER) Original code
7   !!              -   !  1998     (O. Aumont) additions
8   !!              -   !  1999     (C. Le Quere) modifications
9   !!             1.0  !  2004     (O. Aumont) modifications
10   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
11   !!                  !  2011-02  (J. Simeon, J. Orr)  Calcon salinity dependence
12   !!             3.4  !  2011-06  (O. Aumont, C. Ethe) Improvment of calcite dissolution
13   !!             3.6  !  2015-05  (O. Aumont) PISCES quota
14   !!----------------------------------------------------------------------
15   !!   p4z_lys        :   Compute the CaCO3 dissolution
16   !!   p4z_lys_init   :   Read the namelist parameters
17   !!----------------------------------------------------------------------
18   USE oce_trc         !  shared variables between ocean and passive tracers
19   USE trc             !  passive tracers common variables
20   USE sms_pisces      !  PISCES Source Minus Sink variables
21   USE p4zche          !  Chemical model
22   USE prtctl_trc      !  print control for debugging
23   USE iom             !  I/O manager
24
25   IMPLICIT NONE
26   PRIVATE
27
28   PUBLIC   p4z_lys         ! called in trcsms_pisces.F90
29   PUBLIC   p4z_lys_init    ! called in trcsms_pisces.F90
30
31   !! * Shared module variables
32   REAL(wp), PUBLIC :: kdca !: diss. rate constant calcite
33   REAL(wp), PUBLIC :: nca  !: order of reaction for calcite dissolution
34
35   !! * Module variables
36   REAL(wp) :: calcon = 1.03E-2           !: mean calcite concentration [Ca2+] in sea water [mole/kg solution]
37 
38   INTEGER  :: rmtss                      !: number of seconds per month
39
40   !!----------------------------------------------------------------------
41   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
42   !! $Id: p4zlys.F90 3321 2012-03-05 17:10:55Z cetlod $
43   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
44   !!----------------------------------------------------------------------
45
46CONTAINS
47
48   SUBROUTINE p4z_lys( kt, knt )
49      !!---------------------------------------------------------------------
50      !!                     ***  ROUTINE p4z_lys  ***
51      !!
52      !! ** Purpose :   CALCULATES DEGREE OF CACO3 SATURATION IN THE WATER
53      !!                COLUMN, DISSOLUTION/PRECIPITATION OF CACO3 AND LOSS
54      !!                OF CACO3 TO THE CACO3 SEDIMENT POOL.
55      !!
56      !! ** Method  : - ???
57      !!---------------------------------------------------------------------
58      !
59      INTEGER, INTENT(in) ::   kt, knt ! ocean time step
60      INTEGER  ::   ji, jj, jk, jn
61      REAL(wp) ::   zdispot, zfact, zcalcon
62      REAL(wp) ::   zomegaca, zexcess, zexcess0
63      CHARACTER (len=25) :: charout
64      REAL(wp), POINTER, DIMENSION(:,:,:) :: zco3, zcaldiss, zhinit, zhi, zco3sat
65      !!---------------------------------------------------------------------
66      !
67      IF( nn_timing == 1 )  CALL timing_start('p4z_lys')
68      !
69      CALL wrk_alloc( jpi, jpj, jpk, zco3, zcaldiss, zhinit, zhi, zco3sat )
70      !
71!$OMP PARALLEL DO schedule(static) private(jk, jj, ji)
72       DO jk = 1, jpk
73          DO jj = 1, jpj
74             DO ji = 1, jpi
75                zco3    (ji,jj,jk) = 0.
76                zcaldiss(ji,jj,jk) = 0.
77                zhinit(ji,jj,jk)   = hi(ji,jj,jk) * 1000. / ( rhop(ji,jj,jk) + rtrn )
78             END DO
79          END DO
80      END DO
81      !     -------------------------------------------
82      !     COMPUTE [CO3--] and [H+] CONCENTRATIONS
83      !     -------------------------------------------
84
85      CALL solve_at_general(zhinit, zhi)
86
87!$OMP PARALLEL
88!$OMP DO schedule(static) private(jk, jj, ji)
89      DO jk = 1, jpkm1
90         DO jj = 1, jpj
91            DO ji = 1, jpi
92               zco3(ji,jj,jk) = trb(ji,jj,jk,jpdic) * ak13(ji,jj,jk) * ak23(ji,jj,jk) / (zhi(ji,jj,jk)**2   &
93               &                + ak13(ji,jj,jk) * zhi(ji,jj,jk) + ak13(ji,jj,jk) * ak23(ji,jj,jk) + rtrn )
94               hi(ji,jj,jk)   = zhi(ji,jj,jk) * rhop(ji,jj,jk) / 1000.
95            END DO
96         END DO
97      END DO
98
99      !     ---------------------------------------------------------
100      !        CALCULATE DEGREE OF CACO3 SATURATION AND CORRESPONDING
101      !        DISSOLOUTION AND PRECIPITATION OF CACO3 (BE AWARE OF
102      !        MGCO3)
103      !     ---------------------------------------------------------
104
105!$OMP DO schedule(static) private(jk,jj,ji,zcalcon,zfact,zomegaca,zexcess0,zexcess,zdispot)
106      DO jk = 1, jpkm1
107         DO jj = 1, jpj
108            DO ji = 1, jpi
109
110               ! DEVIATION OF [CO3--] FROM SATURATION VALUE
111               ! Salinity dependance in zomegaca and divide by rhop/1000 to have good units
112               zcalcon  = calcon * ( salinprac(ji,jj,jk) / 35._wp )
113               zfact    = rhop(ji,jj,jk) / 1000._wp
114               zomegaca = ( zcalcon * zco3(ji,jj,jk) ) / ( aksp(ji,jj,jk) * zfact + rtrn )
115               zco3sat(ji,jj,jk) = aksp(ji,jj,jk) * zfact / ( zcalcon + rtrn )
116
117               ! SET DEGREE OF UNDER-/SUPERSATURATION
118               excess(ji,jj,jk) = 1._wp - zomegaca
119               zexcess0 = MAX( 0., excess(ji,jj,jk) )
120               zexcess  = zexcess0**nca
121
122               ! AMOUNT CACO3 (12C) THAT RE-ENTERS SOLUTION
123               !       (ACCORDING TO THIS FORMULATION ALSO SOME PARTICULATE
124               !       CACO3 GETS DISSOLVED EVEN IN THE CASE OF OVERSATURATION)
125               zdispot = kdca * zexcess * trb(ji,jj,jk,jpcal)
126              !  CHANGE OF [CO3--] , [ALK], PARTICULATE [CACO3],
127              !       AND [SUM(CO2)] DUE TO CACO3 DISSOLUTION/PRECIPITATION
128              zcaldiss(ji,jj,jk)  = zdispot * rfact2 / rmtss ! calcite dissolution
129              !
130              tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + 2. * zcaldiss(ji,jj,jk)
131              tra(ji,jj,jk,jpcal) = tra(ji,jj,jk,jpcal) -      zcaldiss(ji,jj,jk)
132              tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) +      zcaldiss(ji,jj,jk)
133            END DO
134         END DO
135      END DO
136!$OMP END PARALLEL
137      !
138
139      IF( lk_iomput .AND. knt == nrdttrc ) THEN
140         IF( iom_use( "PH"     ) ) CALL iom_put( "PH"    , -1. * LOG10( hi(:,:,:) )          * tmask(:,:,:) )
141         IF( iom_use( "CO3"    ) ) CALL iom_put( "CO3"   , zco3(:,:,:)    * 1.e+3            * tmask(:,:,:) )
142         IF( iom_use( "CO3sat" ) ) CALL iom_put( "CO3sat", zco3sat(:,:,:) * 1.e+3            * tmask(:,:,:) )
143         IF( iom_use( "DCAL"   ) ) CALL iom_put( "DCAL"  , zcaldiss(:,:,:) * 1.e+3 * rfact2r * tmask(:,:,:) )
144      ENDIF
145      !
146      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
147        WRITE(charout, FMT="('lys ')")
148        CALL prt_ctl_trc_info(charout)
149        CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
150      ENDIF
151      !
152      CALL wrk_dealloc( jpi, jpj, jpk, zco3, zcaldiss, zhinit, zhi, zco3sat )
153      !
154      IF( nn_timing == 1 )  CALL timing_stop('p4z_lys')
155      !
156   END SUBROUTINE p4z_lys
157
158   SUBROUTINE p4z_lys_init
159
160      !!----------------------------------------------------------------------
161      !!                  ***  ROUTINE p4z_lys_init  ***
162      !!
163      !! ** Purpose :   Initialization of CaCO3 dissolution parameters
164      !!
165      !! ** Method  :   Read the nampiscal namelist and check the parameters
166      !!      called at the first timestep (nittrc000)
167      !!
168      !! ** input   :   Namelist nampiscal
169      !!
170      !!----------------------------------------------------------------------
171      INTEGER  ::  ios                 ! Local integer output status for namelist read
172
173      NAMELIST/nampiscal/ kdca, nca
174      !!----------------------------------------------------------------------
175
176      REWIND( numnatp_ref )              ! Namelist nampiscal in reference namelist : Pisces CaCO3 dissolution
177      READ  ( numnatp_ref, nampiscal, IOSTAT = ios, ERR = 901)
178901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampiscal in reference namelist', lwp )
179
180      REWIND( numnatp_cfg )              ! Namelist nampiscal in configuration namelist : Pisces CaCO3 dissolution
181      READ  ( numnatp_cfg, nampiscal, IOSTAT = ios, ERR = 902 )
182902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampiscal in configuration namelist', lwp )
183      IF(lwm) WRITE ( numonp, nampiscal )
184
185      IF(lwp) THEN                         ! control print
186         WRITE(numout,*) ' '
187         WRITE(numout,*) ' Namelist parameters for CaCO3 dissolution, nampiscal'
188         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
189         WRITE(numout,*) '    diss. rate constant calcite (per month)   kdca      =', kdca
190         WRITE(numout,*) '    order of reaction for calcite dissolution nca       =', nca
191      ENDIF
192
193      ! Number of seconds per month
194      rmtss =  nyear_len(1) * rday / raamo
195      !
196   END SUBROUTINE p4z_lys_init
197   !!======================================================================
198END MODULE p4zlys
Note: See TracBrowser for help on using the repository browser.