source: NEMO/branches/2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps/src/TOP/trcini.F90 @ 11504

Last change on this file since 11504 was 11504, checked in by davestorkey, 18 months ago

2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps : Strip out all references to nn_dttrc
and the trcsub.F90 module. Notes:

  1. This version of the code currently breaks the GYRE_PISCES test in SETTE.
  2. With the removal of this option, TOP should use the OCE time index variables, eg. Nbb_trc → Nbb, nittrc000 → nit0000 etc.
  • Property svn:keywords set to Id
File size: 13.6 KB
Line 
1MODULE trcini
2   !!======================================================================
3   !!                         ***  MODULE trcini  ***
4   !! TOP :   Manage the passive tracer initialization
5   !!======================================================================
6   !! History :   -   ! 1991-03 (O. Marti)  original code
7   !!            1.0  ! 2005-03 (O. Aumont, A. El Moussaoui) F90
8   !!            2.0  ! 2005-10 (C. Ethe, G. Madec) revised architecture
9   !!            4.0  ! 2011-01 (A. R. Porter, STFC Daresbury) dynamical allocation
10   !!----------------------------------------------------------------------
11#if defined key_top
12   !!----------------------------------------------------------------------
13   !!   'key_top'                                                TOP models
14   !!----------------------------------------------------------------------
15   !!   trc_init  :   Initialization for passive tracer
16   !!   top_alloc :   allocate the TOP arrays
17   !!----------------------------------------------------------------------
18   USE oce_trc         ! shared variables between ocean and passive tracers
19   USE trc             ! passive tracers common variables
20   USE trcnam          ! Namelist read
21   USE daymod          ! calendar manager
22   USE prtctl_trc      ! Print control passive tracers (prt_ctl_trc_init routine)
23   USE trcrst
24   USE lib_mpp         ! distribued memory computing library
25   USE trcice          ! tracers in sea ice
26   USE trcbc,   only : trc_bc_ini ! generalized Boundary Conditions
27   USE trcstp          ! for time level indices (to be initialised)
28 
29   IMPLICIT NONE
30   PRIVATE
31   
32   PUBLIC   trc_init   ! called by opa
33
34   !!----------------------------------------------------------------------
35   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
36   !! $Id$
37   !! Software governed by the CeCILL license (see ./LICENSE)
38   !!----------------------------------------------------------------------
39CONTAINS
40   
41   SUBROUTINE trc_init
42      !!---------------------------------------------------------------------
43      !!                     ***  ROUTINE trc_init  ***
44      !!
45      !! ** Purpose :   Initialization of the passive tracer fields
46      !!
47      !! ** Method  : - read namelist
48      !!              - control the consistancy
49      !!              - compute specific initialisations
50      !!              - set initial tracer fields (either read restart
51      !!                or read data or analytical formulation
52      !!---------------------------------------------------------------------
53      !
54      IF( ln_timing )   CALL timing_start('trc_init')
55      !
56      IF(lwp) WRITE(numout,*)
57      IF(lwp) WRITE(numout,*) 'trc_init : initial set up of the passive tracers'
58      IF(lwp) WRITE(numout,*) '~~~~~~~~'
59      !
60      ! Initialise time level indices
61      Nbb_trc = 1; Nnn_trc = 2; Naa_trc = 3; Nrhs_trc = Naa_trc
62      !
63      CALL trc_ini_ctl   ! control
64      CALL trc_nam       ! read passive tracers namelists
65      CALL top_alloc()   ! allocate TOP arrays
66
67      !
68      IF(.NOT.ln_trcdta )   ln_trc_ini(:) = .FALSE.
69      !
70      IF(lwp) WRITE(numout,*)
71      IF( ln_rsttr .AND. .NOT. l_offline ) CALL trc_rst_cal( nit000, 'READ' )   ! calendar
72      IF(lwp) WRITE(numout,*)
73      !
74      CALL trc_ini_sms( Nnn_trc )   ! SMS
75      CALL trc_ini_trp          ! passive tracers transport
76      CALL trc_ice_ini          ! Tracers in sea ice
77      !
78      IF( lwm .AND. sn_cfctl%l_trcstat ) THEN
79         CALL ctl_opn( numstr, 'tracer.stat', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp , narea )
80      ENDIF
81      !
82      CALL trc_ini_state( Nbb_trc, Nnn_trc, Naa_trc )  !  passive tracers initialisation : from a restart or from clim
83      !
84      CALL trc_ini_inv( Nnn_trc )    ! Inventories
85      !
86      IF( ln_timing )   CALL timing_stop('trc_init')
87      !
88   END SUBROUTINE trc_init
89
90
91   SUBROUTINE trc_ini_ctl
92      !!----------------------------------------------------------------------
93      !!                     ***  ROUTINE trc_ini_ctl  ***
94      !! ** Purpose :        Control  + ocean volume
95      !!----------------------------------------------------------------------
96      INTEGER ::   jk    ! dummy loop indices
97      !
98      ! Define logical parameter ton control dirunal cycle in TOP
99      l_trcdm2dc = ln_dm2dc .OR. ( ln_cpl .AND. ncpl_qsr_freq /= 1 )
100      l_trcdm2dc = l_trcdm2dc  .AND. .NOT. l_offline
101      IF( l_trcdm2dc .AND. lwp )   CALL ctl_warn( 'Coupling with passive tracers and used of diurnal cycle.',   &
102         &                           'Computation of a daily mean shortwave for some biogeochemical models ' )
103      !
104   END SUBROUTINE trc_ini_ctl
105
106
107   SUBROUTINE trc_ini_inv( Kmm )
108      !!----------------------------------------------------------------------
109      !!                     ***  ROUTINE trc_ini_stat  ***
110      !! ** Purpose :      passive tracers inventories at initialsation phase
111      !!----------------------------------------------------------------------
112      INTEGER, INTENT(in) ::   Kmm    ! time level index
113      INTEGER             ::  jk, jn  ! dummy loop indices
114      CHARACTER (len=25) :: charout
115      !!----------------------------------------------------------------------
116      !
117      IF(lwp) WRITE(numout,*)
118      IF(lwp) WRITE(numout,*) 'trc_ini_inv : initial passive tracers inventories'
119      IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
120      !
121      !                          ! masked grid volume
122      DO jk = 1, jpk
123         cvol(:,:,jk) = e1e2t(:,:) * e3t(:,:,jk,Kmm) * tmask(:,:,jk)
124      END DO
125      !                          ! total volume of the ocean
126      areatot = glob_sum( 'trcini', cvol(:,:,:) )
127      !
128      trai(:) = 0._wp            ! initial content of all tracers
129      DO jn = 1, jptra
130         trai(jn) = trai(jn) + glob_sum( 'trcini', tr(:,:,:,jn,Kmm) * cvol(:,:,:)   )
131      END DO
132
133      IF(lwp) THEN               ! control print
134         WRITE(numout,*)
135         WRITE(numout,*) '   ==>>>   Total number of passive tracer jptra = ', jptra
136         WRITE(numout,*) '           Total volume of ocean                = ', areatot
137         WRITE(numout,*) '           Total inital content of all tracers '
138         WRITE(numout,*)
139         DO jn = 1, jptra
140            WRITE(numout,9000) jn, TRIM( ctrcnm(jn) ), trai(jn)
141         ENDDO
142         WRITE(numout,*)
143      ENDIF
144      IF(lwp) WRITE(numout,*)
145      IF(ln_ctl) THEN            ! print mean trends (used for debugging)
146         CALL prt_ctl_trc_init
147         WRITE(charout, FMT="('ini ')")
148         CALL prt_ctl_trc_info( charout )
149         CALL prt_ctl_trc( tab4d=tr(:,:,:,:,Kmm), mask=tmask, clinfo=ctrcnm )
150      ENDIF
1519000  FORMAT('      tracer nb : ',i2,'      name :',a10,'      initial content :',e18.10)
152      !
153   END SUBROUTINE trc_ini_inv
154
155
156   SUBROUTINE trc_ini_sms( Kmm )
157      !!----------------------------------------------------------------------
158      !!                     ***  ROUTINE trc_ini_sms  ***
159      !! ** Purpose :   SMS initialisation
160      !!----------------------------------------------------------------------
161      USE trcini_pisces  ! PISCES   initialisation
162      USE trcini_cfc     ! CFC      initialisation
163      USE trcini_c14     ! C14  initialisation
164      USE trcini_age     ! age initialisation
165      USE trcini_my_trc  ! MY_TRC   initialisation
166      !
167      INTEGER, INTENT(in) ::   Kmm ! time level indices
168      INTEGER :: jn
169      !!----------------------------------------------------------------------
170      !
171      ! Pass sn_tracer fields to specialized arrays
172      DO jn = 1, jp_bgc
173         ctrcnm    (jn) = TRIM( sn_tracer(jn)%clsname )
174         ctrcln    (jn) = TRIM( sn_tracer(jn)%cllname )
175         ctrcun    (jn) = TRIM( sn_tracer(jn)%clunit  )
176         ln_trc_ini(jn) =       sn_tracer(jn)%llinit
177         ln_trc_sbc(jn) =       sn_tracer(jn)%llsbc
178         ln_trc_cbc(jn) =       sn_tracer(jn)%llcbc
179         ln_trc_obc(jn) =       sn_tracer(jn)%llobc
180      END DO
181      !   
182      IF( ln_pisces      )   CALL trc_ini_pisces( Kmm )     !  PISCES model
183      IF( ln_my_trc      )   CALL trc_ini_my_trc( Kmm )     !  MY_TRC model
184      IF( ll_cfc         )   CALL trc_ini_cfc   ( Kmm )     !  CFC's
185      IF( ln_c14         )   CALL trc_ini_c14   ( Kmm )     !  C14 model
186      IF( ln_age         )   CALL trc_ini_age   ( Kmm )     !  AGE
187      IF( .NOT.ln_pisces ) ALLOCATE( profsed(2) )
188      !
189      IF(lwp) THEN                   ! control print
190         WRITE(numout,*)
191         WRITE(numout,*) 'trc_init_sms : Summary for selected passive tracers'
192         WRITE(numout,*) '~~~~~~~~~~~~'
193         WRITE(numout,*) '    ID     NAME     INI  SBC  CBC  OBC'
194         DO jn = 1, jptra
195            WRITE(numout,9001) jn, TRIM(ctrcnm(jn)), ln_trc_ini(jn), ln_trc_sbc(jn),ln_trc_cbc(jn),ln_trc_obc(jn)
196         END DO
197      ENDIF
1989001  FORMAT(3x,i3,1x,a10,3x,l2,3x,l2,3x,l2,3x,l2)
199      !
200   END SUBROUTINE trc_ini_sms
201
202
203   SUBROUTINE trc_ini_trp
204      !!----------------------------------------------------------------------
205      !!                     ***  ROUTINE trc_ini_trp  ***
206      !!
207      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
208      !!----------------------------------------------------------------------
209      USE trcdmp , ONLY:  trc_dmp_ini
210      USE trcadv , ONLY:  trc_adv_ini
211      USE trcldf , ONLY:  trc_ldf_ini
212      USE trcrad , ONLY:  trc_rad_ini
213      USE trcsink, ONLY:  trc_sink_ini
214      !
215      INTEGER :: ierr
216      !!----------------------------------------------------------------------
217      !
218      IF( ln_trcdmp )  CALL  trc_dmp_ini          ! damping
219                       CALL  trc_adv_ini          ! advection
220                       CALL  trc_ldf_ini          ! lateral diffusion
221                       !                          ! vertical diffusion: always implicit time stepping scheme
222                       CALL  trc_rad_ini          ! positivity of passive tracers
223                       CALL  trc_sink_ini         ! Vertical sedimentation of particles
224      !
225   END SUBROUTINE trc_ini_trp
226
227
228   SUBROUTINE trc_ini_state( Kbb, Kmm, Kaa )
229      !!----------------------------------------------------------------------
230      !!                     ***  ROUTINE trc_ini_state ***
231      !! ** Purpose :          Initialisation of passive tracer concentration
232      !!----------------------------------------------------------------------
233      USE zpshde          ! partial step: hor. derivative   (zps_hde routine)
234      USE trcrst          ! passive tracers restart
235      USE trcdta          ! initialisation from files
236      !
237      INTEGER, INTENT(in) :: Kbb, Kmm, Kaa   ! time level index
238      INTEGER             :: jn, jl          ! dummy loop indices
239      !!----------------------------------------------------------------------
240      !
241      IF( ln_trcdta )   CALL trc_dta_ini( jptra )           ! set initial tracers values
242      !
243      IF( ln_my_trc )   CALL trc_bc_ini ( jptra, Kmm )      ! set tracers Boundary Conditions
244      !
245      !
246      IF( ln_rsttr ) THEN              ! restart from a file
247        !
248        CALL trc_rst_read( Kbb, Kmm )
249        !
250      ELSE                             ! Initialisation of tracer from a file that may also be used for damping
251!!gm BUG ?   if damping and restart, what's happening ?
252        IF( ln_trcdta .AND. nb_trcdta > 0 ) THEN
253            ! update passive tracers arrays with input data read from file
254            DO jn = 1, jptra
255               IF( ln_trc_ini(jn) ) THEN
256                  jl = n_trc_index(jn) 
257                  CALL trc_dta( nit000, Kmm, sf_trcdta(jl), rf_trfac(jl), tr(:,:,:,jn,Kmm) )
258                  !
259                  ! deallocate data structure if data are not used for damping
260                  IF( .NOT.ln_trcdmp .AND. .NOT.ln_trcdmp_clo ) THEN
261                     IF(lwp) WRITE(numout,*) 'trc_ini_state: deallocate data arrays as they are only used to initialize the run'
262                                                  DEALLOCATE( sf_trcdta(jl)%fnow )
263                     IF( sf_trcdta(jl)%ln_tint )  DEALLOCATE( sf_trcdta(jl)%fdta )
264                     !
265                  ENDIF
266               ENDIF
267            END DO
268            !
269        ENDIF
270        !
271        tr(:,:,:,:,Kbb) = tr(:,:,:,:,Kmm)
272        !
273      ENDIF
274      !
275      tr(:,:,:,:,Kaa) = 0._wp
276      !                                                         ! Partial top/bottom cell: GRADh(tr(Kmm))
277   END SUBROUTINE trc_ini_state
278
279
280   SUBROUTINE top_alloc
281      !!----------------------------------------------------------------------
282      !!                     ***  ROUTINE top_alloc  ***
283      !!
284      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
285      !!----------------------------------------------------------------------
286      USE trc           , ONLY:   trc_alloc
287      USE trdtrc_oce    , ONLY:   trd_trc_oce_alloc
288#if defined key_trdmxl_trc 
289      USE trdmxl_trc    , ONLY:   trd_mxl_trc_alloc
290#endif
291      !
292      INTEGER ::   ierr   ! local integer
293      !!----------------------------------------------------------------------
294      !
295      ierr =        trc_alloc()
296      ierr = ierr + trd_trc_oce_alloc()
297#if defined key_trdmxl_trc 
298      ierr = ierr + trd_mxl_trc_alloc()
299#endif
300      !
301      CALL mpp_sum( 'trcini', ierr )
302      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'top_alloc : unable to allocate standard ocean arrays' )
303      !
304   END SUBROUTINE top_alloc
305
306#else
307   !!----------------------------------------------------------------------
308   !!  Empty module :                                     No passive tracer
309   !!----------------------------------------------------------------------
310CONTAINS
311   SUBROUTINE trc_init                      ! Dummy routine   
312   END SUBROUTINE trc_init
313#endif
314
315   !!======================================================================
316END MODULE trcini
Note: See TracBrowser for help on using the repository browser.