New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
icedyn_adv_umx.F90 in NEMO/branches/2018/dev_r10164_HPC09_ESIWACE_PREP_MERGE/src/ICE – NEMO

source: NEMO/branches/2018/dev_r10164_HPC09_ESIWACE_PREP_MERGE/src/ICE/icedyn_adv_umx.F90 @ 10386

Last change on this file since 10386 was 10386, checked in by smasson, 5 years ago

dev_r10164_HPC09_ESIWACE_PREP_MERGE: safer use of l_full_nf_update (2 lines north fold exchange), see #2133
  • Property svn:keywords set to Id
File size: 38.0 KB
Line 
1MODULE icedyn_adv_umx
2   !!==============================================================================
3   !!                       ***  MODULE  icedyn_adv_umx  ***
4   !! sea-ice : advection using the ULTIMATE-MACHO scheme
5   !!==============================================================================
6   !! History :  3.6  !  2014-11  (C. Rousset, G. Madec)  Original code
7   !!            4.0  !  2018     (many people)           SI3 [aka Sea Ice cube]
8   !!----------------------------------------------------------------------
9#if defined key_si3
10   !!----------------------------------------------------------------------
11   !!   'key_si3'                                       SI3 sea-ice model
12   !!----------------------------------------------------------------------
13   !!   ice_dyn_adv_umx   : update the tracer trend with the 3D advection trends using a TVD scheme
14   !!   ultimate_x(_y)    : compute a tracer value at velocity points using ULTIMATE scheme at various orders
15   !!   macho             : ???
16   !!   nonosc_2d         : compute monotonic tracer fluxes by a non-oscillatory algorithm
17   !!----------------------------------------------------------------------
18   USE phycst         ! physical constant
19   USE dom_oce        ! ocean domain
20   USE sbc_oce , ONLY : nn_fsbc   ! update frequency of surface boundary condition
21   USE ice            ! sea-ice variables
22   !
23   USE in_out_manager ! I/O manager
24   USE lib_mpp        ! MPP library
25   USE lib_fortran    ! fortran utilities (glob_sum + no signed zero)
26   USE lbclnk         ! lateral boundary conditions (or mpp links)
27
28   IMPLICIT NONE
29   PRIVATE
30
31   PUBLIC   ice_dyn_adv_umx   ! called by icedyn_adv.F90
32     
33   REAL(wp) ::   z1_6   = 1._wp /   6._wp   ! =1/6
34   REAL(wp) ::   z1_120 = 1._wp / 120._wp   ! =1/120
35
36   !! * Substitutions
37#  include "vectopt_loop_substitute.h90"
38   !!----------------------------------------------------------------------
39   !! NEMO/ICE 4.0 , NEMO Consortium (2018)
40   !! $Id$
41   !! Software governed by the CeCILL license (see ./LICENSE)
42   !!----------------------------------------------------------------------
43CONTAINS
44
45   SUBROUTINE ice_dyn_adv_umx( k_order, kt, pu_ice, pv_ice,  &
46      &                    pato_i, pv_i, pv_s, psv_i, poa_i, pa_i, pa_ip, pv_ip, pe_s, pe_i )
47      !!----------------------------------------------------------------------
48      !!                  ***  ROUTINE ice_dyn_adv_umx  ***
49      !!
50      !! **  Purpose :   Compute the now trend due to total advection of
51      !!                 tracers and add it to the general trend of tracer equations
52      !!                 using an "Ultimate-Macho" scheme
53      !!
54      !! Reference : Leonard, B.P., 1991, Comput. Methods Appl. Mech. Eng., 88, 17-74.
55      !!----------------------------------------------------------------------
56      INTEGER                     , INTENT(in   ) ::   k_order    ! order of the scheme (1-5 or 20)
57      INTEGER                     , INTENT(in   ) ::   kt         ! time step
58      REAL(wp), DIMENSION(:,:)    , INTENT(in   ) ::   pu_ice     ! ice i-velocity
59      REAL(wp), DIMENSION(:,:)    , INTENT(in   ) ::   pv_ice     ! ice j-velocity
60      REAL(wp), DIMENSION(:,:)    , INTENT(inout) ::   pato_i     ! open water area
61      REAL(wp), DIMENSION(:,:,:)  , INTENT(inout) ::   pv_i       ! ice volume
62      REAL(wp), DIMENSION(:,:,:)  , INTENT(inout) ::   pv_s       ! snw volume
63      REAL(wp), DIMENSION(:,:,:)  , INTENT(inout) ::   psv_i      ! salt content
64      REAL(wp), DIMENSION(:,:,:)  , INTENT(inout) ::   poa_i      ! age content
65      REAL(wp), DIMENSION(:,:,:)  , INTENT(inout) ::   pa_i       ! ice concentration
66      REAL(wp), DIMENSION(:,:,:)  , INTENT(inout) ::   pa_ip      ! melt pond fraction
67      REAL(wp), DIMENSION(:,:,:)  , INTENT(inout) ::   pv_ip      ! melt pond volume
68      REAL(wp), DIMENSION(:,:,:,:), INTENT(inout) ::   pe_s       ! snw heat content
69      REAL(wp), DIMENSION(:,:,:,:), INTENT(inout) ::   pe_i       ! ice heat content
70      !
71      INTEGER  ::   ji, jj, jk, jl, jt      ! dummy loop indices
72      INTEGER  ::   initad                  ! number of sub-timestep for the advection
73      INTEGER  ::   ipl                     ! third dimention of tracer array
74
75      REAL(wp) ::   zcfl(2), zusnit, zdt      !   -      -
76      REAL(wp), ALLOCATABLE, DIMENSION(:,:)   ::   zudy, zvdx, zcu_box, zcv_box
77      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) ::   zpato
78      !!----------------------------------------------------------------------
79      !
80      IF( kt == nit000 .AND. lwp )   WRITE(numout,*) '-- ice_dyn_adv_umx: Ultimate-Macho advection scheme'
81      !
82      ALLOCATE( zudy(jpi,jpj) , zvdx(jpi,jpj) , zcu_box(jpi,jpj) , zcv_box(jpi,jpj) )
83      ALLOCATE( zpato(jpi,jpj,1) )
84      !
85      ! --- If ice drift field is too fast, use an appropriate time step for advection (CFL test for stability) --- !
86      !     When needed, the advection split is applied at the next time-step in order to avoid blocking global comm.
87      !     ...this should not affect too much the stability... Was ok on the tests we did...
88      zcfl(1) =               MAXVAL( ABS( pu_ice(:,:) ) * rdt_ice * r1_e1u(:,:) )
89      zcfl(1) = MAX( zcfl(1), MAXVAL( ABS( pv_ice(:,:) ) * rdt_ice * r1_e2v(:,:) ) )
90     
91      ! non-blocking global communication send zcfl(1) and receive zcfl(2)
92      IF( lk_mpp )   CALL mpp_delay_max( 'icedyn_adv_umx', 'advumx_delay', zcfl, kt == nitend - nn_fsbc + 1 )
93
94      IF( zcfl(2) > .5 ) THEN   ;   initad = 2   ;   zusnit = 0.5_wp   ! zcfl(2) corresponding to zcfl(1) of the previous time-step
95      ELSE                      ;   initad = 1   ;   zusnit = 1.0_wp
96      ENDIF
97
98      zdt = rdt_ice / REAL(initad)
99
100      ! --- transport --- !
101      zudy(:,:) = pu_ice(:,:) * e2u(:,:)
102      zvdx(:,:) = pv_ice(:,:) * e1v(:,:)
103
104      ! --- define velocity for advection: u*grad(H) --- !
105      DO jj = 2, jpjm1
106         DO ji = fs_2, fs_jpim1
107            IF    ( pu_ice(ji,jj) * pu_ice(ji-1,jj) <= 0._wp ) THEN   ;   zcu_box(ji,jj) = 0._wp
108            ELSEIF( pu_ice(ji,jj)                   >  0._wp ) THEN   ;   zcu_box(ji,jj) = pu_ice(ji-1,jj)
109            ELSE                                                      ;   zcu_box(ji,jj) = pu_ice(ji  ,jj)
110            ENDIF
111
112            IF    ( pv_ice(ji,jj) * pv_ice(ji,jj-1) <= 0._wp ) THEN   ;   zcv_box(ji,jj) = 0._wp
113            ELSEIF( pv_ice(ji,jj)                   >  0._wp ) THEN   ;   zcv_box(ji,jj) = pv_ice(ji,jj-1)
114            ELSE                                                      ;   zcv_box(ji,jj) = pv_ice(ji,jj  )
115            ENDIF
116         END DO
117      END DO
118
119      zpato (:,:,1) = pato_i(:,:)
120
121      !---------------!
122      !== advection ==!
123      !---------------!
124      DO jt = 1, initad
125         
126         l_full_nf_update = .FALSE.   ! false: disable full North fold update (performances)
127         CALL adv_umx( k_order, kt,   1, zdt, zudy, zvdx, zcu_box, zcv_box, zpato(:,:,1) )        ! Open water area
128         CALL adv_umx( k_order, kt, jpl, zdt, zudy, zvdx, zcu_box, zcv_box, pa_i(:,:,:) )         ! Ice area
129         CALL adv_umx( k_order, kt, jpl, zdt, zudy, zvdx, zcu_box, zcv_box, pv_i(:,:,:) )         ! Ice  volume
130         CALL adv_umx( k_order, kt, jpl, zdt, zudy, zvdx, zcu_box, zcv_box, psv_i(:,:,:) )        ! Salt content
131         CALL adv_umx( k_order, kt, jpl, zdt, zudy, zvdx, zcu_box, zcv_box, poa_i(:,:,:) )        ! Age content
132         DO jk = 1, nlay_i
133            CALL adv_umx( k_order, kt, jpl, zdt, zudy, zvdx, zcu_box, zcv_box, pe_i(:,:,jk,:) )   ! Ice  heat content
134         END DO
135         CALL adv_umx( k_order, kt, jpl, zdt, zudy, zvdx, zcu_box, zcv_box, pv_s(:,:,:) )         ! Snow volume
136         DO jk = 1, nlay_s
137            CALL adv_umx( k_order, kt, jpl, zdt, zudy, zvdx, zcu_box, zcv_box, pe_s(:,:,jk,:) )   ! Snow heat content
138         END DO
139         IF ( ln_pnd_H12 ) THEN
140            CALL adv_umx( k_order, kt, jpl, zdt, zudy, zvdx, zcu_box, zcv_box, pa_ip(:,:,:) )     ! Melt pond fraction
141            CALL adv_umx( k_order, kt, jpl, zdt, zudy, zvdx, zcu_box, zcv_box, pv_ip(:,:,:) )     ! Melt pond volume
142         ENDIF
143
144         l_full_nf_update = jt == initad   ! true: enable full North fold update (performances) when exiting the loop
145         CALL lbc_lnk( 'icedyn_adv_umx', zpato, 'T',  1. )
146         CALL lbc_lnk( 'icedyn_adv_umx', pe_i, 'T',  1. )
147         CALL lbc_lnk( 'icedyn_adv_umx', pe_s, 'T',  1. )
148         IF ( ln_pnd_H12 ) THEN
149            CALL lbc_lnk_multi( 'icedyn_adv_umx',  pa_i, 'T',  1., pv_i, 'T',  1., psv_i, 'T',  1., &
150                                                & poa_i, 'T',  1., pv_s, 'T',  1., pa_ip, 'T',  1., &
151                                                & pv_ip, 'T',  1. )
152         ELSE
153            CALL lbc_lnk_multi( 'icedyn_adv_umx',  pa_i, 'T',  1., pv_i, 'T',  1., psv_i, 'T',  1., &
154                                                & poa_i, 'T',  1., pv_s, 'T',  1. )
155         ENDIF
156         
157      END DO
158      !
159      pato_i(:,:) = zpato (:,:,1)
160      !
161      DEALLOCATE( zudy, zvdx, zcu_box, zcv_box, zpato )
162      !
163   END SUBROUTINE ice_dyn_adv_umx
164
165   
166   SUBROUTINE adv_umx( k_order, kt, ipl, pdt, puc, pvc, pubox, pvbox, ptc )
167      !!----------------------------------------------------------------------
168      !!                  ***  ROUTINE adv_umx  ***
169      !!
170      !! **  Purpose :   Compute the now trend due to total advection of
171      !!       tracers and add it to the general trend of tracer equations
172      !!
173      !! **  Method  :   TVD scheme, i.e. 2nd order centered scheme with
174      !!       corrected flux (monotonic correction)
175      !!       note: - this advection scheme needs a leap-frog time scheme
176      !!
177      !! ** Action : - pt  the after advective tracer
178      !!----------------------------------------------------------------------
179      INTEGER                         , INTENT(in   ) ::   k_order        ! order of the ULTIMATE scheme
180      INTEGER                         , INTENT(in   ) ::   kt             ! number of iteration
181      INTEGER                         , INTENT(in   ) ::   ipl            ! third dimension of tracer array
182      REAL(wp)                        , INTENT(in   ) ::   pdt            ! tracer time-step
183      REAL(wp), DIMENSION(jpi,jpj)    , INTENT(in   ) ::   puc  , pvc     ! 2 ice velocity components => u*e2
184      REAL(wp), DIMENSION(jpi,jpj)    , INTENT(in   ) ::   pubox, pvbox   ! upstream velocity
185      REAL(wp), DIMENSION(jpi,jpj,ipl), INTENT(inout) ::   ptc            ! tracer content field
186      !
187      INTEGER  ::   ji, jj, jl       ! dummy loop indices 
188
189      REAL(wp) ::   ztra             ! local scalar
190      REAL(wp), DIMENSION(jpi,jpj,ipl) ::   zfu_ups, zfu_ho, zt_u, zt_ups
191      REAL(wp), DIMENSION(jpi,jpj,ipl) ::   zfv_ups, zfv_ho, zt_v, ztrd
192
193      DO jl = 1, ipl
194      !!----------------------------------------------------------------------
195      !
196      !  upstream advection with initial mass fluxes & intermediate update
197      ! --------------------------------------------------------------------
198      DO jj = 1, jpjm1         ! upstream tracer flux in the i and j direction
199         DO ji = 1, fs_jpim1   ! vector opt.
200            zfu_ups(ji,jj,jl) = MAX( puc(ji,jj), 0._wp ) * ptc(ji,jj,jl) + MIN( puc(ji,jj), 0._wp ) * ptc(ji+1,jj,jl)
201            zfv_ups(ji,jj,jl) = MAX( pvc(ji,jj), 0._wp ) * ptc(ji,jj,jl) + MIN( pvc(ji,jj), 0._wp ) * ptc(ji,jj+1,jl)
202         END DO
203      END DO
204     
205         DO jj = 2, jpjm1            ! total intermediate advective trends
206            DO ji = fs_2, fs_jpim1   ! vector opt.
207               ztra = - (   zfu_ups(ji,jj,jl) - zfu_ups(ji-1,jj  ,jl)   &
208                  &       + zfv_ups(ji,jj,jl) - zfv_ups(ji  ,jj-1,jl)   ) * r1_e1e2t(ji,jj)
209            !
210               ztrd(ji,jj,jl) =                         ztra                         ! upstream trend [ -div(uh) or -div(uhT) ] 
211               zt_ups (ji,jj,jl) = ( ptc(ji,jj,jl) + pdt * ztra ) * tmask(ji,jj,1)   ! guess after content field with monotonic scheme
212            END DO
213         END DO
214      END DO
215     
216      ! High order (_ho) fluxes
217      ! -----------------------
218      SELECT CASE( k_order )
219      CASE ( 20 )                          ! centered second order
220         DO jl = 1, ipl
221            DO jj = 1, jpjm1
222               DO ji = 1, fs_jpim1   ! vector opt.
223                  zfu_ho(ji,jj,jl) = 0.5 * puc(ji,jj) * ( ptc(ji,jj,jl) + ptc(ji+1,jj,jl) )
224                  zfv_ho(ji,jj,jl) = 0.5 * pvc(ji,jj) * ( ptc(ji,jj,jl) + ptc(ji,jj+1,jl) )
225               END DO
226            END DO
227         END DO
228         !
229      CASE ( 1:5 )                      ! 1st to 5th order ULTIMATE-MACHO scheme
230         CALL macho( k_order, kt, ipl, pdt, ptc, puc, pvc, pubox, pvbox, zt_u, zt_v )
231         !
232         DO jl = 1, ipl
233            DO jj = 2, jpjm1
234               DO ji = 1, fs_jpim1   ! vector opt.
235                  zfu_ho(ji,jj,jl) = puc(ji,jj) * zt_u(ji,jj,jl)
236               END DO
237            END DO
238         END DO
239         DO jl = 1, ipl
240            DO jj = 1, jpjm1
241               DO ji = fs_2, fs_jpim1   ! vector opt.
242                  zfv_ho(ji,jj,jl) = pvc(ji,jj) * zt_v(ji,jj,jl)
243               END DO
244            END DO
245         END DO
246         !
247      END SELECT
248         
249      ! antidiffusive flux : high order minus low order
250      ! --------------------------------------------------
251      DO jl = 1, ipl
252         DO jj = 2, jpjm1
253            DO ji = 1, fs_jpim1   ! vector opt.
254               zfu_ho(ji,jj,jl) = zfu_ho(ji,jj,jl) - zfu_ups(ji,jj,jl)
255            END DO
256         END DO
257      END DO
258      DO jl = 1, ipl
259         DO jj = 1, jpjm1
260            DO ji = fs_2, fs_jpim1   ! vector opt.
261               zfv_ho(ji,jj,jl) = zfv_ho(ji,jj,jl) - zfv_ups(ji,jj,jl)
262            END DO
263         END DO
264      END DO
265
266      CALL lbc_lnk("icedyn_adv_umx",zt_ups, 'T', 1. )        ! Lateral boundary conditions   (unchanged sign)
267     
268      ! monotonicity algorithm
269      ! -------------------------
270      CALL nonosc_2d( ipl, ptc, zfu_ho, zfv_ho, zt_ups, pdt )
271     
272      ! final trend with corrected fluxes
273      ! ------------------------------------
274      DO jl = 1, ipl
275         DO jj = 2, jpjm1
276            DO ji = fs_2, fs_jpim1   ! vector opt. 
277               ztra       = ztrd(ji,jj,jl)  - (  zfu_ho(ji,jj,jl) - zfu_ho(ji-1,jj  ,jl)   &
278                  &                         +    zfv_ho(ji,jj,jl) - zfv_ho(ji  ,jj-1,jl) ) * r1_e1e2t(ji,jj) 
279               ptc(ji,jj,jl) = ptc(ji,jj,jl) + pdt * ztra * tmask(ji,jj,1)
280            END DO
281         END DO
282      END DO
283      !
284   END SUBROUTINE adv_umx
285
286   SUBROUTINE macho( k_order, kt, ipl, pdt, ptc, puc, pvc, pubox, pvbox, pt_u, pt_v )
287      !!---------------------------------------------------------------------
288      !!                    ***  ROUTINE ultimate_x  ***
289      !!     
290      !! **  Purpose :   compute 
291      !!
292      !! **  Method  :   ... ???
293      !!                 TIM = transient interpolation Modeling
294      !!
295      !! Reference : Leonard, B.P., 1991, Comput. Methods Appl. Mech. Eng., 88, 17-74.
296      !!----------------------------------------------------------------------
297      INTEGER                         , INTENT(in   ) ::   k_order    ! order of the ULTIMATE scheme
298      INTEGER                         , INTENT(in   ) ::   kt         ! number of iteration
299      INTEGER                         , INTENT(in   ) ::   ipl        ! third dimension of tracer array
300      REAL(wp)                        , INTENT(in   ) ::   pdt        ! tracer time-step
301      REAL(wp), DIMENSION(jpi,jpj,ipl), INTENT(in   ) ::   ptc        ! tracer fields
302      REAL(wp), DIMENSION(jpi,jpj)    , INTENT(in   ) ::   puc, pvc   ! 2 ice velocity components
303      REAL(wp), DIMENSION(jpi,jpj)    , INTENT(in   ) ::   pubox, pvbox   ! upstream velocity
304      REAL(wp), DIMENSION(jpi,jpj,ipl), INTENT(  out) ::   pt_u, pt_v ! tracer at u- and v-points
305      !
306      INTEGER  ::   ji, jj, jl    ! dummy loop indices
307      REAL(wp) ::   zc_box    !   -      -
308      REAL(wp), DIMENSION(jpi,jpj,ipl) :: zzt
309      !!----------------------------------------------------------------------
310      !
311      IF( MOD( (kt - 1) / nn_fsbc , 2 ) == 0 ) THEN         !==  odd ice time step:  adv_x then adv_y  ==!
312         !
313         !                                                           !--  ultimate interpolation of pt at u-point  --!
314         CALL ultimate_x( k_order, ipl, pdt, ptc, puc, pt_u )
315         !
316         !                                                           !--  advective form update in zzt  --!
317         DO jl = 1, ipl
318            DO jj = 2, jpjm1
319               DO ji = fs_2, fs_jpim1   ! vector opt.
320                  zzt(ji,jj,jl) = ptc(ji,jj,jl) - pubox(ji,jj) * pdt * ( pt_u(ji,jj,jl) - pt_u(ji-1,jj,jl) ) * r1_e1t(ji,jj)  &
321                   &            - ptc(ji,jj,jl) * pdt * ( puc (ji,jj) - puc (ji-1,jj) ) * r1_e1e2t(ji,jj)
322                  zzt(ji,jj,jl) = zzt(ji,jj,jl) * tmask(ji,jj,1)
323               END DO
324            END DO
325         END DO
326         CALL lbc_lnk( 'icedyn_adv_umx', zzt, 'T', 1. )
327         !
328         !                                                           !--  ultimate interpolation of pt at v-point  --!
329         CALL ultimate_y( k_order, ipl, pdt, zzt, pvc, pt_v )
330         !
331      ELSE                                                  !==  even ice time step:  adv_y then adv_x  ==!
332         !
333         !                                                           !--  ultimate interpolation of pt at v-point  --!
334         CALL ultimate_y( k_order, ipl, pdt, ptc, pvc, pt_v )
335         !
336         !                                                           !--  advective form update in zzt  --!
337         DO jl = 1, ipl
338            DO jj = 2, jpjm1
339               DO ji = fs_2, fs_jpim1
340                  zzt(ji,jj,jl) = ptc(ji,jj,jl) - pvbox(ji,jj) * pdt * ( pt_v(ji,jj,jl) - pt_v(ji,jj-1,jl) ) * r1_e2t(ji,jj)  &
341                     &                    - ptc  (ji,jj,jl) * pdt * ( pvc (ji,jj) - pvc (ji,jj-1) ) * r1_e1e2t(ji,jj)
342                  zzt(ji,jj,jl) = zzt(ji,jj,jl) * tmask(ji,jj,1)
343               END DO
344            END DO
345         END DO
346         CALL lbc_lnk( 'icedyn_adv_umx', zzt, 'T', 1. )
347         !
348         !                                                           !--  ultimate interpolation of pt at u-point  --!
349         CALL ultimate_x( k_order, ipl, pdt, zzt, puc, pt_u )
350         !     
351      ENDIF     
352      !
353   END SUBROUTINE macho
354
355
356   SUBROUTINE ultimate_x( k_order, ipl, pdt, pt, puc, pt_u )
357      !!---------------------------------------------------------------------
358      !!                    ***  ROUTINE ultimate_x  ***
359      !!     
360      !! **  Purpose :   compute 
361      !!
362      !! **  Method  :   ... ???
363      !!                 TIM = transient interpolation Modeling
364      !!
365      !! Reference : Leonard, B.P., 1991, Comput. Methods Appl. Mech. Eng., 88, 17-74.
366      !!----------------------------------------------------------------------
367      INTEGER                         , INTENT(in   ) ::   k_order   ! ocean time-step index
368      INTEGER                         , INTENT(in   ) ::   ipl        ! third dimension of tracer array
369      REAL(wp)                        , INTENT(in   ) ::   pdt       ! tracer time-step
370      REAL(wp), DIMENSION(jpi,jpj)    , INTENT(in   ) ::   puc       ! ice i-velocity component
371      REAL(wp), DIMENSION(jpi,jpj,ipl), INTENT(in   ) ::   pt        ! tracer fields
372      REAL(wp), DIMENSION(jpi,jpj,ipl), INTENT(  out) ::   pt_u      ! tracer at u-point
373      !
374      INTEGER  ::   ji, jj, jl       ! dummy loop indices
375      REAL(wp) ::   zcu, zdx2, zdx4    !   -      -
376      REAL(wp), DIMENSION(jpi,jpj) :: ztu1, ztu3
377      REAL(wp), DIMENSION(jpi,jpj,ipl) :: ztu2, ztu4
378      !!----------------------------------------------------------------------
379      !
380      !                                                     !--  Laplacian in i-direction  --!
381      DO jl = 1, ipl
382         DO jj = 2, jpjm1         ! First derivative (gradient)
383            DO ji = 1, fs_jpim1
384               ztu1(ji,jj) = ( pt(ji+1,jj,jl) - pt(ji,jj,jl) ) * r1_e1u(ji,jj) * umask(ji,jj,1)
385            END DO
386            !                     ! Second derivative (Laplacian)
387            DO ji = fs_2, fs_jpim1
388               ztu2(ji,jj,jl) = ( ztu1(ji,jj) - ztu1(ji-1,jj) ) * r1_e1t(ji,jj)
389            END DO
390         END DO
391      END DO
392      CALL lbc_lnk( 'icedyn_adv_umx', ztu2, 'T', 1. )
393      !
394      !                                                     !--  BiLaplacian in i-direction  --!
395      DO jl = 1, ipl
396         DO jj = 2, jpjm1         ! Third derivative
397            DO ji = 1, fs_jpim1
398               ztu3(ji,jj) = ( ztu2(ji+1,jj,jl) - ztu2(ji,jj,jl) ) * r1_e1u(ji,jj) * umask(ji,jj,1)
399            END DO
400            !                     ! Fourth derivative
401            DO ji = fs_2, fs_jpim1
402               ztu4(ji,jj,jl) = ( ztu3(ji,jj) - ztu3(ji-1,jj) ) * r1_e1t(ji,jj)
403            END DO
404         END DO
405      END DO
406      CALL lbc_lnk( 'icedyn_adv_umx', ztu4, 'T', 1. )
407      !
408      !
409      SELECT CASE (k_order )
410      !
411      CASE( 1 )                                                   !==  1st order central TIM  ==! (Eq. 21)
412         !       
413         DO jl = 1, ipl
414            DO jj = 2, jpjm1
415               DO ji = 1, fs_jpim1   ! vector opt.
416                  pt_u(ji,jj,jl) = 0.5_wp * umask(ji,jj,1) * (                               pt(ji+1,jj,jl) + pt(ji,jj,jl)   &
417                     &                                       - SIGN( 1._wp, puc(ji,jj) ) * ( pt(ji+1,jj,jl) - pt(ji,jj,jl) ) )
418               END DO
419            END DO
420         END DO
421         !
422      CASE( 2 )                                                   !==  2nd order central TIM  ==! (Eq. 23)
423         !
424         DO jl = 1, ipl
425            DO jj = 2, jpjm1
426               DO ji = 1, fs_jpim1   ! vector opt.
427                  zcu  = puc(ji,jj) * r1_e2u(ji,jj) * pdt * r1_e1u(ji,jj)
428                  pt_u(ji,jj,jl) = 0.5_wp * umask(ji,jj,1) * (                               pt(ji+1,jj,jl) + pt(ji,jj,jl)   &
429                     &                                              -              zcu   * ( pt(ji+1,jj,jl) - pt(ji,jj,jl) ) ) 
430               END DO
431            END DO
432         END DO
433         ! 
434      CASE( 3 )                                                   !==  3rd order central TIM  ==! (Eq. 24)
435         !
436         DO jl = 1, ipl
437            DO jj = 2, jpjm1
438               DO ji = 1, fs_jpim1   ! vector opt.
439                  zcu  = puc(ji,jj) * r1_e2u(ji,jj) * pdt * r1_e1u(ji,jj)
440                  zdx2 = e1u(ji,jj) * e1u(ji,jj)
441!!rachid       zdx2 = e1u(ji,jj) * e1t(ji,jj)
442                  pt_u(ji,jj,jl) = 0.5_wp * umask(ji,jj,1) * (         (                     pt  (ji+1,jj,jl) + pt  (ji,jj,jl)        &
443                     &                                              -              zcu   * ( pt  (ji+1,jj,jl) - pt  (ji,jj,jl) )  )   &
444                     &        + z1_6 * zdx2 * ( zcu*zcu - 1._wp ) * (                        ztu2(ji+1,jj,jl) + ztu2(ji,jj,jl)        &
445                     &                                              - SIGN( 1._wp, zcu ) * ( ztu2(ji+1,jj,jl) - ztu2(ji,jj,jl) )  )   )
446               END DO
447            END DO
448         END DO
449         !
450      CASE( 4 )                                                   !==  4th order central TIM  ==! (Eq. 27)
451         !
452         DO jl = 1, ipl
453            DO jj = 2, jpjm1
454               DO ji = 1, fs_jpim1   ! vector opt.
455                  zcu  = puc(ji,jj) * r1_e2u(ji,jj) * pdt * r1_e1u(ji,jj)
456                  zdx2 = e1u(ji,jj) * e1u(ji,jj)
457!!rachid       zdx2 = e1u(ji,jj) * e1t(ji,jj)
458                  pt_u(ji,jj,jl) = 0.5_wp * umask(ji,jj,1) * (         (                     pt  (ji+1,jj,jl) + pt  (ji,jj,jl)        &
459                     &                                                    -          zcu * ( pt  (ji+1,jj,jl) - pt  (ji,jj,jl) )  )   &
460                     &        + z1_6 * zdx2 * ( zcu*zcu - 1._wp ) * (                        ztu2(ji+1,jj,jl) + ztu2(ji,jj,jl)        &
461                     &                                                    - 0.5_wp * zcu * ( ztu2(ji+1,jj,jl) - ztu2(ji,jj,jl) )  )   )
462               END DO
463            END DO
464         END DO
465         !
466      CASE( 5 )                                                   !==  5th order central TIM  ==! (Eq. 29)
467         !
468         DO jl = 1, ipl
469            DO jj = 2, jpjm1
470               DO ji = 1, fs_jpim1   ! vector opt.
471                  zcu  = puc(ji,jj) * r1_e2u(ji,jj) * pdt * r1_e1u(ji,jj)
472                  zdx2 = e1u(ji,jj) * e1u(ji,jj)
473!!rachid       zdx2 = e1u(ji,jj) * e1t(ji,jj)
474                  zdx4 = zdx2 * zdx2
475                  pt_u(ji,jj,jl) = 0.5_wp * umask(ji,jj,1) * (           (                   pt  (ji+1,jj,jl) + pt  (ji,jj,jl)       &
476                     &                                                    -          zcu * ( pt  (ji+1,jj,jl) - pt  (ji,jj,jl) ) )   &
477                     &        + z1_6   * zdx2 * ( zcu*zcu - 1._wp ) *    (                   ztu2(ji+1,jj,jl) + ztu2(ji,jj,jl)       &
478                     &                                                    - 0.5_wp * zcu * ( ztu2(ji+1,jj,jl) - ztu2(ji,jj,jl) ) )   &
479                     &       + z1_120 * zdx4 * ( zcu*zcu - 1._wp ) * ( zcu*zcu - 4._wp ) * ( ztu4(ji+1,jj,jl) + ztu4(ji,jj,jl)       &
480                     &                                              - SIGN( 1._wp, zcu ) * ( ztu4(ji+1,jj,jl) - ztu4(ji,jj,jl) ) ) )
481               END DO
482            END DO
483         END DO
484         !
485      END SELECT
486      !
487   END SUBROUTINE ultimate_x
488   
489 
490   SUBROUTINE ultimate_y( k_order, ipl, pdt, pt, pvc, pt_v )
491      !!---------------------------------------------------------------------
492      !!                    ***  ROUTINE ultimate_y  ***
493      !!     
494      !! **  Purpose :   compute 
495      !!
496      !! **  Method  :   ... ???
497      !!                 TIM = transient interpolation Modeling
498      !!
499      !! Reference : Leonard, B.P., 1991, Comput. Methods Appl. Mech. Eng., 88, 17-74.
500      !!----------------------------------------------------------------------
501      INTEGER                         , INTENT(in   ) ::   k_order   ! ocean time-step index
502      INTEGER                         , INTENT(in   ) ::   ipl       ! third dimension of tracer array
503      REAL(wp)                        , INTENT(in   ) ::   pdt       ! tracer time-step
504      REAL(wp), DIMENSION(jpi,jpj)    , INTENT(in   ) ::   pvc       ! ice j-velocity component
505      REAL(wp), DIMENSION(jpi,jpj,ipl), INTENT(in   ) ::   pt        ! tracer fields
506      REAL(wp), DIMENSION(jpi,jpj,ipl), INTENT(  out) ::   pt_v      ! tracer at v-point
507      !
508      INTEGER  ::   ji, jj, jl       ! dummy loop indices
509      REAL(wp) ::   zcv, zdy2, zdy4    !   -      -
510      REAL(wp), DIMENSION(jpi,jpj) :: ztv1, ztv3
511      REAL(wp), DIMENSION(jpi,jpj,ipl) :: ztv2, ztv4
512      !!----------------------------------------------------------------------
513      !
514      !                                                     !--  Laplacian in j-direction  --!
515      DO jl = 1, ipl
516         DO jj = 1, jpjm1         ! First derivative (gradient)
517            DO ji = fs_2, fs_jpim1
518               ztv1(ji,jj) = ( pt(ji,jj+1,jl) - pt(ji,jj,jl) ) * r1_e2v(ji,jj) * vmask(ji,jj,1)
519            END DO
520         END DO
521         DO jj = 2, jpjm1         ! Second derivative (Laplacian)
522            DO ji = fs_2, fs_jpim1
523               ztv2(ji,jj,jl) = ( ztv1(ji,jj) - ztv1(ji,jj-1) ) * r1_e2t(ji,jj)
524            END DO
525         END DO
526      END DO
527      CALL lbc_lnk( 'icedyn_adv_umx', ztv2, 'T', 1. )
528      !
529      !                                                     !--  BiLaplacian in j-direction  --!
530      DO jl = 1, ipl
531         DO jj = 1, jpjm1         ! First derivative
532            DO ji = fs_2, fs_jpim1
533            ztv3(ji,jj) = ( ztv2(ji,jj+1,jl) - ztv2(ji,jj,jl) ) * r1_e2v(ji,jj) * vmask(ji,jj,1)
534            END DO
535         END DO
536         DO jj = 2, jpjm1         ! Second derivative
537            DO ji = fs_2, fs_jpim1
538               ztv4(ji,jj,jl) = ( ztv3(ji,jj) - ztv3(ji,jj-1) ) * r1_e2t(ji,jj)
539            END DO
540         END DO
541      END DO
542      CALL lbc_lnk( 'icedyn_adv_umx', ztv4, 'T', 1. )
543      !
544      !
545      SELECT CASE (k_order )
546      !
547      CASE( 1 )                                                !==  1st order central TIM  ==! (Eq. 21)
548         DO jl = 1, ipl
549            DO jj = 1, jpjm1
550               DO ji = fs_2, fs_jpim1
551                  pt_v(ji,jj,jl) = 0.5_wp * vmask(ji,jj,1) * (                           ( pt(ji,jj+1,jl) + pt(ji,jj,jl) )  &
552                     &                                     - SIGN( 1._wp, pvc(ji,jj) ) * ( pt(ji,jj+1,jl) - pt(ji,jj,jl) ) )
553               END DO
554            END DO
555         END DO
556         !
557      CASE( 2 )                                                !==  2nd order central TIM  ==! (Eq. 23)
558         DO jl = 1, ipl
559            DO jj = 1, jpjm1
560               DO ji = fs_2, fs_jpim1
561                  zcv  = pvc(ji,jj) * r1_e1v(ji,jj) * pdt * r1_e2v(ji,jj)
562                  pt_v(ji,jj,jl) = 0.5_wp * vmask(ji,jj,1) * (     ( pt(ji,jj+1,jl) + pt(ji,jj,jl) )  &
563                     &                                     - zcv * ( pt(ji,jj+1,jl) - pt(ji,jj,jl) ) )
564               END DO
565            END DO
566         END DO
567         CALL lbc_lnk( 'icedyn_adv_umx', pt_v, 'V',  1. )
568         !
569      CASE( 3 )                                                !==  3rd order central TIM  ==! (Eq. 24)
570         DO jl = 1, ipl
571            DO jj = 1, jpjm1
572               DO ji = fs_2, fs_jpim1
573                  zcv  = pvc(ji,jj) * r1_e1v(ji,jj) * pdt * r1_e2v(ji,jj)
574                  zdy2 = e2v(ji,jj) * e2v(ji,jj)
575!!rachid       zdy2 = e2v(ji,jj) * e2t(ji,jj)
576                  pt_v(ji,jj,jl) = 0.5_wp * vmask(ji,jj,1) * (                              ( pt  (ji,jj+1,jl) + pt  (ji,jj,jl)       &
577                     &                                     -                        zcv   * ( pt  (ji,jj+1,jl) - pt  (ji,jj,jl) ) )   &
578                     &        + z1_6 * zdy2 * ( zcv*zcv - 1._wp ) * (                         ztv2(ji,jj+1,jl) + ztv2(ji,jj,jl)       &
579                     &                                               - SIGN( 1._wp, zcv ) * ( ztv2(ji,jj+1,jl) - ztv2(ji,jj,jl) ) ) )
580               END DO
581            END DO
582         END DO
583         !
584      CASE( 4 )                                                !==  4th order central TIM  ==! (Eq. 27)
585         DO jl = 1, ipl
586            DO jj = 1, jpjm1
587               DO ji = fs_2, fs_jpim1
588                  zcv  = pvc(ji,jj) * r1_e1v(ji,jj) * pdt * r1_e2v(ji,jj)
589                  zdy2 = e2v(ji,jj) * e2v(ji,jj)
590!!rachid       zdy2 = e2v(ji,jj) * e2t(ji,jj)
591                  pt_v(ji,jj,jl) = 0.5_wp * vmask(ji,jj,1) * (                        ( pt  (ji,jj+1,jl) + pt  (ji,jj,jl)       &
592                     &                                               -          zcv * ( pt  (ji,jj+1,jl) - pt  (ji,jj,jl) ) )   &
593                     &        + z1_6 * zdy2 * ( zcv*zcv - 1._wp ) * (                   ztv2(ji,jj+1,jl) + ztv2(ji,jj,jl)       &
594                     &                                               - 0.5_wp * zcv * ( ztv2(ji,jj+1,jl) - ztv2(ji,jj,jl) ) ) )
595               END DO
596            END DO
597         END DO
598         !
599      CASE( 5 )                                                !==  5th order central TIM  ==! (Eq. 29)
600         DO jl = 1, ipl
601            DO jj = 1, jpjm1
602               DO ji = fs_2, fs_jpim1
603                  zcv  = pvc(ji,jj) * r1_e1v(ji,jj) * pdt * r1_e2v(ji,jj)
604                  zdy2 = e2v(ji,jj) * e2v(ji,jj)
605!!rachid       zdy2 = e2v(ji,jj) * e2t(ji,jj)
606                  zdy4 = zdy2 * zdy2
607                  pt_v(ji,jj,jl) = 0.5_wp * vmask(ji,jj,1) * (                              ( pt  (ji,jj+1,jl) + pt  (ji,jj,jl)      &
608                     &                                                     -          zcv * ( pt  (ji,jj+1,jl) - pt  (ji,jj,jl) ) )  &
609                     &        + z1_6   * zdy2 * ( zcv*zcv - 1._wp ) *     (                   ztv2(ji,jj+1,jl) + ztv2(ji,jj,jl)      &
610                     &                                                     - 0.5_wp * zcv * ( ztv2(ji,jj+1,jl) - ztv2(ji,jj,jl) ) )  &
611                     &        + z1_120 * zdy4 * ( zcv*zcv - 1._wp ) * ( zcv*zcv - 4._wp ) * ( ztv4(ji,jj+1,jl) + ztv4(ji,jj,jl)      &
612                     &                                               - SIGN( 1._wp, zcv ) * ( ztv4(ji,jj+1,jl) - ztv4(ji,jj,jl) ) ) )
613               END DO
614            END DO
615         END DO
616         !
617      END SELECT
618      !
619   END SUBROUTINE ultimate_y
620   
621 
622   SUBROUTINE nonosc_2d( ipl, pbef, paa, pbb, paft, pdt )
623      !!---------------------------------------------------------------------
624      !!                    ***  ROUTINE nonosc  ***
625      !!     
626      !! **  Purpose :   compute monotonic tracer fluxes from the upstream
627      !!       scheme and the before field by a nonoscillatory algorithm
628      !!
629      !! **  Method  :   ... ???
630      !!       warning : pbef and paft must be masked, but the boundaries
631      !!       conditions on the fluxes are not necessary zalezak (1979)
632      !!       drange (1995) multi-dimensional forward-in-time and upstream-
633      !!       in-space based differencing for fluid
634      !!----------------------------------------------------------------------
635      INTEGER                          , INTENT(in   ) ::   ipl          ! third dimension of tracer array
636      REAL(wp)                         , INTENT(in   ) ::   pdt          ! tracer time-step
637      REAL(wp), DIMENSION (jpi,jpj,ipl), INTENT(in   ) ::   pbef, paft   ! before & after field
638      REAL(wp), DIMENSION (jpi,jpj,ipl), INTENT(inout) ::   paa, pbb     ! monotonic fluxes in the 2 directions
639      !
640      INTEGER  ::   ji, jj, jl    ! dummy loop indices
641      INTEGER  ::   ikm1      ! local integer
642      REAL(wp) ::   zpos, zneg, zbt, za, zb, zc, zbig, zsml, z1_dt   ! local scalars
643      REAL(wp) ::   zau, zbu, zcu, zav, zbv, zcv, zup, zdo            !   -      -
644      REAL(wp), DIMENSION(jpi,jpj) :: zbup, zbdo, zmsk
645      REAL(wp), DIMENSION(jpi,jpj,ipl) :: zbetup, zbetdo, zdiv
646      !!----------------------------------------------------------------------
647      !
648      zbig = 1.e+40_wp
649      zsml = 1.e-15_wp
650
651      ! test on divergence
652      DO jl = 1, ipl
653         DO jj = 2, jpjm1
654            DO ji = fs_2, fs_jpim1   ! vector opt. 
655               zdiv(ji,jj,jl) =  - (  paa(ji,jj,jl) - paa(ji-1,jj  ,jl)   &
656                  &              +    pbb(ji,jj,jl) - pbb(ji  ,jj-1,jl) ) 
657            END DO
658         END DO
659      END DO
660      CALL lbc_lnk( 'icedyn_adv_umx', zdiv, 'T', 1. )        ! Lateral boundary conditions   (unchanged sign)
661
662      DO jl = 1, ipl
663         ! Determine ice masks for before and after tracers
664         WHERE( pbef(:,:,jl) == 0._wp .AND. paft(:,:,jl) == 0._wp .AND. zdiv(:,:,jl) == 0._wp ) 
665            zmsk(:,:) = 0._wp
666         ELSEWHERE                                                                                   
667            zmsk(:,:) = 1._wp * tmask(:,:,1)
668         END WHERE
669
670         ! Search local extrema
671         ! --------------------
672         ! max/min of pbef & paft with large negative/positive value (-/+zbig) inside land
673!         zbup(:,:) = MAX( pbef(:,:) * tmask(:,:,1) - zbig * ( 1.e0 - tmask(:,:,1) ),   &
674!            &             paft(:,:) * tmask(:,:,1) - zbig * ( 1.e0 - tmask(:,:,1) )  )
675!         zbdo(:,:) = MIN( pbef(:,:) * tmask(:,:,1) + zbig * ( 1.e0 - tmask(:,:,1) ),   &
676!            &             paft(:,:) * tmask(:,:,1) + zbig * ( 1.e0 - tmask(:,:,1) )  )
677         zbup(:,:) = MAX( pbef(:,:,jl) * zmsk(:,:) - zbig * ( 1.e0 - zmsk(:,:) ),   &
678            &             paft(:,:,jl) * zmsk(:,:) - zbig * ( 1.e0 - zmsk(:,:) )  )
679         zbdo(:,:) = MIN( pbef(:,:,jl) * zmsk(:,:) + zbig * ( 1.e0 - zmsk(:,:) ),   &
680            &             paft(:,:,jl) * zmsk(:,:) + zbig * ( 1.e0 - zmsk(:,:) )  )
681
682      z1_dt = 1._wp / pdt
683      DO jj = 2, jpjm1
684         DO ji = fs_2, fs_jpim1   ! vector opt.
685            !
686            zup  = MAX(   zbup(ji,jj), zbup(ji-1,jj  ), zbup(ji+1,jj  ),   &        ! search max/min in neighbourhood
687               &                       zbup(ji  ,jj-1), zbup(ji  ,jj+1)    )
688            zdo  = MIN(   zbdo(ji,jj), zbdo(ji-1,jj  ), zbdo(ji+1,jj  ),   &
689               &                       zbdo(ji  ,jj-1), zbdo(ji  ,jj+1)    )
690               !
691               zpos = MAX( 0., paa(ji-1,jj  ,jl) ) - MIN( 0., paa(ji  ,jj  ,jl) )   &        ! positive/negative  part of the flux
692                  & + MAX( 0., pbb(ji  ,jj-1,jl) ) - MIN( 0., pbb(ji  ,jj  ,jl) )
693               zneg = MAX( 0., paa(ji  ,jj  ,jl) ) - MIN( 0., paa(ji-1,jj  ,jl) )   &
694                  & + MAX( 0., pbb(ji  ,jj  ,jl) ) - MIN( 0., pbb(ji  ,jj-1,jl) )
695               !
696               zbt = e1e2t(ji,jj) * z1_dt                                   ! up & down beta terms
697               zbetup(ji,jj,jl) = ( zup            - paft(ji,jj,jl) ) / ( zpos + zsml ) * zbt
698               zbetdo(ji,jj,jl) = ( paft(ji,jj,jl) - zdo         )    / ( zneg + zsml ) * zbt
699            END DO
700         END DO
701      END DO
702      CALL lbc_lnk_multi( 'icedyn_adv_umx', zbetup, 'T', 1., zbetdo, 'T', 1. )   ! lateral boundary cond. (unchanged sign)
703
704      DO jl = 1, ipl
705         ! monotonic flux in the i & j direction (paa & pbb)
706         ! -------------------------------------
707         DO jj = 2, jpjm1
708            DO ji = 1, fs_jpim1   ! vector opt.
709               zau = MIN( 1._wp , zbetdo(ji,jj,jl) , zbetup(ji+1,jj,jl) )
710               zbu = MIN( 1._wp , zbetup(ji,jj,jl) , zbetdo(ji+1,jj,jl) )
711               zcu = 0.5  + SIGN( 0.5 , paa(ji,jj,jl) )
712               !
713               paa(ji,jj,jl) = paa(ji,jj,jl) * ( zcu * zau + ( 1._wp - zcu) * zbu )
714            END DO
715         END DO
716         !
717         DO jj = 1, jpjm1
718            DO ji = fs_2, fs_jpim1   ! vector opt.
719               zav = MIN( 1._wp , zbetdo(ji,jj,jl) , zbetup(ji,jj+1,jl) )
720               zbv = MIN( 1._wp , zbetup(ji,jj,jl) , zbetdo(ji,jj+1,jl) )
721               zcv = 0.5  + SIGN( 0.5 , pbb(ji,jj,jl) )
722               !
723               pbb(ji,jj,jl) = pbb(ji,jj,jl) * ( zcv * zav + ( 1._wp - zcv) * zbv )
724            END DO
725         END DO
726      END DO
727      !
728   END SUBROUTINE nonosc_2d
729
730#else
731   !!----------------------------------------------------------------------
732   !!   Default option           Dummy module         NO SI3 sea-ice model
733   !!----------------------------------------------------------------------
734#endif
735
736   !!======================================================================
737END MODULE icedyn_adv_umx
Note: See TracBrowser for help on using the repository browser.