New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trcstp.F90 in trunk/NEMOGCM/NEMO/TOP_SRC – NEMO

source: trunk/NEMOGCM/NEMO/TOP_SRC/trcstp.F90 @ 7698

Last change on this file since 7698 was 7698, checked in by mocavero, 7 years ago

update trunk with OpenMP parallelization
  • Property svn:keywords set to Id
File size: 10.2 KB
Line 
1MODULE trcstp
2   !!======================================================================
3   !!                       ***  MODULE trcstp  ***
4   !! Time-stepping    : time loop of opa for passive tracer
5   !!======================================================================
6   !! History :  1.0  !  2004-03  (C. Ethe)  Original
7   !!----------------------------------------------------------------------
8#if defined key_top
9   !!----------------------------------------------------------------------
10   !!   trc_stp      : passive tracer system time-stepping
11   !!----------------------------------------------------------------------
12   USE oce_trc          ! ocean dynamics and active tracers variables
13   USE sbc_oce
14   USE trc
15   USE trctrp           ! passive tracers transport
16   USE trcsms           ! passive tracers sources and sinks
17   USE trcwri
18   USE trcrst
19   USE trdtrc_oce
20   USE trdmxl_trc
21   USE prtctl_trc       ! Print control for debbuging
22   USE iom
23   USE in_out_manager
24   USE trcsub
25
26   IMPLICIT NONE
27   PRIVATE
28
29   PUBLIC   trc_stp    ! called by step
30
31   REAL(wp), DIMENSION(:,:,:), SAVE, ALLOCATABLE ::   qsr_arr ! save qsr during TOP time-step
32   REAL(wp) :: rdt_sampl
33   INTEGER  :: nb_rec_per_day
34   REAL(wp) :: rsecfst, rseclast
35   LOGICAL  :: llnew
36
37   !!----------------------------------------------------------------------
38   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
39   !! $Id$
40   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
41   !!----------------------------------------------------------------------
42CONTAINS
43
44   SUBROUTINE trc_stp( kt )
45      !!-------------------------------------------------------------------
46      !!                     ***  ROUTINE trc_stp  ***
47      !!                     
48      !! ** Purpose : Time loop of opa for passive tracer
49      !!
50      !! ** Method  :
51      !!              Compute the passive tracers trends
52      !!              Update the passive tracers
53      !!-------------------------------------------------------------------
54      INTEGER, INTENT( in ) ::  kt      ! ocean time-step index
55      INTEGER               ::  jk, jn, jj, ji  ! dummy loop indices
56      REAL(wp)              ::  ztrai
57      CHARACTER (len=25)    ::  charout 
58
59      !!-------------------------------------------------------------------
60      !
61      IF( nn_timing == 1 )   CALL timing_start('trc_stp')
62      !
63      IF( ( neuler == 0 .AND. kt == nittrc000 ) .OR. ln_top_euler ) THEN     ! at nittrc000
64         r2dttrc =  rdttrc           ! = rdttrc (use or restarting with Euler time stepping)
65      ELSEIF( kt <= nittrc000 + nn_dttrc ) THEN          ! at nittrc000 or nittrc000+1
66         r2dttrc = 2. * rdttrc       ! = 2 rdttrc (leapfrog)
67      ENDIF
68      !
69      IF( kt == nittrc000 .AND. lk_trdmxl_trc )  CALL trd_mxl_trc_init    ! trends: Mixed-layer
70      !
71      IF( .NOT.ln_linssh ) THEN                                           ! update ocean volume due to ssh temporal evolution
72!$OMP PARALLEL DO schedule(static) private(jk,jj,ji)
73         DO jk = 1, jpk
74            DO jj = 1, jpj
75               DO ji = 1, jpi
76                  cvol(ji,jj,jk) = e1e2t(ji,jj) * e3t_n(ji,jj,jk) * tmask(ji,jj,jk)
77               END DO
78            END DO
79         END DO
80         areatot         = glob_sum( cvol(:,:,:) )
81      ENDIF
82      !
83      IF( l_trcdm2dc )   CALL trc_mean_qsr( kt )
84      !   
85      IF( nn_dttrc /= 1 )   CALL trc_sub_stp( kt )  ! averaging physical variables for sub-stepping
86      !   
87      IF( MOD( kt , nn_dttrc ) == 0 ) THEN      ! only every nn_dttrc time step
88         !
89         IF(ln_ctl) THEN
90            WRITE(charout,FMT="('kt =', I4,'  d/m/y =',I2,I2,I4)") kt, nday, nmonth, nyear
91            CALL prt_ctl_trc_info(charout)
92         ENDIF
93         !
94         DO jn = 1, jptra
95!$OMP PARALLEL DO schedule(static) private(jk,jj,ji)
96            DO jk = 1, jpk
97               DO jj = 1, jpj
98                  DO ji = 1, jpi
99                     tra(ji,jj,jk,jn) = 0._wp
100                  END DO
101               END DO
102            END DO
103         END DO
104         !
105                                   CALL trc_rst_opn  ( kt )       ! Open tracer restart file
106         IF( lrst_trc )            CALL trc_rst_cal  ( kt, 'WRITE' )   ! calendar
107                                   CALL trc_wri      ( kt )       ! output of passive tracers with iom I/O manager
108                                   CALL trc_sms      ( kt )       ! tracers: sinks and sources
109                                   CALL trc_trp      ( kt )       ! transport of passive tracers
110         IF( kt == nittrc000 ) THEN
111            CALL iom_close( numrtr )       ! close input tracer restart file
112            IF(lwm) CALL FLUSH( numont )   ! flush namelist output
113         ENDIF
114         IF( lrst_trc )            CALL trc_rst_wri  ( kt )       ! write tracer restart file
115         IF( lk_trdmxl_trc  )      CALL trd_mxl_trc  ( kt )       ! trends: Mixed-layer
116         !
117         IF( nn_dttrc /= 1   )     CALL trc_sub_reset( kt )       ! resetting physical variables when sub-stepping
118         !
119      ENDIF
120      !
121      ztrai = 0._wp                                                   !  content of all tracers
122      DO jn = 1, jptra
123         ztrai = ztrai + glob_sum( trn(:,:,:,jn) * cvol(:,:,:)   )
124      END DO
125      IF( lwp ) WRITE(numstr,9300) kt,  ztrai / areatot
1269300  FORMAT(i10,D23.16)
127      !
128      IF( nn_timing == 1 )   CALL timing_stop('trc_stp')
129      !
130   END SUBROUTINE trc_stp
131
132   SUBROUTINE trc_mean_qsr( kt )
133      !!----------------------------------------------------------------------
134      !!             ***  ROUTINE trc_mean_qsr  ***
135      !!
136      !! ** Purpose :  Compute daily mean qsr for biogeochemical model in case
137      !!               of diurnal cycle
138      !!
139      !! ** Method  : store in TOP the qsr every hour ( or every time-step if the latter
140      !!              is greater than 1 hour ) and then, compute the  mean with
141      !!              a moving average over 24 hours.
142      !!              In coupled mode, the sampling is done at every coupling frequency
143      !!----------------------------------------------------------------------
144      INTEGER, INTENT(in) ::   kt
145      INTEGER  :: jn
146      REAL(wp) :: zkt
147      CHARACTER(len=1)               ::   cl1                      ! 1 character
148      CHARACTER(len=2)               ::   cl2                      ! 2 characters
149
150      IF( kt == nittrc000 ) THEN
151         IF( ln_cpl )  THEN 
152            rdt_sampl = rday / ncpl_qsr_freq
153            nb_rec_per_day = ncpl_qsr_freq
154         ELSE 
155            rdt_sampl = MAX( 3600., rdttrc )
156            nb_rec_per_day = INT( rday / rdt_sampl )
157         ENDIF
158         !
159         IF( lwp ) THEN
160            WRITE(numout,*) 
161            WRITE(numout,*) ' Sampling frequency dt = ', rdt_sampl, 's','   Number of sampling per day  nrec = ', nb_rec_per_day
162            WRITE(numout,*) 
163         ENDIF
164         !
165         ALLOCATE( qsr_arr(jpi,jpj,nb_rec_per_day ) )
166         !
167         !                                            !* Restart: read in restart file
168         IF( ln_rsttr .AND. iom_varid( numrtr, 'qsr_mean' , ldstop = .FALSE. ) > 0 .AND. &
169                            iom_varid( numrtr, 'qsr_arr_1', ldstop = .FALSE. ) > 0 .AND. &
170                            iom_varid( numrtr, 'ktdcy'    , ldstop = .FALSE. ) > 0 ) THEN
171            CALL iom_get( numrtr, 'ktdcy', zkt )   !  A mean of qsr
172            rsecfst = INT( zkt ) * rdttrc
173            IF(lwp) WRITE(numout,*) 'trc_qsr_mean:   qsr_mean read in the restart file at time-step rsecfst =', rsecfst, ' s '
174            CALL iom_get( numrtr, jpdom_autoglo, 'qsr_mean', qsr_mean )   !  A mean of qsr
175            DO jn = 1, nb_rec_per_day 
176             IF( jn <= 9 )  THEN
177               WRITE(cl1,'(i1)') jn
178               CALL iom_get( numrtr, jpdom_autoglo, 'qsr_arr_'//cl1, qsr_arr(:,:,jn) )   !  A mean of qsr
179             ELSE
180               WRITE(cl2,'(i2.2)') jn
181               CALL iom_get( numrtr, jpdom_autoglo, 'qsr_arr_'//cl2, qsr_arr(:,:,jn) )   !  A mean of qsr
182             ENDIF
183           ENDDO
184         ELSE                                         !* no restart: set from nit000 values
185            IF(lwp) WRITE(numout,*) 'trc_qsr_mean:   qsr_mean set to nit000 values'
186            rsecfst  = kt * rdttrc
187            !
188            qsr_mean(:,:) = qsr(:,:)
189            DO jn = 1, nb_rec_per_day
190               qsr_arr(:,:,jn) = qsr_mean(:,:)
191            ENDDO
192         ENDIF
193         !
194      ENDIF
195      !
196      rseclast = kt * rdttrc
197      !
198      llnew   = ( rseclast - rsecfst ) .ge.  rdt_sampl    !   new shortwave to store
199      IF( llnew ) THEN
200          IF( lwp ) WRITE(numout,*) ' New shortwave to sample for TOP at time kt = ', kt, &
201             &                      ' time = ', rseclast/3600.,'hours '
202          rsecfst = rseclast
203          DO jn = 1, nb_rec_per_day - 1
204             qsr_arr(:,:,jn) = qsr_arr(:,:,jn+1)
205          ENDDO
206          qsr_arr (:,:,nb_rec_per_day) = qsr(:,:)
207          qsr_mean(:,:                ) = SUM( qsr_arr(:,:,:), 3 ) / nb_rec_per_day
208      ENDIF
209      !
210      IF( lrst_trc ) THEN    !* Write the mean of qsr in restart file
211         IF(lwp) WRITE(numout,*)
212         IF(lwp) WRITE(numout,*) 'trc_mean_qsr : write qsr_mean in restart file  kt =', kt
213         IF(lwp) WRITE(numout,*) '~~~~~~~'
214         zkt = REAL( kt, wp )
215         CALL iom_rstput( kt, nitrst, numrtw, 'ktdcy', zkt )
216          DO jn = 1, nb_rec_per_day 
217             IF( jn <= 9 )  THEN
218               WRITE(cl1,'(i1)') jn
219               CALL iom_rstput( kt, nitrst, numrtw, 'qsr_arr_'//cl1, qsr_arr(:,:,jn) )
220             ELSE
221               WRITE(cl2,'(i2.2)') jn
222               CALL iom_rstput( kt, nitrst, numrtw, 'qsr_arr_'//cl2, qsr_arr(:,:,jn) )
223             ENDIF
224         ENDDO
225         CALL iom_rstput( kt, nitrst, numrtw, 'qsr_mean', qsr_mean(:,:) )
226      ENDIF
227      !
228   END SUBROUTINE trc_mean_qsr
229
230#else
231   !!----------------------------------------------------------------------
232   !!   Default key                                     NO passive tracers
233   !!----------------------------------------------------------------------
234CONTAINS
235   SUBROUTINE trc_stp( kt )        ! Empty routine
236      WRITE(*,*) 'trc_stp: You should not have seen this print! error?', kt
237   END SUBROUTINE trc_stp
238#endif
239
240   !!======================================================================
241END MODULE trcstp
Note: See TracBrowser for help on using the repository browser.