New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
icedyn_adv_umx.F90 in NEMO/branches/2018/dev_r10164_HPC09_ESIWACE_PREP_MERGE/src/ICE – NEMO

source: NEMO/branches/2018/dev_r10164_HPC09_ESIWACE_PREP_MERGE/src/ICE/icedyn_adv_umx.F90 @ 10359

Last change on this file since 10359 was 10359, checked in by smasson, 5 years ago

dev_r10164_HPC09_ESIWACE_PREP_MERGE: action 4c: introduce a better version of the non-blocking mpp_max, see #2133
  • Property svn:keywords set to Id
File size: 37.7 KB
Line 
1MODULE icedyn_adv_umx
2   !!==============================================================================
3   !!                       ***  MODULE  icedyn_adv_umx  ***
4   !! sea-ice : advection using the ULTIMATE-MACHO scheme
5   !!==============================================================================
6   !! History :  3.6  !  2014-11  (C. Rousset, G. Madec)  Original code
7   !!            4.0  !  2018     (many people)           SI3 [aka Sea Ice cube]
8   !!----------------------------------------------------------------------
9#if defined key_si3
10   !!----------------------------------------------------------------------
11   !!   'key_si3'                                       SI3 sea-ice model
12   !!----------------------------------------------------------------------
13   !!   ice_dyn_adv_umx   : update the tracer trend with the 3D advection trends using a TVD scheme
14   !!   ultimate_x(_y)    : compute a tracer value at velocity points using ULTIMATE scheme at various orders
15   !!   macho             : ???
16   !!   nonosc_2d         : compute monotonic tracer fluxes by a non-oscillatory algorithm
17   !!----------------------------------------------------------------------
18   USE phycst         ! physical constant
19   USE dom_oce        ! ocean domain
20   USE sbc_oce , ONLY : nn_fsbc   ! update frequency of surface boundary condition
21   USE ice            ! sea-ice variables
22   !
23   USE in_out_manager ! I/O manager
24   USE lib_mpp        ! MPP library
25   USE lib_fortran    ! fortran utilities (glob_sum + no signed zero)
26   USE lbclnk         ! lateral boundary conditions (or mpp links)
27
28   IMPLICIT NONE
29   PRIVATE
30
31   PUBLIC   ice_dyn_adv_umx   ! called by icedyn_adv.F90
32     
33   REAL(wp) ::   z1_6   = 1._wp /   6._wp   ! =1/6
34   REAL(wp) ::   z1_120 = 1._wp / 120._wp   ! =1/120
35
36   !! * Substitutions
37#  include "vectopt_loop_substitute.h90"
38   !!----------------------------------------------------------------------
39   !! NEMO/ICE 4.0 , NEMO Consortium (2018)
40   !! $Id$
41   !! Software governed by the CeCILL license (see ./LICENSE)
42   !!----------------------------------------------------------------------
43CONTAINS
44
45   SUBROUTINE ice_dyn_adv_umx( k_order, kt, pu_ice, pv_ice,  &
46      &                    pato_i, pv_i, pv_s, psv_i, poa_i, pa_i, pa_ip, pv_ip, pe_s, pe_i )
47      !!----------------------------------------------------------------------
48      !!                  ***  ROUTINE ice_dyn_adv_umx  ***
49      !!
50      !! **  Purpose :   Compute the now trend due to total advection of
51      !!                 tracers and add it to the general trend of tracer equations
52      !!                 using an "Ultimate-Macho" scheme
53      !!
54      !! Reference : Leonard, B.P., 1991, Comput. Methods Appl. Mech. Eng., 88, 17-74.
55      !!----------------------------------------------------------------------
56      INTEGER                     , INTENT(in   ) ::   k_order    ! order of the scheme (1-5 or 20)
57      INTEGER                     , INTENT(in   ) ::   kt         ! time step
58      REAL(wp), DIMENSION(:,:)    , INTENT(in   ) ::   pu_ice     ! ice i-velocity
59      REAL(wp), DIMENSION(:,:)    , INTENT(in   ) ::   pv_ice     ! ice j-velocity
60      REAL(wp), DIMENSION(:,:)    , INTENT(inout) ::   pato_i     ! open water area
61      REAL(wp), DIMENSION(:,:,:)  , INTENT(inout) ::   pv_i       ! ice volume
62      REAL(wp), DIMENSION(:,:,:)  , INTENT(inout) ::   pv_s       ! snw volume
63      REAL(wp), DIMENSION(:,:,:)  , INTENT(inout) ::   psv_i      ! salt content
64      REAL(wp), DIMENSION(:,:,:)  , INTENT(inout) ::   poa_i      ! age content
65      REAL(wp), DIMENSION(:,:,:)  , INTENT(inout) ::   pa_i       ! ice concentration
66      REAL(wp), DIMENSION(:,:,:)  , INTENT(inout) ::   pa_ip      ! melt pond fraction
67      REAL(wp), DIMENSION(:,:,:)  , INTENT(inout) ::   pv_ip      ! melt pond volume
68      REAL(wp), DIMENSION(:,:,:,:), INTENT(inout) ::   pe_s       ! snw heat content
69      REAL(wp), DIMENSION(:,:,:,:), INTENT(inout) ::   pe_i       ! ice heat content
70      !
71      INTEGER  ::   ji, jj, jk, jl, jt      ! dummy loop indices
72      INTEGER  ::   initad                  ! number of sub-timestep for the advection
73      INTEGER  ::   ipl                     ! third dimention of tracer array
74
75      REAL(wp) ::   zcfl(2), zusnit, zdt      !   -      -
76      REAL(wp), ALLOCATABLE, DIMENSION(:,:)   ::   zudy, zvdx, zcu_box, zcv_box
77      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) ::   zpato
78      !!----------------------------------------------------------------------
79      !
80      IF( kt == nit000 .AND. lwp )   WRITE(numout,*) '-- ice_dyn_adv_umx: Ultimate-Macho advection scheme'
81      !
82      ALLOCATE( zudy(jpi,jpj) , zvdx(jpi,jpj) , zcu_box(jpi,jpj) , zcv_box(jpi,jpj) )
83      ALLOCATE( zpato(jpi,jpj,1) )
84      !
85      ! --- If ice drift field is too fast, use an appropriate time step for advection (CFL test for stability) --- !
86      !     When needed, the advection split is applied at the next time-step in order to avoid blocking global comm.
87      !     ...this should not affect too much the stability... Was ok on the tests we did...
88      zcfl(1) =               MAXVAL( ABS( pu_ice(:,:) ) * rdt_ice * r1_e1u(:,:) )
89      zcfl(1) = MAX( zcfl(1), MAXVAL( ABS( pv_ice(:,:) ) * rdt_ice * r1_e2v(:,:) ) )
90     
91      ! non-blocking global communication send zcfl(1) and receive zcfl(2)
92      IF( lk_mpp )   CALL mpp_delay_max( 'icedyn_adv_umx', 'advumx_delay', zcfl, kt == nitend - nn_fsbc + 1 )
93
94      IF( zcfl(2) > .5 ) THEN   ;   initad = 2   ;   zusnit = 0.5_wp   ! zcfl(2) corresponding to zcfl(1) of the previous time-step
95      ELSE                      ;   initad = 1   ;   zusnit = 1.0_wp
96      ENDIF
97
98      zdt = rdt_ice / REAL(initad)
99
100      ! --- transport --- !
101      zudy(:,:) = pu_ice(:,:) * e2u(:,:)
102      zvdx(:,:) = pv_ice(:,:) * e1v(:,:)
103
104      ! --- define velocity for advection: u*grad(H) --- !
105      DO jj = 2, jpjm1
106         DO ji = fs_2, fs_jpim1
107            IF    ( pu_ice(ji,jj) * pu_ice(ji-1,jj) <= 0._wp ) THEN   ;   zcu_box(ji,jj) = 0._wp
108            ELSEIF( pu_ice(ji,jj)                   >  0._wp ) THEN   ;   zcu_box(ji,jj) = pu_ice(ji-1,jj)
109            ELSE                                                      ;   zcu_box(ji,jj) = pu_ice(ji  ,jj)
110            ENDIF
111
112            IF    ( pv_ice(ji,jj) * pv_ice(ji,jj-1) <= 0._wp ) THEN   ;   zcv_box(ji,jj) = 0._wp
113            ELSEIF( pv_ice(ji,jj)                   >  0._wp ) THEN   ;   zcv_box(ji,jj) = pv_ice(ji,jj-1)
114            ELSE                                                      ;   zcv_box(ji,jj) = pv_ice(ji,jj  )
115            ENDIF
116         END DO
117      END DO
118
119      zpato (:,:,1) = pato_i(:,:)
120
121      !---------------!
122      !== advection ==!
123      !---------------!
124      DO jt = 1, initad
125         CALL adv_umx( k_order, kt,   1, zdt, zudy, zvdx, zcu_box, zcv_box, zpato(:,:,1) )        ! Open water area
126         CALL lbc_lnk( 'icedyn_adv_umx', zpato, 'T',  1. )
127         CALL adv_umx( k_order, kt, jpl, zdt, zudy, zvdx, zcu_box, zcv_box, pa_i(:,:,:) )         ! Ice area
128         CALL adv_umx( k_order, kt, jpl, zdt, zudy, zvdx, zcu_box, zcv_box, pv_i(:,:,:) )         ! Ice  volume
129         CALL adv_umx( k_order, kt, jpl, zdt, zudy, zvdx, zcu_box, zcv_box, psv_i(:,:,:) )        ! Salt content
130         CALL adv_umx( k_order, kt, jpl, zdt, zudy, zvdx, zcu_box, zcv_box, poa_i(:,:,:) )        ! Age content
131         DO jk = 1, nlay_i
132            CALL adv_umx( k_order, kt, jpl, zdt, zudy, zvdx, zcu_box, zcv_box, pe_i(:,:,jk,:) )   ! Ice  heat content
133         END DO
134         CALL lbc_lnk( 'icedyn_adv_umx', pe_i, 'T',  1. )
135
136         CALL adv_umx( k_order, kt, jpl, zdt, zudy, zvdx, zcu_box, zcv_box, pv_s(:,:,:) )         ! Snow volume
137         DO jk = 1, nlay_s
138            CALL adv_umx( k_order, kt, jpl, zdt, zudy, zvdx, zcu_box, zcv_box, pe_s(:,:,jk,:) )   ! Snow heat content
139         END DO
140         CALL lbc_lnk( 'icedyn_adv_umx', pe_s, 'T',  1. )
141
142         IF ( ln_pnd_H12 ) THEN
143            CALL adv_umx( k_order, kt, jpl, zdt, zudy, zvdx, zcu_box, zcv_box, pa_ip(:,:,:) )     ! Melt pond fraction
144            CALL adv_umx( k_order, kt, jpl, zdt, zudy, zvdx, zcu_box, zcv_box, pv_ip(:,:,:) )     ! Melt pond volume
145            CALL lbc_lnk_multi( 'icedyn_adv_umx', pa_i, 'T',  1., pv_i, 'T',  1., psv_i, 'T',  1., &
146                                                & poa_i, 'T',  1., pv_s, 'T',  1., pa_ip, 'T',  1., &
147                                                & pv_ip, 'T',  1. )
148         ELSE
149            CALL lbc_lnk_multi( 'icedyn_adv_umx', pa_i, 'T',  1., pv_i, 'T',  1., psv_i, 'T',  1., &
150                                                & poa_i, 'T',  1., pv_s, 'T',  1. )
151         ENDIF
152      END DO
153      !
154      pato_i(:,:) = zpato (:,:,1)
155      !
156      DEALLOCATE( zudy, zvdx, zcu_box, zcv_box, zpato )
157      !
158   END SUBROUTINE ice_dyn_adv_umx
159
160   
161   SUBROUTINE adv_umx( k_order, kt, ipl, pdt, puc, pvc, pubox, pvbox, ptc )
162      !!----------------------------------------------------------------------
163      !!                  ***  ROUTINE adv_umx  ***
164      !!
165      !! **  Purpose :   Compute the now trend due to total advection of
166      !!       tracers and add it to the general trend of tracer equations
167      !!
168      !! **  Method  :   TVD scheme, i.e. 2nd order centered scheme with
169      !!       corrected flux (monotonic correction)
170      !!       note: - this advection scheme needs a leap-frog time scheme
171      !!
172      !! ** Action : - pt  the after advective tracer
173      !!----------------------------------------------------------------------
174      INTEGER                         , INTENT(in   ) ::   k_order        ! order of the ULTIMATE scheme
175      INTEGER                         , INTENT(in   ) ::   kt             ! number of iteration
176      INTEGER                         , INTENT(in   ) ::   ipl            ! third dimension of tracer array
177      REAL(wp)                        , INTENT(in   ) ::   pdt            ! tracer time-step
178      REAL(wp), DIMENSION(jpi,jpj)    , INTENT(in   ) ::   puc  , pvc     ! 2 ice velocity components => u*e2
179      REAL(wp), DIMENSION(jpi,jpj)    , INTENT(in   ) ::   pubox, pvbox   ! upstream velocity
180      REAL(wp), DIMENSION(jpi,jpj,ipl), INTENT(inout) ::   ptc            ! tracer content field
181      !
182      INTEGER  ::   ji, jj, jl       ! dummy loop indices 
183
184      REAL(wp) ::   ztra             ! local scalar
185      REAL(wp), DIMENSION(jpi,jpj,ipl) ::   zfu_ups, zfu_ho, zt_u, zt_ups
186      REAL(wp), DIMENSION(jpi,jpj,ipl) ::   zfv_ups, zfv_ho, zt_v, ztrd
187
188      DO jl = 1, ipl
189      !!----------------------------------------------------------------------
190      !
191      !  upstream advection with initial mass fluxes & intermediate update
192      ! --------------------------------------------------------------------
193      DO jj = 1, jpjm1         ! upstream tracer flux in the i and j direction
194         DO ji = 1, fs_jpim1   ! vector opt.
195            zfu_ups(ji,jj,jl) = MAX( puc(ji,jj), 0._wp ) * ptc(ji,jj,jl) + MIN( puc(ji,jj), 0._wp ) * ptc(ji+1,jj,jl)
196            zfv_ups(ji,jj,jl) = MAX( pvc(ji,jj), 0._wp ) * ptc(ji,jj,jl) + MIN( pvc(ji,jj), 0._wp ) * ptc(ji,jj+1,jl)
197         END DO
198      END DO
199     
200         DO jj = 2, jpjm1            ! total intermediate advective trends
201            DO ji = fs_2, fs_jpim1   ! vector opt.
202               ztra = - (   zfu_ups(ji,jj,jl) - zfu_ups(ji-1,jj  ,jl)   &
203                  &       + zfv_ups(ji,jj,jl) - zfv_ups(ji  ,jj-1,jl)   ) * r1_e1e2t(ji,jj)
204            !
205               ztrd(ji,jj,jl) =                         ztra                         ! upstream trend [ -div(uh) or -div(uhT) ] 
206               zt_ups (ji,jj,jl) = ( ptc(ji,jj,jl) + pdt * ztra ) * tmask(ji,jj,1)   ! guess after content field with monotonic scheme
207            END DO
208         END DO
209      END DO
210     
211      ! High order (_ho) fluxes
212      ! -----------------------
213      SELECT CASE( k_order )
214      CASE ( 20 )                          ! centered second order
215         DO jl = 1, ipl
216            DO jj = 1, jpjm1
217               DO ji = 1, fs_jpim1   ! vector opt.
218                  zfu_ho(ji,jj,jl) = 0.5 * puc(ji,jj) * ( ptc(ji,jj,jl) + ptc(ji+1,jj,jl) )
219                  zfv_ho(ji,jj,jl) = 0.5 * pvc(ji,jj) * ( ptc(ji,jj,jl) + ptc(ji,jj+1,jl) )
220               END DO
221            END DO
222         END DO
223         !
224      CASE ( 1:5 )                      ! 1st to 5th order ULTIMATE-MACHO scheme
225         CALL macho( k_order, kt, ipl, pdt, ptc, puc, pvc, pubox, pvbox, zt_u, zt_v )
226         !
227         DO jl = 1, ipl
228            DO jj = 2, jpjm1
229               DO ji = 1, fs_jpim1   ! vector opt.
230                  zfu_ho(ji,jj,jl) = puc(ji,jj) * zt_u(ji,jj,jl)
231               END DO
232            END DO
233         END DO
234         DO jl = 1, ipl
235            DO jj = 1, jpjm1
236               DO ji = fs_2, fs_jpim1   ! vector opt.
237                  zfv_ho(ji,jj,jl) = pvc(ji,jj) * zt_v(ji,jj,jl)
238               END DO
239            END DO
240         END DO
241         !
242      END SELECT
243         
244      ! antidiffusive flux : high order minus low order
245      ! --------------------------------------------------
246      DO jl = 1, ipl
247         DO jj = 2, jpjm1
248            DO ji = 1, fs_jpim1   ! vector opt.
249               zfu_ho(ji,jj,jl) = zfu_ho(ji,jj,jl) - zfu_ups(ji,jj,jl)
250            END DO
251         END DO
252      END DO
253      DO jl = 1, ipl
254         DO jj = 1, jpjm1
255            DO ji = fs_2, fs_jpim1   ! vector opt.
256               zfv_ho(ji,jj,jl) = zfv_ho(ji,jj,jl) - zfv_ups(ji,jj,jl)
257            END DO
258         END DO
259      END DO
260
261      CALL lbc_lnk("icedyn_adv_umx",zt_ups, 'T', 1. )        ! Lateral boundary conditions   (unchanged sign)
262     
263      ! monotonicity algorithm
264      ! -------------------------
265      CALL nonosc_2d( ipl, ptc, zfu_ho, zfv_ho, zt_ups, pdt )
266     
267      ! final trend with corrected fluxes
268      ! ------------------------------------
269      DO jl = 1, ipl
270         DO jj = 2, jpjm1
271            DO ji = fs_2, fs_jpim1   ! vector opt. 
272               ztra       = ztrd(ji,jj,jl)  - (  zfu_ho(ji,jj,jl) - zfu_ho(ji-1,jj  ,jl)   &
273                  &                         +    zfv_ho(ji,jj,jl) - zfv_ho(ji  ,jj-1,jl) ) * r1_e1e2t(ji,jj) 
274               ptc(ji,jj,jl) = ptc(ji,jj,jl) + pdt * ztra * tmask(ji,jj,1)
275            END DO
276         END DO
277      END DO
278      !
279   END SUBROUTINE adv_umx
280
281   SUBROUTINE macho( k_order, kt, ipl, pdt, ptc, puc, pvc, pubox, pvbox, pt_u, pt_v )
282      !!---------------------------------------------------------------------
283      !!                    ***  ROUTINE ultimate_x  ***
284      !!     
285      !! **  Purpose :   compute 
286      !!
287      !! **  Method  :   ... ???
288      !!                 TIM = transient interpolation Modeling
289      !!
290      !! Reference : Leonard, B.P., 1991, Comput. Methods Appl. Mech. Eng., 88, 17-74.
291      !!----------------------------------------------------------------------
292      INTEGER                         , INTENT(in   ) ::   k_order    ! order of the ULTIMATE scheme
293      INTEGER                         , INTENT(in   ) ::   kt         ! number of iteration
294      INTEGER                         , INTENT(in   ) ::   ipl        ! third dimension of tracer array
295      REAL(wp)                        , INTENT(in   ) ::   pdt        ! tracer time-step
296      REAL(wp), DIMENSION(jpi,jpj,ipl), INTENT(in   ) ::   ptc        ! tracer fields
297      REAL(wp), DIMENSION(jpi,jpj)    , INTENT(in   ) ::   puc, pvc   ! 2 ice velocity components
298      REAL(wp), DIMENSION(jpi,jpj)    , INTENT(in   ) ::   pubox, pvbox   ! upstream velocity
299      REAL(wp), DIMENSION(jpi,jpj,ipl), INTENT(  out) ::   pt_u, pt_v ! tracer at u- and v-points
300      !
301      INTEGER  ::   ji, jj, jl    ! dummy loop indices
302      REAL(wp) ::   zc_box    !   -      -
303      REAL(wp), DIMENSION(jpi,jpj,ipl) :: zzt
304      !!----------------------------------------------------------------------
305      !
306      IF( MOD( (kt - 1) / nn_fsbc , 2 ) == 0 ) THEN         !==  odd ice time step:  adv_x then adv_y  ==!
307         !
308         !                                                           !--  ultimate interpolation of pt at u-point  --!
309         CALL ultimate_x( k_order, ipl, pdt, ptc, puc, pt_u )
310         !
311         !                                                           !--  advective form update in zzt  --!
312         DO jl = 1, ipl
313            DO jj = 2, jpjm1
314               DO ji = fs_2, fs_jpim1   ! vector opt.
315                  zzt(ji,jj,jl) = ptc(ji,jj,jl) - pubox(ji,jj) * pdt * ( pt_u(ji,jj,jl) - pt_u(ji-1,jj,jl) ) * r1_e1t(ji,jj)  &
316                   &            - ptc(ji,jj,jl) * pdt * ( puc (ji,jj) - puc (ji-1,jj) ) * r1_e1e2t(ji,jj)
317                  zzt(ji,jj,jl) = zzt(ji,jj,jl) * tmask(ji,jj,1)
318               END DO
319            END DO
320         END DO
321         CALL lbc_lnk( 'icedyn_adv_umx', zzt, 'T', 1. )
322         !
323         !                                                           !--  ultimate interpolation of pt at v-point  --!
324         CALL ultimate_y( k_order, ipl, pdt, zzt, pvc, pt_v )
325         !
326      ELSE                                                  !==  even ice time step:  adv_y then adv_x  ==!
327         !
328         !                                                           !--  ultimate interpolation of pt at v-point  --!
329         CALL ultimate_y( k_order, ipl, pdt, ptc, pvc, pt_v )
330         !
331         !                                                           !--  advective form update in zzt  --!
332         DO jl = 1, ipl
333            DO jj = 2, jpjm1
334               DO ji = fs_2, fs_jpim1
335                  zzt(ji,jj,jl) = ptc(ji,jj,jl) - pvbox(ji,jj) * pdt * ( pt_v(ji,jj,jl) - pt_v(ji,jj-1,jl) ) * r1_e2t(ji,jj)  &
336                     &                    - ptc  (ji,jj,jl) * pdt * ( pvc (ji,jj) - pvc (ji,jj-1) ) * r1_e1e2t(ji,jj)
337                  zzt(ji,jj,jl) = zzt(ji,jj,jl) * tmask(ji,jj,1)
338               END DO
339            END DO
340         END DO
341         CALL lbc_lnk( 'icedyn_adv_umx', zzt, 'T', 1. )
342         !
343         !                                                           !--  ultimate interpolation of pt at u-point  --!
344         CALL ultimate_x( k_order, ipl, pdt, zzt, puc, pt_u )
345         !     
346      ENDIF     
347      !
348   END SUBROUTINE macho
349
350
351   SUBROUTINE ultimate_x( k_order, ipl, pdt, pt, puc, pt_u )
352      !!---------------------------------------------------------------------
353      !!                    ***  ROUTINE ultimate_x  ***
354      !!     
355      !! **  Purpose :   compute 
356      !!
357      !! **  Method  :   ... ???
358      !!                 TIM = transient interpolation Modeling
359      !!
360      !! Reference : Leonard, B.P., 1991, Comput. Methods Appl. Mech. Eng., 88, 17-74.
361      !!----------------------------------------------------------------------
362      INTEGER                         , INTENT(in   ) ::   k_order   ! ocean time-step index
363      INTEGER                         , INTENT(in   ) ::   ipl        ! third dimension of tracer array
364      REAL(wp)                        , INTENT(in   ) ::   pdt       ! tracer time-step
365      REAL(wp), DIMENSION(jpi,jpj)    , INTENT(in   ) ::   puc       ! ice i-velocity component
366      REAL(wp), DIMENSION(jpi,jpj,ipl), INTENT(in   ) ::   pt        ! tracer fields
367      REAL(wp), DIMENSION(jpi,jpj,ipl), INTENT(  out) ::   pt_u      ! tracer at u-point
368      !
369      INTEGER  ::   ji, jj, jl       ! dummy loop indices
370      REAL(wp) ::   zcu, zdx2, zdx4    !   -      -
371      REAL(wp), DIMENSION(jpi,jpj) :: ztu1, ztu3
372      REAL(wp), DIMENSION(jpi,jpj,ipl) :: ztu2, ztu4
373      !!----------------------------------------------------------------------
374      !
375      !                                                     !--  Laplacian in i-direction  --!
376      DO jl = 1, ipl
377         DO jj = 2, jpjm1         ! First derivative (gradient)
378            DO ji = 1, fs_jpim1
379               ztu1(ji,jj) = ( pt(ji+1,jj,jl) - pt(ji,jj,jl) ) * r1_e1u(ji,jj) * umask(ji,jj,1)
380            END DO
381            !                     ! Second derivative (Laplacian)
382            DO ji = fs_2, fs_jpim1
383               ztu2(ji,jj,jl) = ( ztu1(ji,jj) - ztu1(ji-1,jj) ) * r1_e1t(ji,jj)
384            END DO
385         END DO
386      END DO
387      CALL lbc_lnk( 'icedyn_adv_umx', ztu2, 'T', 1. )
388      !
389      !                                                     !--  BiLaplacian in i-direction  --!
390      DO jl = 1, ipl
391         DO jj = 2, jpjm1         ! Third derivative
392            DO ji = 1, fs_jpim1
393               ztu3(ji,jj) = ( ztu2(ji+1,jj,jl) - ztu2(ji,jj,jl) ) * r1_e1u(ji,jj) * umask(ji,jj,1)
394            END DO
395            !                     ! Fourth derivative
396            DO ji = fs_2, fs_jpim1
397               ztu4(ji,jj,jl) = ( ztu3(ji,jj) - ztu3(ji-1,jj) ) * r1_e1t(ji,jj)
398            END DO
399         END DO
400      END DO
401      CALL lbc_lnk( 'icedyn_adv_umx', ztu4, 'T', 1. )
402      !
403      !
404      SELECT CASE (k_order )
405      !
406      CASE( 1 )                                                   !==  1st order central TIM  ==! (Eq. 21)
407         !       
408         DO jl = 1, ipl
409            DO jj = 2, jpjm1
410               DO ji = 1, fs_jpim1   ! vector opt.
411                  pt_u(ji,jj,jl) = 0.5_wp * umask(ji,jj,1) * (                               pt(ji+1,jj,jl) + pt(ji,jj,jl)   &
412                     &                                       - SIGN( 1._wp, puc(ji,jj) ) * ( pt(ji+1,jj,jl) - pt(ji,jj,jl) ) )
413               END DO
414            END DO
415         END DO
416         !
417      CASE( 2 )                                                   !==  2nd order central TIM  ==! (Eq. 23)
418         !
419         DO jl = 1, ipl
420            DO jj = 2, jpjm1
421               DO ji = 1, fs_jpim1   ! vector opt.
422                  zcu  = puc(ji,jj) * r1_e2u(ji,jj) * pdt * r1_e1u(ji,jj)
423                  pt_u(ji,jj,jl) = 0.5_wp * umask(ji,jj,1) * (                               pt(ji+1,jj,jl) + pt(ji,jj,jl)   &
424                     &                                              -              zcu   * ( pt(ji+1,jj,jl) - pt(ji,jj,jl) ) ) 
425               END DO
426            END DO
427         END DO
428         ! 
429      CASE( 3 )                                                   !==  3rd order central TIM  ==! (Eq. 24)
430         !
431         DO jl = 1, ipl
432            DO jj = 2, jpjm1
433               DO ji = 1, fs_jpim1   ! vector opt.
434                  zcu  = puc(ji,jj) * r1_e2u(ji,jj) * pdt * r1_e1u(ji,jj)
435                  zdx2 = e1u(ji,jj) * e1u(ji,jj)
436!!rachid       zdx2 = e1u(ji,jj) * e1t(ji,jj)
437                  pt_u(ji,jj,jl) = 0.5_wp * umask(ji,jj,1) * (         (                     pt  (ji+1,jj,jl) + pt  (ji,jj,jl)        &
438                     &                                              -              zcu   * ( pt  (ji+1,jj,jl) - pt  (ji,jj,jl) )  )   &
439                     &        + z1_6 * zdx2 * ( zcu*zcu - 1._wp ) * (                        ztu2(ji+1,jj,jl) + ztu2(ji,jj,jl)        &
440                     &                                              - SIGN( 1._wp, zcu ) * ( ztu2(ji+1,jj,jl) - ztu2(ji,jj,jl) )  )   )
441               END DO
442            END DO
443         END DO
444         !
445      CASE( 4 )                                                   !==  4th order central TIM  ==! (Eq. 27)
446         !
447         DO jl = 1, ipl
448            DO jj = 2, jpjm1
449               DO ji = 1, fs_jpim1   ! vector opt.
450                  zcu  = puc(ji,jj) * r1_e2u(ji,jj) * pdt * r1_e1u(ji,jj)
451                  zdx2 = e1u(ji,jj) * e1u(ji,jj)
452!!rachid       zdx2 = e1u(ji,jj) * e1t(ji,jj)
453                  pt_u(ji,jj,jl) = 0.5_wp * umask(ji,jj,1) * (         (                     pt  (ji+1,jj,jl) + pt  (ji,jj,jl)        &
454                     &                                                    -          zcu * ( pt  (ji+1,jj,jl) - pt  (ji,jj,jl) )  )   &
455                     &        + z1_6 * zdx2 * ( zcu*zcu - 1._wp ) * (                        ztu2(ji+1,jj,jl) + ztu2(ji,jj,jl)        &
456                     &                                                    - 0.5_wp * zcu * ( ztu2(ji+1,jj,jl) - ztu2(ji,jj,jl) )  )   )
457               END DO
458            END DO
459         END DO
460         !
461      CASE( 5 )                                                   !==  5th order central TIM  ==! (Eq. 29)
462         !
463         DO jl = 1, ipl
464            DO jj = 2, jpjm1
465               DO ji = 1, fs_jpim1   ! vector opt.
466                  zcu  = puc(ji,jj) * r1_e2u(ji,jj) * pdt * r1_e1u(ji,jj)
467                  zdx2 = e1u(ji,jj) * e1u(ji,jj)
468!!rachid       zdx2 = e1u(ji,jj) * e1t(ji,jj)
469                  zdx4 = zdx2 * zdx2
470                  pt_u(ji,jj,jl) = 0.5_wp * umask(ji,jj,1) * (           (                   pt  (ji+1,jj,jl) + pt  (ji,jj,jl)       &
471                     &                                                    -          zcu * ( pt  (ji+1,jj,jl) - pt  (ji,jj,jl) ) )   &
472                     &        + z1_6   * zdx2 * ( zcu*zcu - 1._wp ) *    (                   ztu2(ji+1,jj,jl) + ztu2(ji,jj,jl)       &
473                     &                                                    - 0.5_wp * zcu * ( ztu2(ji+1,jj,jl) - ztu2(ji,jj,jl) ) )   &
474                     &       + z1_120 * zdx4 * ( zcu*zcu - 1._wp ) * ( zcu*zcu - 4._wp ) * ( ztu4(ji+1,jj,jl) + ztu4(ji,jj,jl)       &
475                     &                                              - SIGN( 1._wp, zcu ) * ( ztu4(ji+1,jj,jl) - ztu4(ji,jj,jl) ) ) )
476               END DO
477            END DO
478         END DO
479         !
480      END SELECT
481      !
482   END SUBROUTINE ultimate_x
483   
484 
485   SUBROUTINE ultimate_y( k_order, ipl, pdt, pt, pvc, pt_v )
486      !!---------------------------------------------------------------------
487      !!                    ***  ROUTINE ultimate_y  ***
488      !!     
489      !! **  Purpose :   compute 
490      !!
491      !! **  Method  :   ... ???
492      !!                 TIM = transient interpolation Modeling
493      !!
494      !! Reference : Leonard, B.P., 1991, Comput. Methods Appl. Mech. Eng., 88, 17-74.
495      !!----------------------------------------------------------------------
496      INTEGER                         , INTENT(in   ) ::   k_order   ! ocean time-step index
497      INTEGER                         , INTENT(in   ) ::   ipl       ! third dimension of tracer array
498      REAL(wp)                        , INTENT(in   ) ::   pdt       ! tracer time-step
499      REAL(wp), DIMENSION(jpi,jpj)    , INTENT(in   ) ::   pvc       ! ice j-velocity component
500      REAL(wp), DIMENSION(jpi,jpj,ipl), INTENT(in   ) ::   pt        ! tracer fields
501      REAL(wp), DIMENSION(jpi,jpj,ipl), INTENT(  out) ::   pt_v      ! tracer at v-point
502      !
503      INTEGER  ::   ji, jj, jl       ! dummy loop indices
504      REAL(wp) ::   zcv, zdy2, zdy4    !   -      -
505      REAL(wp), DIMENSION(jpi,jpj) :: ztv1, ztv3
506      REAL(wp), DIMENSION(jpi,jpj,ipl) :: ztv2, ztv4
507      !!----------------------------------------------------------------------
508      !
509      !                                                     !--  Laplacian in j-direction  --!
510      DO jl = 1, ipl
511         DO jj = 1, jpjm1         ! First derivative (gradient)
512            DO ji = fs_2, fs_jpim1
513               ztv1(ji,jj) = ( pt(ji,jj+1,jl) - pt(ji,jj,jl) ) * r1_e2v(ji,jj) * vmask(ji,jj,1)
514            END DO
515         END DO
516         DO jj = 2, jpjm1         ! Second derivative (Laplacian)
517            DO ji = fs_2, fs_jpim1
518               ztv2(ji,jj,jl) = ( ztv1(ji,jj) - ztv1(ji,jj-1) ) * r1_e2t(ji,jj)
519            END DO
520         END DO
521      END DO
522      CALL lbc_lnk( 'icedyn_adv_umx', ztv2, 'T', 1. )
523      !
524      !                                                     !--  BiLaplacian in j-direction  --!
525      DO jl = 1, ipl
526         DO jj = 1, jpjm1         ! First derivative
527            DO ji = fs_2, fs_jpim1
528            ztv3(ji,jj) = ( ztv2(ji,jj+1,jl) - ztv2(ji,jj,jl) ) * r1_e2v(ji,jj) * vmask(ji,jj,1)
529            END DO
530         END DO
531         DO jj = 2, jpjm1         ! Second derivative
532            DO ji = fs_2, fs_jpim1
533               ztv4(ji,jj,jl) = ( ztv3(ji,jj) - ztv3(ji,jj-1) ) * r1_e2t(ji,jj)
534            END DO
535         END DO
536      END DO
537      CALL lbc_lnk( 'icedyn_adv_umx', ztv4, 'T', 1. )
538      !
539      !
540      SELECT CASE (k_order )
541      !
542      CASE( 1 )                                                !==  1st order central TIM  ==! (Eq. 21)
543         DO jl = 1, ipl
544            DO jj = 1, jpjm1
545               DO ji = fs_2, fs_jpim1
546                  pt_v(ji,jj,jl) = 0.5_wp * vmask(ji,jj,1) * (                           ( pt(ji,jj+1,jl) + pt(ji,jj,jl) )  &
547                     &                                     - SIGN( 1._wp, pvc(ji,jj) ) * ( pt(ji,jj+1,jl) - pt(ji,jj,jl) ) )
548               END DO
549            END DO
550         END DO
551         !
552      CASE( 2 )                                                !==  2nd order central TIM  ==! (Eq. 23)
553         DO jl = 1, ipl
554            DO jj = 1, jpjm1
555               DO ji = fs_2, fs_jpim1
556                  zcv  = pvc(ji,jj) * r1_e1v(ji,jj) * pdt * r1_e2v(ji,jj)
557                  pt_v(ji,jj,jl) = 0.5_wp * vmask(ji,jj,1) * (     ( pt(ji,jj+1,jl) + pt(ji,jj,jl) )  &
558                     &                                     - zcv * ( pt(ji,jj+1,jl) - pt(ji,jj,jl) ) )
559               END DO
560            END DO
561         END DO
562         CALL lbc_lnk( 'icedyn_adv_umx', pt_v, 'V',  1. )
563         !
564      CASE( 3 )                                                !==  3rd order central TIM  ==! (Eq. 24)
565         DO jl = 1, ipl
566            DO jj = 1, jpjm1
567               DO ji = fs_2, fs_jpim1
568                  zcv  = pvc(ji,jj) * r1_e1v(ji,jj) * pdt * r1_e2v(ji,jj)
569                  zdy2 = e2v(ji,jj) * e2v(ji,jj)
570!!rachid       zdy2 = e2v(ji,jj) * e2t(ji,jj)
571                  pt_v(ji,jj,jl) = 0.5_wp * vmask(ji,jj,1) * (                              ( pt  (ji,jj+1,jl) + pt  (ji,jj,jl)       &
572                     &                                     -                        zcv   * ( pt  (ji,jj+1,jl) - pt  (ji,jj,jl) ) )   &
573                     &        + z1_6 * zdy2 * ( zcv*zcv - 1._wp ) * (                         ztv2(ji,jj+1,jl) + ztv2(ji,jj,jl)       &
574                     &                                               - SIGN( 1._wp, zcv ) * ( ztv2(ji,jj+1,jl) - ztv2(ji,jj,jl) ) ) )
575               END DO
576            END DO
577         END DO
578         !
579      CASE( 4 )                                                !==  4th order central TIM  ==! (Eq. 27)
580         DO jl = 1, ipl
581            DO jj = 1, jpjm1
582               DO ji = fs_2, fs_jpim1
583                  zcv  = pvc(ji,jj) * r1_e1v(ji,jj) * pdt * r1_e2v(ji,jj)
584                  zdy2 = e2v(ji,jj) * e2v(ji,jj)
585!!rachid       zdy2 = e2v(ji,jj) * e2t(ji,jj)
586                  pt_v(ji,jj,jl) = 0.5_wp * vmask(ji,jj,1) * (                        ( pt  (ji,jj+1,jl) + pt  (ji,jj,jl)       &
587                     &                                               -          zcv * ( pt  (ji,jj+1,jl) - pt  (ji,jj,jl) ) )   &
588                     &        + z1_6 * zdy2 * ( zcv*zcv - 1._wp ) * (                   ztv2(ji,jj+1,jl) + ztv2(ji,jj,jl)       &
589                     &                                               - 0.5_wp * zcv * ( ztv2(ji,jj+1,jl) - ztv2(ji,jj,jl) ) ) )
590               END DO
591            END DO
592         END DO
593         !
594      CASE( 5 )                                                !==  5th order central TIM  ==! (Eq. 29)
595         DO jl = 1, ipl
596            DO jj = 1, jpjm1
597               DO ji = fs_2, fs_jpim1
598                  zcv  = pvc(ji,jj) * r1_e1v(ji,jj) * pdt * r1_e2v(ji,jj)
599                  zdy2 = e2v(ji,jj) * e2v(ji,jj)
600!!rachid       zdy2 = e2v(ji,jj) * e2t(ji,jj)
601                  zdy4 = zdy2 * zdy2
602                  pt_v(ji,jj,jl) = 0.5_wp * vmask(ji,jj,1) * (                              ( pt  (ji,jj+1,jl) + pt  (ji,jj,jl)      &
603                     &                                                     -          zcv * ( pt  (ji,jj+1,jl) - pt  (ji,jj,jl) ) )  &
604                     &        + z1_6   * zdy2 * ( zcv*zcv - 1._wp ) *     (                   ztv2(ji,jj+1,jl) + ztv2(ji,jj,jl)      &
605                     &                                                     - 0.5_wp * zcv * ( ztv2(ji,jj+1,jl) - ztv2(ji,jj,jl) ) )  &
606                     &        + z1_120 * zdy4 * ( zcv*zcv - 1._wp ) * ( zcv*zcv - 4._wp ) * ( ztv4(ji,jj+1,jl) + ztv4(ji,jj,jl)      &
607                     &                                               - SIGN( 1._wp, zcv ) * ( ztv4(ji,jj+1,jl) - ztv4(ji,jj,jl) ) ) )
608               END DO
609            END DO
610         END DO
611         !
612      END SELECT
613      !
614   END SUBROUTINE ultimate_y
615   
616 
617   SUBROUTINE nonosc_2d( ipl, pbef, paa, pbb, paft, pdt )
618      !!---------------------------------------------------------------------
619      !!                    ***  ROUTINE nonosc  ***
620      !!     
621      !! **  Purpose :   compute monotonic tracer fluxes from the upstream
622      !!       scheme and the before field by a nonoscillatory algorithm
623      !!
624      !! **  Method  :   ... ???
625      !!       warning : pbef and paft must be masked, but the boundaries
626      !!       conditions on the fluxes are not necessary zalezak (1979)
627      !!       drange (1995) multi-dimensional forward-in-time and upstream-
628      !!       in-space based differencing for fluid
629      !!----------------------------------------------------------------------
630      INTEGER                          , INTENT(in   ) ::   ipl          ! third dimension of tracer array
631      REAL(wp)                         , INTENT(in   ) ::   pdt          ! tracer time-step
632      REAL(wp), DIMENSION (jpi,jpj,ipl), INTENT(in   ) ::   pbef, paft   ! before & after field
633      REAL(wp), DIMENSION (jpi,jpj,ipl), INTENT(inout) ::   paa, pbb     ! monotonic fluxes in the 2 directions
634      !
635      INTEGER  ::   ji, jj, jl    ! dummy loop indices
636      INTEGER  ::   ikm1      ! local integer
637      REAL(wp) ::   zpos, zneg, zbt, za, zb, zc, zbig, zsml, z1_dt   ! local scalars
638      REAL(wp) ::   zau, zbu, zcu, zav, zbv, zcv, zup, zdo            !   -      -
639      REAL(wp), DIMENSION(jpi,jpj) :: zbup, zbdo, zmsk
640      REAL(wp), DIMENSION(jpi,jpj,ipl) :: zbetup, zbetdo, zdiv
641      !!----------------------------------------------------------------------
642      !
643      zbig = 1.e+40_wp
644      zsml = 1.e-15_wp
645
646      ! test on divergence
647      DO jl = 1, ipl
648         DO jj = 2, jpjm1
649            DO ji = fs_2, fs_jpim1   ! vector opt. 
650               zdiv(ji,jj,jl) =  - (  paa(ji,jj,jl) - paa(ji-1,jj  ,jl)   &
651                  &              +    pbb(ji,jj,jl) - pbb(ji  ,jj-1,jl) ) 
652            END DO
653         END DO
654      END DO
655      CALL lbc_lnk( 'icedyn_adv_umx', zdiv, 'T', 1. )        ! Lateral boundary conditions   (unchanged sign)
656
657      DO jl = 1, ipl
658         ! Determine ice masks for before and after tracers
659         WHERE( pbef(:,:,jl) == 0._wp .AND. paft(:,:,jl) == 0._wp .AND. zdiv(:,:,jl) == 0._wp ) 
660            zmsk(:,:) = 0._wp
661         ELSEWHERE                                                                                   
662            zmsk(:,:) = 1._wp * tmask(:,:,1)
663         END WHERE
664
665         ! Search local extrema
666         ! --------------------
667         ! max/min of pbef & paft with large negative/positive value (-/+zbig) inside land
668!         zbup(:,:) = MAX( pbef(:,:) * tmask(:,:,1) - zbig * ( 1.e0 - tmask(:,:,1) ),   &
669!            &             paft(:,:) * tmask(:,:,1) - zbig * ( 1.e0 - tmask(:,:,1) )  )
670!         zbdo(:,:) = MIN( pbef(:,:) * tmask(:,:,1) + zbig * ( 1.e0 - tmask(:,:,1) ),   &
671!            &             paft(:,:) * tmask(:,:,1) + zbig * ( 1.e0 - tmask(:,:,1) )  )
672         zbup(:,:) = MAX( pbef(:,:,jl) * zmsk(:,:) - zbig * ( 1.e0 - zmsk(:,:) ),   &
673            &             paft(:,:,jl) * zmsk(:,:) - zbig * ( 1.e0 - zmsk(:,:) )  )
674         zbdo(:,:) = MIN( pbef(:,:,jl) * zmsk(:,:) + zbig * ( 1.e0 - zmsk(:,:) ),   &
675            &             paft(:,:,jl) * zmsk(:,:) + zbig * ( 1.e0 - zmsk(:,:) )  )
676
677      z1_dt = 1._wp / pdt
678      DO jj = 2, jpjm1
679         DO ji = fs_2, fs_jpim1   ! vector opt.
680            !
681            zup  = MAX(   zbup(ji,jj), zbup(ji-1,jj  ), zbup(ji+1,jj  ),   &        ! search max/min in neighbourhood
682               &                       zbup(ji  ,jj-1), zbup(ji  ,jj+1)    )
683            zdo  = MIN(   zbdo(ji,jj), zbdo(ji-1,jj  ), zbdo(ji+1,jj  ),   &
684               &                       zbdo(ji  ,jj-1), zbdo(ji  ,jj+1)    )
685               !
686               zpos = MAX( 0., paa(ji-1,jj  ,jl) ) - MIN( 0., paa(ji  ,jj  ,jl) )   &        ! positive/negative  part of the flux
687                  & + MAX( 0., pbb(ji  ,jj-1,jl) ) - MIN( 0., pbb(ji  ,jj  ,jl) )
688               zneg = MAX( 0., paa(ji  ,jj  ,jl) ) - MIN( 0., paa(ji-1,jj  ,jl) )   &
689                  & + MAX( 0., pbb(ji  ,jj  ,jl) ) - MIN( 0., pbb(ji  ,jj-1,jl) )
690               !
691               zbt = e1e2t(ji,jj) * z1_dt                                   ! up & down beta terms
692               zbetup(ji,jj,jl) = ( zup            - paft(ji,jj,jl) ) / ( zpos + zsml ) * zbt
693               zbetdo(ji,jj,jl) = ( paft(ji,jj,jl) - zdo         )    / ( zneg + zsml ) * zbt
694            END DO
695         END DO
696      END DO
697      CALL lbc_lnk_multi( 'icedyn_adv_umx', zbetup, 'T', 1., zbetdo, 'T', 1. )   ! lateral boundary cond. (unchanged sign)
698
699      DO jl = 1, ipl
700         ! monotonic flux in the i & j direction (paa & pbb)
701         ! -------------------------------------
702         DO jj = 2, jpjm1
703            DO ji = 1, fs_jpim1   ! vector opt.
704               zau = MIN( 1._wp , zbetdo(ji,jj,jl) , zbetup(ji+1,jj,jl) )
705               zbu = MIN( 1._wp , zbetup(ji,jj,jl) , zbetdo(ji+1,jj,jl) )
706               zcu = 0.5  + SIGN( 0.5 , paa(ji,jj,jl) )
707               !
708               paa(ji,jj,jl) = paa(ji,jj,jl) * ( zcu * zau + ( 1._wp - zcu) * zbu )
709            END DO
710         END DO
711         !
712         DO jj = 1, jpjm1
713            DO ji = fs_2, fs_jpim1   ! vector opt.
714               zav = MIN( 1._wp , zbetdo(ji,jj,jl) , zbetup(ji,jj+1,jl) )
715               zbv = MIN( 1._wp , zbetup(ji,jj,jl) , zbetdo(ji,jj+1,jl) )
716               zcv = 0.5  + SIGN( 0.5 , pbb(ji,jj,jl) )
717               !
718               pbb(ji,jj,jl) = pbb(ji,jj,jl) * ( zcv * zav + ( 1._wp - zcv) * zbv )
719            END DO
720         END DO
721      END DO
722      !
723   END SUBROUTINE nonosc_2d
724
725#else
726   !!----------------------------------------------------------------------
727   !!   Default option           Dummy module         NO SI3 sea-ice model
728   !!----------------------------------------------------------------------
729#endif
730
731   !!======================================================================
732END MODULE icedyn_adv_umx
Note: See TracBrowser for help on using the repository browser.