New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zprod.F90 in trunk/NEMOGCM/NEMO/TOP_SRC/PISCES – NEMO

source: trunk/NEMOGCM/NEMO/TOP_SRC/PISCES/p4zprod.F90 @ 3295

Last change on this file since 3295 was 3295, checked in by cetlod, 12 years ago

trunk:A few additional diagnostics added in PISCES
  • Property svn:keywords set to Id
File size: 26.8 KB
Line 
1MODULE p4zprod
2   !!======================================================================
3   !!                         ***  MODULE p4zprod  ***
4   !! TOP :  Growth Rate of the two phytoplanktons groups
5   !!======================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-05  (O. Aumont, C. Ethe) New parameterization of light limitation
9   !!----------------------------------------------------------------------
10#if defined key_pisces
11   !!----------------------------------------------------------------------
12   !!   'key_pisces'                                       PISCES bio-model
13   !!----------------------------------------------------------------------
14   !!   p4z_prod       :   Compute the growth Rate of the two phytoplanktons groups
15   !!   p4z_prod_init  :   Initialization of the parameters for growth
16   !!   p4z_prod_alloc :   Allocate variables for growth
17   !!----------------------------------------------------------------------
18   USE oce_trc         !  shared variables between ocean and passive tracers
19   USE trc             !  passive tracers common variables
20   USE sms_pisces      !  PISCES Source Minus Sink variables
21   USE p4zopt          !  optical model
22   USE p4zlim          !  Co-limitations of differents nutrients
23   USE prtctl_trc      !  print control for debugging
24   USE iom             !  I/O manager
25
26   IMPLICIT NONE
27   PRIVATE
28
29   PUBLIC   p4z_prod         ! called in p4zbio.F90
30   PUBLIC   p4z_prod_init    ! called in trcsms_pisces.F90
31   PUBLIC   p4z_prod_alloc
32
33   !! * Shared module variables
34   LOGICAL , PUBLIC ::  ln_newprod = .FALSE.
35   REAL(wp), PUBLIC ::  pislope    = 3.0_wp            !:
36   REAL(wp), PUBLIC ::  pislope2   = 3.0_wp            !:
37   REAL(wp), PUBLIC ::  excret     = 10.e-5_wp         !:
38   REAL(wp), PUBLIC ::  excret2    = 0.05_wp           !:
39   REAL(wp), PUBLIC ::  bresp      = 0.00333_wp        !:
40   REAL(wp), PUBLIC ::  chlcnm     = 0.033_wp          !:
41   REAL(wp), PUBLIC ::  chlcdm     = 0.05_wp           !:
42   REAL(wp), PUBLIC ::  chlcmin    = 0.00333_wp        !:
43   REAL(wp), PUBLIC ::  fecnm      = 10.E-6_wp         !:
44   REAL(wp), PUBLIC ::  fecdm      = 15.E-6_wp         !:
45   REAL(wp), PUBLIC ::  grosip     = 0.151_wp          !:
46
47   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   prmax    !: optimal production = f(temperature)
48   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   quotan   !: proxy of N quota in Nanophyto
49   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   quotad   !: proxy of N quota in diatomee
50   
51   REAL(wp) :: r1_rday                !: 1 / rday
52   REAL(wp) :: texcret                !: 1 - excret
53   REAL(wp) :: texcret2               !: 1 - excret2       
54   REAL(wp) :: tpp                    !: Total primary production
55
56
57   !!* Substitution
58#  include "top_substitute.h90"
59   !!----------------------------------------------------------------------
60   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
61   !! $Id$
62   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
63   !!----------------------------------------------------------------------
64CONTAINS
65
66   SUBROUTINE p4z_prod( kt , jnt )
67      !!---------------------------------------------------------------------
68      !!                     ***  ROUTINE p4z_prod  ***
69      !!
70      !! ** Purpose :   Compute the phytoplankton production depending on
71      !!              light, temperature and nutrient availability
72      !!
73      !! ** Method  : - ???
74      !!---------------------------------------------------------------------
75      !
76      INTEGER, INTENT(in) :: kt, jnt
77      !
78      INTEGER  ::   ji, jj, jk
79      REAL(wp) ::   zsilfac, zfact, znanotot, zdiattot, zconctemp, zconctemp2
80      REAL(wp) ::   zratio, zmax, zsilim, ztn, zadap
81      REAL(wp) ::   zlim, zsilfac2, zsiborn, zprod, zproreg, zproreg2
82      REAL(wp) ::   zmxltst, zmxlday, zmaxday
83      REAL(wp) ::   zpislopen  , zpislope2n
84      REAL(wp) ::   zrum, zcodel, zargu, zval
85      REAL(wp) ::   zrfact2
86      CHARACTER (len=25) :: charout
87      REAL(wp), POINTER, DIMENSION(:,:  ) :: zmixnano, zmixdiat, zstrn
88      REAL(wp), POINTER, DIMENSION(:,:,:) :: zpislopead, zpislopead2, zprdia, zprbio, zprdch, zprnch, zysopt   
89      REAL(wp), POINTER, DIMENSION(:,:,:) :: zprorca, zprorcad, zprofed, zprofen, zprochln, zprochld, zpronew, zpronewd
90      !!---------------------------------------------------------------------
91      !
92      IF( nn_timing == 1 )  CALL timing_start('p4z_prod')
93      !
94      !  Allocate temporary workspace
95      CALL wrk_alloc( jpi, jpj,      zmixnano, zmixdiat, zstrn                                                  )
96      CALL wrk_alloc( jpi, jpj, jpk, zpislopead, zpislopead2, zprdia, zprbio, zprdch, zprnch, zysopt            ) 
97      CALL wrk_alloc( jpi, jpj, jpk, zprorca, zprorcad, zprofed, zprofen, zprochln, zprochld, zpronew, zpronewd )
98      !
99      zprorca (:,:,:) = 0._wp
100      zprorcad(:,:,:) = 0._wp
101      zprofed (:,:,:) = 0._wp
102      zprofen (:,:,:) = 0._wp
103      zprochln(:,:,:) = 0._wp
104      zprochld(:,:,:) = 0._wp
105      zpronew (:,:,:) = 0._wp
106      zpronewd(:,:,:) = 0._wp
107      zprdia  (:,:,:) = 0._wp
108      zprbio  (:,:,:) = 0._wp
109      zprdch  (:,:,:) = 0._wp
110      zprnch  (:,:,:) = 0._wp
111      zysopt  (:,:,:) = 0._wp
112
113      ! Computation of the optimal production
114      prmax(:,:,:) = 0.6_wp * r1_rday * tgfunc(:,:,:) 
115      IF( lk_degrad )  prmax(:,:,:) = prmax(:,:,:) * facvol(:,:,:) 
116
117      ! compute the day length depending on latitude and the day
118      zrum = REAL( nday_year - 80, wp ) / REAL( nyear_len(1), wp )
119      zcodel = ASIN(  SIN( zrum * rpi * 2._wp ) * SIN( rad * 23.5_wp )  )
120
121      ! day length in hours
122      zstrn(:,:) = 0.
123      DO jj = 1, jpj
124         DO ji = 1, jpi
125            zargu = TAN( zcodel ) * TAN( gphit(ji,jj) * rad )
126            zargu = MAX( -1., MIN(  1., zargu ) )
127            zstrn(ji,jj) = MAX( 0.0, 24. - 2. * ACOS( zargu ) / rad / 15. )
128         END DO
129      END DO
130
131      IF( ln_newprod ) THEN
132         ! Impact of the day duration on phytoplankton growth
133         DO jk = 1, jpkm1
134            DO jj = 1 ,jpj
135               DO ji = 1, jpi
136                  zval = MAX( 1., zstrn(ji,jj) )
137                  zval = 1.5 * zval / ( 12. + zval )
138                  zprbio(ji,jj,jk) = prmax(ji,jj,jk) * zval
139                  zprdia(ji,jj,jk) = zprbio(ji,jj,jk)
140               END DO
141            END DO
142         END DO
143      ENDIF
144
145      ! Maximum light intensity
146      WHERE( zstrn(:,:) < 1.e0 ) zstrn(:,:) = 24.
147      zstrn(:,:) = 24. / zstrn(:,:)
148
149      IF( ln_newprod ) THEN
150!CDIR NOVERRCHK
151         DO jk = 1, jpkm1
152!CDIR NOVERRCHK
153            DO jj = 1, jpj
154!CDIR NOVERRCHK
155               DO ji = 1, jpi
156
157                  ! Computation of the P-I slope for nanos and diatoms
158                  IF( etot(ji,jj,jk) > 1.E-3 ) THEN
159                      ztn    = MAX( 0., tsn(ji,jj,jk,jp_tem) - 15. )
160                      zadap  = ztn / ( 2.+ ztn )
161
162                      zconctemp   = MAX( 0.e0 , trn(ji,jj,jk,jpdia) - 5e-7 )
163                      zconctemp2  = trn(ji,jj,jk,jpdia) - zconctemp
164
165                      znanotot = enano(ji,jj,jk) * zstrn(ji,jj)
166                      zdiattot = ediat(ji,jj,jk) * zstrn(ji,jj)
167
168                      zfact  = EXP( -0.21 * znanotot )
169                      zpislopead (ji,jj,jk) = pislope  * ( 1.+ zadap  * zfact )  &
170                         &                   * trn(ji,jj,jk,jpnch) /( trn(ji,jj,jk,jpphy) * 12. + rtrn)
171
172                      zpislopead2(ji,jj,jk) = (pislope * zconctemp2 + pislope2 * zconctemp) / ( trn(ji,jj,jk,jpdia) + rtrn )   &
173                         &                   * trn(ji,jj,jk,jpdch) /( trn(ji,jj,jk,jpdia) * 12. + rtrn)
174
175                      ! Computation of production function for Carbon
176                      !  ---------------------------------------------
177                      zpislopen  = zpislopead (ji,jj,jk) / ( ( r1_rday + bresp * r1_rday / chlcnm ) * rday + rtrn)
178                      zpislope2n = zpislopead2(ji,jj,jk) / ( ( r1_rday + bresp * r1_rday / chlcdm ) * rday + rtrn)
179                      zprbio(ji,jj,jk) = zprbio(ji,jj,jk) * ( 1.- EXP( -zpislopen  * znanotot )  )
180                      zprdia(ji,jj,jk) = zprdia(ji,jj,jk) * ( 1.- EXP( -zpislope2n * zdiattot )  )
181
182                      !  Computation of production function for Chlorophyll
183                      !--------------------------------------------------
184                      zmaxday  = 1._wp / ( prmax(ji,jj,jk) * rday + rtrn )
185                      zprnch(ji,jj,jk) = prmax(ji,jj,jk) * ( 1.- EXP( -zpislopead (ji,jj,jk) * zmaxday * znanotot ) )
186                      zprdch(ji,jj,jk) = prmax(ji,jj,jk) * ( 1.- EXP( -zpislopead2(ji,jj,jk) * zmaxday * zdiattot ) )
187                  ENDIF
188               END DO
189            END DO
190         END DO
191      ELSE
192!CDIR NOVERRCHK
193         DO jk = 1, jpkm1
194!CDIR NOVERRCHK
195            DO jj = 1, jpj
196!CDIR NOVERRCHK
197               DO ji = 1, jpi
198
199                  ! Computation of the P-I slope for nanos and diatoms
200                  IF( etot(ji,jj,jk) > 1.E-3 ) THEN
201                      ztn    = MAX( 0., tsn(ji,jj,jk,jp_tem) - 15. )
202                      zadap  = ztn / ( 2.+ ztn )
203
204                      zfact  = EXP( -0.21 * enano(ji,jj,jk) )
205                      zpislopead (ji,jj,jk) = pislope  * ( 1.+ zadap  * zfact )
206                      zpislopead2(ji,jj,jk) = pislope2
207
208                      zpislopen =  zpislopead(ji,jj,jk) * trn(ji,jj,jk,jpnch)                &
209                        &          / ( trn(ji,jj,jk,jpphy) * 12.                  + rtrn )   &
210                        &          / ( prmax(ji,jj,jk) * rday * xlimphy(ji,jj,jk) + rtrn )
211
212                      zpislope2n = zpislopead2(ji,jj,jk) * trn(ji,jj,jk,jpdch)                &
213                        &          / ( trn(ji,jj,jk,jpdia) * 12.                  + rtrn )   &
214                        &          / ( prmax(ji,jj,jk) * rday * xlimdia(ji,jj,jk) + rtrn )
215
216                      ! Computation of production function for Carbon
217                      !  ---------------------------------------------
218                      zprbio(ji,jj,jk) = prmax(ji,jj,jk) * ( 1.- EXP( -zpislopen  * enano(ji,jj,jk) ) )
219                      zprdia(ji,jj,jk) = prmax(ji,jj,jk) * ( 1.- EXP( -zpislope2n * ediat(ji,jj,jk) ) )
220
221                      !  Computation of production function for Chlorophyll
222                      !--------------------------------------------------
223                      zprnch(ji,jj,jk) = prmax(ji,jj,jk) * ( 1.- EXP( -zpislopen  * enano(ji,jj,jk) * zstrn(ji,jj) ) )
224                      zprdch(ji,jj,jk) = prmax(ji,jj,jk) * ( 1.- EXP( -zpislope2n * ediat(ji,jj,jk) * zstrn(ji,jj) ) )
225                  ENDIF
226               END DO
227            END DO
228         END DO
229      ENDIF
230
231      !  Computation of a proxy of the N/C ratio
232      !  ---------------------------------------
233!CDIR NOVERRCHK
234      DO jk = 1, jpkm1
235!CDIR NOVERRCHK
236         DO jj = 1, jpj
237!CDIR NOVERRCHK
238            DO ji = 1, jpi
239                zval = ( xnanonh4(ji,jj,jk) + xnanono3(ji,jj,jk) ) * prmax(ji,jj,jk) / ( zprbio(ji,jj,jk) + rtrn )
240                quotan(ji,jj,jk) = MIN( 1., 0.5 + 0.5 * zval )
241                zval = ( xdiatnh4(ji,jj,jk) + xdiatno3(ji,jj,jk) ) * prmax(ji,jj,jk) / ( zprdia(ji,jj,jk) + rtrn )
242                quotad(ji,jj,jk) = MIN( 1., 0.5 + 0.5 * zval )
243            END DO
244         END DO
245      END DO
246
247
248      DO jk = 1, jpkm1
249         DO jj = 1, jpj
250            DO ji = 1, jpi
251
252                IF( etot(ji,jj,jk) > 1.E-3 ) THEN
253                   !    Si/C of diatoms
254                   !    ------------------------
255                   !    Si/C increases with iron stress and silicate availability
256                   !    Si/C is arbitrariliy increased for very high Si concentrations
257                   !    to mimic the very high ratios observed in the Southern Ocean (silpot2)
258                  zlim  = trn(ji,jj,jk,jpsil) / ( trn(ji,jj,jk,jpsil) + xksi1 )
259                  zsilim = MIN( zprdia(ji,jj,jk) / ( prmax(ji,jj,jk) + rtrn ), xlimsi(ji,jj,jk) )
260                  zsilfac = 4.4 * EXP( -4.23 * zsilim ) * MAX( 0.e0, MIN( 1., 2.2 * ( zlim - 0.5 ) )  ) + 1.e0
261                  zsiborn = MAX( 0.e0, ( trn(ji,jj,jk,jpsil) - 15.e-6 ) )
262                  zsilfac2 = 1.+ 2.* zsiborn / ( zsiborn + xksi2 )
263                  zsilfac = MIN( 5.4, zsilfac * zsilfac2)
264                  zysopt(ji,jj,jk) = grosip * zlim * zsilfac
265              ENDIF
266            END DO
267         END DO
268      END DO
269
270      !  Computation of the limitation term due to a mixed layer deeper than the euphotic depth
271      DO jj = 1, jpj
272         DO ji = 1, jpi
273            zmxltst = MAX( 0.e0, hmld(ji,jj) - heup(ji,jj) )
274            zmxlday = zmxltst * zmxltst * r1_rday
275            zmixnano(ji,jj) = 1. - zmxlday / ( 3. + zmxlday )
276            zmixdiat(ji,jj) = 1. - zmxlday / ( 4. + zmxlday )
277         END DO
278      END DO
279 
280      !  Mixed-layer effect on production                                                                               
281      DO jk = 1, jpkm1
282         DO jj = 1, jpj
283            DO ji = 1, jpi
284               IF( fsdepw(ji,jj,jk+1) <= hmld(ji,jj) ) THEN
285                  zprbio(ji,jj,jk) = zprbio(ji,jj,jk) * zmixnano(ji,jj)
286                  zprdia(ji,jj,jk) = zprdia(ji,jj,jk) * zmixdiat(ji,jj)
287               ENDIF
288            END DO
289         END DO
290      END DO
291
292      ! Computation of the various production terms
293!CDIR NOVERRCHK
294      DO jk = 1, jpkm1
295!CDIR NOVERRCHK
296         DO jj = 1, jpj
297!CDIR NOVERRCHK
298            DO ji = 1, jpi
299               IF( etot(ji,jj,jk) > 1.E-3 ) THEN
300                  !  production terms for nanophyto.
301                  zprorca(ji,jj,jk) = zprbio(ji,jj,jk)  * xlimphy(ji,jj,jk) * trn(ji,jj,jk,jpphy) * rfact2
302                  zpronew(ji,jj,jk) = zprorca(ji,jj,jk) * xnanono3(ji,jj,jk) / ( xnanono3(ji,jj,jk) + xnanonh4(ji,jj,jk) + rtrn )
303                  !
304                  zratio = trn(ji,jj,jk,jpnfe) / ( trn(ji,jj,jk,jpphy) + rtrn )
305                  zratio = zratio / fecnm 
306                  zmax   = MAX( 0., ( 1. - zratio ) / ABS( 1.05 - zratio ) ) 
307                  zprofen(ji,jj,jk) = fecnm * prmax(ji,jj,jk)  &
308                  &             * ( 4. - 4.5 * xlimnfe(ji,jj,jk) / ( xlimnfe(ji,jj,jk) + 0.5 ) )    &
309                  &             * trn(ji,jj,jk,jpfer) / ( trn(ji,jj,jk,jpfer) + concnfe(ji,jj,jk) )  &
310                  &             * zmax * trn(ji,jj,jk,jpphy) * rfact2
311                  !  production terms for diatomees
312                  zprorcad(ji,jj,jk) = zprdia(ji,jj,jk) * xlimdia(ji,jj,jk) * trn(ji,jj,jk,jpdia) * rfact2
313                  zpronewd(ji,jj,jk) = zprorcad(ji,jj,jk) * xdiatno3(ji,jj,jk) / ( xdiatno3(ji,jj,jk) + xdiatnh4(ji,jj,jk) + rtrn )
314                  !
315                  zratio = trn(ji,jj,jk,jpdfe) / ( trn(ji,jj,jk,jpdia) + rtrn )
316                  zratio = zratio / fecdm 
317                  zmax   = MAX( 0., ( 1. - zratio ) / ABS( 1.05 - zratio ) ) 
318                  zprofed(ji,jj,jk) = fecdm * prmax(ji,jj,jk)  &
319                  &             * ( 4. - 4.5 * xlimdfe(ji,jj,jk) / ( xlimdfe(ji,jj,jk) + 0.5 ) )    &
320                  &             * trn(ji,jj,jk,jpfer) / ( trn(ji,jj,jk,jpfer) + concdfe(ji,jj,jk) )  &
321                  &             * zmax * trn(ji,jj,jk,jpdia) * rfact2
322               ENDIF
323            END DO
324         END DO
325      END DO
326
327      IF( ln_newprod ) THEN
328!CDIR NOVERRCHK
329         DO jk = 1, jpkm1
330!CDIR NOVERRCHK
331            DO jj = 1, jpj
332!CDIR NOVERRCHK
333               DO ji = 1, jpi
334                  IF( fsdepw(ji,jj,jk+1) <= hmld(ji,jj) ) THEN
335                     zprnch(ji,jj,jk) = zprnch(ji,jj,jk) * zmixnano(ji,jj)
336                     zprdch(ji,jj,jk) = zprdch(ji,jj,jk) * zmixdiat(ji,jj)
337                  ENDIF
338                  IF( etot(ji,jj,jk) > 1.E-3 ) THEN
339                     !  production terms for nanophyto. ( chlorophyll )
340                     znanotot = enano(ji,jj,jk) * zstrn(ji,jj)
341                     zprod    = rday * zprorca(ji,jj,jk) * zprnch(ji,jj,jk) * xlimphy(ji,jj,jk)
342                     zprochln(ji,jj,jk) = chlcmin * 12. * zprorca (ji,jj,jk)
343                     zprochln(ji,jj,jk) = zprochln(ji,jj,jk) + chlcnm * 12. * zprod / (  zpislopead(ji,jj,jk) * znanotot +rtrn)
344                     !  production terms for diatomees ( chlorophyll )
345                     zdiattot = ediat(ji,jj,jk) * zstrn(ji,jj)
346                     zprod = rday * zprorcad(ji,jj,jk) * zprdch(ji,jj,jk) * xlimdia(ji,jj,jk)
347                     zprochld(ji,jj,jk) = chlcmin * 12. * zprorcad(ji,jj,jk)
348                     zprochld(ji,jj,jk) = zprochld(ji,jj,jk) + chlcdm * 12. * zprod / ( zpislopead2(ji,jj,jk) * zdiattot +rtrn )
349                  ENDIF
350               END DO
351            END DO
352         END DO
353      ELSE
354!CDIR NOVERRCHK
355         DO jk = 1, jpkm1
356!CDIR NOVERRCHK
357            DO jj = 1, jpj
358!CDIR NOVERRCHK
359               DO ji = 1, jpi
360                  IF( etot(ji,jj,jk) > 1.E-3 ) THEN
361                     !  production terms for nanophyto. ( chlorophyll )
362                     znanotot = enano(ji,jj,jk) * zstrn(ji,jj)
363                     zprod = rday * zprorca(ji,jj,jk) * zprnch(ji,jj,jk) * trn(ji,jj,jk,jpphy) * xlimphy(ji,jj,jk)
364                     zprochln(ji,jj,jk) = chlcnm * 144. * zprod / (  zpislopead(ji,jj,jk) * trn(ji,jj,jk,jpnch) * znanotot +rtrn)
365                     !  production terms for diatomees ( chlorophyll )
366                     zdiattot = ediat(ji,jj,jk) * zstrn(ji,jj)
367                     zprod = rday * zprorcad(ji,jj,jk) * zprdch(ji,jj,jk) * trn(ji,jj,jk,jpdia) * xlimdia(ji,jj,jk)
368                     zprochld(ji,jj,jk) = chlcdm * 144. * zprod / ( zpislopead2(ji,jj,jk) * trn(ji,jj,jk,jpdch) * zdiattot +rtrn )
369                  ENDIF
370               END DO
371            END DO
372         END DO
373      ENDIF
374
375      !   Update the arrays TRA which contain the biological sources and sinks
376      DO jk = 1, jpkm1
377         DO jj = 1, jpj
378           DO ji =1 ,jpi
379              zproreg  = zprorca(ji,jj,jk) - zpronew(ji,jj,jk)
380              zproreg2 = zprorcad(ji,jj,jk) - zpronewd(ji,jj,jk)
381              tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) - zprorca(ji,jj,jk) - zprorcad(ji,jj,jk)
382              tra(ji,jj,jk,jpno3) = tra(ji,jj,jk,jpno3) - zpronew(ji,jj,jk) - zpronewd(ji,jj,jk)
383              tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) - zproreg - zproreg2
384              tra(ji,jj,jk,jpphy) = tra(ji,jj,jk,jpphy) + zprorca(ji,jj,jk) * texcret
385              tra(ji,jj,jk,jpnch) = tra(ji,jj,jk,jpnch) + zprochln(ji,jj,jk) * texcret
386              tra(ji,jj,jk,jpnfe) = tra(ji,jj,jk,jpnfe) + zprofen(ji,jj,jk) * texcret
387              tra(ji,jj,jk,jpdia) = tra(ji,jj,jk,jpdia) + zprorcad(ji,jj,jk) * texcret2
388              tra(ji,jj,jk,jpdch) = tra(ji,jj,jk,jpdch) + zprochld(ji,jj,jk) * texcret2
389              tra(ji,jj,jk,jpdfe) = tra(ji,jj,jk,jpdfe) + zprofed(ji,jj,jk) * texcret2
390              tra(ji,jj,jk,jpdsi) = tra(ji,jj,jk,jpdsi) + zprorcad(ji,jj,jk) * zysopt(ji,jj,jk) * texcret2
391              tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) + excret2 * zprorcad(ji,jj,jk) + excret * zprorca(ji,jj,jk)
392              tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) + o2ut * ( zproreg + zproreg2) &
393                 &                + ( o2ut + o2nit ) * ( zpronew(ji,jj,jk) + zpronewd(ji,jj,jk) )
394              tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) - texcret * zprofen(ji,jj,jk) - texcret2 * zprofed(ji,jj,jk)
395              tra(ji,jj,jk,jpsil) = tra(ji,jj,jk,jpsil) - texcret2 * zprorcad(ji,jj,jk) * zysopt(ji,jj,jk)
396              tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) - zprorca(ji,jj,jk) - zprorcad(ji,jj,jk)
397              tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + rno3 * ( zpronew(ji,jj,jk) + zpronewd(ji,jj,jk) ) &
398                 &                                      - rno3 * ( zproreg + zproreg2 )
399          END DO
400        END DO
401     END DO
402
403     ! Total primary production per year
404     tpp = tpp + glob_sum( ( zprorca(:,:,:) + zprorcad(:,:,:) ) * cvol(:,:,:) )
405
406     IF( kt == nitend .AND. jnt == nrdttrc ) THEN
407        WRITE(numout,*) 'Total PP (Gtc) :'
408        WRITE(numout,*) '-------------------- : ',tpp * 12. / 1.E12
409        WRITE(numout,*) 
410      ENDIF
411
412     IF( ln_diatrc ) THEN
413         !
414         zrfact2 = 1.e3 * rfact2r  ! conversion from mol/L/timestep into mol/m3/s
415         IF( lk_iomput ) THEN
416           IF( jnt == nrdttrc ) THEN
417              CALL iom_put( "PPPHY"   , zprorca (:,:,:) * zrfact2 * tmask(:,:,:) )  ! primary production by nanophyto
418              CALL iom_put( "PPPHY2"  , zprorcad(:,:,:) * zrfact2 * tmask(:,:,:) )  ! primary production by diatom
419              CALL iom_put( "PPNEWN"  , zpronew (:,:,:) * zrfact2 * tmask(:,:,:) )  ! new primary production by nanophyto
420              CALL iom_put( "PPNEWD"  , zpronewd(:,:,:) * zrfact2 * tmask(:,:,:) )  ! new primary production by diatom
421              CALL iom_put( "PBSi"    , zprorcad(:,:,:) * zrfact2 * tmask(:,:,:) * zysopt(:,:,:) ) ! biogenic silica production
422              CALL iom_put( "PFeD"    , zprofed (:,:,:) * zrfact2 * tmask(:,:,:) )  ! biogenic iron production by diatom
423              CALL iom_put( "PFeN"    , zprofen (:,:,:) * zrfact2 * tmask(:,:,:) )  ! biogenic iron production by nanophyto
424              CALL iom_put( "Mumax"   , prmax   (:,:,:) * tmask(:,:,:) )  ! Maximum growth rate
425              CALL iom_put( "MuN"     , zprbio  (:,:,:) * xlimphy(:,:,:) * tmask(:,:,:) )  ! Realized growth rate for nanophyto
426              CALL iom_put( "MuD"     , zprdia  (:,:,:) * xlimdia(:,:,:) * tmask(:,:,:) )  ! Realized growth rate for diatoms
427              CALL iom_put( "MuNlight", zprbio  (:,:,:) * tmask(:,:,:) )  ! Light limited growth rate phytoplankton
428              CALL iom_put( "MuDlight", zprdia  (:,:,:) * tmask(:,:,:) )  ! Light limited growth rate diatoms
429              CALL iom_put( "LNnut"   , xlimphy (:,:,:) * tmask(:,:,:) )  ! Nutrient limitation term
430              CALL iom_put( "LDnut"   , xlimdia (:,:,:) * tmask(:,:,:) )  ! Nutrient limitation term
431              CALL iom_put( "LNFe"    , xlimnfe (:,:,:) * tmask(:,:,:) )  ! Iron limitation term
432              CALL iom_put( "LDFe"    , xlimdfe (:,:,:) * tmask(:,:,:) )  ! Iron limitation term
433              CALL iom_put( "LNlight" , zprbio  (:,:,:) / (prmax(:,:,:) + rtrn) * tmask(:,:,:) )  ! light limitation term
434              CALL iom_put( "LDlight" , zprdia  (:,:,:) / (prmax(:,:,:) + rtrn) * tmask(:,:,:) )  ! light limitation term
435           ENDIF
436         ELSE
437              trc3d(:,:,:,jp_pcs0_3d + 4)  = zprorca (:,:,:) * zrfact2 * tmask(:,:,:)
438              trc3d(:,:,:,jp_pcs0_3d + 5)  = zprorcad(:,:,:) * zrfact2 * tmask(:,:,:)
439              trc3d(:,:,:,jp_pcs0_3d + 6)  = zpronew (:,:,:) * zrfact2 * tmask(:,:,:)
440              trc3d(:,:,:,jp_pcs0_3d + 7)  = zpronewd(:,:,:) * zrfact2 * tmask(:,:,:)
441              trc3d(:,:,:,jp_pcs0_3d + 8)  = zprorcad(:,:,:) * zrfact2 * tmask(:,:,:) * zysopt(:,:,:)
442              trc3d(:,:,:,jp_pcs0_3d + 9)  = zprofed (:,:,:) * zrfact2 * tmask(:,:,:)
443#  if ! defined key_kriest
444              trc3d(:,:,:,jp_pcs0_3d + 10) = zprofen (:,:,:) * zrfact2 * tmask(:,:,:)
445#  endif
446         ENDIF
447         !
448      ENDIF
449
450      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
451         WRITE(charout, FMT="('prod')")
452         CALL prt_ctl_trc_info(charout)
453         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
454      ENDIF
455      !
456      CALL wrk_dealloc( jpi, jpj,      zmixnano, zmixdiat, zstrn                                                  )
457      CALL wrk_dealloc( jpi, jpj, jpk, zpislopead, zpislopead2, zprdia, zprbio, zprdch, zprnch, zysopt            ) 
458      CALL wrk_dealloc( jpi, jpj, jpk, zprorca, zprorcad, zprofed, zprofen, zprochln, zprochld, zpronew, zpronewd )
459      !
460      IF( nn_timing == 1 )  CALL timing_stop('p4z_prod')
461      !
462   END SUBROUTINE p4z_prod
463
464
465   SUBROUTINE p4z_prod_init
466      !!----------------------------------------------------------------------
467      !!                  ***  ROUTINE p4z_prod_init  ***
468      !!
469      !! ** Purpose :   Initialization of phytoplankton production parameters
470      !!
471      !! ** Method  :   Read the nampisprod namelist and check the parameters
472      !!      called at the first timestep (nittrc000)
473      !!
474      !! ** input   :   Namelist nampisprod
475      !!----------------------------------------------------------------------
476      !
477      NAMELIST/nampisprod/ pislope, pislope2, ln_newprod, bresp, excret, excret2,  &
478         &                 chlcnm, chlcdm, chlcmin, fecnm, fecdm, grosip
479      !!----------------------------------------------------------------------
480
481      REWIND( numnatp )                     ! read numnatp
482      READ  ( numnatp, nampisprod )
483
484      IF(lwp) THEN                         ! control print
485         WRITE(numout,*) ' '
486         WRITE(numout,*) ' Namelist parameters for phytoplankton growth, nampisprod'
487         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
488         WRITE(numout,*) '    Enable new parame. of production (T/F)   ln_newprod   =', ln_newprod
489         WRITE(numout,*) '    mean Si/C ratio                           grosip       =', grosip
490         WRITE(numout,*) '    P-I slope                                 pislope      =', pislope
491         WRITE(numout,*) '    excretion ratio of nanophytoplankton      excret       =', excret
492         WRITE(numout,*) '    excretion ratio of diatoms                excret2      =', excret2
493         IF( ln_newprod )  THEN
494            WRITE(numout,*) '    basal respiration in phytoplankton        bresp        =', bresp
495            WRITE(numout,*) '    Maximum Chl/C in phytoplankton            chlcmin      =', chlcmin
496         ENDIF
497         WRITE(numout,*) '    P-I slope  for diatoms                    pislope2     =', pislope2
498         WRITE(numout,*) '    Minimum Chl/C in nanophytoplankton        chlcnm       =', chlcnm
499         WRITE(numout,*) '    Minimum Chl/C in diatoms                  chlcdm       =', chlcdm
500         WRITE(numout,*) '    Maximum Fe/C in nanophytoplankton         fecnm        =', fecnm
501         WRITE(numout,*) '    Minimum Fe/C in diatoms                   fecdm        =', fecdm
502      ENDIF
503      !
504      r1_rday   = 1._wp / rday 
505      texcret   = 1._wp - excret
506      texcret2  = 1._wp - excret2
507      tpp       = 0._wp
508      !
509   END SUBROUTINE p4z_prod_init
510
511
512   INTEGER FUNCTION p4z_prod_alloc()
513      !!----------------------------------------------------------------------
514      !!                     ***  ROUTINE p4z_prod_alloc  ***
515      !!----------------------------------------------------------------------
516      ALLOCATE( prmax(jpi,jpj,jpk), quotan(jpi,jpj,jpk), quotad(jpi,jpj,jpk), STAT = p4z_prod_alloc )
517      !
518      IF( p4z_prod_alloc /= 0 ) CALL ctl_warn('p4z_prod_alloc : failed to allocate arrays.')
519      !
520   END FUNCTION p4z_prod_alloc
521
522#else
523   !!======================================================================
524   !!  Dummy module :                                   No PISCES bio-model
525   !!======================================================================
526CONTAINS
527   SUBROUTINE p4z_prod                    ! Empty routine
528   END SUBROUTINE p4z_prod
529#endif 
530
531   !!======================================================================
532END MODULE  p4zprod
Note: See TracBrowser for help on using the repository browser.