New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zsed.F90 in NEMO/branches/2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps/src/TOP/PISCES/P4Z – NEMO

source: NEMO/branches/2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps/src/TOP/PISCES/P4Z/p4zsed.F90 @ 11822

Last change on this file since 11822 was 11822, checked in by acc, 4 years ago

Branch 2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps. Sette tested updates to branch to align with trunk changes between 10721 and 11740. Sette tests are passing but results differ from branch before these changes (except for GYRE_PISCES and VORTEX) and branch results already differed from trunk because of algorithmic fixes. Will need more checks to confirm correctness.
  • Property svn:keywords set to Id
File size: 26.0 KB
Line 
1MODULE p4zsed
2   !!======================================================================
3   !!                         ***  MODULE p4sed  ***
4   !! TOP :   PISCES Compute loss of organic matter in the sediments
5   !!======================================================================
6   !! History :   1.0  !  2004-03 (O. Aumont) Original code
7   !!             2.0  !  2007-12 (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-06 (C. Ethe) USE of fldread
9   !!             3.5  !  2012-07 (O. Aumont) improvment of river input of nutrients
10   !!----------------------------------------------------------------------
11   !!   p4z_sed        :  Compute loss of organic matter in the sediments
12   !!----------------------------------------------------------------------
13   USE oce_trc         !  shared variables between ocean and passive tracers
14   USE trc             !  passive tracers common variables
15   USE sms_pisces      !  PISCES Source Minus Sink variables
16   USE p4zlim          !  Co-limitations of differents nutrients
17   USE p4zsbc          !  External source of nutrients
18   USE p4zint          !  interpolation and computation of various fields
19   USE sed             !  Sediment module
20   USE iom             !  I/O manager
21   USE prtctl_trc      !  print control for debugging
22
23   IMPLICIT NONE
24   PRIVATE
25
26   PUBLIC   p4z_sed 
27   PUBLIC   p4z_sed_alloc
28 
29   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: nitrpot    !: Nitrogen fixation
30   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:  ) :: sdenit     !: Nitrate reduction in the sediments
31   REAL(wp) :: r1_rday                  !: inverse of rday
32   LOGICAL, SAVE :: lk_sed
33
34   !!----------------------------------------------------------------------
35   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
36   !! $Id$
37   !! Software governed by the CeCILL license (see ./LICENSE)
38   !!----------------------------------------------------------------------
39CONTAINS
40
41   SUBROUTINE p4z_sed( kt, knt, Kbb, Kmm, Krhs )
42      !!---------------------------------------------------------------------
43      !!                     ***  ROUTINE p4z_sed  ***
44      !!
45      !! ** Purpose :   Compute loss of organic matter in the sediments. This
46      !!              is by no way a sediment model. The loss is simply
47      !!              computed to balance the inout from rivers and dust
48      !!
49      !! ** Method  : - ???
50      !!---------------------------------------------------------------------
51      !
52      INTEGER, INTENT(in) ::   kt, knt ! ocean time step
53      INTEGER, INTENT(in) ::   Kbb, Kmm, Krhs  ! time level indices
54      INTEGER  ::  ji, jj, jk, ikt
55      REAL(wp) ::  zrivalk, zrivsil, zrivno3
56      REAL(wp) ::  zwflux, zlim, zfact, zfactcal
57      REAL(wp) ::  zo2, zno3, zflx, zpdenit, z1pdenit, zolimit
58      REAL(wp) ::  zsiloss, zcaloss, zws3, zws4, zwsc, zdep
59      REAL(wp) ::  zwstpoc, zwstpon, zwstpop
60      REAL(wp) ::  ztrfer, ztrpo4s, ztrdp, zwdust, zmudia, ztemp
61      REAL(wp) ::  xdiano3, xdianh4
62      !
63      CHARACTER (len=25) :: charout
64      REAL(wp), DIMENSION(jpi,jpj    ) :: zdenit2d, zbureff, zwork
65      REAL(wp), DIMENSION(jpi,jpj    ) :: zwsbio3, zwsbio4
66      REAL(wp), DIMENSION(jpi,jpj    ) :: zsedcal, zsedsi, zsedc
67      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zsoufer, zlight
68      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) :: ztrpo4, ztrdop, zirondep, zpdep
69      REAL(wp), ALLOCATABLE, DIMENSION(:,:  ) :: zsidep, zironice
70      !!---------------------------------------------------------------------
71      !
72      IF( ln_timing )  CALL timing_start('p4z_sed')
73      !
74      IF( kt == nittrc000 .AND. knt == 1 )   THEN
75          r1_rday  = 1. / rday
76          IF (ln_sediment .AND. ln_sed_2way) THEN
77             lk_sed = .TRUE.
78          ELSE
79             lk_sed = .FALSE.
80          ENDIF
81      ENDIF
82      !
83      IF( kt == nittrc000 .AND. knt == 1 )   r1_rday  = 1. / rday
84      !
85      ! Allocate temporary workspace
86      ALLOCATE( ztrpo4(jpi,jpj,jpk) )
87      IF( ln_p5z )    ALLOCATE( ztrdop(jpi,jpj,jpk) )
88
89      zdenit2d(:,:) = 0.e0
90      zbureff (:,:) = 0.e0
91      zwork   (:,:) = 0.e0
92      zsedsi  (:,:) = 0.e0
93      zsedcal (:,:) = 0.e0
94      zsedc   (:,:) = 0.e0
95
96      ! Iron input/uptake due to sea ice : Crude parameterization based on Lancelot et al.
97      ! ----------------------------------------------------
98      IF( ln_ironice ) THEN 
99         !                                             
100         ALLOCATE( zironice(jpi,jpj) )
101         !                                             
102         DO jj = 1, jpj
103            DO ji = 1, jpi
104               zdep    = rfact2 / e3t(ji,jj,1,Kmm)
105               zwflux  = fmmflx(ji,jj) / 1000._wp
106               zironice(ji,jj) =  MAX( -0.99 * tr(ji,jj,1,jpfer,Kbb), -zwflux * icefeinput * zdep )
107            END DO
108         END DO
109         !
110         tr(:,:,1,jpfer,Krhs) = tr(:,:,1,jpfer,Krhs) + zironice(:,:) 
111         !
112         IF( lk_iomput .AND. knt == nrdttrc .AND. iom_use( "Ironice" ) )   &
113            &   CALL iom_put( "Ironice", zironice(:,:) * 1.e+3 * rfact2r * e3t(:,:,1,Kmm) * tmask(:,:,1) ) ! iron flux from ice
114         !
115         DEALLOCATE( zironice )
116         !                                             
117      ENDIF
118
119      ! Add the external input of nutrients from dust deposition
120      ! ----------------------------------------------------------
121      IF( ln_dust ) THEN
122         !                                             
123         ALLOCATE( zsidep(jpi,jpj), zpdep(jpi,jpj,jpk), zirondep(jpi,jpj,jpk) )
124         !                                              ! Iron and Si deposition at the surface
125         IF( ln_solub ) THEN
126            zirondep(:,:,1) = solub(:,:) * dust(:,:) * mfrac * rfact2 / e3t(:,:,1,Kmm) / 55.85 + 3.e-10 * r1_ryyss 
127         ELSE
128            zirondep(:,:,1) = dustsolub  * dust(:,:) * mfrac * rfact2 / e3t(:,:,1,Kmm) / 55.85 + 3.e-10 * r1_ryyss 
129         ENDIF
130         zsidep(:,:)   = 8.8 * 0.075 * dust(:,:) * mfrac * rfact2 / e3t(:,:,1,Kmm) / 28.1 
131         zpdep (:,:,1) = 0.1 * 0.021 * dust(:,:) * mfrac * rfact2 / e3t(:,:,1,Kmm) / 31. / po4r 
132         !                                              ! Iron solubilization of particles in the water column
133         !                                              ! dust in kg/m2/s ---> 1/55.85 to put in mol/Fe ;  wdust in m/j
134         zwdust = 0.03 * rday / ( wdust * 55.85 ) / ( 270. * rday )
135         DO jk = 2, jpkm1
136            zirondep(:,:,jk) = dust(:,:) * mfrac * zwdust * rfact2 * EXP( -gdept(:,:,jk,Kmm) / 540. )
137            zpdep   (:,:,jk) = zirondep(:,:,jk) * 0.023
138         END DO
139         !                                              ! Iron solubilization of particles in the water column
140         tr(:,:,1,jpsil,Krhs) = tr(:,:,1,jpsil,Krhs) + zsidep  (:,:)
141         DO jk = 1, jpkm1
142            tr(:,:,jk,jppo4,Krhs) = tr(:,:,jk,jppo4,Krhs) + zpdep   (:,:,jk)
143            tr(:,:,jk,jpfer,Krhs) = tr(:,:,jk,jpfer,Krhs) + zirondep(:,:,jk) 
144         ENDDO
145         !
146         IF( lk_iomput ) THEN
147            IF( knt == nrdttrc ) THEN
148                IF( iom_use( "Irondep" ) )   &
149                &  CALL iom_put( "Irondep", zirondep(:,:,1) * 1.e+3 * rfact2r * e3t(:,:,1,Kmm) * tmask(:,:,1) ) ! surface downward dust depo of iron
150                IF( iom_use( "pdust" ) )   &
151                &  CALL iom_put( "pdust"  , dust(:,:) / ( wdust * rday )  * tmask(:,:,1) ) ! dust concentration at surface
152            ENDIF
153         ENDIF
154         DEALLOCATE( zsidep, zpdep, zirondep )
155         !                                             
156      ENDIF
157     
158      ! Add the external input of nutrients from river
159      ! ----------------------------------------------------------
160      IF( ln_river ) THEN
161         DO jj = 1, jpj
162            DO ji = 1, jpi
163               DO jk = 1, nk_rnf(ji,jj)
164                  tr(ji,jj,jk,jppo4,Krhs) = tr(ji,jj,jk,jppo4,Krhs) +  rivdip(ji,jj) * rfact2
165                  tr(ji,jj,jk,jpno3,Krhs) = tr(ji,jj,jk,jpno3,Krhs) +  rivdin(ji,jj) * rfact2
166                  tr(ji,jj,jk,jpfer,Krhs) = tr(ji,jj,jk,jpfer,Krhs) +  rivdic(ji,jj) * 5.e-5 * rfact2
167                  tr(ji,jj,jk,jpsil,Krhs) = tr(ji,jj,jk,jpsil,Krhs) +  rivdsi(ji,jj) * rfact2
168                  tr(ji,jj,jk,jpdic,Krhs) = tr(ji,jj,jk,jpdic,Krhs) +  rivdic(ji,jj) * rfact2
169                  tr(ji,jj,jk,jptal,Krhs) = tr(ji,jj,jk,jptal,Krhs) +  ( rivalk(ji,jj) - rno3 * rivdin(ji,jj) ) * rfact2
170                  tr(ji,jj,jk,jpdoc,Krhs) = tr(ji,jj,jk,jpdoc,Krhs) +  rivdoc(ji,jj) * rfact2
171               ENDDO
172            ENDDO
173         ENDDO
174         IF (ln_ligand) THEN
175            DO jj = 1, jpj
176               DO ji = 1, jpi
177                  DO jk = 1, nk_rnf(ji,jj)
178                     tr(ji,jj,jk,jplgw,Krhs) = tr(ji,jj,jk,jplgw,Krhs) +  rivdic(ji,jj) * 5.e-5 * rfact2
179                  ENDDO
180               ENDDO
181            ENDDO
182         ENDIF
183         IF( ln_p5z ) THEN
184            DO jj = 1, jpj
185               DO ji = 1, jpi
186                  DO jk = 1, nk_rnf(ji,jj)
187                     tr(ji,jj,jk,jpdop,Krhs) = tr(ji,jj,jk,jpdop,Krhs) + rivdop(ji,jj) * rfact2
188                     tr(ji,jj,jk,jpdon,Krhs) = tr(ji,jj,jk,jpdon,Krhs) + rivdon(ji,jj) * rfact2
189                  ENDDO
190               ENDDO
191            ENDDO
192         ENDIF
193      ENDIF
194     
195      ! Add the external input of nutrients from nitrogen deposition
196      ! ----------------------------------------------------------
197      IF( ln_ndepo ) THEN
198         tr(:,:,1,jpno3,Krhs) = tr(:,:,1,jpno3,Krhs) + nitdep(:,:) * rfact2
199         tr(:,:,1,jptal,Krhs) = tr(:,:,1,jptal,Krhs) - rno3 * nitdep(:,:) * rfact2
200      ENDIF
201
202      ! Add the external input of iron from hydrothermal vents
203      ! ------------------------------------------------------
204      IF( ln_hydrofe ) THEN
205            tr(:,:,:,jpfer,Krhs) = tr(:,:,:,jpfer,Krhs) + hydrofe(:,:,:) * rfact2
206         IF( ln_ligand ) THEN
207            tr(:,:,:,jplgw,Krhs) = tr(:,:,:,jplgw,Krhs) + ( hydrofe(:,:,:) * lgw_rath ) * rfact2
208         ENDIF
209         !
210         IF( lk_iomput .AND. knt == nrdttrc .AND. iom_use( "HYDR" ) )   &
211            &   CALL iom_put( "HYDR", hydrofe(:,:,:) * 1.e+3 * tmask(:,:,:) ) ! hydrothermal iron input
212      ENDIF
213
214      ! OA: Warning, the following part is necessary to avoid CFL problems above the sediments
215      ! --------------------------------------------------------------------
216      DO jj = 1, jpj
217         DO ji = 1, jpi
218            ikt  = mbkt(ji,jj)
219            zdep = e3t(ji,jj,ikt,Kmm) / xstep
220            zwsbio4(ji,jj) = MIN( 0.99 * zdep, wsbio4(ji,jj,ikt) )
221            zwsbio3(ji,jj) = MIN( 0.99 * zdep, wsbio3(ji,jj,ikt) )
222         END DO
223      END DO
224      !
225      IF( .NOT.lk_sed ) THEN
226!
227         ! Add the external input of iron from sediment mobilization
228         ! ------------------------------------------------------
229         IF( ln_ironsed ) THEN
230                            tr(:,:,:,jpfer,Krhs) = tr(:,:,:,jpfer,Krhs) + ironsed(:,:,:) * rfact2
231            !
232            IF( lk_iomput .AND. knt == nrdttrc .AND. iom_use( "Ironsed" ) )   &
233               &   CALL iom_put( "Ironsed", ironsed(:,:,:) * 1.e+3 * tmask(:,:,:) ) ! iron inputs from sediments
234         ENDIF
235
236         ! Computation of the sediment denitrification proportion: The metamodel from midlleburg (2006) is being used
237         ! Computation of the fraction of organic matter that is permanently buried from Dunne's model
238         ! -------------------------------------------------------
239         DO jj = 1, jpj
240            DO ji = 1, jpi
241              IF( tmask(ji,jj,1) == 1 ) THEN
242                 ikt = mbkt(ji,jj)
243                 zflx = (  tr(ji,jj,ikt,jpgoc,Kbb) * zwsbio4(ji,jj)   &
244                   &     + tr(ji,jj,ikt,jppoc,Kbb) * zwsbio3(ji,jj) )  * 1E3 * 1E6 / 1E4
245                 zflx  = LOG10( MAX( 1E-3, zflx ) )
246                 zo2   = LOG10( MAX( 10. , tr(ji,jj,ikt,jpoxy,Kbb) * 1E6 ) )
247                 zno3  = LOG10( MAX( 1.  , tr(ji,jj,ikt,jpno3,Kbb) * 1E6 * rno3 ) )
248                 zdep  = LOG10( gdepw(ji,jj,ikt+1,Kmm) )
249                 zdenit2d(ji,jj) = -2.2567 - 1.185 * zflx - 0.221 * zflx**2 - 0.3995 * zno3 * zo2 + 1.25 * zno3    &
250                   &                + 0.4721 * zo2 - 0.0996 * zdep + 0.4256 * zflx * zo2
251                 zdenit2d(ji,jj) = 10.0**( zdenit2d(ji,jj) )
252                   !
253                 zflx = (  tr(ji,jj,ikt,jpgoc,Kbb) * zwsbio4(ji,jj)   &
254                   &     + tr(ji,jj,ikt,jppoc,Kbb) * zwsbio3(ji,jj) ) * 1E6
255                 zbureff(ji,jj) = 0.013 + 0.53 * zflx**2 / ( 7.0 + zflx )**2
256              ENDIF
257            END DO
258         END DO 
259         !
260      ENDIF
261
262      ! This loss is scaled at each bottom grid cell for equilibrating the total budget of silica in the ocean.
263      ! Thus, the amount of silica lost in the sediments equal the supply at the surface (dust+rivers)
264      ! ------------------------------------------------------
265      IF( .NOT.lk_sed )  zrivsil = 1._wp - sedsilfrac
266
267      DO jj = 1, jpj
268         DO ji = 1, jpi
269            ikt  = mbkt(ji,jj)
270            zdep = xstep / e3t(ji,jj,ikt,Kmm) 
271            zwsc = zwsbio4(ji,jj) * zdep
272            zsiloss = tr(ji,jj,ikt,jpgsi,Kbb) * zwsc
273            zcaloss = tr(ji,jj,ikt,jpcal,Kbb) * zwsc
274            !
275            tr(ji,jj,ikt,jpgsi,Krhs) = tr(ji,jj,ikt,jpgsi,Krhs) - zsiloss
276            tr(ji,jj,ikt,jpcal,Krhs) = tr(ji,jj,ikt,jpcal,Krhs) - zcaloss
277         END DO
278      END DO
279      !
280      IF( .NOT.lk_sed ) THEN
281         DO jj = 1, jpj
282            DO ji = 1, jpi
283               ikt  = mbkt(ji,jj)
284               zdep = xstep / e3t(ji,jj,ikt,Kmm) 
285               zwsc = zwsbio4(ji,jj) * zdep
286               zsiloss = tr(ji,jj,ikt,jpgsi,Kbb) * zwsc
287               zcaloss = tr(ji,jj,ikt,jpcal,Kbb) * zwsc
288               tr(ji,jj,ikt,jpsil,Krhs) = tr(ji,jj,ikt,jpsil,Krhs) + zsiloss * zrivsil 
289               !
290               zfactcal = MIN( excess(ji,jj,ikt), 0.2 )
291               zfactcal = MIN( 1., 1.3 * ( 0.2 - zfactcal ) / ( 0.4 - zfactcal ) )
292               zrivalk  = sedcalfrac * zfactcal
293               tr(ji,jj,ikt,jptal,Krhs) =  tr(ji,jj,ikt,jptal,Krhs) + zcaloss * zrivalk * 2.0
294               tr(ji,jj,ikt,jpdic,Krhs) =  tr(ji,jj,ikt,jpdic,Krhs) + zcaloss * zrivalk
295               zsedcal(ji,jj) = (1.0 - zrivalk) * zcaloss * e3t(ji,jj,ikt,Kmm) 
296               zsedsi (ji,jj) = (1.0 - zrivsil) * zsiloss * e3t(ji,jj,ikt,Kmm) 
297            END DO
298         END DO
299      ENDIF
300      !
301      DO jj = 1, jpj
302         DO ji = 1, jpi
303            ikt  = mbkt(ji,jj)
304            zdep = xstep / e3t(ji,jj,ikt,Kmm) 
305            zws4 = zwsbio4(ji,jj) * zdep
306            zws3 = zwsbio3(ji,jj) * zdep
307            tr(ji,jj,ikt,jpgoc,Krhs) = tr(ji,jj,ikt,jpgoc,Krhs) - tr(ji,jj,ikt,jpgoc,Kbb) * zws4 
308            tr(ji,jj,ikt,jppoc,Krhs) = tr(ji,jj,ikt,jppoc,Krhs) - tr(ji,jj,ikt,jppoc,Kbb) * zws3
309            tr(ji,jj,ikt,jpbfe,Krhs) = tr(ji,jj,ikt,jpbfe,Krhs) - tr(ji,jj,ikt,jpbfe,Kbb) * zws4
310            tr(ji,jj,ikt,jpsfe,Krhs) = tr(ji,jj,ikt,jpsfe,Krhs) - tr(ji,jj,ikt,jpsfe,Kbb) * zws3
311         END DO
312      END DO
313      !
314      IF( ln_p5z ) THEN
315         DO jj = 1, jpj
316            DO ji = 1, jpi
317               ikt  = mbkt(ji,jj)
318               zdep = xstep / e3t(ji,jj,ikt,Kmm) 
319               zws4 = zwsbio4(ji,jj) * zdep
320               zws3 = zwsbio3(ji,jj) * zdep
321               tr(ji,jj,ikt,jpgon,Krhs) = tr(ji,jj,ikt,jpgon,Krhs) - tr(ji,jj,ikt,jpgon,Kbb) * zws4
322               tr(ji,jj,ikt,jppon,Krhs) = tr(ji,jj,ikt,jppon,Krhs) - tr(ji,jj,ikt,jppon,Kbb) * zws3
323               tr(ji,jj,ikt,jpgop,Krhs) = tr(ji,jj,ikt,jpgop,Krhs) - tr(ji,jj,ikt,jpgop,Kbb) * zws4
324               tr(ji,jj,ikt,jppop,Krhs) = tr(ji,jj,ikt,jppop,Krhs) - tr(ji,jj,ikt,jppop,Kbb) * zws3
325            END DO
326         END DO
327      ENDIF
328
329      IF( .NOT.lk_sed ) THEN
330         ! The 0.5 factor in zpdenit is to avoid negative NO3 concentration after
331         ! denitrification in the sediments. Not very clever, but simpliest option.
332         DO jj = 1, jpj
333            DO ji = 1, jpi
334               ikt  = mbkt(ji,jj)
335               zdep = xstep / e3t(ji,jj,ikt,Kmm) 
336               zws4 = zwsbio4(ji,jj) * zdep
337               zws3 = zwsbio3(ji,jj) * zdep
338               zrivno3 = 1. - zbureff(ji,jj)
339               zwstpoc = tr(ji,jj,ikt,jpgoc,Kbb) * zws4 + tr(ji,jj,ikt,jppoc,Kbb) * zws3
340               zpdenit  = MIN( 0.5 * ( tr(ji,jj,ikt,jpno3,Kbb) - rtrn ) / rdenit, zdenit2d(ji,jj) * zwstpoc * zrivno3 )
341               z1pdenit = zwstpoc * zrivno3 - zpdenit
342               zolimit = MIN( ( tr(ji,jj,ikt,jpoxy,Kbb) - rtrn ) / o2ut, z1pdenit * ( 1.- nitrfac(ji,jj,ikt) ) )
343               tr(ji,jj,ikt,jpdoc,Krhs) = tr(ji,jj,ikt,jpdoc,Krhs) + z1pdenit - zolimit
344               tr(ji,jj,ikt,jppo4,Krhs) = tr(ji,jj,ikt,jppo4,Krhs) + zpdenit + zolimit
345               tr(ji,jj,ikt,jpnh4,Krhs) = tr(ji,jj,ikt,jpnh4,Krhs) + zpdenit + zolimit
346               tr(ji,jj,ikt,jpno3,Krhs) = tr(ji,jj,ikt,jpno3,Krhs) - rdenit * zpdenit
347               tr(ji,jj,ikt,jpoxy,Krhs) = tr(ji,jj,ikt,jpoxy,Krhs) - zolimit * o2ut
348               tr(ji,jj,ikt,jptal,Krhs) = tr(ji,jj,ikt,jptal,Krhs) + rno3 * (zolimit + (1.+rdenit) * zpdenit )
349               tr(ji,jj,ikt,jpdic,Krhs) = tr(ji,jj,ikt,jpdic,Krhs) + zpdenit + zolimit 
350               sdenit(ji,jj) = rdenit * zpdenit * e3t(ji,jj,ikt,Kmm)
351               zsedc(ji,jj)   = (1. - zrivno3) * zwstpoc * e3t(ji,jj,ikt,Kmm)
352               IF( ln_p5z ) THEN
353                  zwstpop              = tr(ji,jj,ikt,jpgop,Kbb) * zws4 + tr(ji,jj,ikt,jppop,Kbb) * zws3
354                  zwstpon              = tr(ji,jj,ikt,jpgon,Kbb) * zws4 + tr(ji,jj,ikt,jppon,Kbb) * zws3
355                  tr(ji,jj,ikt,jpdon,Krhs) = tr(ji,jj,ikt,jpdon,Krhs) + ( z1pdenit - zolimit ) * zwstpon / (zwstpoc + rtrn)
356                  tr(ji,jj,ikt,jpdop,Krhs) = tr(ji,jj,ikt,jpdop,Krhs) + ( z1pdenit - zolimit ) * zwstpop / (zwstpoc + rtrn)
357               ENDIF
358            END DO
359         END DO
360       ENDIF
361
362
363      ! Nitrogen fixation process
364      ! Small source iron from particulate inorganic iron
365      !-----------------------------------
366      DO jk = 1, jpkm1
367         zlight (:,:,jk) =  ( 1.- EXP( -etot_ndcy(:,:,jk) / diazolight ) ) * ( 1. - fr_i(:,:) ) 
368         zsoufer(:,:,jk) = zlight(:,:,jk) * 2E-11 / ( 2E-11 + biron(:,:,jk) )
369      ENDDO
370      IF( ln_p4z ) THEN
371         DO jk = 1, jpkm1
372            DO jj = 1, jpj
373               DO ji = 1, jpi
374                  !                      ! Potential nitrogen fixation dependant on temperature and iron
375                  ztemp = ts(ji,jj,jk,jp_tem,Kmm)
376                  zmudia = MAX( 0.,-0.001096*ztemp**2 + 0.057*ztemp -0.637 ) * 7.625
377                  !       Potential nitrogen fixation dependant on temperature and iron
378                  xdianh4 = tr(ji,jj,jk,jpnh4,Kbb) / ( concnnh4 + tr(ji,jj,jk,jpnh4,Kbb) )
379                  xdiano3 = tr(ji,jj,jk,jpno3,Kbb) / ( concnno3 + tr(ji,jj,jk,jpno3,Kbb) ) * (1. - xdianh4)
380                  zlim = ( 1.- xdiano3 - xdianh4 )
381                  IF( zlim <= 0.1 )   zlim = 0.01
382                  zfact = zlim * rfact2
383                  ztrfer = biron(ji,jj,jk) / ( concfediaz + biron(ji,jj,jk) )
384                  ztrpo4(ji,jj,jk) = tr(ji,jj,jk,jppo4,Kbb) / ( 1E-6 + tr(ji,jj,jk,jppo4,Kbb) )
385                  ztrdp = ztrpo4(ji,jj,jk)
386                  nitrpot(ji,jj,jk) =  zmudia * r1_rday * zfact * MIN( ztrfer, ztrdp ) * zlight(ji,jj,jk)
387               END DO
388            END DO
389         END DO
390      ELSE       ! p5z
391         DO jk = 1, jpkm1
392            DO jj = 1, jpj
393               DO ji = 1, jpi
394                  !                      ! Potential nitrogen fixation dependant on temperature and iron
395                  ztemp = ts(ji,jj,jk,jp_tem,Kmm)
396                  zmudia = MAX( 0.,-0.001096*ztemp**2 + 0.057*ztemp -0.637 ) * 7.625
397                  !       Potential nitrogen fixation dependant on temperature and iron
398                  xdianh4 = tr(ji,jj,jk,jpnh4,Kbb) / ( concnnh4 + tr(ji,jj,jk,jpnh4,Kbb) )
399                  xdiano3 = tr(ji,jj,jk,jpno3,Kbb) / ( concnno3 + tr(ji,jj,jk,jpno3,Kbb) ) * (1. - xdianh4)
400                  zlim = ( 1.- xdiano3 - xdianh4 )
401                  IF( zlim <= 0.1 )   zlim = 0.01
402                  zfact = zlim * rfact2
403                  ztrfer = biron(ji,jj,jk) / ( concfediaz + biron(ji,jj,jk) )
404                  ztrpo4(ji,jj,jk) = tr(ji,jj,jk,jppo4,Kbb) / ( 1E-6 + tr(ji,jj,jk,jppo4,Kbb) )
405                  ztrdop(ji,jj,jk) = tr(ji,jj,jk,jpdop,Kbb) / ( 1E-6 + tr(ji,jj,jk,jpdop,Kbb) ) * (1. - ztrpo4(ji,jj,jk))
406                  ztrdp = ztrpo4(ji,jj,jk) + ztrdop(ji,jj,jk)
407                  nitrpot(ji,jj,jk) =  zmudia * r1_rday * zfact * MIN( ztrfer, ztrdp ) * zlight(ji,jj,jk)
408               END DO
409            END DO
410         END DO
411      ENDIF
412
413      ! Nitrogen change due to nitrogen fixation
414      ! ----------------------------------------
415      IF( ln_p4z ) THEN
416         DO jk = 1, jpkm1
417            DO jj = 1, jpj
418               DO ji = 1, jpi
419                  zfact = nitrpot(ji,jj,jk) * nitrfix
420                  tr(ji,jj,jk,jpnh4,Krhs) = tr(ji,jj,jk,jpnh4,Krhs) + zfact / 3.0
421                  tr(ji,jj,jk,jptal,Krhs) = tr(ji,jj,jk,jptal,Krhs) + rno3 * zfact / 3.0
422                  tr(ji,jj,jk,jppo4,Krhs) = tr(ji,jj,jk,jppo4,Krhs) - zfact * 2.0 / 3.0
423                  tr(ji,jj,jk,jpdoc,Krhs) = tr(ji,jj,jk,jpdoc,Krhs) + zfact * 1.0 / 3.0
424                  tr(ji,jj,jk,jppoc,Krhs) = tr(ji,jj,jk,jppoc,Krhs) + zfact * 1.0 / 3.0 * 2.0 / 3.0
425                  tr(ji,jj,jk,jpgoc,Krhs) = tr(ji,jj,jk,jpgoc,Krhs) + zfact * 1.0 / 3.0 * 1.0 / 3.0
426                  tr(ji,jj,jk,jpoxy,Krhs) = tr(ji,jj,jk,jpoxy,Krhs) + ( o2ut + o2nit ) * zfact * 2.0 / 3.0 + o2nit * zfact / 3.0
427                  tr(ji,jj,jk,jpfer,Krhs) = tr(ji,jj,jk,jpfer,Krhs) - 30E-6 * zfact * 1.0 / 3.0
428                  tr(ji,jj,jk,jpsfe,Krhs) = tr(ji,jj,jk,jpsfe,Krhs) + 30E-6 * zfact * 1.0 / 3.0 * 2.0 / 3.0
429                  tr(ji,jj,jk,jpbfe,Krhs) = tr(ji,jj,jk,jpbfe,Krhs) + 30E-6 * zfact * 1.0 / 3.0 * 1.0 / 3.0
430                  tr(ji,jj,jk,jpfer,Krhs) = tr(ji,jj,jk,jpfer,Krhs) + 0.002 * 4E-10 * zsoufer(ji,jj,jk) * rfact2 / rday
431                  tr(ji,jj,jk,jppo4,Krhs) = tr(ji,jj,jk,jppo4,Krhs) + concdnh4 / ( concdnh4 + tr(ji,jj,jk,jppo4,Kbb) ) &
432                  &                     * 0.001 * tr(ji,jj,jk,jpdoc,Kbb) * xstep
433              END DO
434            END DO
435         END DO
436      ELSE    ! p5z
437         DO jk = 1, jpkm1
438            DO jj = 1, jpj
439               DO ji = 1, jpi
440                  zfact = nitrpot(ji,jj,jk) * nitrfix
441                  tr(ji,jj,jk,jpnh4,Krhs) = tr(ji,jj,jk,jpnh4,Krhs) + zfact / 3.0
442                  tr(ji,jj,jk,jptal,Krhs) = tr(ji,jj,jk,jptal,Krhs) + rno3 * zfact / 3.0
443                  tr(ji,jj,jk,jppo4,Krhs) = tr(ji,jj,jk,jppo4,Krhs) - 16.0 / 46.0 * zfact * ( 1.0 - 1.0 / 3.0 ) &
444                  &                     * ztrpo4(ji,jj,jk) / (ztrpo4(ji,jj,jk) + ztrdop(ji,jj,jk) + rtrn)
445                  tr(ji,jj,jk,jpdon,Krhs) = tr(ji,jj,jk,jpdon,Krhs) + zfact * 1.0 / 3.0
446                  tr(ji,jj,jk,jpdoc,Krhs) = tr(ji,jj,jk,jpdoc,Krhs) + zfact * 1.0 / 3.0
447                  tr(ji,jj,jk,jpdop,Krhs) = tr(ji,jj,jk,jpdop,Krhs) + 16.0 / 46.0 * zfact / 3.0  &
448                  &                     - 16.0 / 46.0 * zfact * ztrdop(ji,jj,jk)   &
449                  &                     / (ztrpo4(ji,jj,jk) + ztrdop(ji,jj,jk) + rtrn)
450                  tr(ji,jj,jk,jppoc,Krhs) = tr(ji,jj,jk,jppoc,Krhs) + zfact * 1.0 / 3.0 * 2.0 / 3.0
451                  tr(ji,jj,jk,jppon,Krhs) = tr(ji,jj,jk,jppon,Krhs) + zfact * 1.0 / 3.0 * 2.0 /3.0
452                  tr(ji,jj,jk,jppop,Krhs) = tr(ji,jj,jk,jppop,Krhs) + 16.0 / 46.0 * zfact * 1.0 / 3.0 * 2.0 /3.0
453                  tr(ji,jj,jk,jpgoc,Krhs) = tr(ji,jj,jk,jpgoc,Krhs) + zfact * 1.0 / 3.0 * 1.0 / 3.0
454                  tr(ji,jj,jk,jpgon,Krhs) = tr(ji,jj,jk,jpgon,Krhs) + zfact * 1.0 / 3.0 * 1.0 /3.0
455                  tr(ji,jj,jk,jpgop,Krhs) = tr(ji,jj,jk,jpgop,Krhs) + 16.0 / 46.0 * zfact * 1.0 / 3.0 * 1.0 /3.0
456                  tr(ji,jj,jk,jpoxy,Krhs) = tr(ji,jj,jk,jpoxy,Krhs) + ( o2ut + o2nit ) * zfact * 2.0 / 3.0 + o2nit * zfact / 3.0
457                  tr(ji,jj,jk,jpfer,Krhs) = tr(ji,jj,jk,jpfer,Krhs) - 30E-6 * zfact * 1.0 / 3.0 
458                  tr(ji,jj,jk,jpsfe,Krhs) = tr(ji,jj,jk,jpsfe,Krhs) + 30E-6 * zfact * 1.0 / 3.0 * 2.0 / 3.0
459                  tr(ji,jj,jk,jpbfe,Krhs) = tr(ji,jj,jk,jpbfe,Krhs) + 30E-6 * zfact * 1.0 / 3.0 * 1.0 / 3.0
460                  tr(ji,jj,jk,jpfer,Krhs) = tr(ji,jj,jk,jpfer,Krhs) + 0.002 * 4E-10 * zsoufer(ji,jj,jk) * rfact2 / rday
461              END DO
462            END DO
463         END DO
464         !
465      ENDIF
466
467      IF( lk_iomput ) THEN
468         IF( knt == nrdttrc ) THEN
469            zfact = 1.e+3 * rfact2r !  conversion from molC/l/kt  to molN/m3/s
470            IF( iom_use("Nfix"   ) ) CALL iom_put( "Nfix", nitrpot(:,:,:) * nitrfix * rno3 * zfact * tmask(:,:,:) )  ! nitrogen fixation
471            IF( iom_use("INTNFIX") ) THEN   ! nitrogen fixation rate in ocean ( vertically integrated )
472               zwork(:,:) = 0.
473               DO jk = 1, jpkm1
474                 zwork(:,:) = zwork(:,:) + nitrpot(:,:,jk) * nitrfix * rno3 * zfact * e3t(:,:,jk,Kmm) * tmask(:,:,jk)
475               ENDDO
476               CALL iom_put( "INTNFIX" , zwork ) 
477            ENDIF
478            IF( iom_use("SedCal" ) ) CALL iom_put( "SedCal", zsedcal(:,:) * zfact )
479            IF( iom_use("SedSi" ) )  CALL iom_put( "SedSi",  zsedsi (:,:) * zfact )
480            IF( iom_use("SedC" ) )   CALL iom_put( "SedC",   zsedc  (:,:) * zfact )
481            IF( iom_use("Sdenit" ) ) CALL iom_put( "Sdenit", sdenit (:,:) * zfact * rno3 )
482         ENDIF
483      ENDIF
484      !
485      IF(ln_ctl) THEN  ! print mean trends (USEd for debugging)
486         WRITE(charout, fmt="('sed ')")
487         CALL prt_ctl_trc_info(charout)
488         CALL prt_ctl_trc(tab4d=tr(:,:,:,:,Krhs), mask=tmask, clinfo=ctrcnm)
489      ENDIF
490      !
491      IF( ln_p5z )    DEALLOCATE( ztrpo4, ztrdop )
492      !
493      IF( ln_timing )  CALL timing_stop('p4z_sed')
494      !
495   END SUBROUTINE p4z_sed
496
497
498   INTEGER FUNCTION p4z_sed_alloc()
499      !!----------------------------------------------------------------------
500      !!                     ***  ROUTINE p4z_sed_alloc  ***
501      !!----------------------------------------------------------------------
502      ALLOCATE( nitrpot(jpi,jpj,jpk), sdenit(jpi,jpj), STAT=p4z_sed_alloc )
503      !
504      IF( p4z_sed_alloc /= 0 )   CALL ctl_stop( 'STOP', 'p4z_sed_alloc: failed to allocate arrays' )
505      !
506   END FUNCTION p4z_sed_alloc
507
508   !!======================================================================
509END MODULE p4zsed
Note: See TracBrowser for help on using the repository browser.