source: NEMO/branches/2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps/src/OCE/DYN/dynadv_cen2.F90 @ 10874

Last change on this file since 10874 was 10874, checked in by davestorkey, 20 months ago

branches/2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps : Revert all changes so far in preparation for implementation of new design.

  • Property svn:keywords set to Id
File size: 7.1 KB
Line 
1MODULE dynadv_cen2
2   !!======================================================================
3   !!                       ***  MODULE  dynadv  ***
4   !! Ocean dynamics: Update the momentum trend with the flux form advection
5   !!                 using a 2nd order centred scheme
6   !!======================================================================
7   !! History :  2.0  ! 2006-08  (G. Madec, S. Theetten)  Original code
8   !!            3.2  ! 2009-07  (R. Benshila)  Suppression of rigid-lid option
9   !!----------------------------------------------------------------------
10
11   !!----------------------------------------------------------------------
12   !!   dyn_adv_cen2  : flux form momentum advection (ln_dynadv_cen2=T) using a 2nd order centred scheme 
13   !!----------------------------------------------------------------------
14   USE oce            ! ocean dynamics and tracers
15   USE dom_oce        ! ocean space and time domain
16   USE trd_oce        ! trends: ocean variables
17   USE trddyn         ! trend manager: dynamics
18   !
19   USE in_out_manager ! I/O manager
20   USE lib_mpp        ! MPP library
21   USE prtctl         ! Print control
22
23   IMPLICIT NONE
24   PRIVATE
25
26   PUBLIC   dyn_adv_cen2   ! routine called by step.F90
27
28   !! * Substitutions
29#  include "vectopt_loop_substitute.h90"
30   !!----------------------------------------------------------------------
31   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
32   !! $Id$
33   !! Software governed by the CeCILL license (see ./LICENSE)
34   !!----------------------------------------------------------------------
35CONTAINS
36
37   SUBROUTINE dyn_adv_cen2( kt )
38      !!----------------------------------------------------------------------
39      !!                  ***  ROUTINE dyn_adv_cen2  ***
40      !!
41      !! ** Purpose :   Compute the now momentum advection trend in flux form
42      !!              and the general trend of the momentum equation.
43      !!
44      !! ** Method  :   Trend evaluated using now fields (centered in time)
45      !!
46      !! ** Action  :   (ua,va) updated with the now vorticity term trend
47      !!----------------------------------------------------------------------
48      INTEGER, INTENT( in ) ::   kt   ! ocean time-step index
49      !
50      INTEGER  ::   ji, jj, jk   ! dummy loop indices
51      REAL(wp), DIMENSION(jpi,jpj,jpk) ::  zfu_t, zfu_f, zfu_uw, zfu
52      REAL(wp), DIMENSION(jpi,jpj,jpk) ::  zfv_t, zfv_f, zfv_vw, zfv, zfw
53      !!----------------------------------------------------------------------
54      !
55      IF( kt == nit000 .AND. lwp ) THEN
56         WRITE(numout,*)
57         WRITE(numout,*) 'dyn_adv_cen2 : 2nd order flux form momentum advection'
58         WRITE(numout,*) '~~~~~~~~~~~~'
59      ENDIF
60      !
61      IF( l_trddyn ) THEN           ! trends: store the input trends
62         zfu_uw(:,:,:) = ua(:,:,:)
63         zfv_vw(:,:,:) = va(:,:,:)
64      ENDIF
65      !
66      !                             !==  Horizontal advection  ==!
67      !
68      DO jk = 1, jpkm1                    ! horizontal transport
69         zfu(:,:,jk) = 0.25_wp * e2u(:,:) * e3u_n(:,:,jk) * un(:,:,jk)
70         zfv(:,:,jk) = 0.25_wp * e1v(:,:) * e3v_n(:,:,jk) * vn(:,:,jk)
71         DO jj = 1, jpjm1                 ! horizontal momentum fluxes (at T- and F-point)
72            DO ji = 1, fs_jpim1   ! vector opt.
73               zfu_t(ji+1,jj  ,jk) = ( zfu(ji,jj,jk) + zfu(ji+1,jj,jk) ) * ( un(ji,jj,jk) + un(ji+1,jj  ,jk) )
74               zfv_f(ji  ,jj  ,jk) = ( zfv(ji,jj,jk) + zfv(ji+1,jj,jk) ) * ( un(ji,jj,jk) + un(ji  ,jj+1,jk) )
75               zfu_f(ji  ,jj  ,jk) = ( zfu(ji,jj,jk) + zfu(ji,jj+1,jk) ) * ( vn(ji,jj,jk) + vn(ji+1,jj  ,jk) )
76               zfv_t(ji  ,jj+1,jk) = ( zfv(ji,jj,jk) + zfv(ji,jj+1,jk) ) * ( vn(ji,jj,jk) + vn(ji  ,jj+1,jk) )
77            END DO
78         END DO
79         DO jj = 2, jpjm1                 ! divergence of horizontal momentum fluxes
80            DO ji = fs_2, fs_jpim1   ! vector opt.
81               ua(ji,jj,jk) = ua(ji,jj,jk) - (  zfu_t(ji+1,jj,jk) - zfu_t(ji,jj  ,jk)    &
82                  &                           + zfv_f(ji  ,jj,jk) - zfv_f(ji,jj-1,jk)  ) * r1_e1e2u(ji,jj) / e3u_n(ji,jj,jk)
83               va(ji,jj,jk) = va(ji,jj,jk) - (  zfu_f(ji,jj  ,jk) - zfu_f(ji-1,jj,jk)    &
84                  &                           + zfv_t(ji,jj+1,jk) - zfv_t(ji  ,jj,jk)  ) * r1_e1e2v(ji,jj) / e3v_n(ji,jj,jk)
85            END DO
86         END DO
87      END DO
88      !
89      IF( l_trddyn ) THEN           ! trends: send trend to trddyn for diagnostic
90         zfu_uw(:,:,:) = ua(:,:,:) - zfu_uw(:,:,:)
91         zfv_vw(:,:,:) = va(:,:,:) - zfv_vw(:,:,:)
92         CALL trd_dyn( zfu_uw, zfv_vw, jpdyn_keg, kt )
93         zfu_t(:,:,:) = ua(:,:,:)
94         zfv_t(:,:,:) = va(:,:,:)
95      ENDIF
96      !
97      !                             !==  Vertical advection  ==!
98      !
99      DO jj = 2, jpjm1                    ! surface/bottom advective fluxes set to zero
100         DO ji = fs_2, fs_jpim1
101            zfu_uw(ji,jj,jpk) = 0._wp   ;   zfv_vw(ji,jj,jpk) = 0._wp
102            zfu_uw(ji,jj, 1 ) = 0._wp   ;   zfv_vw(ji,jj, 1 ) = 0._wp
103         END DO
104      END DO
105      IF( ln_linssh ) THEN                ! linear free surface: advection through the surface
106         DO jj = 2, jpjm1
107            DO ji = fs_2, fs_jpim1
108               zfu_uw(ji,jj,1) = 0.5_wp * ( e1e2t(ji,jj) * wn(ji,jj,1) + e1e2t(ji+1,jj) * wn(ji+1,jj,1) ) * un(ji,jj,1)
109               zfv_vw(ji,jj,1) = 0.5_wp * ( e1e2t(ji,jj) * wn(ji,jj,1) + e1e2t(ji,jj+1) * wn(ji,jj+1,1) ) * vn(ji,jj,1)
110            END DO
111         END DO
112      ENDIF
113      DO jk = 2, jpkm1                    ! interior advective fluxes
114         DO jj = 2, jpj                       ! 1/4 * Vertical transport
115            DO ji = 2, jpi
116               zfw(ji,jj,jk) = 0.25_wp * e1e2t(ji,jj) * wn(ji,jj,jk)
117            END DO
118         END DO
119         DO jj = 2, jpjm1
120            DO ji = fs_2, fs_jpim1   ! vector opt.
121               zfu_uw(ji,jj,jk) = ( zfw(ji,jj,jk) + zfw(ji+1,jj  ,jk) ) * ( un(ji,jj,jk) + un(ji,jj,jk-1) )
122               zfv_vw(ji,jj,jk) = ( zfw(ji,jj,jk) + zfw(ji  ,jj+1,jk) ) * ( vn(ji,jj,jk) + vn(ji,jj,jk-1) )
123            END DO
124         END DO
125      END DO
126      DO jk = 1, jpkm1                    ! divergence of vertical momentum flux divergence
127         DO jj = 2, jpjm1 
128            DO ji = fs_2, fs_jpim1   ! vector opt.
129               ua(ji,jj,jk) = ua(ji,jj,jk) - ( zfu_uw(ji,jj,jk) - zfu_uw(ji,jj,jk+1) ) * r1_e1e2u(ji,jj) / e3u_n(ji,jj,jk)
130               va(ji,jj,jk) = va(ji,jj,jk) - ( zfv_vw(ji,jj,jk) - zfv_vw(ji,jj,jk+1) ) * r1_e1e2v(ji,jj) / e3v_n(ji,jj,jk)
131            END DO
132         END DO
133      END DO
134      !
135      IF( l_trddyn ) THEN                 ! trends: send trend to trddyn for diagnostic
136         zfu_t(:,:,:) = ua(:,:,:) - zfu_t(:,:,:)
137         zfv_t(:,:,:) = va(:,:,:) - zfv_t(:,:,:)
138         CALL trd_dyn( zfu_t, zfv_t, jpdyn_zad, kt )
139      ENDIF
140      !                                   ! Control print
141      IF(ln_ctl)   CALL prt_ctl( tab3d_1=ua, clinfo1=' cen2 adv - Ua: ', mask1=umask,   &
142         &                       tab3d_2=va, clinfo2=           ' Va: ', mask2=vmask, clinfo3='dyn' )
143      !
144   END SUBROUTINE dyn_adv_cen2
145
146   !!==============================================================================
147END MODULE dynadv_cen2
Note: See TracBrowser for help on using the repository browser.