New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zmicro.F90 in trunk/NEMOGCM/NEMO/TOP_SRC/PISCES – NEMO

source: trunk/NEMOGCM/NEMO/TOP_SRC/PISCES/p4zmicro.F90 @ 2730

Last change on this file since 2730 was 2528, checked in by rblod, 13 years ago

Update NEMOGCM from branch nemo_v3_3_beta
  • Property svn:keywords set to Id
File size: 11.2 KB
Line 
1MODULE p4zmicro
2   !!======================================================================
3   !!                         ***  MODULE p4zmicro  ***
4   !! TOP :   PISCES Compute the sources/sinks for microzooplankton
5   !!======================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!----------------------------------------------------------------------
9#if defined key_pisces
10   !!----------------------------------------------------------------------
11   !!   'key_pisces'                                       PISCES bio-model
12   !!----------------------------------------------------------------------
13   !!   p4z_micro       :   Compute the sources/sinks for microzooplankton
14   !!   p4z_micro_init  :   Initialize and read the appropriate namelist
15   !!----------------------------------------------------------------------
16   USE trc
17   USE oce_trc         !
18   USE trc         !
19   USE sms_pisces      !
20   USE prtctl_trc
21   USE p4zint
22   USE p4zsink
23   USE iom
24
25   IMPLICIT NONE
26   PRIVATE
27
28   PUBLIC   p4z_micro         ! called in p4zbio.F90
29   PUBLIC   p4z_micro_init    ! called in trcsms_pisces.F90
30
31   !! * Shared module variables
32   REAL(wp), PUBLIC ::   &
33      xpref2c = 0.0_wp       ,  &  !:
34      xpref2p = 0.5_wp       ,  &  !:
35      xpref2d = 0.5_wp       ,  &  !:
36      resrat  = 0.03_wp      ,  &  !:
37      mzrat   = 0.0_wp       ,  &  !:
38      grazrat = 4.0_wp       ,  &  !:
39      xkgraz  = 20E-6_wp     ,  &  !:
40      unass   = 0.3_wp       ,  &  !:
41      sigma1  = 0.6_wp       ,  &  !:
42      epsher  = 0.33_wp
43
44
45   !!* Substitution
46#  include "top_substitute.h90"
47   !!----------------------------------------------------------------------
48   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
49   !! $Id$
50   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
51   !!----------------------------------------------------------------------
52
53CONTAINS
54
55   SUBROUTINE p4z_micro( kt )
56      !!---------------------------------------------------------------------
57      !!                     ***  ROUTINE p4z_micro  ***
58      !!
59      !! ** Purpose :   Compute the sources/sinks for microzooplankton
60      !!
61      !! ** Method  : - ???
62      !!---------------------------------------------------------------------
63      INTEGER, INTENT(in) ::   kt ! ocean time step
64      INTEGER  :: ji, jj, jk
65      REAL(wp) :: zcompadi, zcompadi2, zcompaz , zcompaph, zcompapoc
66      REAL(wp) :: zgraze  , zdenom  , zdenom2, zstep
67      REAL(wp) :: zfact   , zinano , zidiat, zipoc
68      REAL(wp) :: zgrarem, zgrafer, zgrapoc, zprcaca, zmortz
69      REAL(wp) :: zrespz, ztortz
70      REAL(wp) :: zgrazp, zgrazm, zgrazsd
71      REAL(wp) :: zgrazmf, zgrazsf, zgrazpf
72      CHARACTER (len=25) :: charout
73
74      !!---------------------------------------------------------------------
75
76
77#if defined key_diatrc
78      grazing(:,:,:) = 0.  !: Initialisation of  grazing
79#endif
80
81      zstep = rfact2 / rday      ! Time step duration for biology
82
83      DO jk = 1, jpkm1
84         DO jj = 1, jpj
85            DO ji = 1, jpi
86               zcompaz = MAX( ( trn(ji,jj,jk,jpzoo) - 1.e-9 ), 0.e0 )
87# if defined key_degrad
88               zstep   = xstep * facvol(ji,jj,jk)
89# else
90               zstep   = xstep
91# endif
92               zfact   = zstep * tgfunc(ji,jj,jk) * zcompaz
93
94               !  Respiration rates of both zooplankton
95               !  -------------------------------------
96               zrespz = resrat * zfact  * ( 1.+ 3.* nitrfac(ji,jj,jk) )     &
97                  &            * trn(ji,jj,jk,jpzoo) / ( xkmort + trn(ji,jj,jk,jpzoo) )
98
99               !  Zooplankton mortality. A square function has been selected with
100               !  no real reason except that it seems to be more stable and may mimic predation.
101               !  ---------------------------------------------------------------
102               ztortz = mzrat * 1.e6 * zfact * trn(ji,jj,jk,jpzoo)
103
104               zcompadi  = MAX( ( trn(ji,jj,jk,jpdia) - 1.e-8 ), 0.e0 )
105               zcompadi2 = MIN( zcompadi, 5.e-7 )
106               zcompaph  = MAX( ( trn(ji,jj,jk,jpphy) - 2.e-7 ), 0.e0 )
107               zcompapoc = MAX( ( trn(ji,jj,jk,jppoc) - 1.e-8 ), 0.e0 )
108               
109               !     Microzooplankton grazing
110               !     ------------------------
111               zdenom2 = 1./ ( xpref2p * zcompaph + xpref2c * zcompapoc + xpref2d * zcompadi2 + rtrn )
112
113               zgraze = grazrat * zstep * tgfunc(ji,jj,jk) * trn(ji,jj,jk,jpzoo)
114
115               zinano = xpref2p * zcompaph  * zdenom2
116               zipoc  = xpref2c * zcompapoc * zdenom2
117               zidiat = xpref2d * zcompadi2 * zdenom2
118
119               zdenom = 1./ ( xkgraz + zinano * zcompaph + zipoc * zcompapoc + zidiat * zcompadi2 )
120
121               zgrazp  = zgraze * zinano * zcompaph * zdenom
122               zgrazm  = zgraze * zipoc  * zcompapoc * zdenom
123               zgrazsd = zgraze * zidiat * zcompadi2 * zdenom
124
125               zgrazpf = zgrazp  * trn(ji,jj,jk,jpnfe) / (trn(ji,jj,jk,jpphy) + rtrn)
126               zgrazmf = zgrazm  * trn(ji,jj,jk,jpsfe) / (trn(ji,jj,jk,jppoc) + rtrn)
127               zgrazsf = zgrazsd * trn(ji,jj,jk,jpdfe) / (trn(ji,jj,jk,jpdia) + rtrn)
128#if defined key_diatrc
129               ! Grazing by microzooplankton
130               grazing(ji,jj,jk) = grazing(ji,jj,jk) + zgrazp + zgrazm + zgrazsd 
131#endif
132
133               !    Various remineralization and excretion terms
134               !    --------------------------------------------
135               zgrarem = ( zgrazp + zgrazm + zgrazsd ) * ( 1.- epsher - unass )
136               zgrafer = ( zgrazpf + zgrazsf + zgrazmf ) * ( 1.- epsher - unass ) &
137                  &      + epsher * ( zgrazm  * MAX((trn(ji,jj,jk,jpsfe) / (trn(ji,jj,jk,jppoc)+ rtrn)-ferat3),0.e0) & 
138                  &                 + zgrazp  * MAX((trn(ji,jj,jk,jpnfe) / (trn(ji,jj,jk,jpphy)+ rtrn)-ferat3),0.e0) &
139                  &                 + zgrazsd * MAX((trn(ji,jj,jk,jpdfe) / (trn(ji,jj,jk,jpdia)+ rtrn)-ferat3),0.e0 )  )
140
141               zgrapoc = (  zgrazp + zgrazm + zgrazsd ) 
142
143               !  Update of the TRA arrays
144               !  ------------------------
145
146               tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) + zgrarem * sigma1
147               tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) + zgrarem * sigma1
148               tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) + zgrarem * (1.-sigma1)
149               tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) - o2ut * zgrarem * sigma1
150               tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) + zgrafer
151               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + zgrapoc * unass
152               tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) + zgrarem * sigma1
153#if defined key_kriest
154               tra(ji,jj,jk,jpnum) = tra(ji,jj,jk,jpnum) + zgrapoc * unass * xkr_ddiat
155#endif
156
157               !
158               !   Update the arrays TRA which contain the biological sources and sinks
159               !   --------------------------------------------------------------------
160
161               zmortz = ztortz + zrespz
162               tra(ji,jj,jk,jpzoo) = tra(ji,jj,jk,jpzoo) - zmortz + epsher * zgrapoc 
163               tra(ji,jj,jk,jpphy) = tra(ji,jj,jk,jpphy) - zgrazp
164               tra(ji,jj,jk,jpdia) = tra(ji,jj,jk,jpdia) - zgrazsd
165               tra(ji,jj,jk,jpnch) = tra(ji,jj,jk,jpnch) - zgrazp  * trn(ji,jj,jk,jpnch)/(trn(ji,jj,jk,jpphy)+rtrn)
166               tra(ji,jj,jk,jpdch) = tra(ji,jj,jk,jpdch) - zgrazsd * trn(ji,jj,jk,jpdch)/(trn(ji,jj,jk,jpdia)+rtrn)
167               tra(ji,jj,jk,jpbsi) = tra(ji,jj,jk,jpbsi) - zgrazsd * trn(ji,jj,jk,jpbsi)/(trn(ji,jj,jk,jpdia)+rtrn)
168               tra(ji,jj,jk,jpdsi) = tra(ji,jj,jk,jpdsi) + zgrazsd * trn(ji,jj,jk,jpbsi)/(trn(ji,jj,jk,jpdia)+rtrn)
169               tra(ji,jj,jk,jpnfe) = tra(ji,jj,jk,jpnfe) - zgrazpf
170               tra(ji,jj,jk,jpdfe) = tra(ji,jj,jk,jpdfe) - zgrazsf
171               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + zmortz - zgrazm
172               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + ferat3 * zmortz + unass * ( zgrazpf + zgrazsf ) - (1.-unass) * zgrazmf
173               zprcaca = xfracal(ji,jj,jk) * unass * zgrazp
174#if defined key_diatrc
175               prodcal(ji,jj,jk) = prodcal(ji,jj,jk) + zprcaca  ! prodcal=prodcal(nanophy)+prodcal(microzoo)+prodcal(mesozoo)
176#endif
177               zprcaca = part * zprcaca
178               tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) - zprcaca
179               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) - 2. * zprcaca
180               tra(ji,jj,jk,jpcal) = tra(ji,jj,jk,jpcal) + zprcaca
181#if defined key_kriest
182               tra(ji,jj,jk,jpnum) = tra(ji,jj,jk,jpnum) + ( zmortz - zgrazm ) * xkr_ddiat
183#endif
184            END DO
185         END DO
186      END DO
187      !
188      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
189         WRITE(charout, FMT="('micro')")
190         CALL prt_ctl_trc_info(charout)
191         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
192      ENDIF
193
194   END SUBROUTINE p4z_micro
195
196
197   SUBROUTINE p4z_micro_init
198
199      !!----------------------------------------------------------------------
200      !!                  ***  ROUTINE p4z_micro_init  ***
201      !!
202      !! ** Purpose :   Initialization of microzooplankton parameters
203      !!
204      !! ** Method  :   Read the nampiszoo namelist and check the parameters
205      !!      called at the first timestep (nit000)
206      !!
207      !! ** input   :   Namelist nampiszoo
208      !!
209      !!----------------------------------------------------------------------
210
211      NAMELIST/nampiszoo/ grazrat,resrat,mzrat,xpref2c, xpref2p, &
212         &             xpref2d, xkgraz, epsher, sigma1, unass
213
214      REWIND( numnat )                     ! read numnat
215      READ  ( numnat, nampiszoo )
216
217      IF(lwp) THEN                         ! control print
218         WRITE(numout,*) ' '
219         WRITE(numout,*) ' Namelist parameters for microzooplankton, nampiszoo'
220         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
221         WRITE(numout,*) '    zoo preference for POC                    xpref2c    =', xpref2c
222         WRITE(numout,*) '    zoo preference for nano                   xpref2p    =', xpref2p
223         WRITE(numout,*) '    zoo preference for diatoms                xpref2d    =', xpref2d
224         WRITE(numout,*) '    exsudation rate of microzooplankton       resrat    =', resrat
225         WRITE(numout,*) '    microzooplankton mortality rate           mzrat     =', mzrat
226         WRITE(numout,*) '    maximal microzoo grazing rate             grazrat   =', grazrat
227         WRITE(numout,*) '    non assimilated fraction of P by microzoo unass     =', unass
228         WRITE(numout,*) '    Efficicency of microzoo growth            epsher    =', epsher
229         WRITE(numout,*) '    Fraction of microzoo excretion as DOM     sigma1    =', sigma1
230         WRITE(numout,*) '    half sturation constant for grazing 1     xkgraz    =', xkgraz
231      ENDIF
232
233   END SUBROUTINE p4z_micro_init
234
235#else
236   !!======================================================================
237   !!  Dummy module :                                   No PISCES bio-model
238   !!======================================================================
239CONTAINS
240   SUBROUTINE p4z_micro                    ! Empty routine
241   END SUBROUTINE p4z_micro
242#endif 
243
244   !!======================================================================
245END MODULE  p4zmicro
Note: See TracBrowser for help on using the repository browser.