New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zmeso.F90 in trunk/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z – NEMO

source: trunk/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z/p4zmeso.F90 @ 3868

Last change on this file since 3868 was 3856, checked in by cetlod, 11 years ago

trunk: take into account the proportion filter in mesozoo mortality, see ticket #1067
File size: 18.4 KB
Line 
1MODULE p4zmeso
2   !!======================================================================
3   !!                         ***  MODULE p4zmeso  ***
4   !! TOP :   PISCES Compute the sources/sinks for mesozooplankton
5   !!======================================================================
6   !! History :   1.0  !  2002     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-06  (O. Aumont, C. Ethe) Quota model for iron
9   !!----------------------------------------------------------------------
10#if defined key_pisces
11   !!----------------------------------------------------------------------
12   !!   'key_pisces'                                       PISCES bio-model
13   !!----------------------------------------------------------------------
14   !!   p4z_meso       :   Compute the sources/sinks for mesozooplankton
15   !!   p4z_meso_init  :   Initialization of the parameters for mesozooplankton
16   !!----------------------------------------------------------------------
17   USE oce_trc         !  shared variables between ocean and passive tracers
18   USE trc             !  passive tracers common variables
19   USE sms_pisces      !  PISCES Source Minus Sink variables
20   USE p4zsink         !  vertical flux of particulate matter due to sinking
21   USE p4zint          !  interpolation and computation of various fields
22   USE p4zprod         !  production
23   USE prtctl_trc      !  print control for debugging
24   USE iom             !  I/O manager
25
26   IMPLICIT NONE
27   PRIVATE
28
29   PUBLIC   p4z_meso              ! called in p4zbio.F90
30   PUBLIC   p4z_meso_init         ! called in trcsms_pisces.F90
31
32   !! * Shared module variables
33   REAL(wp), PUBLIC ::  part2       = 0.5_wp     !: part of calcite not dissolved in mesozoo guts
34   REAL(wp), PUBLIC ::  xprefc      = 1.0_wp     !: mesozoo preference for POC
35   REAL(wp), PUBLIC ::  xprefp      = 0.3_wp     !: mesozoo preference for nanophyto
36   REAL(wp), PUBLIC ::  xprefz      = 1.0_wp     !: mesozoo preference for diatoms
37   REAL(wp), PUBLIC ::  xprefpoc    = 0.3_wp     !: mesozoo preference for POC
38   REAL(wp), PUBLIC ::  xthresh2zoo = 1E-8_wp    !: zoo feeding threshold for mesozooplankton
39   REAL(wp), PUBLIC ::  xthresh2dia = 1E-8_wp    !: diatoms feeding threshold for mesozooplankton
40   REAL(wp), PUBLIC ::  xthresh2phy = 2E-7_wp    !: nanophyto feeding threshold for mesozooplankton
41   REAL(wp), PUBLIC ::  xthresh2poc = 1E-8_wp    !: poc feeding threshold for mesozooplankton
42   REAL(wp), PUBLIC ::  xthresh2    = 0._wp      !: feeding threshold for mesozooplankton
43   REAL(wp), PUBLIC ::  resrat2     = 0.005_wp   !: exsudation rate of mesozooplankton
44   REAL(wp), PUBLIC ::  mzrat2      = 0.04_wp    !: microzooplankton mortality rate
45   REAL(wp), PUBLIC ::  grazrat2    = 0.9_wp     !: maximal mesozoo grazing rate
46   REAL(wp), PUBLIC ::  xkgraz2     = 20E-6_wp   !: non assimilated fraction of P by mesozoo
47   REAL(wp), PUBLIC ::  unass2      = 0.3_wp     !: Efficicency of mesozoo growth
48   REAL(wp), PUBLIC ::  sigma2      = 0.6_wp     !: Fraction of mesozoo excretion as DOM
49   REAL(wp), PUBLIC ::  epsher2     = 0.3_wp     !: half sturation constant for grazing 2
50   REAL(wp), PUBLIC ::  grazflux    = 3.E3_wp    !: mesozoo flux feeding rate
51
52   !!* Substitution
53#  include "top_substitute.h90"
54   !!----------------------------------------------------------------------
55   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
56   !! $Id: p4zmeso.F90 3160 2011-11-20 14:27:18Z cetlod $
57   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
58   !!----------------------------------------------------------------------
59
60CONTAINS
61
62   SUBROUTINE p4z_meso( kt, jnt )
63      !!---------------------------------------------------------------------
64      !!                     ***  ROUTINE p4z_meso  ***
65      !!
66      !! ** Purpose :   Compute the sources/sinks for mesozooplankton
67      !!
68      !! ** Method  : - ???
69      !!---------------------------------------------------------------------
70      INTEGER, INTENT(in) ::   kt, jnt ! ocean time step
71      INTEGER  :: ji, jj, jk
72      REAL(wp) :: zcompadi, zcompaph, zcompapoc, zcompaz, zcompam
73      REAL(wp) :: zgraze2 , zdenom, zdenom2, zncratio
74      REAL(wp) :: zfact   , zstep, zfood, zfoodlim, zproport
75      REAL(wp) :: zmortzgoc, zfrac, zfracfe, zratio, zratio2
76      REAL(wp) :: zepshert, zepsherv, zgrarsig, zgraztot, zgraztotf
77      REAL(wp) :: zgrarem2, zgrafer2, zgrapoc2, zprcaca, zmortz2, zgrasrat
78#if defined key_kriest
79      REAL znumpoc
80#endif
81      REAL(wp) :: zrespz2, ztortz2, zgrazd, zgrazz, zgrazpof
82      REAL(wp) :: zgrazn, zgrazpoc, zgraznf, zgrazf
83      REAL(wp) :: zgrazfffp, zgrazfffg, zgrazffep, zgrazffeg
84      CHARACTER (len=25) :: charout
85      REAL(wp) :: zrfact2
86      REAL(wp), POINTER, DIMENSION(:,:,:) :: zgrazing
87
88      !!---------------------------------------------------------------------
89      !
90      IF( nn_timing == 1 )  CALL timing_start('p4z_meso')
91      !
92      IF( ln_diatrc .AND. lk_iomput ) THEN
93         CALL wrk_alloc( jpi, jpj, jpk, zgrazing )
94         zgrazing(:,:,:) = 0._wp
95      ENDIF
96
97      DO jk = 1, jpkm1
98         DO jj = 1, jpj
99            DO ji = 1, jpi
100               zcompam   = MAX( ( trn(ji,jj,jk,jpmes) - 1.e-8 ), 0.e0 )
101# if defined key_degrad
102               zstep     = xstep * facvol(ji,jj,jk)
103# else
104               zstep     = xstep
105# endif
106               zfact     = zstep * tgfunc2(ji,jj,jk) * zcompam
107
108               !  Respiration rates of both zooplankton
109               !  -------------------------------------
110               zrespz2   = resrat2 * zfact * trn(ji,jj,jk,jpmes) / ( xkmort + trn(ji,jj,jk,jpmes) )  &
111                  &      + resrat2 * zfact * 3. * nitrfac(ji,jj,jk)
112
113               !  Zooplankton mortality. A square function has been selected with
114               !  no real reason except that it seems to be more stable and may mimic predation
115               !  ---------------------------------------------------------------
116               ztortz2   = mzrat2 * 1.e6 * zfact * trn(ji,jj,jk,jpmes)
117               !
118
119               zcompadi  = MAX( ( trn(ji,jj,jk,jpdia) - xthresh2dia ), 0.e0 )
120               zcompaz   = MAX( ( trn(ji,jj,jk,jpzoo) - xthresh2zoo ), 0.e0 )
121               zcompaph  = MAX( ( trn(ji,jj,jk,jpphy) - xthresh2phy ), 0.e0 )
122               zcompapoc = MAX( ( trn(ji,jj,jk,jppoc) - xthresh2poc ), 0.e0 )
123
124               zfood     = xprefc * zcompadi + xprefz * zcompaz + xprefp * zcompaph + xprefpoc * zcompapoc 
125               zfoodlim  = MAX( 0., zfood - MIN( 0.5 * zfood, xthresh2 ) )
126               zdenom    = zfoodlim / ( xkgraz2 + zfoodlim )
127               zdenom2   = zdenom / ( zfood + rtrn )
128               zgraze2   = grazrat2 * zstep * tgfunc2(ji,jj,jk) * trn(ji,jj,jk,jpmes) 
129
130               zgrazd    = zgraze2  * xprefc   * zcompadi  * zdenom2 
131               zgrazz    = zgraze2  * xprefz   * zcompaz   * zdenom2 
132               zgrazn    = zgraze2  * xprefp   * zcompaph  * zdenom2 
133               zgrazpoc  = zgraze2  * xprefpoc * zcompapoc * zdenom2 
134
135               zgraznf   = zgrazn   * trn(ji,jj,jk,jpnfe) / ( trn(ji,jj,jk,jpphy) + rtrn)
136               zgrazf    = zgrazd   * trn(ji,jj,jk,jpdfe) / ( trn(ji,jj,jk,jpdia) + rtrn)
137               zgrazpof  = zgrazpoc * trn(ji,jj,jk,jpsfe) / ( trn(ji,jj,jk,jppoc) + rtrn)
138
139               !  Mesozooplankton flux feeding on GOC
140               !  ----------------------------------
141# if ! defined key_kriest
142               zgrazffeg = grazflux  * zstep * wsbio4(ji,jj,jk)      &
143!                 &                   * tgfunc2(ji,jj,jk) * trn(ji,jj,jk,jpgoc) * trn(ji,jj,jk,jpmes)
144               &                     * 2. *  trn(ji,jj,jk,jpgoc) * trn(ji,jj,jk,jpmes)
145               zgrazfffg = zgrazffeg * trn(ji,jj,jk,jpbfe) / (trn(ji,jj,jk,jpgoc) + rtrn)
146# endif
147               zgrazffep = grazflux  * zstep *  wsbio3(ji,jj,jk)     &
148!                 &                   * tgfunc2(ji,jj,jk) * trn(ji,jj,jk,jppoc) * trn(ji,jj,jk,jpmes)
149               &                     * 2. * trn(ji,jj,jk,jppoc) * trn(ji,jj,jk,jpmes)
150               zgrazfffp = zgrazffep * trn(ji,jj,jk,jpsfe) / (trn(ji,jj,jk,jppoc) + rtrn)
151              !
152# if ! defined key_kriest
153              zgraztot  = zgrazd + zgrazz + zgrazn + zgrazpoc + zgrazffep + zgrazffeg
154              ! Compute the proportion of filter feeders
155              zproport  = (zgrazffep + zgrazffeg)/(rtrn + zgraztot)
156              zratio    = trn(ji,jj,jk,jpgsi) / ( trn(ji,jj,jk,jpgoc) + rtrn )
157              zratio2   = zratio * zratio
158!              zfrac =  zproport * 0.15 * zstep *                     &
159!                       ( 0.2 + 0.8 * zratio2 / ( 1.5**2 + zratio2 ) )   &
160!                      *trn(ji,jj,jk,jpmes)/3E-7 *trn(ji,jj,jk,jpgoc)
161              zfrac     = zproport * grazflux  * zstep * wsbio4(ji,jj,jk)      &
162                 &       * ( 0.1 + 3.9 * zratio2 / ( 1.**2 + zratio2 ) )       &
163                 &       * 2. * trn(ji,jj,jk,jpmes) * trn(ji,jj,jk,jpgoc) 
164
165              zfracfe   = zfrac * trn(ji,jj,jk,jpbfe) / (trn(ji,jj,jk,jpgoc) + rtrn)
166
167              zgrazffep = zproport * zgrazffep
168              zgrazffeg = zproport * zgrazffeg
169              zgrazfffp = zproport * zgrazfffp
170              zgrazfffg = zproport * zgrazfffg
171              zgraztot  = zgrazd + zgrazz + zgrazn + zgrazpoc + zgrazffep + zgrazffeg
172              zgraztotf = zgrazf + zgraznf + zgrazz * ferat3 + zgrazpof + zgrazfffp + zgrazfffg
173# else
174              zgraztot  = zgrazd + zgrazz + zgrazn + zgrazpoc + zgrazffep
175              ! Compute the proportion of filter feeders
176              zproport  = zgrazffep / ( zgraztot + rtrn )
177              zgrazffep = zproport * zgrazffep
178              zgrazfffp = zproport * zgrazfffp
179              zgraztot  = zgrazd + zgrazz + zgrazn + zgrazpoc + zgrazffep
180              zgraztotf = zgrazf + zgraznf + zgrazz * ferat3 + zgrazpof + zgrazfffp
181# endif
182
183              ! Total grazing ( grazing by microzoo is already computed in p4zmicro )
184              IF( ln_diatrc .AND. lk_iomput )  zgrazing(ji,jj,jk) = zgraztot
185
186              !    Mesozooplankton efficiency
187              !    --------------------------
188              zgrasrat   =  zgraztotf / ( zgraztot + rtrn )
189              zncratio   = (  xprefc   * zcompadi * quotad(ji,jj,jk)  &
190                  &         + xprefp   * zcompaph * quotan(ji,jj,jk)  &
191                  &         + xprefz   * zcompaz                      &
192                  &         + xprefpoc * zcompapoc   ) / ( zfood + rtrn )
193               zepshert  = epsher2 * MIN( 1., zncratio )
194               zepsherv  = zepshert * MIN( 1., zgrasrat / ferat3 )
195               zgrarem2  = zgraztot * ( 1. - zepsherv - unass2 ) + zrespz2  &
196               &    + ( 1. - zepsherv - unass2 ) /( 1. - zepsherv + rtrn) * ztortz2
197               zgrafer2  = zgraztot * MAX( 0. , ( 1. - unass2 ) * zgrasrat - ferat3 * zepsherv )    &
198               &    + ferat3 * ( zrespz2 + ( 1. - zepsherv - unass2 ) /( 1. - zepsherv + rtrn) * ztortz2 )
199               zgrapoc2  = zgraztot * unass2
200
201               !   Update the arrays TRA which contain the biological sources and sinks
202               zgrarsig  = zgrarem2 * sigma2
203               tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) + zgrarsig
204               tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) + zgrarsig
205               tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) + zgrarem2 - zgrarsig
206               tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) - o2ut * zgrarsig
207               tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) + zgrafer2
208               tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) + zgrarsig
209               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + rno3 * zgrarsig             
210#if defined key_kriest
211               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + zgrapoc2
212               tra(ji,jj,jk,jpnum) = tra(ji,jj,jk,jpnum) + zgrapoc2 * xkr_dmeso
213               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + zgraztotf * unass2
214#else
215               tra(ji,jj,jk,jpgoc) = tra(ji,jj,jk,jpgoc) + zgrapoc2 - zfrac 
216               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + zfrac
217               tra(ji,jj,jk,jpbfe) = tra(ji,jj,jk,jpbfe) + zgraztotf * unass2 - zfracfe
218               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + zfracfe
219
220#endif
221               zmortz2 = ztortz2 + zrespz2
222               zmortzgoc = unass2 / ( 1. - zepsherv + rtrn ) * ztortz2
223               tra(ji,jj,jk,jpmes) = tra(ji,jj,jk,jpmes) - zmortz2 + zepsherv * zgraztot 
224               tra(ji,jj,jk,jpdia) = tra(ji,jj,jk,jpdia) - zgrazd
225               tra(ji,jj,jk,jpzoo) = tra(ji,jj,jk,jpzoo) - zgrazz
226               tra(ji,jj,jk,jpphy) = tra(ji,jj,jk,jpphy) - zgrazn
227               tra(ji,jj,jk,jpnch) = tra(ji,jj,jk,jpnch) - zgrazn * trn(ji,jj,jk,jpnch) / ( trn(ji,jj,jk,jpphy) + rtrn )
228               tra(ji,jj,jk,jpdch) = tra(ji,jj,jk,jpdch) - zgrazd * trn(ji,jj,jk,jpdch) / ( trn(ji,jj,jk,jpdia) + rtrn )
229               tra(ji,jj,jk,jpdsi) = tra(ji,jj,jk,jpdsi) - zgrazd * trn(ji,jj,jk,jpdsi) / ( trn(ji,jj,jk,jpdia) + rtrn )
230               tra(ji,jj,jk,jpgsi) = tra(ji,jj,jk,jpgsi) + zgrazd * trn(ji,jj,jk,jpdsi) / ( trn(ji,jj,jk,jpdia) + rtrn )
231               tra(ji,jj,jk,jpnfe) = tra(ji,jj,jk,jpnfe) - zgraznf
232               tra(ji,jj,jk,jpdfe) = tra(ji,jj,jk,jpdfe) - zgrazf
233
234               zprcaca = xfracal(ji,jj,jk) * zgrazn
235               ! calcite production
236               prodcal(ji,jj,jk) = prodcal(ji,jj,jk) + zprcaca  ! prodcal=prodcal(nanophy)+prodcal(microzoo)+prodcal(mesozoo)
237               !
238               zprcaca = part2 * zprcaca
239               tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) - zprcaca
240               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) - 2. * zprcaca
241               tra(ji,jj,jk,jpcal) = tra(ji,jj,jk,jpcal) + zprcaca
242#if defined key_kriest
243               znumpoc = trn(ji,jj,jk,jpnum) / ( trn(ji,jj,jk,jppoc) + rtrn )
244               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + zmortzgoc - zgrazpoc - zgrazffep
245               tra(ji,jj,jk,jpnum) = tra(ji,jj,jk,jpnum) - zgrazpoc * znumpoc &
246               &   + zmortzgoc * xkr_dmeso - zgrazffep * znumpoc * wsbio4(ji,jj,jk) / ( wsbio3(ji,jj,jk) + rtrn )
247               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + ferat3 * zmortz2 - zgrazfffp - zgrazpof
248#else
249               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) - zgrazpoc - zgrazffep
250               tra(ji,jj,jk,jpgoc) = tra(ji,jj,jk,jpgoc) + zmortzgoc - zgrazffeg
251               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) - zgrazpof - zgrazfffp
252               tra(ji,jj,jk,jpbfe) = tra(ji,jj,jk,jpbfe) + ferat3 * zmortzgoc - zgrazfffg
253#endif
254
255            END DO
256         END DO
257      END DO
258      !
259      IF( ln_diatrc .AND. lk_iomput .AND. jnt == nrdttrc ) THEN
260         zrfact2 = 1.e3 * rfact2r
261         CALL iom_put( "GRAZ2", zgrazing(:,:,:) * zrfact2 * tmask(:,:,:) )  ! Total grazing of phyto by zooplankton
262         CALL iom_put( "PCAL" , prodcal(:,:,:)  * zrfact2 * tmask(:,:,:) )  ! Calcite production
263      ENDIF
264      !
265      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
266        WRITE(charout, FMT="('meso')")
267        CALL prt_ctl_trc_info(charout)
268        CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
269      ENDIF
270      !
271      IF( ln_diatrc .AND. lk_iomput )  CALL wrk_dealloc( jpi, jpj, jpk, zgrazing )
272      !
273      IF( nn_timing == 1 )  CALL timing_stop('p4z_meso')
274      !
275   END SUBROUTINE p4z_meso
276
277   SUBROUTINE p4z_meso_init
278
279      !!----------------------------------------------------------------------
280      !!                  ***  ROUTINE p4z_meso_init  ***
281      !!
282      !! ** Purpose :   Initialization of mesozooplankton parameters
283      !!
284      !! ** Method  :   Read the nampismes namelist and check the parameters
285      !!      called at the first timestep (nittrc000)
286      !!
287      !! ** input   :   Namelist nampismes
288      !!
289      !!----------------------------------------------------------------------
290
291      NAMELIST/nampismes/ part2, grazrat2, resrat2, mzrat2, xprefc, xprefp, xprefz,   &
292         &                xprefpoc, xthresh2dia, xthresh2phy, xthresh2zoo, xthresh2poc, &
293         &                xthresh2, xkgraz2, epsher2, sigma2, unass2, grazflux
294
295      REWIND( numnatp )                     ! read numnatp
296      READ  ( numnatp, nampismes )
297
298
299      IF(lwp) THEN                         ! control print
300         WRITE(numout,*) ' ' 
301         WRITE(numout,*) ' Namelist parameters for mesozooplankton, nampismes'
302         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
303         WRITE(numout,*) '    part of calcite not dissolved in mesozoo guts  part2        =', part2
304         WRITE(numout,*) '    mesozoo preference for phyto                   xprefc       =', xprefc
305         WRITE(numout,*) '    mesozoo preference for POC                     xprefp       =', xprefp
306         WRITE(numout,*) '    mesozoo preference for zoo                     xprefz       =', xprefz
307         WRITE(numout,*) '    mesozoo preference for poc                     xprefpoc     =', xprefpoc
308         WRITE(numout,*) '    microzoo feeding threshold  for mesozoo        xthresh2zoo  =', xthresh2zoo
309         WRITE(numout,*) '    diatoms feeding threshold  for mesozoo         xthresh2dia  =', xthresh2dia
310         WRITE(numout,*) '    nanophyto feeding threshold for mesozoo        xthresh2phy  =', xthresh2phy
311         WRITE(numout,*) '    poc feeding threshold for mesozoo              xthresh2poc  =', xthresh2poc
312         WRITE(numout,*) '    feeding threshold for mesozooplankton          xthresh2     =', xthresh2
313         WRITE(numout,*) '    exsudation rate of mesozooplankton             resrat2      =', resrat2
314         WRITE(numout,*) '    mesozooplankton mortality rate                 mzrat2       =', mzrat2
315         WRITE(numout,*) '    maximal mesozoo grazing rate                   grazrat2     =', grazrat2
316         WRITE(numout,*) '    mesozoo flux feeding rate                      grazflux     =', grazflux
317         WRITE(numout,*) '    non assimilated fraction of P by mesozoo       unass2       =', unass2
318         WRITE(numout,*) '    Efficicency of Mesozoo growth                  epsher2      =', epsher2
319         WRITE(numout,*) '    Fraction of mesozoo excretion as DOM           sigma2       =', sigma2
320         WRITE(numout,*) '    half sturation constant for grazing 2          xkgraz2      =', xkgraz2
321      ENDIF
322
323
324   END SUBROUTINE p4z_meso_init
325
326
327#else
328   !!======================================================================
329   !!  Dummy module :                                   No PISCES bio-model
330   !!======================================================================
331CONTAINS
332   SUBROUTINE p4z_meso                    ! Empty routine
333   END SUBROUTINE p4z_meso
334#endif 
335
336   !!======================================================================
337END MODULE  p4zmeso
Note: See TracBrowser for help on using the repository browser.