New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
iom_nf90.F90 in NEMO/branches/2018/dev_r10164_HPC09_ESIWACE_PREP_MERGE/src/OCE/IOM – NEMO

source: NEMO/branches/2018/dev_r10164_HPC09_ESIWACE_PREP_MERGE/src/OCE/IOM/iom_nf90.F90 @ 10380

Last change on this file since 10380 was 10380, checked in by smasson, 5 years ago

dev_r10164_HPC09_ESIWACE_PREP_MERGE: iom cleaning: (1) get rid of jpnf90, jprstlib, jlibalt, iolib and (2) improve iom_getatt and iom_putatt, see #2133
  • Property svn:keywords set to Id
File size: 41.6 KB
Line 
1MODULE iom_nf90
2   !!======================================================================
3   !!                    ***  MODULE  iom_nf90 ***
4   !! Input/Output manager :  Library to read input files with NF90 (only fliocom module)
5   !!======================================================================
6   !! History :  9.0  ! 05 12  (J. Belier) Original code
7   !!            9.0  ! 06 02  (S. Masson) Adaptation to NEMO
8   !!             "   ! 07 07  (D. Storkey) Changes to iom_nf90_gettime
9   !!            3.6  ! 2015-15  (J. Harle) Added procedure to read REAL attributes
10   !!            4.0  ! 2017-11 (M. Andrejczuk) Extend IOM interface to write any 3D fields
11   !!----------------------------------------------------------------------
12
13   !!----------------------------------------------------------------------
14   !!   iom_open       : open a file read only
15   !!   iom_close      : close a file or all files opened by iom
16   !!   iom_get        : read a field (interfaced to several routines)
17   !!   iom_gettime    : read the time axis kvid in the file
18   !!   iom_varid      : get the id of a variable in a file
19   !!   iom_rstput     : write a field in a restart file (interfaced to several routines)
20   !!----------------------------------------------------------------------
21   USE dom_oce         ! ocean space and time domain
22   USE lbclnk          ! lateal boundary condition / mpp exchanges
23   USE iom_def         ! iom variables definitions
24   USE netcdf          ! NetCDF library
25   USE in_out_manager  ! I/O manager
26   USE lib_mpp         ! MPP library
27
28   IMPLICIT NONE
29   PRIVATE
30
31   PUBLIC iom_nf90_open  , iom_nf90_close, iom_nf90_varid, iom_nf90_get, iom_nf90_gettime, iom_nf90_rstput
32   PUBLIC iom_nf90_getatt, iom_nf90_putatt
33
34   INTERFACE iom_nf90_get
35      MODULE PROCEDURE iom_nf90_g0d, iom_nf90_g123d
36   END INTERFACE
37   INTERFACE iom_nf90_rstput
38      MODULE PROCEDURE iom_nf90_rp0123d
39   END INTERFACE
40
41   !!----------------------------------------------------------------------
42   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
43   !! $Id$
44   !! Software governed by the CeCILL license (see ./LICENSE)
45   !!----------------------------------------------------------------------
46CONTAINS
47
48   SUBROUTINE iom_nf90_open( cdname, kiomid, ldwrt, ldok, kdompar, kdlev )
49      !!---------------------------------------------------------------------
50      !!                   ***  SUBROUTINE  iom_open  ***
51      !!
52      !! ** Purpose : open an input file with NF90
53      !!---------------------------------------------------------------------
54      CHARACTER(len=*)       , INTENT(inout)           ::   cdname      ! File name
55      INTEGER                , INTENT(  out)           ::   kiomid      ! nf90 identifier of the opened file
56      LOGICAL                , INTENT(in   )           ::   ldwrt       ! read or write the file?
57      LOGICAL                , INTENT(in   )           ::   ldok        ! check the existence
58      INTEGER, DIMENSION(2,5), INTENT(in   ), OPTIONAL ::   kdompar     ! domain parameters:
59      INTEGER                , INTENT(in   ), OPTIONAL ::   kdlev       ! size of the third dimension
60
61      CHARACTER(LEN=256) ::   clinfo           ! info character
62      CHARACTER(LEN=256) ::   cltmp            ! temporary character
63      INTEGER            ::   iln              ! lengths of character
64      INTEGER            ::   istop            ! temporary storage of nstop
65      INTEGER            ::   if90id           ! nf90 identifier of the opened file
66      INTEGER            ::   idmy             ! dummy variable
67      INTEGER            ::   jl               ! loop variable
68      INTEGER            ::   ichunk           ! temporary storage of nn_chunksz
69      INTEGER            ::   imode            ! creation mode flag: NF90_CLOBBER or NF90_NOCLOBBER or NF90_HDF5
70      INTEGER            ::   ihdf5            ! local variable for retrieval of value for NF90_HDF5
71      LOGICAL            ::   llclobber        ! local definition of ln_clobber
72      INTEGER            ::   ilevels           ! vertical levels
73      !---------------------------------------------------------------------
74      !
75      clinfo = '                    iom_nf90_open ~~~  '
76      istop = nstop     ! store the actual value of nstop
77      !
78      !                 !number of vertical levels
79      IF( PRESENT(kdlev) ) THEN   ;   ilevels = kdlev    ! use input value (useful for sea-ice)
80      ELSE                        ;   ilevels = jpk      ! by default jpk
81      ENDIF
82      !
83      IF( nn_chunksz > 0 ) THEN   ;   ichunk = nn_chunksz
84      ELSE                        ;   ichunk = NF90_SIZEHINT_DEFAULT
85      ENDIF
86      !
87      llclobber = ldwrt .AND. ln_clobber
88      IF( ldok .AND. .NOT. llclobber ) THEN      !==  Open existing file ==!
89         !                                       !=========================!
90         IF( ldwrt ) THEN  ! ... in write mode
91            IF(lwp) WRITE(numout,*) TRIM(clinfo)//' open existing file: '//TRIM(cdname)//' in WRITE mode'
92            IF( snc4set%luse ) THEN
93               CALL iom_nf90_check(NF90_OPEN( TRIM(cdname), NF90_WRITE  , if90id ), clinfo)
94            ELSE
95               CALL iom_nf90_check(NF90_OPEN( TRIM(cdname), NF90_WRITE  , if90id, chunksize = ichunk ), clinfo)
96            ENDIF
97            CALL iom_nf90_check(NF90_SET_FILL( if90id, NF90_NOFILL, idmy                          ), clinfo)
98         ELSE              ! ... in read mode
99            IF(lwp) WRITE(numout,*) TRIM(clinfo)//' open existing file: '//TRIM(cdname)//' in READ mode'
100            CALL iom_nf90_check(NF90_OPEN( TRIM(cdname), NF90_NOWRITE, if90id, chunksize = ichunk ), clinfo)
101         ENDIF
102      ELSE                                       !== the file doesn't exist ==!   (or we overwrite it)
103         !                                       !============================!
104         iln = INDEX( cdname, '.nc' )
105         IF( ldwrt ) THEN              !* the file should be open in write mode so we create it...
106            IF( jpnij > 1 ) THEN
107               WRITE(cltmp,'(a,a,i4.4,a)') cdname(1:iln-1), '_', narea-1, '.nc'
108               cdname = TRIM(cltmp)
109            ENDIF
110            IF(lwp) WRITE(numout,*) TRIM(clinfo)//' create new file: '//TRIM(cdname)//' in WRITE mode'
111
112            IF( llclobber ) THEN   ;   imode = IOR( NF90_64BIT_OFFSET, NF90_CLOBBER   )
113            ELSE                   ;   imode = IOR( NF90_64BIT_OFFSET, NF90_NOCLOBBER ) 
114            ENDIF
115            IF( snc4set%luse ) THEN
116               IF(lwp) WRITE(numout,*) TRIM(clinfo)//' creating file: '//TRIM(cdname)//' in hdf5 (netcdf4) mode'
117               CALL GET_NF90_SYMBOL("NF90_HDF5", ihdf5)
118               IF( llclobber ) THEN   ;   imode = IOR(ihdf5, NF90_CLOBBER)
119               ELSE                   ;   imode = IOR(ihdf5, NF90_NOCLOBBER)
120               ENDIF
121               CALL iom_nf90_check(NF90_CREATE( TRIM(cdname), imode, if90id ), clinfo)
122            ELSE
123               CALL iom_nf90_check(NF90_CREATE( TRIM(cdname), imode, if90id, chunksize = ichunk ), clinfo)
124            ENDIF
125            CALL iom_nf90_check(NF90_SET_FILL( if90id, NF90_NOFILL,                   idmy ), clinfo)
126            ! define dimensions
127            CALL iom_nf90_check(NF90_DEF_DIM( if90id,            'x',   kdompar(1,1), idmy ), clinfo)
128            CALL iom_nf90_check(NF90_DEF_DIM( if90id,            'y',   kdompar(2,1), idmy ), clinfo)
129            CALL iom_nf90_check(NF90_DEF_DIM( if90id,      'nav_lev',            jpk, idmy ), clinfo)
130            CALL iom_nf90_check(NF90_DEF_DIM( if90id, 'time_counter', NF90_UNLIMITED, idmy ), clinfo)
131            IF( PRESENT(kdlev) )   &
132               CALL iom_nf90_check(NF90_DEF_DIM( if90id,    'numcat',          kdlev, idmy ), clinfo)
133            ! global attributes
134            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_number_total'   , jpnij              ), clinfo)
135            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_number'         , narea-1            ), clinfo)
136            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_dimensions_ids' , (/1     , 2     /) ), clinfo)
137            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_size_global'    , (/jpiglo, jpjglo/) ), clinfo)
138            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_size_local'     , kdompar(:,1)       ), clinfo)
139            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_position_first' , kdompar(:,2)       ), clinfo)
140            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_position_last'  , kdompar(:,3)       ), clinfo)
141            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_halo_size_start', kdompar(:,4)       ), clinfo)
142            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_halo_size_end'  , kdompar(:,5)       ), clinfo)
143            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_type'           , 'BOX'              ), clinfo)
144         ELSE                          !* the file should be open for read mode so it must exist...
145            CALL ctl_stop( TRIM(clinfo), ' should be impossible case...' )
146         ENDIF
147      ENDIF
148      !
149      ! start to fill file informations
150      ! =============
151      IF( istop == nstop ) THEN   ! no error within this routine
152!does not work with some compilers         kiomid = MINLOC(iom_file(:)%nfid, dim = 1)
153         kiomid = 0
154         DO jl = jpmax_files, 1, -1
155            IF( iom_file(jl)%nfid == 0 )   kiomid = jl
156         ENDDO
157         iom_file(kiomid)%name   = TRIM(cdname)
158         iom_file(kiomid)%nfid   = if90id
159         iom_file(kiomid)%nvars  = 0
160         iom_file(kiomid)%irec   = -1   ! useless for NetCDF files, used to know if the file is in define mode
161         iom_file(kiomid)%nlev   = ilevels
162         CALL iom_nf90_check(NF90_Inquire(if90id, unlimitedDimId = iom_file(kiomid)%iduld), clinfo)
163         IF( iom_file(kiomid)%iduld .GE. 0 ) THEN
164            CALL iom_nf90_check(NF90_Inquire_Dimension(if90id, iom_file(kiomid)%iduld,    & 
165               &                                       name = iom_file(kiomid)%uldname,   &
166               &                                       len  = iom_file(kiomid)%lenuld ), clinfo )
167         ENDIF
168         IF(lwp) WRITE(numout,*) '                   ---> '//TRIM(cdname)//' OK'
169      ELSE
170         kiomid = 0               ! return error flag
171      ENDIF
172      !
173   END SUBROUTINE iom_nf90_open
174
175
176   SUBROUTINE iom_nf90_close( kiomid )
177      !!--------------------------------------------------------------------
178      !!                   ***  SUBROUTINE  iom_nf90_close  ***
179      !!
180      !! ** Purpose : close an input file with NF90
181      !!--------------------------------------------------------------------
182      INTEGER, INTENT(in) ::   kiomid   ! iom identifier of the file to be closed
183      CHARACTER(LEN=100)  ::   clinfo   ! info character
184      !---------------------------------------------------------------------
185      clinfo = '      iom_nf90_close    , file: '//TRIM(iom_file(kiomid)%name)
186      CALL iom_nf90_check(NF90_CLOSE(iom_file(kiomid)%nfid), clinfo)
187   END SUBROUTINE iom_nf90_close
188
189
190   FUNCTION iom_nf90_varid ( kiomid, cdvar, kiv, kdimsz, kndims ) 
191      !!-----------------------------------------------------------------------
192      !!                  ***  FUNCTION  iom_varid  ***
193      !!
194      !! ** Purpose : get the id of a variable in a file with NF90
195      !!-----------------------------------------------------------------------
196      INTEGER              , INTENT(in   )           ::   kiomid   ! file Identifier
197      CHARACTER(len=*)     , INTENT(in   )           ::   cdvar    ! name of the variable
198      INTEGER              , INTENT(in   )           ::   kiv   !
199      INTEGER, DIMENSION(:), INTENT(  out), OPTIONAL ::   kdimsz   ! size of the dimensions
200      INTEGER,               INTENT(  out), OPTIONAL ::   kndims   ! size of the dimensions
201      !
202      INTEGER                        ::   iom_nf90_varid   ! iom variable Id
203      INTEGER                        ::   if90id           ! nf90 file identifier
204      INTEGER                        ::   ji               ! dummy loop index
205      INTEGER                        ::   ivarid           ! NetCDF  variable Id
206      INTEGER                        ::   i_nvd            ! number of dimension of the variable
207      INTEGER, DIMENSION(jpmax_dims) ::   idimid           ! dimension ids of the variable
208      LOGICAL                        ::   llok             ! ok  test
209      CHARACTER(LEN=100)             ::   clinfo           ! info character
210      !!-----------------------------------------------------------------------
211      clinfo = '          iom_nf90_varid, file: '//TRIM(iom_file(kiomid)%name)//', var: '//TRIM(cdvar)
212      iom_nf90_varid = 0                    ! default definition
213      IF( PRESENT(kdimsz) ) kdimsz(:) = 0   ! default definition
214      if90id = iom_file(kiomid)%nfid        ! get back NetCDF file id
215      !
216      llok = NF90_INQ_VARID( if90id, TRIM(cdvar), ivarid ) == nf90_noerr   ! does the variable exist in the file
217      IF( llok ) THEN
218         iom_nf90_varid = kiv
219         iom_file(kiomid)%nvars       = kiv
220         iom_file(kiomid)%nvid(kiv)   = ivarid
221         iom_file(kiomid)%cn_var(kiv) = TRIM(cdvar)
222         CALL iom_nf90_check(NF90_Inquire_Variable(if90id, ivarid, ndims = i_nvd), clinfo)   ! number of dimensions
223         iom_file(kiomid)%ndims(kiv)  = i_nvd
224         CALL iom_nf90_check(NF90_Inquire_Variable(if90id, ivarid, dimids = idimid(1:i_nvd)), clinfo)   ! dimensions ids
225         iom_file(kiomid)%luld(kiv) = .FALSE.   ! default value
226         iom_file(kiomid)%dimsz(:,kiv) = 0      ! reset dimsz in case previously used
227         DO ji = 1, i_nvd                       ! dimensions size
228            CALL iom_nf90_check(NF90_Inquire_Dimension(if90id, idimid(ji), len = iom_file(kiomid)%dimsz(ji,kiv)), clinfo)   
229            IF( idimid(ji) == iom_file(kiomid)%iduld ) iom_file(kiomid)%luld(kiv) = .TRUE.   ! unlimited dimension?
230         END DO
231         !---------- Deal with scale_factor and add_offset
232         llok = NF90_Inquire_attribute(if90id, ivarid, 'scale_factor') == nf90_noerr
233         IF( llok) THEN
234            CALL iom_nf90_check(NF90_GET_ATT(if90id, ivarid, 'scale_factor', iom_file(kiomid)%scf(kiv)), clinfo)
235         ELSE
236            iom_file(kiomid)%scf(kiv) = 1.
237         END IF
238         llok = NF90_Inquire_attribute(if90id, ivarid, 'add_offset') == nf90_noerr
239         IF( llok ) THEN
240            CALL iom_nf90_check(NF90_GET_ATT(if90id, ivarid, 'add_offset', iom_file(kiomid)%ofs(kiv)), clinfo)
241         ELSE
242            iom_file(kiomid)%ofs(kiv) = 0.
243         END IF
244         ! return the simension size
245         IF( PRESENT(kdimsz) ) THEN
246            IF( i_nvd <= SIZE(kdimsz) ) THEN
247               kdimsz(1:i_nvd) = iom_file(kiomid)%dimsz(1:i_nvd,kiv)
248            ELSE
249               WRITE(ctmp1,*) i_nvd, SIZE(kdimsz)
250               CALL ctl_stop( TRIM(clinfo), 'error in kdimsz size'//TRIM(ctmp1) )
251            ENDIF
252         ENDIF
253         IF( PRESENT(kndims) )  kndims = iom_file(kiomid)%ndims(kiv)
254      ELSE 
255         iom_nf90_varid = -1   !   variable not found, return error code: -1
256      ENDIF
257      !
258   END FUNCTION iom_nf90_varid
259
260   !!----------------------------------------------------------------------
261   !!                   INTERFACE iom_nf90_get
262   !!----------------------------------------------------------------------
263
264   SUBROUTINE iom_nf90_g0d( kiomid, kvid, pvar, kstart )
265      !!-----------------------------------------------------------------------
266      !!                  ***  ROUTINE  iom_nf90_g0d  ***
267      !!
268      !! ** Purpose : read a scalar with NF90
269      !!-----------------------------------------------------------------------
270      INTEGER ,               INTENT(in   )            ::   kiomid   ! Identifier of the file
271      INTEGER ,               INTENT(in   )            ::   kvid     ! variable id
272      REAL(wp),               INTENT(  out)            ::   pvar     ! read field
273      INTEGER , DIMENSION(1), INTENT(in   ), OPTIONAL  ::   kstart   ! start position of the reading in each axis
274      !
275      CHARACTER(LEN=100)      ::   clinfo   ! info character
276      !---------------------------------------------------------------------
277      clinfo = 'iom_nf90_g0d , file: '//TRIM(iom_file(kiomid)%name)//', var: '//TRIM(iom_file(kiomid)%cn_var(kvid))
278      CALL iom_nf90_check(NF90_GET_VAR(iom_file(kiomid)%nfid, iom_file(kiomid)%nvid(kvid), pvar, start = kstart), clinfo )
279   END SUBROUTINE iom_nf90_g0d
280
281
282   SUBROUTINE iom_nf90_g123d( kiomid, kvid, knbdim, kstart, kcount, kx1, kx2, ky1, ky2,   &
283         &                    pv_r1d, pv_r2d, pv_r3d )
284      !!-----------------------------------------------------------------------
285      !!                  ***  ROUTINE  iom_nf90_g123d  ***
286      !!
287      !! ** Purpose : read a 1D/2D/3D variable with NF90
288      !!
289      !! ** Method : read ONE record at each CALL
290      !!-----------------------------------------------------------------------
291      INTEGER                    , INTENT(in   )           ::   kiomid    ! iom identifier of the file
292      INTEGER                    , INTENT(in   )           ::   kvid      ! Name of the variable
293      INTEGER                    , INTENT(in   )           ::   knbdim    ! number of dimensions of the variable
294      INTEGER , DIMENSION(:)     , INTENT(in   )           ::   kstart    ! start position of the reading in each axis
295      INTEGER , DIMENSION(:)     , INTENT(in   )           ::   kcount    ! number of points to be read in each axis
296      INTEGER ,                    INTENT(in   )           ::   kx1, kx2, ky1, ky2   ! subdomain indexes
297      REAL(wp), DIMENSION(:)     , INTENT(  out), OPTIONAL ::   pv_r1d    ! read field (1D case)
298      REAL(wp), DIMENSION(:,:)   , INTENT(  out), OPTIONAL ::   pv_r2d    ! read field (2D case)
299      REAL(wp), DIMENSION(:,:,:) , INTENT(  out), OPTIONAL ::   pv_r3d    ! read field (3D case)
300      !
301      CHARACTER(LEN=100) ::   clinfo               ! info character
302      INTEGER            ::   if90id               ! nf90 identifier of the opened file
303      INTEGER            ::   ivid                 ! nf90 variable id
304      !---------------------------------------------------------------------
305      clinfo = 'iom_nf90_g123d , file: '//TRIM(iom_file(kiomid)%name)//', var: '//TRIM(iom_file(kiomid)%cn_var(kvid))
306      if90id = iom_file(kiomid)%nfid         ! get back NetCDF file id
307      ivid   = iom_file(kiomid)%nvid(kvid)   ! get back NetCDF var id
308      !
309      IF(     PRESENT(pv_r1d) ) THEN
310         CALL iom_nf90_check( NF90_GET_VAR(if90id, ivid, pv_r1d(:                ), start = kstart(1:knbdim),   &
311            &                                                                       count = kcount(1:knbdim)), clinfo )
312      ELSEIF( PRESENT(pv_r2d) ) THEN
313         CALL iom_nf90_check( NF90_GET_VAR(if90id, ivid, pv_r2d(kx1:kx2,ky1:ky2  ), start = kstart(1:knbdim),   &
314            &                                                                       count = kcount(1:knbdim)), clinfo )
315      ELSEIF( PRESENT(pv_r3d) ) THEN
316         CALL iom_nf90_check( NF90_GET_VAR(if90id, ivid, pv_r3d(kx1:kx2,ky1:ky2,:), start = kstart(1:knbdim),   &
317            &                                                                       count = kcount(1:knbdim)), clinfo )
318      ENDIF
319      !
320   END SUBROUTINE iom_nf90_g123d
321
322
323   SUBROUTINE iom_nf90_getatt( kiomid, cdatt, katt0d, katt1d, patt0d, patt1d, cdatt0d, cdvar)
324      !!-----------------------------------------------------------------------
325      !!                  ***  ROUTINE  iom_nf90_getatt  ***
326      !!
327      !! ** Purpose : read an attribute with NF90
328      !!              (either a global attribute (default) or a variable
329      !!               attribute if optional variable name is supplied (cdvar))
330      !!-----------------------------------------------------------------------
331      INTEGER               , INTENT(in   )           ::   kiomid   ! Identifier of the file
332      CHARACTER(len=*)      , INTENT(in   )           ::   cdatt    ! attribute name
333      INTEGER               , INTENT(  out), OPTIONAL ::   katt0d   ! read scalar integer
334      INTEGER, DIMENSION(:) , INTENT(  out), OPTIONAL ::   katt1d   ! read 1d array integer
335      REAL(wp)              , INTENT(  out), OPTIONAL ::   patt0d   ! read scalar  real
336      REAL(wp), DIMENSION(:), INTENT(  out), OPTIONAL ::   patt1d   ! read 1d array real
337      CHARACTER(len=*)      , INTENT(  out), OPTIONAL ::   cdatt0d  ! read character
338      CHARACTER(len=*)      , INTENT(in   ), OPTIONAL ::   cdvar    ! name of the variable
339      !
340      INTEGER                         ::   if90id   ! temporary integer
341      INTEGER                         ::   ivarid   ! NetCDF variable Id
342      LOGICAL                         ::   llok     ! temporary logical
343      CHARACTER(LEN=100)              ::   clinfo   ! info character
344      !---------------------------------------------------------------------
345      !
346      if90id = iom_file(kiomid)%nfid
347      IF( PRESENT(cdvar) ) THEN
348         ! check the variable exists in the file
349         llok = NF90_INQ_VARID( if90id, TRIM(cdvar), ivarid ) == nf90_noerr
350         IF( llok ) THEN
351            ! check the variable has the attribute required
352            llok = NF90_Inquire_attribute(if90id, ivarid, cdatt) == nf90_noerr
353         ELSE
354            CALL ctl_warn('iom_nf90_getatt: no variable '//TRIM(cdvar)//' found')
355         ENDIF
356      ELSE
357         llok = NF90_Inquire_attribute(if90id, NF90_GLOBAL, cdatt) == nf90_noerr
358         ivarid = NF90_GLOBAL
359      ENDIF
360      !
361      IF( llok) THEN
362         clinfo = 'iom_nf90_getatt, file: '//TRIM(iom_file(kiomid)%name)//', att: '//TRIM(cdatt)
363         IF(PRESENT( katt0d))   CALL iom_nf90_check(NF90_GET_ATT(if90id, ivarid, cdatt, values =  katt0d), clinfo)
364         IF(PRESENT( katt1d))   CALL iom_nf90_check(NF90_GET_ATT(if90id, ivarid, cdatt, values =  katt1d), clinfo)
365         IF(PRESENT( patt0d))   CALL iom_nf90_check(NF90_GET_ATT(if90id, ivarid, cdatt, values =  patt0d), clinfo)
366         IF(PRESENT( patt1d))   CALL iom_nf90_check(NF90_GET_ATT(if90id, ivarid, cdatt, values =  patt1d), clinfo)
367         IF(PRESENT(cdatt0d))   CALL iom_nf90_check(NF90_GET_ATT(if90id, ivarid, cdatt, values = cdatt0d), clinfo)
368      ELSE
369         CALL ctl_warn('iom_nf90_getatt: no attribute '//TRIM(cdatt)//' found')
370         IF(PRESENT( katt0d))    katt0d    = -999
371         IF(PRESENT( katt1d))    katt1d(:) = -999
372         IF(PRESENT( patt0d))    patt0d    = -999._wp
373         IF(PRESENT( patt1d))    patt1d(:) = -999._wp
374         IF(PRESENT(cdatt0d))   cdatt0d    = '!'
375      ENDIF
376      !
377   END SUBROUTINE iom_nf90_getatt
378
379
380   SUBROUTINE iom_nf90_putatt( kiomid, cdatt, katt0d, katt1d, patt0d, patt1d, cdatt0d, cdvar)
381      !!-----------------------------------------------------------------------
382      !!                  ***  ROUTINE  iom_nf90_putatt  ***
383      !!
384      !! ** Purpose : write an attribute with NF90
385      !!              (either a global attribute (default) or a variable
386      !!               attribute if optional variable name is supplied (cdvar))
387      !!-----------------------------------------------------------------------
388      INTEGER               , INTENT(in   )           ::   kiomid   ! Identifier of the file
389      CHARACTER(len=*)      , INTENT(in   )           ::   cdatt    ! attribute name
390      INTEGER               , INTENT(in   ), OPTIONAL ::   katt0d   ! read scalar integer
391      INTEGER, DIMENSION(:) , INTENT(in   ), OPTIONAL ::   katt1d   ! read 1d array integer
392      REAL(wp)              , INTENT(in   ), OPTIONAL ::   patt0d   ! read scalar  real
393      REAL(wp), DIMENSION(:), INTENT(in   ), OPTIONAL ::   patt1d   ! read 1d array real
394      CHARACTER(len=*)      , INTENT(in   ), OPTIONAL ::   cdatt0d  ! read character
395      CHARACTER(len=*)      , INTENT(in   ), OPTIONAL ::   cdvar    ! name of the variable
396      !
397      INTEGER                         ::   if90id   ! temporary integer
398      INTEGER                         ::   ivarid   ! NetCDF variable Id
399      LOGICAL                         ::   llok     ! temporary logical
400      LOGICAL                         ::   lenddef  ! temporary logical
401      CHARACTER(LEN=100)              ::   clinfo   ! info character
402      !---------------------------------------------------------------------
403      !
404      if90id = iom_file(kiomid)%nfid
405      lenddef = .false.
406      IF( PRESENT(cdvar) ) THEN
407         ! check the variable exists in the file
408         llok = NF90_INQ_VARID( if90id, TRIM(cdvar), ivarid ) == nf90_noerr
409         IF( .NOT. llok ) THEN
410            CALL ctl_warn('iom_nf90_putatt: no variable '//TRIM(cdvar)//' found')
411         ENDIF
412      ELSE
413         llok = .true.
414         ivarid = NF90_GLOBAL
415      ENDIF
416      !
417      IF( llok) THEN
418         clinfo = 'iom_nf90_putatt, file: '//TRIM(iom_file(kiomid)%name)//', att: '//TRIM(cdatt)
419         IF( iom_file(kiomid)%irec /= -1 ) THEN   
420            ! trick: irec used to know if the file is in define mode or not
421            ! if it is not then temporarily put it into define mode
422            CALL iom_nf90_check(NF90_REDEF( if90id ), clinfo)
423            lenddef = .true.
424         ENDIF
425         !
426         IF(PRESENT( katt0d))   CALL iom_nf90_check(NF90_PUT_ATT(if90id, ivarid, cdatt, values =  katt0d), clinfo)
427         IF(PRESENT( katt1d))   CALL iom_nf90_check(NF90_PUT_ATT(if90id, ivarid, cdatt, values =  katt1d), clinfo)
428         IF(PRESENT( patt0d))   CALL iom_nf90_check(NF90_PUT_ATT(if90id, ivarid, cdatt, values =  patt0d), clinfo)
429         IF(PRESENT( patt1d))   CALL iom_nf90_check(NF90_PUT_ATT(if90id, ivarid, cdatt, values =  patt1d), clinfo)
430         IF(PRESENT(cdatt0d))   CALL iom_nf90_check(NF90_PUT_ATT(if90id, ivarid, cdatt, values = cdatt0d), clinfo)
431         !
432         IF( lenddef ) THEN   ! file was in data mode on entry; put it back in that mode
433            CALL iom_nf90_check(NF90_ENDDEF( if90id ), clinfo)
434         ENDIF
435      ELSE
436         CALL ctl_warn('iom_nf90_putatt: no attribute '//TRIM(cdatt)//' written')
437      ENDIF
438      !
439   END SUBROUTINE iom_nf90_putatt
440
441
442   SUBROUTINE iom_nf90_gettime( kiomid, kvid, ptime, cdunits, cdcalendar )
443      !!--------------------------------------------------------------------
444      !!                   ***  SUBROUTINE iom_gettime  ***
445      !!
446      !! ** Purpose : read the time axis kvid in the file with NF90
447      !!--------------------------------------------------------------------
448      INTEGER                   , INTENT(in   ) ::   kiomid     ! file Identifier
449      INTEGER                   , INTENT(in   ) ::   kvid       ! variable id
450      REAL(wp), DIMENSION(:)    , INTENT(  out) ::   ptime      ! the time axis
451      CHARACTER(len=*), OPTIONAL, INTENT(  out) ::   cdunits    ! units attribute
452      CHARACTER(len=*), OPTIONAL, INTENT(  out) ::   cdcalendar ! calendar attribute
453      !
454      CHARACTER(LEN=100) ::   clinfo     ! info character
455      !---------------------------------------------------------------------
456      clinfo = 'iom_nf90_gettime, file: '//TRIM(iom_file(kiomid)%name)//', var: '//TRIM(iom_file(kiomid)%cn_var(kvid))
457      CALL iom_nf90_check(NF90_GET_VAR(iom_file(kiomid)%nfid, iom_file(kiomid)%nvid(kvid), ptime(:),   &
458            &                           start=(/ 1 /), count=(/ iom_file(kiomid)%dimsz(1, kvid) /)), clinfo)
459      IF ( PRESENT(cdunits) ) THEN
460         CALL iom_nf90_check(NF90_GET_ATT(iom_file(kiomid)%nfid, iom_file(kiomid)%nvid(kvid), "units", &
461            &                           values=cdunits), clinfo)
462      ENDIF
463      IF ( PRESENT(cdcalendar) ) THEN
464         CALL iom_nf90_check(NF90_GET_ATT(iom_file(kiomid)%nfid, iom_file(kiomid)%nvid(kvid), "calendar", &
465            &                           values=cdcalendar), clinfo)
466      ENDIF
467      !
468   END SUBROUTINE iom_nf90_gettime
469
470
471   SUBROUTINE iom_nf90_rp0123d( kt, kwrite, kiomid, cdvar , kvid  , ktype,   &
472         &                                  pv_r0d, pv_r1d, pv_r2d, pv_r3d )
473      !!--------------------------------------------------------------------
474      !!                   ***  SUBROUTINE  iom_nf90_rstput  ***
475      !!
476      !! ** Purpose : read the time axis cdvar in the file
477      !!--------------------------------------------------------------------
478      INTEGER                     , INTENT(in)           ::   kt       ! ocean time-step
479      INTEGER                     , INTENT(in)           ::   kwrite   ! writing time-step
480      INTEGER                     , INTENT(in)           ::   kiomid   ! Identifier of the file
481      CHARACTER(len=*)            , INTENT(in)           ::   cdvar    ! variable name
482      INTEGER                     , INTENT(in)           ::   kvid     ! variable id
483      INTEGER                     , INTENT(in), OPTIONAL ::   ktype    ! variable type (default R8)
484      REAL(wp)                    , INTENT(in), OPTIONAL ::   pv_r0d   ! written Od field
485      REAL(wp), DIMENSION(      :), INTENT(in), OPTIONAL ::   pv_r1d   ! written 1d field
486      REAL(wp), DIMENSION(:, :   ), INTENT(in), OPTIONAL ::   pv_r2d   ! written 2d field
487      REAL(wp), DIMENSION(:, :, :), INTENT(in), OPTIONAL ::   pv_r3d   ! written 3d field
488      !
489      INTEGER               :: idims                ! number of dimension
490      INTEGER               :: idvar                ! variable id
491      INTEGER               :: jd                   ! dimension loop counter   
492      INTEGER               :: ix1, ix2, iy1, iy2   ! subdomain indexes   
493      INTEGER, DIMENSION(4) :: idimsz               ! dimensions size 
494      INTEGER, DIMENSION(4) :: idimid               ! dimensions id
495      CHARACTER(LEN=256)    :: clinfo               ! info character
496      CHARACTER(LEN= 12), DIMENSION(5) :: cltmp     ! temporary character
497      INTEGER               :: if90id               ! nf90 file identifier
498      INTEGER               :: idmy                 ! dummy variable
499      INTEGER               :: itype                ! variable type
500      INTEGER, DIMENSION(4) :: ichunksz             ! NetCDF4 chunk sizes. Will be computed using
501      !                                             ! nn_nchunks_[i,j,k,t] namelist parameters
502      INTEGER               :: ichunkalg, ishuffle, ideflate, ideflate_level
503      !                                             ! NetCDF4 internally fixed parameters
504      LOGICAL               :: lchunk               ! logical switch to activate chunking and compression
505      !                                             ! when appropriate (currently chunking is applied to 4d fields only)
506      INTEGER               :: idlv                 ! local variable
507      INTEGER               :: idim3                ! id of the third dimension
508      !---------------------------------------------------------------------
509      !
510      clinfo = '          iom_nf90_rp0123d, file: '//TRIM(iom_file(kiomid)%name)//', var: '//TRIM(cdvar)
511      if90id = iom_file(kiomid)%nfid
512      !
513      ! define dimension variables if it is not already done
514      ! ==========================
515      IF( iom_file(kiomid)%nvars == 0 ) THEN
516         ! are we in define mode?
517         IF( iom_file(kiomid)%irec /= -1 ) THEN   ! trick: irec used to know if the file is in define mode or not
518            CALL iom_nf90_check(NF90_REDEF( if90id ), clinfo)   ;   iom_file(kiomid)%irec = -1
519         ENDIF
520         ! define the dimension variables if it is not already done
521         cltmp = (/ 'nav_lon', 'nav_lat', 'nav_lev', 'time_counter', 'numcat' /)
522         CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(cltmp(1)), NF90_FLOAT , (/ 1, 2 /), iom_file(kiomid)%nvid(1) ), clinfo)
523         CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(cltmp(2)), NF90_FLOAT , (/ 1, 2 /), iom_file(kiomid)%nvid(2) ), clinfo)
524         CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(cltmp(3)), NF90_FLOAT , (/ 3    /), iom_file(kiomid)%nvid(3) ), clinfo)
525         CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(cltmp(4)), NF90_DOUBLE, (/ 4    /), iom_file(kiomid)%nvid(4) ), clinfo)
526         ! update informations structure related the dimension variable we just added...
527         iom_file(kiomid)%nvars       = 4
528         iom_file(kiomid)%luld(1:4)   = (/ .FALSE., .FALSE., .FALSE., .TRUE. /)
529         iom_file(kiomid)%cn_var(1:4) = cltmp(1:4)
530         iom_file(kiomid)%ndims(1:4)  = (/ 2, 2, 1, 1 /)
531         IF( NF90_INQ_DIMID( if90id, 'numcat', idmy ) == nf90_noerr ) THEN   ! add a 5th variable corresponding to the 5th dimension
532            CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(cltmp(5)), NF90_FLOAT , (/ 5 /), iom_file(kiomid)%nvid(5) ), clinfo)
533            iom_file(kiomid)%nvars     = 5
534            iom_file(kiomid)%luld(5)   = .FALSE.
535            iom_file(kiomid)%cn_var(5) = cltmp(5)
536            iom_file(kiomid)%ndims(5)  = 1
537         ENDIF
538         ! trick: defined to 0 to say that dimension variables are defined but not yet written
539         iom_file(kiomid)%dimsz(1, 1)  = 0   
540         IF(lwp) WRITE(numout,*) TRIM(clinfo)//' define dimension variables done'
541      ENDIF
542      ! define the data if it is not already done
543      ! ===============
544      IF( kvid <= 0 ) THEN
545         !
546         ! NetCDF4 chunking and compression fixed settings
547         ichunkalg = 0
548         ishuffle = 1
549         ideflate = 1
550         ideflate_level = 1
551         !
552         idvar = iom_file(kiomid)%nvars + 1
553         ! are we in define mode?
554         IF( iom_file(kiomid)%irec /= -1 ) THEN   ! trick: irec used to know if the file is in define mode or not
555            CALL iom_nf90_check(NF90_REDEF( if90id ), clinfo)   ;   iom_file(kiomid)%irec = -1
556         ENDIF
557         ! variable definition
558         IF(     PRESENT(pv_r0d) ) THEN   ;   idims = 0
559         ELSEIF( PRESENT(pv_r1d) ) THEN
560            IF( SIZE(pv_r1d,1) == jpk ) THEN   ;   idim3 = 3
561            ELSE                               ;   idim3 = 5
562            ENDIF
563                                              idims = 2   ;   idimid(1:idims) = (/idim3,4/)
564         ELSEIF( PRESENT(pv_r2d) ) THEN   ;   idims = 3   ;   idimid(1:idims) = (/1,2  ,4/)
565         ELSEIF( PRESENT(pv_r3d) ) THEN
566            IF( SIZE(pv_r3d,3) == jpk ) THEN   ;   idim3 = 3
567            ELSE                               ;   idim3 = 5
568            ENDIF
569                                              idims = 4   ;   idimid(1:idims) = (/1,2,idim3,4/)
570         ENDIF
571         IF( PRESENT(ktype) ) THEN   ! variable external type
572            SELECT CASE (ktype)
573            CASE (jp_r8)   ;   itype = NF90_DOUBLE
574            CASE (jp_r4)   ;   itype = NF90_FLOAT
575            CASE (jp_i4)   ;   itype = NF90_INT
576            CASE (jp_i2)   ;   itype = NF90_SHORT
577            CASE (jp_i1)   ;   itype = NF90_BYTE
578            CASE DEFAULT   ;   CALL ctl_stop( TRIM(clinfo)//' unknown variable type' )
579            END SELECT
580         ELSE
581            itype = NF90_DOUBLE
582         ENDIF
583         IF( PRESENT(pv_r0d) ) THEN
584            CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(cdvar), itype,                    &
585               &                              iom_file(kiomid)%nvid(idvar) ), clinfo )
586         ELSE
587            CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(cdvar), itype, idimid(1:idims),   &
588               &                              iom_file(kiomid)%nvid(idvar) ), clinfo )
589         ENDIF
590         lchunk = .false.
591         IF( snc4set%luse .AND. idims == 4 )   lchunk = .true.
592         ! update informations structure related the new variable we want to add...
593         iom_file(kiomid)%nvars         = idvar
594         iom_file(kiomid)%cn_var(idvar) = TRIM(cdvar)
595         iom_file(kiomid)%scf(idvar)    = 1.
596         iom_file(kiomid)%ofs(idvar)    = 0.
597         iom_file(kiomid)%ndims(idvar)  = idims
598         IF( .NOT. PRESENT(pv_r0d) ) THEN   ;   iom_file(kiomid)%luld(idvar) = .TRUE.
599         ELSE                               ;   iom_file(kiomid)%luld(idvar) = .FALSE.
600         ENDIF
601         DO jd = 1, idims
602            CALL iom_nf90_check(NF90_INQUIRE_DIMENSION( if90id, idimid(jd), len = iom_file(kiomid)%dimsz(jd,idvar) ), clinfo)
603            IF ( lchunk ) ichunksz(jd) = iom_file(kiomid)%dimsz(jd,idvar)
604         END DO
605         IF ( lchunk ) THEN
606            ! Calculate chunk sizes by partitioning each dimension as requested in namnc4 namelist
607            ! Disallow very small chunk sizes and prevent chunk sizes larger than each individual dimension
608            ichunksz(1) = MIN( ichunksz(1),MAX( (ichunksz(1)-1)/snc4set%ni + 1 ,16 ) ) ! Suggested default nc4set%ni=4
609            ichunksz(2) = MIN( ichunksz(2),MAX( (ichunksz(2)-1)/snc4set%nj + 1 ,16 ) ) ! Suggested default nc4set%nj=2
610            ichunksz(3) = MIN( ichunksz(3),MAX( (ichunksz(3)-1)/snc4set%nk + 1 , 1 ) ) ! Suggested default nc4set%nk=6
611            ichunksz(4) = 1                                                            ! Do not allow chunks to span the
612            !                                                                          ! unlimited dimension
613            CALL iom_nf90_check(SET_NF90_DEF_VAR_CHUNKING(if90id, idvar, ichunkalg, ichunksz), clinfo)
614            CALL iom_nf90_check(SET_NF90_DEF_VAR_DEFLATE(if90id, idvar, ishuffle, ideflate, ideflate_level), clinfo)
615            IF(lwp) WRITE(numout,*) TRIM(clinfo)//' chunked ok. Chunks sizes: ', ichunksz
616         ENDIF
617         IF(lwp) WRITE(numout,*) TRIM(clinfo)//' defined ok'
618      ELSE
619         idvar = kvid
620      ENDIF
621      !
622      ! time step kwrite : write the variable
623      IF( kt == kwrite ) THEN
624         ! are we in write mode?
625         IF( iom_file(kiomid)%irec == -1 ) THEN   ! trick: irec used to know if the file is in define mode or not
626            CALL iom_nf90_check(NF90_ENDDEF( if90id ), clinfo)   ;   iom_file(kiomid)%irec = 0
627         ENDIF
628         ! on what kind of domain must the data be written?
629         IF( PRESENT(pv_r2d) .OR. PRESENT(pv_r3d) ) THEN
630            idimsz(1:2) = iom_file(kiomid)%dimsz(1:2,idvar)
631            IF(     idimsz(1) == (nlei - nldi + 1) .AND. idimsz(2) == (nlej - nldj + 1) ) THEN
632               ix1 = nldi   ;   ix2 = nlei   ;   iy1 = nldj   ;   iy2 = nlej
633            ELSEIF( idimsz(1) == nlci              .AND. idimsz(2) == nlcj              ) THEN
634               ix1 = 1      ;   ix2 = nlci   ;   iy1 = 1      ;   iy2 = nlcj
635            ELSEIF( idimsz(1) == jpi               .AND. idimsz(2) == jpj               ) THEN
636               ix1 = 1      ;   ix2 = jpi    ;   iy1 = 1      ;   iy2 = jpj
637            ELSE
638               CALL ctl_stop( 'iom_nf90_rp0123d: should have been an impossible case...' )
639            ENDIF
640
641            ! write dimension variables if it is not already done
642            ! =============
643            ! trick: is defined to 0 => dimension variable are defined but not yet written
644            IF( iom_file(kiomid)%dimsz(1, 1) == 0 ) THEN
645               CALL iom_nf90_check( NF90_INQ_VARID( if90id, 'nav_lon'     , idmy )         , clinfo )
646               CALL iom_nf90_check( NF90_PUT_VAR  ( if90id, idmy, glamt(ix1:ix2, iy1:iy2) ), clinfo )
647               CALL iom_nf90_check( NF90_INQ_VARID( if90id, 'nav_lat'     , idmy )         , clinfo )
648               CALL iom_nf90_check( NF90_PUT_VAR  ( if90id, idmy, gphit(ix1:ix2, iy1:iy2) ), clinfo )
649               CALL iom_nf90_check( NF90_INQ_VARID( if90id, 'nav_lev'     , idmy ), clinfo )
650               CALL iom_nf90_check( NF90_PUT_VAR  ( if90id, idmy, gdept_1d       ), clinfo )
651               IF( NF90_INQ_VARID( if90id, 'numcat', idmy ) == nf90_noerr ) THEN
652                  CALL iom_nf90_check( NF90_PUT_VAR  ( if90id, idmy, (/ (idlv, idlv = 1,iom_file(kiomid)%nlev) /)), clinfo )
653               ENDIF
654               ! +++ WRONG VALUE: to be improved but not really useful...
655               CALL iom_nf90_check( NF90_INQ_VARID( if90id, 'time_counter', idmy ), clinfo )
656               CALL iom_nf90_check( NF90_PUT_VAR( if90id, idmy, kt                      ), clinfo )   
657               ! update the values of the variables dimensions size
658               CALL iom_nf90_check( NF90_INQUIRE_DIMENSION( if90id, 1, len = iom_file(kiomid)%dimsz(1,1) ), clinfo )
659               CALL iom_nf90_check( NF90_INQUIRE_DIMENSION( if90id, 2, len = iom_file(kiomid)%dimsz(2,1) ), clinfo )
660               iom_file(kiomid)%dimsz(1:2, 2) = iom_file(kiomid)%dimsz(1:2, 1)
661               CALL iom_nf90_check( NF90_INQUIRE_DIMENSION( if90id, 3, len = iom_file(kiomid)%dimsz(1,3) ), clinfo )
662               iom_file(kiomid)%dimsz(1  , 4) = 1   ! unlimited dimension
663               IF(lwp) WRITE(numout,*) TRIM(clinfo)//' write dimension variables done'
664            ENDIF
665         ENDIF
666
667         ! write the data
668         ! =============
669         IF(     PRESENT(pv_r0d) ) THEN
670            CALL iom_nf90_check( NF90_PUT_VAR( if90id, idvar, pv_r0d                    ), clinfo )
671         ELSEIF( PRESENT(pv_r1d) ) THEN
672            CALL iom_nf90_check( NF90_PUT_VAR( if90id, idvar, pv_r1d(:)                 ), clinfo )
673         ELSEIF( PRESENT(pv_r2d) ) THEN
674            CALL iom_nf90_check( NF90_PUT_VAR( if90id, idvar, pv_r2d(ix1:ix2,iy1:iy2)   ), clinfo )
675         ELSEIF( PRESENT(pv_r3d) ) THEN
676            CALL iom_nf90_check( NF90_PUT_VAR( if90id, idvar, pv_r3d(ix1:ix2,iy1:iy2,:) ), clinfo )
677         ENDIF
678         ! add 1 to the size of the temporal dimension (not really useful...)
679         IF( iom_file(kiomid)%luld(idvar) )   iom_file(kiomid)%dimsz(iom_file(kiomid)%ndims(idvar), idvar)    &
680               &                            = iom_file(kiomid)%dimsz(iom_file(kiomid)%ndims(idvar), idvar) + 1
681         IF(lwp) WRITE(numout,*) TRIM(clinfo)//' written ok'
682      ENDIF
683      !     
684   END SUBROUTINE iom_nf90_rp0123d
685
686
687   SUBROUTINE iom_nf90_check( kstatus, cdinfo )
688      !!--------------------------------------------------------------------
689      !!                   ***  SUBROUTINE iom_nf90_check  ***
690      !!
691      !! ** Purpose :   check nf90 errors
692      !!--------------------------------------------------------------------
693      INTEGER,          INTENT(in) :: kstatus
694      CHARACTER(LEN=*), INTENT(in) :: cdinfo
695      !---------------------------------------------------------------------
696      IF(kstatus /= nf90_noerr)   CALL ctl_stop( 'iom_nf90_check : '//TRIM(nf90_strerror(kstatus)), TRIM(cdinfo) )
697   END SUBROUTINE iom_nf90_check
698
699   !!======================================================================
700END MODULE iom_nf90
Note: See TracBrowser for help on using the repository browser.