New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trcsbc.F90 in trunk/NEMOGCM/NEMO/TOP_SRC/TRP – NEMO

source: trunk/NEMOGCM/NEMO/TOP_SRC/TRP/trcsbc.F90 @ 2528

Last change on this file since 2528 was 2528, checked in by rblod, 13 years ago

Update NEMOGCM from branch nemo_v3_3_beta

  • Property svn:keywords set to Id
File size: 6.0 KB
Line 
1MODULE trcsbc
2   !!==============================================================================
3   !!                       ***  MODULE  trcsbc  ***
4   !! Ocean passive tracers:  surface boundary condition
5   !!======================================================================
6   !! History :  8.2  !  1998-10  (G. Madec, G. Roullet, M. Imbard)  Original code
7   !!            8.2  !  2001-02  (D. Ludicone)  sea ice and free surface
8   !!            8.5  !  2002-06  (G. Madec)  F90: Free form and module
9   !!            9.0  !  2004-03  (C. Ethe)  adapted for passive tracers
10   !!                 !  2006-08  (C. Deltel) Diagnose ML trends for passive tracers
11   !!==============================================================================
12#if defined key_top
13   !!----------------------------------------------------------------------
14   !!   'key_top'                                                TOP models
15   !!----------------------------------------------------------------------
16   !!   trc_sbc      : update the tracer trend at ocean surface
17   !!----------------------------------------------------------------------
18   !! * Modules used
19   USE oce_trc             ! ocean dynamics and active tracers variables
20   USE trc                 ! ocean  passive tracers variables
21   USE prtctl_trc          ! Print control for debbuging
22   USE trdmod_oce
23   USE trdtra
24
25   IMPLICIT NONE
26   PRIVATE
27
28   !! * Routine accessibility
29   PUBLIC trc_sbc              ! routine called by step.F90
30
31   !! * Substitutions
32#  include "top_substitute.h90"
33   !!----------------------------------------------------------------------
34   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
35   !! $Id$
36   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
37   !!----------------------------------------------------------------------
38
39CONTAINS
40
41   SUBROUTINE trc_sbc ( kt )
42      !!----------------------------------------------------------------------
43      !!                  ***  ROUTINE trc_sbc  ***
44      !!                   
45      !! ** Purpose :   Compute the tracer surface boundary condition trend of
46      !!      (concentration/dilution effect) and add it to the general
47      !!       trend of tracer equations.
48      !!
49      !! ** Method :
50      !!      * concentration/dilution effect:
51      !!            The surface freshwater flux modify the ocean volume
52      !!         and thus the concentration of a tracer as :
53      !!            tra = tra + emp * trn / e3t   for k=1
54      !!         where emp, the surface freshwater budget (evaporation minus
55      !!         precipitation minus runoff) given in kg/m2/s is divided
56      !!         by 1035 kg/m3 (density of ocean water) to obtain m/s.
57      !!
58      !! ** Action  : - Update the 1st level of tra with the trend associated
59      !!                with the tracer surface boundary condition
60      !!
61      !!----------------------------------------------------------------------
62      !! * Arguments
63      INTEGER, INTENT( in ) ::   kt          ! ocean time-step index
64
65      !! * Local declarations
66      INTEGER  ::   ji, jj, jn           ! dummy loop indices
67      REAL(wp) ::   zsrau, zse3t   ! temporary scalars
68      REAL(wp), DIMENSION(jpi,jpj) ::   zemps  ! surface freshwater flux
69      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::   ztrtrd
70      CHARACTER (len=22) :: charout
71      !!----------------------------------------------------------------------
72
73      IF( kt == nit000 ) THEN
74         IF(lwp) WRITE(numout,*)
75         IF(lwp) WRITE(numout,*) 'trc_sbc : Passive tracers surface boundary condition'
76         IF(lwp) WRITE(numout,*) '~~~~~~~ '
77      ENDIF
78
79
80      IF( l_trdtrc ) ALLOCATE( ztrtrd(jpi,jpj,jpk) )
81
82      IF( lk_offline ) THEN          ! emps in dynamical files contains emps - rnf
83         zemps(:,:) = emps(:,:) 
84      ELSE                           ! Concentration dilution effect on tracer due to evaporation, precipitation, and river runoff
85         IF( lk_vvl ) THEN                      ! volume variable
86            zemps(:,:) = emps(:,:) - emp(:,:)   
87!!ch         zemps(:,:) = 0.
88         ELSE                                   ! linear free surface
89            IF( ln_rnf ) THEN  ;  zemps(:,:) = emps(:,:) - rnf(:,:)   !  E-P-R
90            ELSE               ;  zemps(:,:) = emps(:,:)
91            ENDIF
92         ENDIF
93      ENDIF 
94
95      ! 0. initialization
96      zsrau = 1. / rau0
97      DO jn = 1, jptra
98         !
99         IF( l_trdtrc ) ztrtrd(:,:,:) = tra(:,:,:,jn)  ! save trends
100         !                                             ! add the trend to the general tracer trend
101         DO jj = 2, jpj
102            DO ji = fs_2, fs_jpim1   ! vector opt.
103               zse3t = 1. / fse3t(ji,jj,1)
104               tra(ji,jj,1,jn) = tra(ji,jj,1,jn) + zemps(ji,jj) *  zsrau * trn(ji,jj,1,jn) * zse3t
105            END DO
106         END DO
107         
108         IF( l_trdtrc ) THEN
109            ztrtrd(:,:,:) = tra(:,:,:,jn) - ztrtrd(:,:,:)
110            CALL trd_tra( kt, 'TRC', jn, jptra_trd_nsr, ztrtrd )
111         END IF
112         !                                                       ! ===========
113      END DO                                                     ! tracer loop
114      !                                                          ! ===========
115      IF( l_trdtrc ) DEALLOCATE( ztrtrd )
116
117      IF( ln_ctl )   THEN
118         WRITE(charout, FMT="('sbc ')") ;  CALL prt_ctl_trc_info(charout)
119                                           CALL prt_ctl_trc( tab4d=tra, mask=tmask, clinfo=ctrcnm, clinfo2='trd' )
120      ENDIF
121
122   END SUBROUTINE trc_sbc
123
124#else
125   !!----------------------------------------------------------------------
126   !!   Dummy module :                      NO passive tracer
127   !!----------------------------------------------------------------------
128CONTAINS
129   SUBROUTINE trc_sbc (kt)              ! Empty routine
130      INTEGER, INTENT(in) :: kt
131      WRITE(*,*) 'trc_sbc: You should not have seen this print! error?', kt
132   END SUBROUTINE trc_sbc
133#endif
134   
135   !!======================================================================
136END MODULE trcsbc
Note: See TracBrowser for help on using the repository browser.