source: trunk/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z/p4zmeso.F90 @ 8533

Last change on this file since 8533 was 8533, checked in by cetlod, 3 years ago

trunk: bugfixes to solve problem particle in PISCES, see ticket #1940

File size: 17.4 KB
Line 
1MODULE p4zmeso
2   !!======================================================================
3   !!                         ***  MODULE p4zmeso  ***
4   !! TOP :   PISCES Compute the sources/sinks for mesozooplankton
5   !!======================================================================
6   !! History :   1.0  !  2002     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-06  (O. Aumont, C. Ethe) Quota model for iron
9   !!----------------------------------------------------------------------
10   !!   p4z_meso       :   Compute the sources/sinks for mesozooplankton
11   !!   p4z_meso_init  :   Initialization of the parameters for mesozooplankton
12   !!----------------------------------------------------------------------
13   USE oce_trc         !  shared variables between ocean and passive tracers
14   USE trc             !  passive tracers common variables
15   USE sms_pisces      !  PISCES Source Minus Sink variables
16   USE p4zprod         !  production
17   USE prtctl_trc      !  print control for debugging
18   USE iom             !  I/O manager
19
20   IMPLICIT NONE
21   PRIVATE
22
23   PUBLIC   p4z_meso              ! called in p4zbio.F90
24   PUBLIC   p4z_meso_init         ! called in trcsms_pisces.F90
25
26   !! * Shared module variables
27   REAL(wp), PUBLIC ::  part2        !: part of calcite not dissolved in mesozoo guts
28   REAL(wp), PUBLIC ::  xprefc       !: mesozoo preference for POC
29   REAL(wp), PUBLIC ::  xprefp       !: mesozoo preference for nanophyto
30   REAL(wp), PUBLIC ::  xprefz       !: mesozoo preference for diatoms
31   REAL(wp), PUBLIC ::  xprefpoc     !: mesozoo preference for POC
32   REAL(wp), PUBLIC ::  xthresh2zoo  !: zoo feeding threshold for mesozooplankton
33   REAL(wp), PUBLIC ::  xthresh2dia  !: diatoms feeding threshold for mesozooplankton
34   REAL(wp), PUBLIC ::  xthresh2phy  !: nanophyto feeding threshold for mesozooplankton
35   REAL(wp), PUBLIC ::  xthresh2poc  !: poc feeding threshold for mesozooplankton
36   REAL(wp), PUBLIC ::  xthresh2     !: feeding threshold for mesozooplankton
37   REAL(wp), PUBLIC ::  resrat2      !: exsudation rate of mesozooplankton
38   REAL(wp), PUBLIC ::  mzrat2       !: microzooplankton mortality rate
39   REAL(wp), PUBLIC ::  grazrat2     !: maximal mesozoo grazing rate
40   REAL(wp), PUBLIC ::  xkgraz2      !: non assimilated fraction of P by mesozoo
41   REAL(wp), PUBLIC ::  unass2       !: Efficicency of mesozoo growth
42   REAL(wp), PUBLIC ::  sigma2       !: Fraction of mesozoo excretion as DOM
43   REAL(wp), PUBLIC ::  epsher2      !: half sturation constant for grazing 2
44   REAL(wp), PUBLIC ::  grazflux     !: mesozoo flux feeding rate
45
46   !!----------------------------------------------------------------------
47   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
48   !! $Id: p4zmeso.F90 3160 2011-11-20 14:27:18Z cetlod $
49   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
50   !!----------------------------------------------------------------------
51
52CONTAINS
53
54   SUBROUTINE p4z_meso( kt, knt )
55      !!---------------------------------------------------------------------
56      !!                     ***  ROUTINE p4z_meso  ***
57      !!
58      !! ** Purpose :   Compute the sources/sinks for mesozooplankton
59      !!
60      !! ** Method  : - ???
61      !!---------------------------------------------------------------------
62      INTEGER, INTENT(in) ::   kt, knt ! ocean time step
63      INTEGER  :: ji, jj, jk
64      REAL(wp) :: zcompadi, zcompaph, zcompapoc, zcompaz, zcompam
65      REAL(wp) :: zgraze2 , zdenom, zdenom2
66      REAL(wp) :: zfact   , zfood, zfoodlim, zproport
67      REAL(wp) :: zmortzgoc, zfrac, zfracfe, zratio, zratio2, zfracal, zgrazcal
68      REAL(wp) :: zepshert, zepsherv, zgrarsig, zgraztot, zgraztotn, zgraztotf
69      REAL(wp) :: zgrarem2, zgrafer2, zgrapoc2, zprcaca, zmortz2, zgrasrat, zgrasratn
70      REAL(wp) :: zrespz2, ztortz2, zgrazd, zgrazz, zgrazpof
71      REAL(wp) :: zgrazn, zgrazpoc, zgraznf, zgrazf
72      REAL(wp) :: zgrazfffp, zgrazfffg, zgrazffep, zgrazffeg
73      CHARACTER (len=25) :: charout
74      REAL(wp), POINTER, DIMENSION(:,:,:) :: zgrazing, zw3d
75
76      !!---------------------------------------------------------------------
77      !
78      IF( nn_timing == 1 )  CALL timing_start('p4z_meso')
79      !
80      CALL wrk_alloc( jpi, jpj, jpk, zgrazing )
81      zgrazing(:,:,:) = 0._wp
82
83      DO jk = 1, jpkm1
84         DO jj = 1, jpj
85            DO ji = 1, jpi
86               zcompam   = MAX( ( trb(ji,jj,jk,jpmes) - 1.e-9 ), 0.e0 )
87               zfact     = xstep * tgfunc2(ji,jj,jk) * zcompam
88
89               !  Respiration rates of both zooplankton
90               !  -------------------------------------
91               zrespz2   = resrat2 * zfact * trb(ji,jj,jk,jpmes) / ( xkmort + trb(ji,jj,jk,jpmes) )  &
92                  &      + resrat2 * zfact * 3. * nitrfac(ji,jj,jk)
93
94               !  Zooplankton mortality. A square function has been selected with
95               !  no real reason except that it seems to be more stable and may mimic predation
96               !  ---------------------------------------------------------------
97               ztortz2   = mzrat2 * 1.e6 * zfact * trb(ji,jj,jk,jpmes)  * (1. - nitrfac(ji,jj,jk) )
98               !
99               zcompadi  = MAX( ( trb(ji,jj,jk,jpdia) - xthresh2dia ), 0.e0 )
100               zcompaz   = MAX( ( trb(ji,jj,jk,jpzoo) - xthresh2zoo ), 0.e0 )
101               ! Size effect of nanophytoplankton on grazing : the smaller it is, the less prone
102               ! it is to predation by mesozooplankton
103               ! -------------------------------------------------------------------------------
104               zcompaph  = MAX( ( trb(ji,jj,jk,jpphy) - xthresh2phy ), 0.e0 ) &
105                  &      * MIN(1., MAX( 0., ( quotan(ji,jj,jk) - 0.2) / 0.3 ) )
106               zcompapoc = MAX( ( trb(ji,jj,jk,jppoc) - xthresh2poc ), 0.e0 )
107
108               zfood     = xprefc * zcompadi + xprefz * zcompaz + xprefp * zcompaph + xprefpoc * zcompapoc 
109               zfoodlim  = MAX( 0., zfood - MIN( 0.5 * zfood, xthresh2 ) )
110               zdenom    = zfoodlim / ( xkgraz2 + zfoodlim )
111               zdenom2   = zdenom / ( zfood + rtrn )
112               zgraze2   = grazrat2 * xstep * tgfunc2(ji,jj,jk) * trb(ji,jj,jk,jpmes) 
113
114               zgrazd    = zgraze2  * xprefc   * zcompadi  * zdenom2 
115               zgrazz    = zgraze2  * xprefz   * zcompaz   * zdenom2 
116               zgrazn    = zgraze2  * xprefp   * zcompaph  * zdenom2 
117               zgrazpoc  = zgraze2  * xprefpoc * zcompapoc * zdenom2 
118
119               zgraznf   = zgrazn   * trb(ji,jj,jk,jpnfe) / ( trb(ji,jj,jk,jpphy) + rtrn)
120               zgrazf    = zgrazd   * trb(ji,jj,jk,jpdfe) / ( trb(ji,jj,jk,jpdia) + rtrn)
121               zgrazpof  = zgrazpoc * trb(ji,jj,jk,jpsfe) / ( trb(ji,jj,jk,jppoc) + rtrn)
122
123               !  Mesozooplankton flux feeding on GOC
124               !  ----------------------------------
125               !  ----------------------------------
126               zgrazffeg = grazflux  * xstep * wsbio4(ji,jj,jk)      &
127               &           * tgfunc2(ji,jj,jk) * trb(ji,jj,jk,jpgoc) * trb(ji,jj,jk,jpmes) &
128               &           * (1. - nitrfac(ji,jj,jk))
129               zgrazfffg = zgrazffeg * trb(ji,jj,jk,jpbfe) / (trb(ji,jj,jk,jpgoc) + rtrn)
130               zgrazffep = grazflux  * xstep *  wsbio3(ji,jj,jk)     &
131               &           * tgfunc2(ji,jj,jk) * trb(ji,jj,jk,jppoc) * trb(ji,jj,jk,jpmes) &
132               &           * (1. - nitrfac(ji,jj,jk))
133               zgrazfffp = zgrazffep * trb(ji,jj,jk,jpsfe) / (trb(ji,jj,jk,jppoc) + rtrn)
134              !
135              zgraztot  = zgrazd + zgrazz + zgrazn + zgrazpoc + zgrazffep + zgrazffeg
136              ! Compute the proportion of filter feeders
137              zproport  = (zgrazffep + zgrazffeg)/(rtrn + zgraztot)
138              ! Compute fractionation of aggregates. It is assumed that
139              ! diatoms based aggregates are more prone to fractionation
140              ! since they are more porous (marine snow instead of fecal pellets)
141              zratio    = trb(ji,jj,jk,jpgsi) / ( trb(ji,jj,jk,jpgoc) + rtrn )
142              zratio2   = zratio * zratio
143              zfrac     = zproport * grazflux  * xstep * wsbio4(ji,jj,jk)      &
144               &          * trb(ji,jj,jk,jpgoc) * trb(ji,jj,jk,jpmes)          &
145               &          * ( 0.2 + 3.8 * zratio2 / ( 1.**2 + zratio2 ) )
146              zfracfe   = zfrac * trb(ji,jj,jk,jpbfe) / (trb(ji,jj,jk,jpgoc) + rtrn)
147
148              zgrazffep = zproport * zgrazffep
149              zgrazffeg = zproport * zgrazffeg
150              zgrazfffp = zproport * zgrazfffp
151              zgrazfffg = zproport * zgrazfffg
152              zgraztot  = zgrazd + zgrazz + zgrazn + zgrazpoc + zgrazffep + zgrazffeg
153              zgraztotn = zgrazd * quotad(ji,jj,jk) + zgrazz + zgrazn * quotan(ji,jj,jk)   &
154              &   + zgrazpoc + zgrazffep + zgrazffeg
155              zgraztotf = zgrazf + zgraznf + zgrazz * ferat3 + zgrazpof + zgrazfffp + zgrazfffg
156
157              ! Total grazing ( grazing by microzoo is already computed in p4zmicro )
158              zgrazing(ji,jj,jk) = zgraztot
159
160              !    Mesozooplankton efficiency
161              !    --------------------------
162               zgrasrat  =  ( zgraztotf +rtrn )/ ( zgraztot + rtrn )
163               zgrasratn =  ( zgraztotn +rtrn )/ ( zgraztot + rtrn )
164               zepshert  = MIN( 1., zgrasratn, zgrasrat / ferat3)
165               zepsherv  = zepshert * MIN( epsher2, (1. - unass2) * zgrasrat / ferat3, (1. - unass2) * zgrasratn )
166               zgrarem2  = zgraztot * ( 1. - zepsherv - unass2 ) &
167                &       + ( 1. - epsher2 - unass2 ) / ( 1. - epsher2 ) * ztortz2
168               zgrafer2  = zgraztot * MAX( 0. , ( 1. - unass2 ) * zgrasrat - ferat3 * zepsherv )    &
169                &       + ferat3 * ( ( 1. - epsher2 - unass2 ) /( 1. - epsher2 ) * ztortz2 )
170               zgrapoc2  = zgraztot * unass2
171
172               !   Update the arrays TRA which contain the biological sources and sinks
173               zgrarsig  = zgrarem2 * sigma2
174               tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) + zgrarsig
175               tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) + zgrarsig
176               tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) + zgrarem2 - zgrarsig
177               !
178               IF( ln_ligand ) tra(ji,jj,jk,jplgw) = tra(ji,jj,jk,jplgw) + (zgrarem2 - zgrarsig) * ldocz
179               !
180               tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) - o2ut * zgrarsig
181               tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) + zgrafer2
182               tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) + zgrarsig
183               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + rno3 * zgrarsig             
184
185               zmortz2 = ztortz2 + zrespz2
186               zmortzgoc = unass2 / ( 1. - epsher2 ) * ztortz2 + zrespz2
187               tra(ji,jj,jk,jpmes) = tra(ji,jj,jk,jpmes) - zmortz2 + zepsherv * zgraztot 
188               tra(ji,jj,jk,jpdia) = tra(ji,jj,jk,jpdia) - zgrazd
189               tra(ji,jj,jk,jpzoo) = tra(ji,jj,jk,jpzoo) - zgrazz
190               tra(ji,jj,jk,jpphy) = tra(ji,jj,jk,jpphy) - zgrazn
191               tra(ji,jj,jk,jpnch) = tra(ji,jj,jk,jpnch) - zgrazn * trb(ji,jj,jk,jpnch) / ( trb(ji,jj,jk,jpphy) + rtrn )
192               tra(ji,jj,jk,jpdch) = tra(ji,jj,jk,jpdch) - zgrazd * trb(ji,jj,jk,jpdch) / ( trb(ji,jj,jk,jpdia) + rtrn )
193               tra(ji,jj,jk,jpdsi) = tra(ji,jj,jk,jpdsi) - zgrazd * trb(ji,jj,jk,jpdsi) / ( trb(ji,jj,jk,jpdia) + rtrn )
194               tra(ji,jj,jk,jpgsi) = tra(ji,jj,jk,jpgsi) + zgrazd * trb(ji,jj,jk,jpdsi) / ( trb(ji,jj,jk,jpdia) + rtrn )
195               tra(ji,jj,jk,jpnfe) = tra(ji,jj,jk,jpnfe) - zgraznf
196               tra(ji,jj,jk,jpdfe) = tra(ji,jj,jk,jpdfe) - zgrazf
197
198              tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) - zgrazpoc - zgrazffep + zfrac
199              prodpoc(ji,jj,jk) = prodpoc(ji,jj,jk) + zfrac
200              conspoc(ji,jj,jk) = conspoc(ji,jj,jk) - zgrazpoc - zgrazffep
201              tra(ji,jj,jk,jpgoc) = tra(ji,jj,jk,jpgoc) + zmortzgoc - zgrazffeg + zgrapoc2 - zfrac
202              prodgoc(ji,jj,jk) = prodgoc(ji,jj,jk) + zmortzgoc + zgrapoc2
203              consgoc(ji,jj,jk) = consgoc(ji,jj,jk) - zgrazffeg - zfrac
204              tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) - zgrazpof - zgrazfffp + zfracfe
205              tra(ji,jj,jk,jpbfe) = tra(ji,jj,jk,jpbfe) + ferat3 * zmortzgoc - zgrazfffg     &
206                 &                + zgraztotf * unass2 - zfracfe
207              zfracal = trb(ji,jj,jk,jpcal) / (trb(ji,jj,jk,jppoc) + trb(ji,jj,jk,jpgoc) + rtrn )
208              zgrazcal = (zgrazffeg + zgrazpoc) * (1. - part2) * zfracal
209              ! calcite production
210              zprcaca = xfracal(ji,jj,jk) * zgrazn
211              prodcal(ji,jj,jk) = prodcal(ji,jj,jk) + zprcaca  ! prodcal=prodcal(nanophy)+prodcal(microzoo)+prodcal(mesozoo)
212              !
213              zprcaca = part2 * zprcaca
214              tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) + zgrazcal - zprcaca
215              tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) - 2. * ( zgrazcal + zprcaca )
216              tra(ji,jj,jk,jpcal) = tra(ji,jj,jk,jpcal) - zgrazcal + zprcaca
217            END DO
218         END DO
219      END DO
220      !
221      IF( lk_iomput .AND. knt == nrdttrc ) THEN
222         CALL wrk_alloc( jpi, jpj, jpk, zw3d )
223         IF( iom_use( "GRAZ2" ) ) THEN
224            zw3d(:,:,:) = zgrazing(:,:,:) * 1.e+3 * rfact2r * tmask(:,:,:)  !   Total grazing of phyto by zooplankton
225            CALL iom_put( "GRAZ2", zw3d )
226         ENDIF
227         IF( iom_use( "PCAL" ) ) THEN
228            zw3d(:,:,:) = prodcal(:,:,:) * 1.e+3 * rfact2r * tmask(:,:,:)   !  Calcite production
229            CALL iom_put( "PCAL", zw3d ) 
230         ENDIF
231         CALL wrk_dealloc( jpi, jpj, jpk, zw3d )
232      ENDIF
233      !
234      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
235        WRITE(charout, FMT="('meso')")
236        CALL prt_ctl_trc_info(charout)
237        CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
238      ENDIF
239      !
240      CALL wrk_dealloc( jpi, jpj, jpk, zgrazing )
241      !
242      IF( nn_timing == 1 )  CALL timing_stop('p4z_meso')
243      !
244   END SUBROUTINE p4z_meso
245
246   SUBROUTINE p4z_meso_init
247
248      !!----------------------------------------------------------------------
249      !!                  ***  ROUTINE p4z_meso_init  ***
250      !!
251      !! ** Purpose :   Initialization of mesozooplankton parameters
252      !!
253      !! ** Method  :   Read the nampismes namelist and check the parameters
254      !!      called at the first timestep (nittrc000)
255      !!
256      !! ** input   :   Namelist nampismes
257      !!
258      !!----------------------------------------------------------------------
259
260      NAMELIST/namp4zmes/ part2, grazrat2, resrat2, mzrat2, xprefc, xprefp, xprefz,   &
261         &                xprefpoc, xthresh2dia, xthresh2phy, xthresh2zoo, xthresh2poc, &
262         &                xthresh2, xkgraz2, epsher2, sigma2, unass2, grazflux
263      INTEGER :: ios                 ! Local integer output status for namelist read
264
265      REWIND( numnatp_ref )              ! Namelist nampismes in reference namelist : Pisces mesozooplankton
266      READ  ( numnatp_ref, namp4zmes, IOSTAT = ios, ERR = 901)
267901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namp4zmes in reference namelist', lwp )
268
269      REWIND( numnatp_cfg )              ! Namelist nampismes in configuration namelist : Pisces mesozooplankton
270      READ  ( numnatp_cfg, namp4zmes, IOSTAT = ios, ERR = 902 )
271902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namp4zmes in configuration namelist', lwp )
272      IF(lwm) WRITE ( numonp, namp4zmes )
273
274
275      IF(lwp) THEN                         ! control print
276         WRITE(numout,*) ' ' 
277         WRITE(numout,*) ' Namelist parameters for mesozooplankton, namp4zmes'
278         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
279         WRITE(numout,*) '    part of calcite not dissolved in mesozoo guts  part2        =', part2
280         WRITE(numout,*) '    mesozoo preference for phyto                   xprefc       =', xprefc
281         WRITE(numout,*) '    mesozoo preference for POC                     xprefp       =', xprefp
282         WRITE(numout,*) '    mesozoo preference for zoo                     xprefz       =', xprefz
283         WRITE(numout,*) '    mesozoo preference for poc                     xprefpoc     =', xprefpoc
284         WRITE(numout,*) '    microzoo feeding threshold  for mesozoo        xthresh2zoo  =', xthresh2zoo
285         WRITE(numout,*) '    diatoms feeding threshold  for mesozoo         xthresh2dia  =', xthresh2dia
286         WRITE(numout,*) '    nanophyto feeding threshold for mesozoo        xthresh2phy  =', xthresh2phy
287         WRITE(numout,*) '    poc feeding threshold for mesozoo              xthresh2poc  =', xthresh2poc
288         WRITE(numout,*) '    feeding threshold for mesozooplankton          xthresh2     =', xthresh2
289         WRITE(numout,*) '    exsudation rate of mesozooplankton             resrat2      =', resrat2
290         WRITE(numout,*) '    mesozooplankton mortality rate                 mzrat2       =', mzrat2
291         WRITE(numout,*) '    maximal mesozoo grazing rate                   grazrat2     =', grazrat2
292         WRITE(numout,*) '    mesozoo flux feeding rate                      grazflux     =', grazflux
293         WRITE(numout,*) '    non assimilated fraction of P by mesozoo       unass2       =', unass2
294         WRITE(numout,*) '    Efficicency of Mesozoo growth                  epsher2      =', epsher2
295         WRITE(numout,*) '    Fraction of mesozoo excretion as DOM           sigma2       =', sigma2
296         WRITE(numout,*) '    half sturation constant for grazing 2          xkgraz2      =', xkgraz2
297      ENDIF
298
299
300   END SUBROUTINE p4z_meso_init
301
302   !!======================================================================
303END MODULE p4zmeso
Note: See TracBrowser for help on using the repository browser.