source: NEMO/branches/2019/dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps_rewrite_time_filterswap/src/TOP/TRP/trcatf.F90 @ 11099

Last change on this file since 11099 was 11099, checked in by davestorkey, 18 months ago

dev_r10721_KERNEL-02_Storkey_Coward_IMMERSE_first_steps_rewrite_time_filterswap : Updates and bug fixes. This version still doesn't pass all SETTE tests.

  • Property svn:keywords set to Id
File size: 13.3 KB
Line 
1MODULE trcatf
2   !!======================================================================
3   !!                       ***  MODULE  trcatf  ***
4   !! Ocean passive tracers:  time stepping on passives tracers
5   !!======================================================================
6   !! History :  7.0  !  1991-11  (G. Madec)  Original code
7   !!                 !  1993-03  (M. Guyon)  symetrical conditions
8   !!                 !  1995-02  (M. Levy)   passive tracers
9   !!                 !  1996-02  (G. Madec & M. Imbard)  opa release 8.0
10   !!            8.0  !  1996-04  (A. Weaver)  Euler forward step
11   !!            8.2  !  1999-02  (G. Madec, N. Grima)  semi-implicit pressure grad.
12   !!  NEMO      1.0  !  2002-08  (G. Madec)  F90: Free form and module
13   !!                 !  2002-08  (G. Madec)  F90: Free form and module
14   !!                 !  2002-11  (C. Talandier, A-M Treguier) Open boundaries
15   !!                 !  2004-03  (C. Ethe) passive tracers
16   !!                 !  2007-02  (C. Deltel) Diagnose ML trends for passive tracers
17   !!            2.0  !  2006-02  (L. Debreu, C. Mazauric) Agrif implementation
18   !!            3.0  !  2008-06  (G. Madec)  time stepping always done in trazdf
19   !!            3.1  !  2009-02  (G. Madec, R. Benshila)  re-introduce the vvl option
20   !!            3.3  !  2010-06  (C. Ethe, G. Madec) Merge TRA-TRC
21   !!----------------------------------------------------------------------
22#if defined key_top
23   !!----------------------------------------------------------------------
24   !!   'key_top'                                                TOP models
25   !!----------------------------------------------------------------------
26   !!   trc_atf     : time stepping on passive tracers
27   !!----------------------------------------------------------------------
28   USE oce_trc         ! ocean dynamics and tracers variables
29   USE trc             ! ocean passive tracers variables
30   USE trd_oce
31   USE trdtra
32   USE traatf
33   USE bdy_oce   , ONLY: ln_bdy
34   USE trcbdy          ! BDY open boundaries
35# if defined key_agrif
36   USE agrif_top_interp
37# endif
38   !
39   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
40   USE prtctl_trc      ! Print control for debbuging
41
42   IMPLICIT NONE
43   PRIVATE
44
45   PUBLIC   trc_atf   ! routine called by step.F90
46
47   REAL(wp) ::   rfact1, rfact2
48
49   !!----------------------------------------------------------------------
50   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
51   !! $Id$
52   !! Software governed by the CeCILL license (see ./LICENSE)
53   !!----------------------------------------------------------------------
54CONTAINS
55
56   SUBROUTINE trc_atf( kt, Kbb, Kmm, Kaa, ptr )
57      !!----------------------------------------------------------------------
58      !!                   ***  ROUTINE trcatf  ***
59      !!
60      !!        !!!!!!!!!!!!!!!! REWRITE HEADER COMMENTS !!!!!!!!!!!!!!
61      !!
62      !! ** Purpose :   Compute the passive tracers fields at the
63      !!      next time-step from their temporal trends and swap the fields.
64      !!
65      !! ** Method  :   Apply lateral boundary conditions on (uu(Kaa),vv(Kaa)) through
66      !!      call to lbc_lnk routine
67      !!   default:
68      !!      arrays swap
69      !!         (tr(Kmm)) = (tr(Kaa)) ; (tr(Kaa)) = (0,0)
70      !!         (tr(Kbb)) = (tr(Kmm))
71      !!
72      !!   For Arakawa or TVD Scheme :
73      !!      A Asselin time filter applied on now tracers (tr(:,:,:,:,Kmm)) to avoid
74      !!      the divergence of two consecutive time-steps and tr arrays
75      !!      to prepare the next time_step:
76      !!         (tr(Kbb)) = (tr(Kmm)) + atfp [ (tr(Kbb)) + (tr(Kaa)) - 2 (tr(Kmm)) ]
77      !!         (tr(Kmm)) = (tr(Kaa)) ; (tr(Kaa)) = (0,0)
78      !!
79      !!
80      !! ** Action  : - update tr(Kbb), tr(Kmm)
81      !!----------------------------------------------------------------------
82      INTEGER                                   , INTENT( in )  :: kt             ! ocean time-step index
83      INTEGER                                   , INTENT( in )  :: Kbb, Kmm, Kaa ! time level indices
84      REAL(wp), DIMENSION(jpi,jpj,jpk,jptra,jpt), INTENT(inout) :: ptr            ! passive tracers
85      !
86      INTEGER  ::   jk, jn   ! dummy loop indices
87      REAL(wp) ::   zfact            ! temporary scalar
88      CHARACTER (len=22) :: charout
89      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:,:) ::   ztrdt    ! 4D workspace
90      !!----------------------------------------------------------------------
91      !
92      IF( ln_timing )   CALL timing_start('trc_atf')
93      !
94      IF( kt == nittrc000 .AND. lwp ) THEN
95         WRITE(numout,*)
96         WRITE(numout,*) 'trc_atf : Asselin time filtering on passive tracers'
97      ENDIF
98      !
99#if defined key_agrif
100      CALL Agrif_trc                   ! AGRIF zoom boundaries
101#endif
102      ! Update after tracer on domain lateral boundaries
103      CALL lbc_lnk( 'trcatf', ptr(:,:,:,:,Kaa), 'T', 1. )   
104
105      IF( ln_bdy )  CALL trc_bdy( kt, Kbb, Kmm, Kaa )
106
107      IF( l_trdtrc )  THEN             ! trends: store now fields before the Asselin filter application
108         ALLOCATE( ztrdt(jpi,jpj,jpk,jptra) )
109         ztrdt(:,:,:,:)  = 0._wp
110         IF( ln_traldf_iso ) THEN                       ! diagnose the "pure" Kz diffusive trend
111            DO jn = 1, jptra
112               CALL trd_tra( kt, Kmm, Kaa, 'TRC', jn, jptra_zdfp, ztrdt(:,:,:,jn) )
113            ENDDO
114         ENDIF
115
116         ! total trend for the non-time-filtered variables.
117         zfact = 1.0 / rdttrc
118         ! G Nurser 23 Mar 2017. Recalculate trend as Delta(e3t*T)/e3tn; e3tn cancel from ts(Kmm) terms
119         IF( ln_linssh ) THEN       ! linear sea surface height only
120            DO jn = 1, jptra
121               DO jk = 1, jpkm1
122                  ztrdt(:,:,jk,jn) = ( ptr(:,:,jk,jn,Kaa)*e3t(:,:,jk,Kaa) / e3t(:,:,jk,Kmm) - ptr(:,:,jk,jn,Kmm)) * zfact
123               END DO
124            END DO
125         ELSE
126            DO jn = 1, jptra
127               DO jk = 1, jpkm1
128                  ztrdt(:,:,jk,jn) = ( ptr(:,:,jk,jn,Kaa) - ptr(:,:,jk,jn,Kmm) ) * zfact
129               END DO
130            END DO
131         ENDIF
132         !
133         DO jn = 1, jptra
134            CALL trd_tra( kt, Kmm, Kaa, 'TRC', jn, jptra_tot, ztrdt(:,:,:,jn) )
135         ENDDO
136         !
137         IF( ln_linssh ) THEN       ! linear sea surface height only
138            ! Store now fields before applying the Asselin filter
139            ! in order to calculate Asselin filter trend later.
140            ztrdt(:,:,:,:) = ptr(:,:,:,:,Kmm) 
141         ENDIF
142
143      ENDIF
144      !                                ! Leap-Frog + Asselin filter time stepping
145      IF( (neuler == 0 .AND. kt == nittrc000) .OR. ln_top_euler ) THEN    ! Euler time-stepping
146         !
147         IF (l_trdtrc .AND. .NOT. ln_linssh ) THEN   ! Zero Asselin filter contribution must be explicitly written out since for vvl
148            !                                        ! Asselin filter is output by tra_nxt_vvl that is not called on this time step
149            ztrdt(:,:,:,:) = 0._wp           
150            DO jn = 1, jptra
151               CALL trd_tra( kt, Kmm, Kaa, 'TRC', jn, jptra_atf, ztrdt(:,:,:,jn) )
152            ENDDO
153         END IF
154         !
155      ELSE     
156         IF( .NOT. l_offline ) THEN ! Leap-Frog + Asselin filter time stepping
157            IF( ln_linssh ) THEN   ;   CALL tra_atf_fix( kt, Kbb, Kmm, Kaa, nittrc000,         'TRC', ptr, jptra )                     !     linear ssh
158            ELSE                   ;   CALL tra_atf_vvl( kt, Kbb, Kmm, Kaa, nittrc000, rdttrc, 'TRC', ptr, sbc_trc, sbc_trc_b, jptra ) ! non-linear ssh
159            ENDIF
160         ELSE
161                                       CALL trc_atf_off( kt, Kbb, Kmm, Kaa, ptr )       ! offline
162         ENDIF
163         !
164         CALL lbc_lnk_multi( 'trcatf', ptr(:,:,:,:,Kbb), 'T', 1._wp, ptr(:,:,:,:,Kmm), 'T', 1._wp, ptr(:,:,:,:,Kaa), 'T', 1._wp )
165      ENDIF
166      !
167      IF( l_trdtrc .AND. ln_linssh ) THEN      ! trend of the Asselin filter (tb filtered - tb)/dt )
168         DO jn = 1, jptra
169            DO jk = 1, jpkm1
170               zfact = 1._wp / r2dttrc 
171               ztrdt(:,:,jk,jn) = ( ptr(:,:,jk,jn,Kbb) - ztrdt(:,:,jk,jn) ) * zfact 
172            END DO
173            CALL trd_tra( kt, Kmm, Kaa, 'TRC', jn, jptra_atf, ztrdt(:,:,:,jn) )
174         END DO
175      END IF
176      IF( l_trdtrc ) DEALLOCATE( ztrdt ) 
177      !
178      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
179         WRITE(charout, FMT="('nxt')")
180         CALL prt_ctl_trc_info(charout)
181         CALL prt_ctl_trc(tab4d=ptr(:,:,:,:,Kmm), mask=tmask, clinfo=ctrcnm)
182      ENDIF
183      !
184      IF( ln_timing )   CALL timing_stop('trc_atf')
185      !
186   END SUBROUTINE trc_atf
187
188
189   SUBROUTINE trc_atf_off( kt, Kbb, Kmm, Kaa, ptr )
190      !!----------------------------------------------------------------------
191      !!                   ***  ROUTINE tra_atf_off  ***
192      !!
193      !!          !!!!!!!!!!!!!!!!! REWRITE HEADER COMMENTS !!!!!!!!!!!!!!
194      !!
195      !! ** Purpose :   Time varying volume: apply the Asselin time filter 
196      !!
197      !! ** Method  : - Apply a thickness weighted Asselin time filter on now fields.
198      !!              - save in (ta,sa) a thickness weighted average over the three
199      !!             time levels which will be used to compute rdn and thus the semi-
200      !!             implicit hydrostatic pressure gradient (ln_dynhpg_imp = T)
201      !!              - swap tracer fields to prepare the next time_step.
202      !!                This can be summurized for tempearture as:
203      !!             ztm = ( e3t_n*tn + rbcp*[ e3t_b*tb - 2 e3t_n*tn + e3t_a*ta ] )   ln_dynhpg_imp = T
204      !!                  /( e3t(:,:,:,Kmm)    + rbcp*[ e3t(:,:,:,Kbb)    - 2 e3t(:,:,:,Kmm)    + e3t(:,:,:,Kaa)    ] )   
205      !!             ztm = 0                                                       otherwise
206      !!             tb  = ( e3t_n*tn + atfp*[ e3t_b*tb - 2 e3t_n*tn + e3t_a*ta ] )
207      !!                  /( e3t(:,:,:,Kmm)    + atfp*[ e3t(:,:,:,Kbb)    - 2 e3t(:,:,:,Kmm)    + e3t(:,:,:,Kaa)    ] )
208      !!             tn  = ta
209      !!             ta  = zt        (NB: reset to 0 after eos_bn2 call)
210      !!
211      !! ** Action  : - (tb,sb) and (tn,sn) ready for the next time step
212      !!              - (ta,sa) time averaged (t,s)   (ln_dynhpg_imp = T)
213      !!----------------------------------------------------------------------
214      INTEGER                                   , INTENT(in   ) ::  kt            ! ocean time-step index
215      INTEGER                                   , INTENT(in   ) ::  Kbb, Kmm, Kaa ! time level indices
216      REAL(wp), DIMENSION(jpi,jpj,jpk,jptra,jpt), INTENT(inout) ::  ptr           ! passive tracers
217      !!     
218      INTEGER  ::   ji, jj, jk, jn              ! dummy loop indices
219      REAL(wp) ::   ztc_a , ztc_n , ztc_b , ztc_f , ztc_d    ! local scalar
220      REAL(wp) ::   ze3t_b, ze3t_n, ze3t_a, ze3t_f, ze3t_d   !   -      -
221      !!----------------------------------------------------------------------
222      !
223      IF( kt == nittrc000 )  THEN
224         IF(lwp) WRITE(numout,*)
225         IF(lwp) WRITE(numout,*) 'trc_atf_off : Asselin time filtering'
226         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
227         IF( .NOT. ln_linssh ) THEN
228            rfact1 = atfp * rdttrc
229            rfact2 = rfact1 / rau0
230         ENDIF
231       
232      ENDIF
233      !
234      DO jn = 1, jptra     
235         DO jk = 1, jpkm1
236            DO jj = 1, jpj
237               DO ji = 1, jpi
238                  ze3t_b = e3t(ji,jj,jk,Kbb)
239                  ze3t_n = e3t(ji,jj,jk,Kmm)
240                  ze3t_a = e3t(ji,jj,jk,Kaa)
241                  !                                         ! tracer content at Before, now and after
242                  ztc_b  = ptr(ji,jj,jk,jn,Kbb)  * ze3t_b
243                  ztc_n  = ptr(ji,jj,jk,jn,Kmm)  * ze3t_n
244                  ztc_a  = ptr(ji,jj,jk,jn,Kaa) * ze3t_a
245                  !
246                  ze3t_d = ze3t_a - 2. * ze3t_n + ze3t_b
247                  ztc_d  = ztc_a  - 2. * ztc_n  + ztc_b
248                  !
249                  ze3t_f = ze3t_n + atfp * ze3t_d
250                  ztc_f  = ztc_n  + atfp * ztc_d
251                  !
252                  IF( .NOT. ln_linssh .AND. jk == mikt(ji,jj) ) THEN           ! first level
253                     ze3t_f = ze3t_f - rfact2 * ( emp_b(ji,jj)      - emp(ji,jj)   ) 
254                     ztc_f  = ztc_f  - rfact1 * ( sbc_trc(ji,jj,jn) - sbc_trc_b(ji,jj,jn) )
255                  ENDIF
256
257                  ze3t_f = 1.e0 / ze3t_f
258                  ptr(ji,jj,jk,jn,Kmm) = ztc_f * ze3t_f     ! time filtered "now" field
259                  !
260               END DO
261            END DO
262         END DO
263         !
264      END DO
265      !
266   END SUBROUTINE trc_atf_off
267
268#else
269   !!----------------------------------------------------------------------
270   !!   Default option                                         Empty module
271   !!----------------------------------------------------------------------
272   USE par_oce
273   USE par_trc
274CONTAINS
275   SUBROUTINE trc_atf( kt, Kbb, Kmm, Kaa, ptr ) 
276      INTEGER                                   , INTENT(in)    :: kt
277      INTEGER,                                    INTENT(in   ) :: Kbb, Kmm, Kaa ! time level indices
278      REAL(wp), DIMENSION(jpi,jpj,jpk,jptra,jpt), INTENT(inout) :: ptr           ! passive tracers and RHS of tracer equation
279      WRITE(*,*) 'trc_atf: You should not have seen this print! error?', kt
280   END SUBROUTINE trc_atf
281#endif
282   !!======================================================================
283END MODULE trcatf
Note: See TracBrowser for help on using the repository browser.