New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv_mus.F90 in NEMO/branches/2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps/src/OCE/TRA – NEMO

source: NEMO/branches/2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps/src/OCE/TRA/traadv_mus.F90 @ 10806

Last change on this file since 10806 was 10806, checked in by davestorkey, 5 years ago

2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps branch: Latest updates. Make sure all time-dependent 3D variables are converted in previously modified modules.
  • Property svn:keywords set to Id
File size: 15.3 KB
Line 
1MODULE traadv_mus
2   !!======================================================================
3   !!                       ***  MODULE  traadv_mus  ***
4   !! Ocean  tracers:  horizontal & vertical advective trend
5   !!======================================================================
6   !! History :       !  2000-06  (A.Estublier)  for passive tracers
7   !!                 !  2001-08  (E.Durand, G.Madec)  adapted for T & S
8   !!   NEMO     1.0  !  2002-06  (G. Madec)  F90: Free form and module
9   !!            3.2  !  2010-05  (C. Ethe, G. Madec)  merge TRC-TRA + switch from velocity to transport
10   !!            3.4  !  2012-06  (P. Oddo, M. Vichi) include the upstream where needed
11   !!            3.7  !  2015-09  (G. Madec) add the ice-shelf cavities boundary condition
12   !!----------------------------------------------------------------------
13
14   !!----------------------------------------------------------------------
15   !!   tra_adv_mus   : update the tracer trend with the horizontal
16   !!                   and vertical advection trends using MUSCL scheme
17   !!----------------------------------------------------------------------
18   USE oce            ! ocean dynamics and active tracers
19   USE trc_oce        ! share passive tracers/Ocean variables
20   USE dom_oce        ! ocean space and time domain
21   USE trd_oce        ! trends: ocean variables
22   USE trdtra         ! tracers trends manager
23   USE sbcrnf         ! river runoffs
24   USE diaptr         ! poleward transport diagnostics
25   USE diaar5         ! AR5 diagnostics
26
27   !
28   USE iom            ! XIOS library
29   USE in_out_manager ! I/O manager
30   USE lib_mpp        ! distribued memory computing
31   USE lbclnk         ! ocean lateral boundary condition (or mpp link)
32   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
33
34   IMPLICIT NONE
35   PRIVATE
36
37   PUBLIC   tra_adv_mus   ! routine called by traadv.F90
38   
39   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   upsmsk   !: mixed upstream/centered scheme near some straits
40   !                                                           !  and in closed seas (orca 2 and 1 configurations)
41   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   xind     !: mixed upstream/centered index
42   
43   LOGICAL  ::   l_trd   ! flag to compute trends
44   LOGICAL  ::   l_ptr   ! flag to compute poleward transport
45   LOGICAL  ::   l_hst   ! flag to compute heat/salt transport
46
47   !! * Substitutions
48#  include "vectopt_loop_substitute.h90"
49   !!----------------------------------------------------------------------
50   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
51   !! $Id$
52   !! Software governed by the CeCILL license (see ./LICENSE)
53   !!----------------------------------------------------------------------
54CONTAINS
55
56   SUBROUTINE tra_adv_mus( kt, kit000, ktlev, kt2lev, cdtype, p2dt, pu, pv, pw,             &
57      &                                                             pt, pt_rhs, kjpt, ld_msc_ups )
58      !!----------------------------------------------------------------------
59      !!                    ***  ROUTINE tra_adv_mus  ***
60      !!
61      !! ** Purpose :   Compute the now trend due to total advection of tracers
62      !!              using a MUSCL scheme (Monotone Upstream-centered Scheme for
63      !!              Conservation Laws) and add it to the general tracer trend.
64      !!
65      !! ** Method  : MUSCL scheme plus centered scheme at ocean boundaries
66      !!              ld_msc_ups=T :
67      !!
68      !! ** Action : - update pt_rhs  with the now advective tracer trends
69      !!             - send trends to trdtra module for further diagnostcs (l_trdtra=T)
70      !!             - htr_adv, str_adv : poleward advective heat and salt transport (ln_diaptr=T)
71      !!
72      !! References : Estubier, A., and M. Levy, Notes Techn. Pole de Modelisation
73      !!              IPSL, Sept. 2000 (http://www.lodyc.jussieu.fr/opa)
74      !!----------------------------------------------------------------------
75      INTEGER                              , INTENT(in   ) ::   kt              ! ocean time-step index
76      INTEGER                              , INTENT(in   ) ::   kit000          ! first time step index
77      INTEGER                              , INTENT(in   ) ::   ktlev           ! time level index for 3-time-level source terms
78      INTEGER                              , INTENT(in   ) ::   kt2lev          ! time level index for 2-time-level source terms
79      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
80      INTEGER                              , INTENT(in   ) ::   kjpt            ! number of tracers
81      LOGICAL                              , INTENT(in   ) ::   ld_msc_ups      ! use upstream scheme within muscl
82      REAL(wp)                             , INTENT(in   ) ::   p2dt            ! tracer time-step
83      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ) ::   pu, pv, pw   ! 3 ocean velocity components
84      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   pt             ! before tracer field
85      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pt_rhs             ! tracer trend
86      !
87      INTEGER  ::   ji, jj, jk, jn   ! dummy loop indices
88      INTEGER  ::   ierr             ! local integer
89      REAL(wp) ::   zu, z0u, zzwx, zw , zalpha   ! local scalars
90      REAL(wp) ::   zv, z0v, zzwy, z0w           !   -      -
91      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zwx, zslpx   ! 3D workspace
92      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zwy, zslpy   ! -      -
93      !!----------------------------------------------------------------------
94      !
95      IF( kt == kit000 )  THEN
96         IF(lwp) WRITE(numout,*)
97         IF(lwp) WRITE(numout,*) 'tra_adv : MUSCL advection scheme on ', cdtype
98         IF(lwp) WRITE(numout,*) '        : mixed up-stream           ', ld_msc_ups
99         IF(lwp) WRITE(numout,*) '~~~~~~~'
100         IF(lwp) WRITE(numout,*)
101         !
102         ! Upstream / MUSCL scheme indicator
103         !
104         ALLOCATE( xind(jpi,jpj,jpk), STAT=ierr )
105         xind(:,:,:) = 1._wp              ! set equal to 1 where up-stream is not needed
106         !
107         IF( ld_msc_ups ) THEN            ! define the upstream indicator (if asked)
108            ALLOCATE( upsmsk(jpi,jpj), STAT=ierr )
109            upsmsk(:,:) = 0._wp                             ! not upstream by default
110            !
111            DO jk = 1, jpkm1
112               xind(:,:,jk) = 1._wp                              &                 ! =>1 where up-stream is not needed
113                  &         - MAX ( rnfmsk(:,:) * rnfmsk_z(jk),  &                 ! =>0 near runoff mouths (& closed sea outflows)
114                  &                 upsmsk(:,:)                ) * tmask(:,:,jk)   ! =>0 in some user defined area
115            END DO
116         ENDIF 
117         !
118      ENDIF 
119      !     
120      l_trd = .FALSE.
121      l_hst = .FALSE.
122      l_ptr = .FALSE.
123      IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR. ( cdtype == 'TRC' .AND. l_trdtrc ) )      l_trd = .TRUE.
124      IF(   cdtype == 'TRA' .AND. ln_diaptr )                                               l_ptr = .TRUE. 
125      IF(   cdtype == 'TRA' .AND. ( iom_use("uadv_heattr") .OR. iom_use("vadv_heattr") .OR. &
126         &                          iom_use("uadv_salttr") .OR. iom_use("vadv_salttr")  ) ) l_hst = .TRUE.
127      !
128      DO jn = 1, kjpt            !==  loop over the tracers  ==!
129         !
130         !                          !* Horizontal advective fluxes
131         !
132         !                                !-- first guess of the slopes
133         zwx(:,:,jpk) = 0._wp                   ! bottom values
134         zwy(:,:,jpk) = 0._wp 
135         DO jk = 1, jpkm1                       ! interior values
136            DO jj = 1, jpjm1     
137               DO ji = 1, fs_jpim1   ! vector opt.
138                  zwx(ji,jj,jk) = umask(ji,jj,jk) * ( pt(ji+1,jj,jk,jn) - pt(ji,jj,jk,jn) )
139                  zwy(ji,jj,jk) = vmask(ji,jj,jk) * ( pt(ji,jj+1,jk,jn) - pt(ji,jj,jk,jn) )
140               END DO
141           END DO
142         END DO
143         ! lateral boundary conditions   (changed sign)
144         CALL lbc_lnk_multi( 'traadv_mus', zwx, 'U', -1. , zwy, 'V', -1. )
145         !                                !-- Slopes of tracer
146         zslpx(:,:,jpk) = 0._wp                 ! bottom values
147         zslpy(:,:,jpk) = 0._wp
148         DO jk = 1, jpkm1                       ! interior values
149            DO jj = 2, jpj
150               DO ji = fs_2, jpi   ! vector opt.
151                  zslpx(ji,jj,jk) =                    ( zwx(ji,jj,jk) + zwx(ji-1,jj  ,jk) )   &
152                     &            * ( 0.25 + SIGN( 0.25, zwx(ji,jj,jk) * zwx(ji-1,jj  ,jk) ) )
153                  zslpy(ji,jj,jk) =                    ( zwy(ji,jj,jk) + zwy(ji  ,jj-1,jk) )   &
154                     &            * ( 0.25 + SIGN( 0.25, zwy(ji,jj,jk) * zwy(ji  ,jj-1,jk) ) )
155               END DO
156            END DO
157         END DO
158         !
159         DO jk = 1, jpkm1                 !-- Slopes limitation
160            DO jj = 2, jpj
161               DO ji = fs_2, jpi   ! vector opt.
162                  zslpx(ji,jj,jk) = SIGN( 1., zslpx(ji,jj,jk) ) * MIN(    ABS( zslpx(ji  ,jj,jk) ),   &
163                     &                                                 2.*ABS( zwx  (ji-1,jj,jk) ),   &
164                     &                                                 2.*ABS( zwx  (ji  ,jj,jk) ) )
165                  zslpy(ji,jj,jk) = SIGN( 1., zslpy(ji,jj,jk) ) * MIN(    ABS( zslpy(ji,jj  ,jk) ),   &
166                     &                                                 2.*ABS( zwy  (ji,jj-1,jk) ),   &
167                     &                                                 2.*ABS( zwy  (ji,jj  ,jk) ) )
168               END DO
169           END DO
170         END DO
171         !
172         DO jk = 1, jpkm1                 !-- MUSCL horizontal advective fluxes
173            DO jj = 2, jpjm1
174               DO ji = fs_2, fs_jpim1   ! vector opt.
175                  ! MUSCL fluxes
176                  z0u = SIGN( 0.5, pu(ji,jj,jk) )
177                  zalpha = 0.5 - z0u
178                  zu  = z0u - 0.5 * pu(ji,jj,jk) * p2dt * r1_e1e2u(ji,jj) / e3u(ji,jj,jk,ktlev)
179                  zzwx = pt(ji+1,jj,jk,jn) + xind(ji,jj,jk) * zu * zslpx(ji+1,jj,jk)
180                  zzwy = pt(ji  ,jj,jk,jn) + xind(ji,jj,jk) * zu * zslpx(ji  ,jj,jk)
181                  zwx(ji,jj,jk) = pu(ji,jj,jk) * ( zalpha * zzwx + (1.-zalpha) * zzwy )
182                  !
183                  z0v = SIGN( 0.5, pv(ji,jj,jk) )
184                  zalpha = 0.5 - z0v
185                  zv  = z0v - 0.5 * pv(ji,jj,jk) * p2dt * r1_e1e2v(ji,jj) / e3v(ji,jj,jk,ktlev)
186                  zzwx = pt(ji,jj+1,jk,jn) + xind(ji,jj,jk) * zv * zslpy(ji,jj+1,jk)
187                  zzwy = pt(ji,jj  ,jk,jn) + xind(ji,jj,jk) * zv * zslpy(ji,jj  ,jk)
188                  zwy(ji,jj,jk) = pv(ji,jj,jk) * ( zalpha * zzwx + (1.-zalpha) * zzwy )
189               END DO
190            END DO
191         END DO
192         CALL lbc_lnk_multi( 'traadv_mus', zwx, 'U', -1. , zwy, 'V', -1. )   ! lateral boundary conditions   (changed sign)
193         !
194         DO jk = 1, jpkm1                 !-- Tracer advective trend
195            DO jj = 2, jpjm1     
196               DO ji = fs_2, fs_jpim1   ! vector opt.
197                  pt_rhs(ji,jj,jk,jn) = pt_rhs(ji,jj,jk,jn) - ( zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )       &
198                  &                                     + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  ) )     &
199                  &                                   * r1_e1e2t(ji,jj) / e3t(ji,jj,jk,ktlev)
200               END DO
201           END DO
202         END DO       
203         !                                ! trend diagnostics
204         IF( l_trd )  THEN
205            CALL trd_tra( kt, cdtype, jn, jptra_xad, zwx, pu, pt(:,:,:,jn) )
206            CALL trd_tra( kt, cdtype, jn, jptra_yad, zwy, pv, pt(:,:,:,jn) )
207         END IF
208         !                                 ! "Poleward" heat and salt transports
209         IF( l_ptr )  CALL dia_ptr_hst( jn, 'adv', zwy(:,:,:) )
210         !                                 !  heat transport
211         IF( l_hst )  CALL dia_ar5_hst( jn, 'adv', zwx(:,:,:), zwy(:,:,:) )
212         !
213         !                          !* Vertical advective fluxes
214         !
215         !                                !-- first guess of the slopes
216         zwx(:,:, 1 ) = 0._wp                   ! surface & bottom boundary conditions
217         zwx(:,:,jpk) = 0._wp
218         DO jk = 2, jpkm1                       ! interior values
219            zwx(:,:,jk) = tmask(:,:,jk) * ( pt(:,:,jk-1,jn) - pt(:,:,jk,jn) )
220         END DO
221         !                                !-- Slopes of tracer
222         zslpx(:,:,1) = 0._wp                   ! surface values
223         DO jk = 2, jpkm1                       ! interior value
224            DO jj = 1, jpj
225               DO ji = 1, jpi
226                  zslpx(ji,jj,jk) =                     ( zwx(ji,jj,jk) + zwx(ji,jj,jk+1) )  &
227                     &            * (  0.25 + SIGN( 0.25, zwx(ji,jj,jk) * zwx(ji,jj,jk+1) )  )
228               END DO
229            END DO
230         END DO
231         DO jk = 2, jpkm1                 !-- Slopes limitation
232            DO jj = 1, jpj                      ! interior values
233               DO ji = 1, jpi
234                  zslpx(ji,jj,jk) = SIGN( 1., zslpx(ji,jj,jk) ) * MIN(    ABS( zslpx(ji,jj,jk  ) ),   &
235                     &                                                 2.*ABS( zwx  (ji,jj,jk+1) ),   &
236                     &                                                 2.*ABS( zwx  (ji,jj,jk  ) )  )
237               END DO
238            END DO
239         END DO
240         DO jk = 1, jpk-2                 !-- vertical advective flux
241            DO jj = 2, jpjm1     
242               DO ji = fs_2, fs_jpim1   ! vector opt.
243                  z0w = SIGN( 0.5, pw(ji,jj,jk+1) )
244                  zalpha = 0.5 + z0w
245                  zw  = z0w - 0.5 * pw(ji,jj,jk+1) * p2dt * r1_e1e2t(ji,jj) / e3w(ji,jj,jk+1,kt2lev)
246                  zzwx = pt(ji,jj,jk+1,jn) + xind(ji,jj,jk) * zw * zslpx(ji,jj,jk+1)
247                  zzwy = pt(ji,jj,jk  ,jn) + xind(ji,jj,jk) * zw * zslpx(ji,jj,jk  )
248                  zwx(ji,jj,jk+1) = pw(ji,jj,jk+1) * ( zalpha * zzwx + (1.-zalpha) * zzwy ) * wmask(ji,jj,jk)
249               END DO
250            END DO
251         END DO
252         IF( ln_linssh ) THEN                   ! top values, linear free surface only
253            IF( ln_isfcav ) THEN                      ! ice-shelf cavities (top of the ocean)
254               DO jj = 1, jpj
255                  DO ji = 1, jpi
256                     zwx(ji,jj, mikt(ji,jj) ) = pw(ji,jj,mikt(ji,jj)) * pt(ji,jj,mikt(ji,jj),jn)
257                  END DO
258               END DO   
259            ELSE                                      ! no cavities: only at the ocean surface
260               zwx(:,:,1) = pw(:,:,1) * pt(:,:,1,jn)
261            ENDIF
262         ENDIF
263         !
264         DO jk = 1, jpkm1                 !-- vertical advective trend
265            DO jj = 2, jpjm1     
266               DO ji = fs_2, fs_jpim1   ! vector opt.
267                  pt_rhs(ji,jj,jk,jn) =  pt_rhs(ji,jj,jk,jn) - ( zwx(ji,jj,jk) - zwx(ji,jj,jk+1) ) * r1_e1e2t(ji,jj) / e3t(ji,jj,jk,ktlev)
268               END DO
269            END DO
270         END DO
271         !                                ! send trends for diagnostic
272         IF( l_trd )  CALL trd_tra( kt, cdtype, jn, jptra_zad, zwx, pw, pt(:,:,:,jn) )
273         !
274      END DO                     ! end of tracer loop
275      !
276   END SUBROUTINE tra_adv_mus
277
278   !!======================================================================
279END MODULE traadv_mus
Note: See TracBrowser for help on using the repository browser.