New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zrem.F90 in trunk/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z – NEMO

source: trunk/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z/p4zrem.F90 @ 7698

Last change on this file since 7698 was 7698, checked in by mocavero, 7 years ago

update trunk with OpenMP parallelization
File size: 19.2 KB
Line 
1MODULE p4zrem
2   !!======================================================================
3   !!                         ***  MODULE p4zrem  ***
4   !! TOP :   PISCES Compute remineralization/dissolution of organic compounds
5   !!=========================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-06  (O. Aumont, C. Ethe) Quota model for iron
9   !!----------------------------------------------------------------------
10   !!   p4z_rem       :  Compute remineralization/dissolution of organic compounds
11   !!   p4z_rem_init  :  Initialisation of parameters for remineralisation
12   !!   p4z_rem_alloc :  Allocate remineralisation variables
13   !!----------------------------------------------------------------------
14   USE oce_trc         !  shared variables between ocean and passive tracers
15   USE trc             !  passive tracers common variables
16   USE sms_pisces      !  PISCES Source Minus Sink variables
17   USE p4zche          !  chemical model
18   USE p4zprod         !  Growth rate of the 2 phyto groups
19   USE p4zlim
20   USE prtctl_trc      !  print control for debugging
21   USE iom             !  I/O manager
22
23
24   IMPLICIT NONE
25   PRIVATE
26
27   PUBLIC   p4z_rem         ! called in p4zbio.F90
28   PUBLIC   p4z_rem_init    ! called in trcsms_pisces.F90
29   PUBLIC   p4z_rem_alloc
30
31   !! * Shared module variables
32   REAL(wp), PUBLIC ::  xremikc    !: remineralisation rate of DOC
33   REAL(wp), PUBLIC ::  xremikn    !: remineralisation rate of DON
34   REAL(wp), PUBLIC ::  xremikp    !: remineralisation rate of DOP
35   REAL(wp), PUBLIC ::  xremik     !: remineralisation rate of POC
36   REAL(wp), PUBLIC ::  nitrif     !: NH4 nitrification rate
37   REAL(wp), PUBLIC ::  xsirem     !: remineralisation rate of POC
38   REAL(wp), PUBLIC ::  xsiremlab  !: fast remineralisation rate of POC
39   REAL(wp), PUBLIC ::  xsilab     !: fraction of labile biogenic silica
40   REAL(wp), PUBLIC ::  feratb     !: Fe/C quota in bacteria
41   REAL(wp), PUBLIC ::  xkferb     !: Half-saturation constant for bacteria Fe/C
42
43   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   denitr     !: denitrification array
44
45   !!----------------------------------------------------------------------
46   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
47   !! $Id: p4zrem.F90 3160 2011-11-20 14:27:18Z cetlod $
48   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
49   !!----------------------------------------------------------------------
50CONTAINS
51
52   SUBROUTINE p4z_rem( kt, knt )
53      !!---------------------------------------------------------------------
54      !!                     ***  ROUTINE p4z_rem  ***
55      !!
56      !! ** Purpose :   Compute remineralization/scavenging of organic compounds
57      !!
58      !! ** Method  : - ???
59      !!---------------------------------------------------------------------
60      !
61      INTEGER, INTENT(in) ::   kt, knt ! ocean time step
62      !
63      INTEGER  ::   ji, jj, jk
64      REAL(wp) ::   zremik, zremikc, zremikn, zremikp, zsiremin, zfact 
65      REAL(wp) ::   zsatur, zsatur2, znusil, znusil2, zdep, zdepmin, zfactdep
66      REAL(wp) ::   zbactfer, zolimit, zonitr, zrfact2
67      REAL(wp) ::   zosil, ztem, zdenitnh4, zolimic, zolimin, zolimip, zdenitrn, zdenitrp
68      CHARACTER (len=25) :: charout
69      REAL(wp), POINTER, DIMENSION(:,:  ) :: ztempbac
70      REAL(wp), POINTER, DIMENSION(:,:,:) :: zdepbac, zolimi, zdepprod, zfacsi, zw3d, zfacsib
71      !!---------------------------------------------------------------------
72      !
73      IF( nn_timing == 1 )  CALL timing_start('p4z_rem')
74      !
75      ! Allocate temporary workspace
76      CALL wrk_alloc( jpi, jpj,      ztempbac                  )
77      CALL wrk_alloc( jpi, jpj, jpk, zdepbac, zdepprod, zolimi, zfacsi, zfacsib )
78
79      ! Initialisation of temprary arrys
80!$OMP PARALLEL
81!$OMP DO schedule(static) private(jk,jj,ji)
82      DO jk = 1, jpk
83         DO jj = 1, jpj
84            DO ji = 1, jpi
85               zdepprod(ji,jj,jk) = 1._wp
86               zfacsib(ji,jj,jk)  = xsilab / ( 1.0 - xsilab )
87               zfacsi(ji,jj,jk)   = xsilab
88            END DO
89         END DO
90      END DO
91!$OMP DO schedule(static) private(jj,ji)
92      DO jj = 1, jpj
93         DO ji = 1, jpi
94            ztempbac(ji,jj)   = 0._wp
95         END DO
96      END DO
97
98      ! Computation of the mean phytoplankton concentration as
99      ! a crude estimate of the bacterial biomass
100      ! this parameterization has been deduced from a model version
101      ! that was modeling explicitely bacteria
102      ! -------------------------------------------------------
103      DO jk = 1, jpkm1
104!$OMP DO schedule(static) private(jj,ji,zdep,zdepmin)
105         DO jj = 1, jpj
106            DO ji = 1, jpi
107               zdep = MAX( hmld(ji,jj), heup(ji,jj) )
108               IF( gdept_n(ji,jj,jk) < zdep ) THEN
109                  zdepbac(ji,jj,jk) = MIN( 0.7 * ( trb(ji,jj,jk,jpzoo) + 2.* trb(ji,jj,jk,jpmes) ), 4.e-6 )
110                  ztempbac(ji,jj)   = zdepbac(ji,jj,jk)
111               ELSE
112                  zdepmin = MIN( 1., zdep / gdept_n(ji,jj,jk) )
113                  zdepbac (ji,jj,jk) = zdepmin**0.683 * ztempbac(ji,jj)
114                  zdepprod(ji,jj,jk) = zdepmin**0.273
115               ENDIF
116            END DO
117         END DO
118      END DO
119
120      IF( ln_p4z ) THEN
121!$OMP DO schedule(static) private(jk,jj,ji,zremik,zolimit)
122         DO jk = 1, jpkm1
123            DO jj = 1, jpj
124               DO ji = 1, jpi
125                  ! DOC ammonification. Depends on depth, phytoplankton biomass
126                  ! and a limitation term which is supposed to be a parameterization of the bacterial activity.
127                  zremik = xremik * xstep / 1.e-6 * xlimbac(ji,jj,jk) * zdepbac(ji,jj,jk) 
128                  zremik = MAX( zremik, 2.74e-4 * xstep )
129                  ! Ammonification in oxic waters with oxygen consumption
130                  ! -----------------------------------------------------
131                  zolimit = zremik * ( 1.- nitrfac(ji,jj,jk) ) * trb(ji,jj,jk,jpdoc) 
132                  zolimi(ji,jj,jk) = MIN( ( trb(ji,jj,jk,jpoxy) - rtrn ) / o2ut, zolimit ) 
133                  ! Ammonification in suboxic waters with denitrification
134                  ! -------------------------------------------------------
135                  denitr(ji,jj,jk)  = MIN(  ( trb(ji,jj,jk,jpno3) - rtrn ) / rdenit,   &
136                     &                     zremik * nitrfac(ji,jj,jk) * trb(ji,jj,jk,jpdoc)  )
137                  !
138                  zolimi (ji,jj,jk) = MAX( 0.e0, zolimi (ji,jj,jk) )
139                  denitr (ji,jj,jk) = MAX( 0.e0, denitr (ji,jj,jk) )
140                  !
141                  tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) + zolimi (ji,jj,jk) + denitr(ji,jj,jk)
142                  tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) + zolimi (ji,jj,jk) + denitr(ji,jj,jk)
143                  tra(ji,jj,jk,jpno3) = tra(ji,jj,jk,jpno3) - denitr (ji,jj,jk) * rdenit
144                  tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) - zolimi (ji,jj,jk) - denitr(ji,jj,jk)
145                  tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) - zolimi (ji,jj,jk) * o2ut
146                  tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) + zolimi (ji,jj,jk) + denitr(ji,jj,jk)
147                  tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + rno3 * ( zolimi(ji,jj,jk)    &
148                  &                     + ( rdenit + 1.) * denitr(ji,jj,jk) )
149               END DO
150            END DO
151         END DO
152      ELSE
153!$OMP DO schedule(static) private(jk,jj,ji,zremik,zremikc,zremikn,zremikp,zolimit,zolimic,zolimin,zolimip,zdenitrn,zdenitrp)
154         DO jk = 1, jpkm1
155            DO jj = 1, jpj
156               DO ji = 1, jpi
157                  ! DOC ammonification. Depends on depth, phytoplankton biomass
158                  ! and a limitation term which is supposed to be a parameterization of the bacterial activity.
159                  ! -----------------------------------------------------------------
160                  zremik = xstep / 1.e-6 * MAX(0.01, xlimbac(ji,jj,jk)) * zdepbac(ji,jj,jk) 
161                  zremik = MAX( zremik, 2.74e-4 * xstep / xremikc )
162
163                  zremikc = xremikc * zremik
164                  zremikn = xremikn / xremikc
165                  zremikp = xremikp / xremikc
166
167                  ! Ammonification in oxic waters with oxygen consumption
168                  ! -----------------------------------------------------
169                  zolimit = zremikc * ( 1.- nitrfac(ji,jj,jk) ) * trb(ji,jj,jk,jpdoc) 
170                  zolimic = MAX( 0.e0, MIN( ( trb(ji,jj,jk,jpoxy) - rtrn ) / o2ut, zolimit ) ) 
171                  zolimi(ji,jj,jk) = zolimic
172                  zolimin = zremikn * zolimic * trb(ji,jj,jk,jpdon) / ( trb(ji,jj,jk,jpdoc) + rtrn )
173                  zolimip = zremikp * zolimic * trb(ji,jj,jk,jpdop) / ( trb(ji,jj,jk,jpdoc) + rtrn ) 
174
175                  ! Ammonification in suboxic waters with denitrification
176                  ! -------------------------------------------------------
177                  zolimit = zremikc * nitrfac(ji,jj,jk) * trb(ji,jj,jk,jpdoc)
178                  denitr(ji,jj,jk)  = MIN(  ( trb(ji,jj,jk,jpno3) - rtrn ) / rdenit, zolimit )
179                  denitr(ji,jj,jk) = MAX( 0.e0, denitr(ji,jj,jk) )
180                  zdenitrn  = zremikn * denitr(ji,jj,jk) * trb(ji,jj,jk,jpdon) / ( trb(ji,jj,jk,jpdoc) + rtrn )
181                  zdenitrp  = zremikp * denitr(ji,jj,jk) * trb(ji,jj,jk,jpdop) / ( trb(ji,jj,jk,jpdoc) + rtrn )
182
183                  tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) + zolimip + zdenitrp
184                  tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) + zolimin + zdenitrn
185                  tra(ji,jj,jk,jpno3) = tra(ji,jj,jk,jpno3) - denitr(ji,jj,jk) * rdenit
186                  tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) - zolimic - denitr(ji,jj,jk)
187                  tra(ji,jj,jk,jpdon) = tra(ji,jj,jk,jpdon) - zolimin - zdenitrn
188                  tra(ji,jj,jk,jpdop) = tra(ji,jj,jk,jpdop) - zolimip - zdenitrp
189                  tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) - zolimic * o2ut
190                  tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) + zolimic + denitr(ji,jj,jk)
191                  tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + rno3 * ( zolimin + ( rdenit + 1.) * zdenitrn )
192               END DO
193            END DO
194         END DO
195         !
196      ENDIF
197
198
199!$OMP DO schedule(static) private(jk,jj,ji,zonitr,zdenitnh4)
200      DO jk = 1, jpkm1
201         DO jj = 1, jpj
202            DO ji = 1, jpi
203               ! NH4 nitrification to NO3. Ceased for oxygen concentrations
204               ! below 2 umol/L. Inhibited at strong light
205               ! ----------------------------------------------------------
206               zonitr  = nitrif * xstep * trb(ji,jj,jk,jpnh4) * ( 1.- nitrfac(ji,jj,jk) )  &
207               &         / ( 1.+ emoy(ji,jj,jk) ) * ( 1. + fr_i(ji,jj) * emoy(ji,jj,jk) ) 
208               zdenitnh4 = nitrif * xstep * trb(ji,jj,jk,jpnh4) * nitrfac(ji,jj,jk)
209               ! Update of the tracers trends
210               ! ----------------------------
211               tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) - zonitr - zdenitnh4
212               tra(ji,jj,jk,jpno3) = tra(ji,jj,jk,jpno3) + zonitr - rdenita * zdenitnh4
213               tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) - o2nit * zonitr
214               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) - 2 * rno3 * zonitr + rno3 * ( rdenita - 1. ) * zdenitnh4
215            END DO
216         END DO
217      END DO
218!$OMP END PARALLEL
219
220      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
221        WRITE(charout, FMT="('rem1')")
222        CALL prt_ctl_trc_info(charout)
223        CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
224      ENDIF
225
226!$OMP PARALLEL DO schedule(static) private(jk,jj,ji,zbactfer)
227      DO jk = 1, jpkm1
228         DO jj = 1, jpj
229            DO ji = 1, jpi
230
231               ! Bacterial uptake of iron. No iron is available in DOC. So
232               ! Bacteries are obliged to take up iron from the water. Some
233               ! studies (especially at Papa) have shown this uptake to be significant
234               ! ----------------------------------------------------------
235               zbactfer = feratb *  rfact2 * prmax(ji,jj,jk) * xlimbacl(ji,jj,jk)             &
236                  &              * trb(ji,jj,jk,jpfer) / ( xkferb + trb(ji,jj,jk,jpfer) )    &
237                  &              * zdepprod(ji,jj,jk) * zdepbac(ji,jj,jk)
238               tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) - zbactfer*0.16
239               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + zbactfer*0.12
240               tra(ji,jj,jk,jpbfe) = tra(ji,jj,jk,jpbfe) + zbactfer*0.04
241            END DO
242         END DO
243      END DO
244
245      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
246        WRITE(charout, FMT="('rem2')")
247        CALL prt_ctl_trc_info(charout)
248        CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
249      ENDIF
250
251      ! Initialization of the array which contains the labile fraction
252      ! of bSi. Set to a constant in the upper ocean
253      ! ---------------------------------------------------------------
254
255      DO jk = 1, jpkm1
256!$OMP PARALLEL DO schedule(static) private(jj,ji,zdep,zsatur,zsatur2,znusil,zsiremin,zosil)
257         DO jj = 1, jpj
258            DO ji = 1, jpi
259               zdep     = MAX( hmld(ji,jj), heup_01(ji,jj) )
260               zsatur   = MAX( rtrn, ( sio3eq(ji,jj,jk) - trb(ji,jj,jk,jpsil) ) / ( sio3eq(ji,jj,jk) + rtrn ) )
261               zsatur2  = ( 1. + tsn(ji,jj,jk,jp_tem) / 400.)**37
262               znusil   = 0.225  * ( 1. + tsn(ji,jj,jk,jp_tem) / 15.) * zsatur + 0.775 * zsatur2 * zsatur**9.25
263               ! Remineralization rate of BSi depedant on T and saturation
264               ! ---------------------------------------------------------
265               IF ( gdept_n(ji,jj,jk) > zdep ) THEN
266                  zfacsib(ji,jj,jk) = zfacsib(ji,jj,jk-1) * EXP( -0.5 * ( xsiremlab - xsirem )  &
267                  &                   * znusil * e3t_n(ji,jj,jk) / wsbio4(ji,jj,jk) )
268                  zfacsi(ji,jj,jk)  = zfacsib(ji,jj,jk) / ( 1.0 + zfacsib(ji,jj,jk) )
269                  zfacsib(ji,jj,jk) = zfacsib(ji,jj,jk) * EXP( -0.5 * ( xsiremlab - xsirem )    &
270                  &                   * znusil * e3t_n(ji,jj,jk) / wsbio4(ji,jj,jk) )
271               ENDIF
272               zsiremin = ( xsiremlab * zfacsi(ji,jj,jk) + xsirem * ( 1. - zfacsi(ji,jj,jk) ) ) * xstep * znusil
273               zosil    = zsiremin * trb(ji,jj,jk,jpgsi)
274               !
275               tra(ji,jj,jk,jpgsi) = tra(ji,jj,jk,jpgsi) - zosil
276               tra(ji,jj,jk,jpsil) = tra(ji,jj,jk,jpsil) + zosil
277               !
278            END DO
279         END DO
280      END DO
281
282      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
283         WRITE(charout, FMT="('rem3')")
284         CALL prt_ctl_trc_info(charout)
285         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
286      ENDIF
287
288      IF( knt == nrdttrc ) THEN
289         CALL wrk_alloc( jpi, jpj, jpk, zw3d )
290         zfact = 1.e+3 * rfact2r  !  conversion from mol/l/kt to  mol/m3/s
291         !
292         IF( iom_use( "REMIN" ) )  THEN
293!$OMP PARALLEL DO schedule(static) private(jk,jj,ji)
294            DO jk = 1, jpk
295               DO jj = 1, jpj
296                  DO ji = 1, jpi
297                     zw3d(ji,jj,jk) = zolimi(ji,jj,jk) * tmask(ji,jj,jk) * zfact !  Remineralisation rate
298                  END DO
299               END DO
300            END DO
301            CALL iom_put( "REMIN"  , zw3d )
302         ENDIF
303         IF( iom_use( "DENIT" ) )  THEN
304!$OMP PARALLEL DO schedule(static) private(jk,jj,ji)
305            DO jk = 1, jpk
306               DO jj = 1, jpj
307                  DO ji = 1, jpi
308                     zw3d(ji,jj,jk) = denitr(ji,jj,jk) * rdenit * rno3 * tmask(ji,jj,jk) * zfact ! Denitrification
309                  END DO
310               END DO
311            END DO
312            CALL iom_put( "DENIT"  , zw3d )
313         ENDIF
314         !
315         CALL wrk_dealloc( jpi, jpj, jpk, zw3d )
316      ENDIF
317      !
318      CALL wrk_dealloc( jpi, jpj,      ztempbac                  )
319      CALL wrk_dealloc( jpi, jpj, jpk, zdepbac, zdepprod, zolimi, zfacsi, zfacsib )
320      !
321      IF( nn_timing == 1 )  CALL timing_stop('p4z_rem')
322      !
323   END SUBROUTINE p4z_rem
324
325
326   SUBROUTINE p4z_rem_init
327      !!----------------------------------------------------------------------
328      !!                  ***  ROUTINE p4z_rem_init  ***
329      !!
330      !! ** Purpose :   Initialization of remineralization parameters
331      !!
332      !! ** Method  :   Read the nampisrem namelist and check the parameters
333      !!      called at the first timestep
334      !!
335      !! ** input   :   Namelist nampisrem
336      !!
337      !!----------------------------------------------------------------------
338      NAMELIST/nampisrem/ xremik, nitrif, xsirem, xsiremlab, xsilab, feratb, xkferb, & 
339         &                xremikc, xremikn, xremikp
340      INTEGER :: ios                 ! Local integer output status for namelist read
341      INTEGER :: ji, jj, jk
342
343      REWIND( numnatp_ref )              ! Namelist nampisrem in reference namelist : Pisces remineralization
344      READ  ( numnatp_ref, nampisrem, IOSTAT = ios, ERR = 901)
345901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisrem in reference namelist', lwp )
346
347      REWIND( numnatp_cfg )              ! Namelist nampisrem in configuration namelist : Pisces remineralization
348      READ  ( numnatp_cfg, nampisrem, IOSTAT = ios, ERR = 902 )
349902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisrem in configuration namelist', lwp )
350      IF(lwm) WRITE ( numonp, nampisrem )
351
352      IF(lwp) THEN                         ! control print
353         WRITE(numout,*) ' '
354         WRITE(numout,*) ' Namelist parameters for remineralization, nampisrem'
355         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
356         IF( ln_p4z ) THEN
357            WRITE(numout,*) '    remineralization rate of DOC              xremik    =', xremik
358         ELSE
359            WRITE(numout,*) '    remineralization rate of DOC              xremikc   =', xremikc
360            WRITE(numout,*) '    remineralization rate of DON              xremikn   =', xremikn
361            WRITE(numout,*) '    remineralization rate of DOP              xremikp   =', xremikp
362         ENDIF
363         WRITE(numout,*) '    remineralization rate of Si               xsirem    =', xsirem
364         WRITE(numout,*) '    fast remineralization rate of Si          xsiremlab =', xsiremlab
365         WRITE(numout,*) '    fraction of labile biogenic silica        xsilab    =', xsilab
366         WRITE(numout,*) '    NH4 nitrification rate                    nitrif    =', nitrif
367         WRITE(numout,*) '    Bacterial Fe/C ratio                      feratb    =', feratb
368         WRITE(numout,*) '    Half-saturation constant for bact. Fe/C   xkferb    =', xkferb
369      ENDIF
370      !
371!$OMP PARALLEL DO schedule(static) private(jk,jj,ji)
372      DO jk = 1, jpk
373         DO jj = 1, jpj
374            DO ji = 1, jpi
375               denitr  (ji,jj,jk) = 0._wp
376            END DO
377         END DO
378      END DO
379      !
380   END SUBROUTINE p4z_rem_init
381
382
383   INTEGER FUNCTION p4z_rem_alloc()
384      !!----------------------------------------------------------------------
385      !!                     ***  ROUTINE p4z_rem_alloc  ***
386      !!----------------------------------------------------------------------
387      ALLOCATE( denitr(jpi,jpj,jpk), STAT=p4z_rem_alloc )
388      !
389      IF( p4z_rem_alloc /= 0 )   CALL ctl_warn('p4z_rem_alloc: failed to allocate arrays')
390      !
391   END FUNCTION p4z_rem_alloc
392
393   !!======================================================================
394END MODULE p4zrem
Note: See TracBrowser for help on using the repository browser.