New URL for NEMO forge! http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.

bdydta.F90 in NEMO/branches/2019/dev_r10742_ENHANCE-12_SimonM-Tides/src/OCE/BDY – NEMO

Context Navigation

source: NEMO/branches/2019/dev_r10742_ENHANCE-12_SimonM-Tides/src/OCE/BDY/bdydta.F90 @ 11574

Last change on this file since 11574 was 10865, checked in by smueller, 5 years ago
Removal of redundant source code in modules bdydta and bdytides (ticket #2194)
Property svn:keywords set to `Id`
File size: 34.0 KB

Rev	Line
[911]	1	MODULE bdydta
[1125]	2	!!======================================================================
	3	!! * MODULE bdydta *
[911]	4	!! Open boundary data : read the data for the unstructured open boundaries.
[1125]	5	!!======================================================================
	6	!! History : 1.0 ! 2005-01 (J. Chanut, A. Sellar) Original code
	7	!! - ! 2007-01 (D. Storkey) Update to use IOM module
[2528]	8	!! - ! 2007-07 (D. Storkey) add bdy_dta_fla
[1125]	9	!! 3.0 ! 2008-04 (NEMO team) add in the reference version
[2528]	10	!! 3.3 ! 2010-09 (E.O'Dea) modifications for Shelf configurations
	11	!! 3.3 ! 2010-09 (D.Storkey) add ice boundary conditions
[3294]	12	!! 3.4 ! 2011 (D. Storkey) rewrite in preparation for OBC-BDY merge
[9656]	13	!! 3.6 ! 2012-01 (C. Rousset) add ice boundary conditions for sea ice
	14	!! 4.0 ! 2018 (C. Rousset) SI3 compatibility
[1125]	15	!!----------------------------------------------------------------------
[9019]	16
[1125]	17	!!----------------------------------------------------------------------
[9019]	18	!! bdy_dta : read external data along open boundaries from file
	19	!! bdy_dta_init : initialise arrays etc for reading of external data
	20	!!----------------------------------------------------------------------
	21	USE oce ! ocean dynamics and tracers
	22	USE dom_oce ! ocean space and time domain
	23	USE phycst ! physical constants
	24	USE sbcapr ! atmospheric pressure forcing
[10773]	25	USE tide_mod, ONLY: ln_tide ! tidal forcing
[9019]	26	USE bdy_oce ! ocean open boundary conditions
	27	USE bdytides ! tidal forcing at boundaries
[9570]	28	#if defined key_si3
[9019]	29	USE ice ! sea-ice variables
	30	USE icevar ! redistribute ice input into categories
[2528]	31	#endif
[9019]	32	!
[10529]	33	USE lib_mpp, ONLY: ctl_stop, ctl_nam
[9019]	34	USE fldread ! read input fields
	35	USE iom ! IOM library
	36	USE in_out_manager ! I/O logical units
	37	USE timing ! Timing
[911]	38
	39	IMPLICIT NONE
	40	PRIVATE
	41
[3294]	42	PUBLIC bdy_dta ! routine called by step.F90 and dynspg_ts.F90
	43	PUBLIC bdy_dta_init ! routine called by nemogcm.F90
[911]	44
[3294]	45	INTEGER, ALLOCATABLE, DIMENSION(:) :: nb_bdy_fld ! Number of fields to update for each boundary set.
	46	INTEGER :: nb_bdy_fld_sum ! Total number of fields to update for all boundary sets.
	47	LOGICAL, DIMENSION(jp_bdy) :: ln_full_vel_array ! =T => full velocities in 3D boundary conditions
	48	! =F => baroclinic velocities in 3D boundary conditions
[4354]	49	!$AGRIF_DO_NOT_TREAT
[3294]	50	TYPE(FLD), PUBLIC, ALLOCATABLE, DIMENSION(:), TARGET :: bf ! structure of input fields (file informations, fields read)
[4354]	51	!$AGRIF_END_DO_NOT_TREAT
[3294]	52	TYPE(MAP_POINTER), ALLOCATABLE, DIMENSION(:) :: nbmap_ptr ! array of pointers to nbmap
[911]	53
[9570]	54	#if defined key_si3
[9019]	55	INTEGER :: nice_cat ! number of categories in the input file
	56	INTEGER :: jfld_hti, jfld_hts, jfld_ai ! indices of ice thickness, snow thickness and concentration in bf structure
[9810]	57	INTEGER, DIMENSION(jp_bdy) :: jfld_htit, jfld_htst, jfld_ait
[4292]	58	#endif
	59
[1125]	60	!!----------------------------------------------------------------------
[9598]	61	!! NEMO/OCE 4.0 , NEMO Consortium (2018)
[1146]	62	!! $Id$
[10068]	63	!! Software governed by the CeCILL license (see ./LICENSE)
[1125]	64	!!----------------------------------------------------------------------
[911]	65	CONTAINS
	66
[10865]	67	SUBROUTINE bdy_dta( kt, time_offset )
[1125]	68	!!----------------------------------------------------------------------
[3294]	69	!! * SUBROUTINE bdy_dta *
[911]	70	!!
[3294]	71	!! ** Purpose : Update external data for open boundary conditions
[911]	72	!!
[3294]	73	!! ** Method : Use fldread.F90
	74	!!
[1125]	75	!!----------------------------------------------------------------------
[6140]	76	INTEGER, INTENT(in) :: kt ! ocean time-step index
[10865]	77	INTEGER, INTENT(in), OPTIONAL :: time_offset ! time offset in units of timesteps.
[6140]	78	! ! time_offset = 0 => get data at "now" time level
	79	! ! time_offset = -1 => get data at "before" time level
	80	! ! time_offset = +1 => get data at "after" time level
	81	! ! etc.
	82	!
[9019]	83	INTEGER :: jbdy, jfld, jstart, jend, ib, jl ! dummy loop indices
	84	INTEGER :: ii, ij, ik, igrd ! local integers
[3294]	85	INTEGER, DIMENSION(jpbgrd) :: ilen1
	86	INTEGER, POINTER, DIMENSION(:) :: nblen, nblenrim ! short cuts
[4292]	87	TYPE(OBC_DATA), POINTER :: dta ! short cut
[911]	88	!!---------------------------------------------------------------------------
[6140]	89	!
[9124]	90	IF( ln_timing ) CALL timing_start('bdy_dta')
[6140]	91	!
[3294]	92	! Initialise data arrays once for all from initial conditions where required
	93	!---------------------------------------------------------------------------
[10865]	94	IF( kt == nit000 ) THEN
[1125]	95
[3294]	96	! Calculate depth-mean currents
	97	!-----------------------------
	98
[9019]	99	DO jbdy = 1, nb_bdy
[6140]	100	!
[9019]	101	nblen => idx_bdy(jbdy)%nblen
	102	nblenrim => idx_bdy(jbdy)%nblenrim
	103	dta => dta_bdy(jbdy)
	104	!
	105	IF( nn_dyn2d_dta(jbdy) == 0 ) THEN
[3651]	106	ilen1(:) = nblen(:)
[4292]	107	IF( dta%ll_ssh ) THEN
	108	igrd = 1
	109	DO ib = 1, ilen1(igrd)
[9019]	110	ii = idx_bdy(jbdy)%nbi(ib,igrd)
	111	ij = idx_bdy(jbdy)%nbj(ib,igrd)
	112	dta_bdy(jbdy)%ssh(ib) = sshn(ii,ij) * tmask(ii,ij,1)
[4292]	113	END DO
[9019]	114	ENDIF
[4292]	115	IF( dta%ll_u2d ) THEN
	116	igrd = 2
	117	DO ib = 1, ilen1(igrd)
[9019]	118	ii = idx_bdy(jbdy)%nbi(ib,igrd)
	119	ij = idx_bdy(jbdy)%nbj(ib,igrd)
	120	dta_bdy(jbdy)%u2d(ib) = un_b(ii,ij) * umask(ii,ij,1)
[4292]	121	END DO
[9019]	122	ENDIF
[4292]	123	IF( dta%ll_v2d ) THEN
	124	igrd = 3
	125	DO ib = 1, ilen1(igrd)
[9019]	126	ii = idx_bdy(jbdy)%nbi(ib,igrd)
	127	ij = idx_bdy(jbdy)%nbj(ib,igrd)
	128	dta_bdy(jbdy)%v2d(ib) = vn_b(ii,ij) * vmask(ii,ij,1)
[4292]	129	END DO
[9019]	130	ENDIF
[4292]	131	ENDIF
[9019]	132	!
	133	IF( nn_dyn3d_dta(jbdy) == 0 ) THEN
[4292]	134	ilen1(:) = nblen(:)
	135	IF( dta%ll_u3d ) THEN
	136	igrd = 2
	137	DO ib = 1, ilen1(igrd)
	138	DO ik = 1, jpkm1
[9019]	139	ii = idx_bdy(jbdy)%nbi(ib,igrd)
	140	ij = idx_bdy(jbdy)%nbj(ib,igrd)
	141	dta_bdy(jbdy)%u3d(ib,ik) = ( un(ii,ij,ik) - un_b(ii,ij) ) * umask(ii,ij,ik)
[3294]	142	END DO
[4292]	143	END DO
[9019]	144	ENDIF
[4292]	145	IF( dta%ll_v3d ) THEN
	146	igrd = 3
	147	DO ib = 1, ilen1(igrd)
	148	DO ik = 1, jpkm1
[9019]	149	ii = idx_bdy(jbdy)%nbi(ib,igrd)
	150	ij = idx_bdy(jbdy)%nbj(ib,igrd)
	151	dta_bdy(jbdy)%v3d(ib,ik) = ( vn(ii,ij,ik) - vn_b(ii,ij) ) * vmask(ii,ij,ik)
[4292]	152	END DO
	153	END DO
[9019]	154	ENDIF
[3294]	155	ENDIF
[911]	156
[9019]	157	IF( nn_tra_dta(jbdy) == 0 ) THEN
[3651]	158	ilen1(:) = nblen(:)
[4292]	159	IF( dta%ll_tem ) THEN
	160	igrd = 1
	161	DO ib = 1, ilen1(igrd)
	162	DO ik = 1, jpkm1
[9019]	163	ii = idx_bdy(jbdy)%nbi(ib,igrd)
	164	ij = idx_bdy(jbdy)%nbj(ib,igrd)
	165	dta_bdy(jbdy)%tem(ib,ik) = tsn(ii,ij,ik,jp_tem) * tmask(ii,ij,ik)
[4292]	166	END DO
	167	END DO
[9019]	168	ENDIF
[4292]	169	IF( dta%ll_sal ) THEN
	170	igrd = 1
	171	DO ib = 1, ilen1(igrd)
	172	DO ik = 1, jpkm1
[9019]	173	ii = idx_bdy(jbdy)%nbi(ib,igrd)
	174	ij = idx_bdy(jbdy)%nbj(ib,igrd)
	175	dta_bdy(jbdy)%sal(ib,ik) = tsn(ii,ij,ik,jp_sal) * tmask(ii,ij,ik)
[4292]	176	END DO
	177	END DO
[9019]	178	ENDIF
[3294]	179	ENDIF
[911]	180
[9570]	181	#if defined key_si3
[9657]	182	IF( nn_ice_dta(jbdy) == 0 ) THEN ! set ice to initial values
[3651]	183	ilen1(:) = nblen(:)
[4292]	184	IF( dta%ll_a_i ) THEN
	185	igrd = 1
	186	DO jl = 1, jpl
	187	DO ib = 1, ilen1(igrd)
[9019]	188	ii = idx_bdy(jbdy)%nbi(ib,igrd)
	189	ij = idx_bdy(jbdy)%nbj(ib,igrd)
	190	dta_bdy(jbdy)%a_i (ib,jl) = a_i(ii,ij,jl) * tmask(ii,ij,1)
[4292]	191	END DO
	192	END DO
	193	ENDIF
[9019]	194	IF( dta%ll_h_i ) THEN
[4292]	195	igrd = 1
	196	DO jl = 1, jpl
	197	DO ib = 1, ilen1(igrd)
[9019]	198	ii = idx_bdy(jbdy)%nbi(ib,igrd)
	199	ij = idx_bdy(jbdy)%nbj(ib,igrd)
	200	dta_bdy(jbdy)%h_i (ib,jl) = h_i(ii,ij,jl) * tmask(ii,ij,1)
[4292]	201	END DO
	202	END DO
	203	ENDIF
[9019]	204	IF( dta%ll_h_s ) THEN
[4292]	205	igrd = 1
	206	DO jl = 1, jpl
	207	DO ib = 1, ilen1(igrd)
[9019]	208	ii = idx_bdy(jbdy)%nbi(ib,igrd)
	209	ij = idx_bdy(jbdy)%nbj(ib,igrd)
	210	dta_bdy(jbdy)%h_s (ib,jl) = h_s(ii,ij,jl) * tmask(ii,ij,1)
[4292]	211	END DO
	212	END DO
	213	ENDIF
	214	ENDIF
[3294]	215	#endif
[9019]	216	END DO ! jbdy
[6140]	217	!
	218	ENDIF ! kt == nit000
[911]	219
[3294]	220	! update external data from files
	221	!--------------------------------
	222
	223	jstart = 1
[9019]	224	DO jbdy = 1, nb_bdy
	225	dta => dta_bdy(jbdy)
	226	IF( nn_dta(jbdy) == 1 ) THEN ! skip this bit if no external data required
[3294]	227
[10865]	228	IF (cn_tra(jbdy) == 'runoff') then ! runoff condition
	229	jend = nb_bdy_fld(jbdy)
	230	CALL fld_read( kt=kt, kn_fsbc=1, sd=bf(jstart:jend), &
	231	& map=nbmap_ptr(jstart:jend), kt_offset=time_offset )
	232	!
	233	igrd = 2 ! zonal velocity
	234	DO ib = 1, idx_bdy(jbdy)%nblen(igrd)
	235	ii = idx_bdy(jbdy)%nbi(ib,igrd)
	236	ij = idx_bdy(jbdy)%nbj(ib,igrd)
	237	dta%u2d(ib) = dta%u2d(ib) / ( e2u(ii,ij) * hu_0(ii,ij) )
	238	END DO
	239	!
	240	igrd = 3 ! meridional velocity
	241	DO ib = 1, idx_bdy(jbdy)%nblen(igrd)
	242	ii = idx_bdy(jbdy)%nbi(ib,igrd)
	243	ij = idx_bdy(jbdy)%nbj(ib,igrd)
	244	dta%v2d(ib) = dta%v2d(ib) / ( e1v(ii,ij) * hv_0(ii,ij) )
	245	END DO
	246	ELSE
	247	IF( nn_dyn2d_dta(jbdy) == 2 ) THEN ! tidal harmonic forcing ONLY: initialise arrays
	248	IF( dta%ll_ssh ) dta%ssh(:) = 0._wp
	249	IF( dta%ll_u2d ) dta%u2d(:) = 0._wp
	250	IF( dta%ll_v2d ) dta%v2d(:) = 0._wp
[1125]	251	ENDIF
[10865]	252	IF( dta%nread(1) .gt. 0 ) THEN ! update external data
	253	jend = jstart + dta%nread(1) - 1
	254	CALL fld_read( kt=kt, kn_fsbc=1, sd=bf(jstart:jend), &
	255	& map=nbmap_ptr(jstart:jend), kt_offset=time_offset, jpk_bdy=nb_jpk_bdy, &
	256	& fvl=ln_full_vel_array(jbdy) )
	257	ENDIF
	258	! If full velocities in boundary data then split into barotropic and baroclinic data
	259	IF( ln_full_vel_array(jbdy) .and. &
	260	& ( nn_dyn2d_dta(jbdy) == 1 .OR. nn_dyn2d_dta(jbdy) == 3 .OR. &
	261	& nn_dyn3d_dta(jbdy) == 1 ) ) THEN
[3651]	262	igrd = 2 ! zonal velocity
[10865]	263	dta%u2d(:) = 0._wp
[9019]	264	DO ib = 1, idx_bdy(jbdy)%nblen(igrd)
	265	ii = idx_bdy(jbdy)%nbi(ib,igrd)
	266	ij = idx_bdy(jbdy)%nbj(ib,igrd)
[10865]	267	DO ik = 1, jpkm1
	268	dta%u2d(ib) = dta%u2d(ib) &
	269	& + e3u_n(ii,ij,ik) * umask(ii,ij,ik) * dta%u3d(ib,ik)
	270	END DO
	271	dta%u2d(ib) = dta%u2d(ib) * r1_hu_n(ii,ij)
	272	DO ik = 1, jpkm1
	273	dta%u3d(ib,ik) = dta%u3d(ib,ik) - dta%u2d(ib)
	274	END DO
[3651]	275	END DO
	276	igrd = 3 ! meridional velocity
[10865]	277	dta%v2d(:) = 0._wp
[9019]	278	DO ib = 1, idx_bdy(jbdy)%nblen(igrd)
	279	ii = idx_bdy(jbdy)%nbi(ib,igrd)
	280	ij = idx_bdy(jbdy)%nbj(ib,igrd)
[10865]	281	DO ik = 1, jpkm1
	282	dta%v2d(ib) = dta%v2d(ib) &
	283	& + e3v_n(ii,ij,ik) * vmask(ii,ij,ik) * dta%v3d(ib,ik)
[3651]	284	END DO
[10865]	285	dta%v2d(ib) = dta%v2d(ib) * r1_hv_n(ii,ij)
	286	DO ik = 1, jpkm1
	287	dta%v3d(ib,ik) = dta%v3d(ib,ik) - dta%v2d(ib)
[3651]	288	END DO
[10865]	289	END DO
	290	ENDIF
[4292]	291
[10865]	292	ENDIF
[9570]	293	#if defined key_si3
[10865]	294	! convert N-cat fields (input) into jpl-cat (output)
	295	IF( cn_ice(jbdy) /= 'none' .AND. nn_ice_dta(jbdy) == 1 ) THEN
	296	jfld_hti = jfld_htit(jbdy)
	297	jfld_hts = jfld_htst(jbdy)
	298	jfld_ai = jfld_ait(jbdy)
	299	IF ( jpl /= 1 .AND. nice_cat == 1 ) THEN ! case input cat = 1
	300	CALL ice_var_itd ( bf(jfld_hti)%fnow(:,1,1), bf(jfld_hts)%fnow(:,1,1), bf(jfld_ai)%fnow(:,1,1), &
	301	& dta_bdy(jbdy)%h_i , dta_bdy(jbdy)%h_s , dta_bdy(jbdy)%a_i )
	302	ELSEIF( jpl /= 1 .AND. nice_cat /= 1 .AND. nice_cat /= jpl ) THEN ! case input cat /=1 and /=jpl
	303	CALL ice_var_itd2( bf(jfld_hti)%fnow(:,1,:), bf(jfld_hts)%fnow(:,1,:), bf(jfld_ai)%fnow(:,1,:), &
	304	& dta_bdy(jbdy)%h_i , dta_bdy(jbdy)%h_s , dta_bdy(jbdy)%a_i )
[4292]	305	ENDIF
[10865]	306	ENDIF
[4292]	307	#endif
	308	jstart = jstart + dta%nread(1)
[9019]	309	ENDIF ! nn_dta(jbdy) = 1
	310	END DO ! jbdy
[911]	311
[10647]	312	IF ( ln_apr_obc ) THEN
	313	DO jbdy = 1, nb_bdy
	314	IF (cn_tra(jbdy) /= 'runoff')THEN
	315	igrd = 1 ! meridional velocity
	316	DO ib = 1, idx_bdy(jbdy)%nblenrim(igrd)
	317	ii = idx_bdy(jbdy)%nbi(ib,igrd)
	318	ij = idx_bdy(jbdy)%nbj(ib,igrd)
	319	dta_bdy(jbdy)%ssh(ib) = dta_bdy(jbdy)%ssh(ib) + ssh_ib(ii,ij)
	320	END DO
	321	ENDIF
	322	END DO
	323	ENDIF
	324
[7646]	325	IF ( ln_tide ) THEN
	326	IF (ln_dynspg_ts) THEN ! Fill temporary arrays with slow-varying bdy data
[9019]	327	DO jbdy = 1, nb_bdy ! Tidal component added in ts loop
	328	IF ( nn_dyn2d_dta(jbdy) .ge. 2 ) THEN
	329	nblen => idx_bdy(jbdy)%nblen
	330	nblenrim => idx_bdy(jbdy)%nblenrim
	331	IF( cn_dyn2d(jbdy) == 'frs' ) THEN; ilen1(:)=nblen(:) ; ELSE ; ilen1(:)=nblenrim(:) ; ENDIF
	332	IF ( dta_bdy(jbdy)%ll_ssh ) dta_bdy_s(jbdy)%ssh(1:ilen1(1)) = dta_bdy(jbdy)%ssh(1:ilen1(1))
	333	IF ( dta_bdy(jbdy)%ll_u2d ) dta_bdy_s(jbdy)%u2d(1:ilen1(2)) = dta_bdy(jbdy)%u2d(1:ilen1(2))
	334	IF ( dta_bdy(jbdy)%ll_v2d ) dta_bdy_s(jbdy)%v2d(1:ilen1(3)) = dta_bdy(jbdy)%v2d(1:ilen1(3))
[7646]	335	ENDIF
	336	END DO
	337	ELSE ! Add tides if not split-explicit free surface else this is done in ts loop
	338	!
	339	CALL bdy_dta_tides( kt=kt, time_offset=time_offset )
	340	ENDIF
[5930]	341	ENDIF
[4292]	342
[6140]	343	!
[9124]	344	IF( ln_timing ) CALL timing_stop('bdy_dta')
[6140]	345	!
	346	END SUBROUTINE bdy_dta
[911]	347
	348
[6140]	349	SUBROUTINE bdy_dta_init
[3294]	350	!!----------------------------------------------------------------------
	351	!! * SUBROUTINE bdy_dta_init *
	352	!!
	353	!! ** Purpose : Initialise arrays for reading of external data
	354	!! for open boundary conditions
	355	!!
[4292]	356	!! ** Method :
[3294]	357	!!
	358	!!----------------------------------------------------------------------
[9019]	359	INTEGER :: jbdy, jfld, jstart, jend, ierror, ios ! Local integers
[6140]	360	!
[3294]	361	CHARACTER(len=100) :: cn_dir ! Root directory for location of data files
	362	CHARACTER(len=100), DIMENSION(nb_bdy) :: cn_dir_array ! Root directory for location of data files
[5919]	363	CHARACTER(len = 256):: clname ! temporary file name
[3294]	364	LOGICAL :: ln_full_vel ! =T => full velocities in 3D boundary data
[9019]	365	! ! =F => baroclinic velocities in 3D boundary data
[3294]	366	INTEGER :: ilen_global ! Max length required for global bdy dta arrays
	367	INTEGER, ALLOCATABLE, DIMENSION(:) :: ilen1, ilen3 ! size of 1st and 3rd dimensions of local arrays
	368	INTEGER, ALLOCATABLE, DIMENSION(:) :: ibdy ! bdy set for a particular jfld
	369	INTEGER, ALLOCATABLE, DIMENSION(:) :: igrid ! index for grid type (1,2,3 = T,U,V)
	370	INTEGER, POINTER, DIMENSION(:) :: nblen, nblenrim ! short cuts
[4292]	371	TYPE(OBC_DATA), POINTER :: dta ! short cut
[9570]	372	#if defined key_si3
[9019]	373	INTEGER :: kndims ! number of dimensions in an array (i.e. 3 = wo ice cat; 4 = w ice cat)
	374	INTEGER, DIMENSION(4) :: kdimsz ! size of dimensions
[4292]	375	INTEGER :: inum,id1 ! local integer
	376	#endif
[3294]	377	TYPE(FLD_N), ALLOCATABLE, DIMENSION(:) :: blf_i ! array of namelist information structures
	378	TYPE(FLD_N) :: bn_tem, bn_sal, bn_u3d, bn_v3d !
	379	TYPE(FLD_N) :: bn_ssh, bn_u2d, bn_v2d ! informations about the fields to be read
[9570]	380	#if defined key_si3
[9019]	381	TYPE(FLD_N) :: bn_a_i, bn_h_i, bn_h_s
[2528]	382	#endif
[3294]	383	NAMELIST/nambdy_dta/ cn_dir, bn_tem, bn_sal, bn_u3d, bn_v3d, bn_ssh, bn_u2d, bn_v2d
[9570]	384	#if defined key_si3
[9019]	385	NAMELIST/nambdy_dta/ bn_a_i, bn_h_i, bn_h_s
[3294]	386	#endif
[7646]	387	NAMELIST/nambdy_dta/ ln_full_vel, nb_jpk_bdy
[3294]	388	!!---------------------------------------------------------------------------
[6140]	389	!
[3651]	390	IF(lwp) WRITE(numout,*)
	391	IF(lwp) WRITE(numout,*) 'bdy_dta_ini : initialization of data at the open boundaries'
	392	IF(lwp) WRITE(numout,*) '~~~~~~~~~~'
	393	IF(lwp) WRITE(numout,*) ''
	394
[3294]	395	! Set nn_dta
[9019]	396	DO jbdy = 1, nb_bdy
	397	nn_dta(jbdy) = MAX( nn_dyn2d_dta (jbdy) &
	398	& , nn_dyn3d_dta (jbdy) &
	399	& , nn_tra_dta (jbdy) &
[9570]	400	#if defined key_si3
[9657]	401	& , nn_ice_dta (jbdy) &
[2528]	402	#endif
[3294]	403	)
[9019]	404	IF(nn_dta(jbdy) > 1) nn_dta(jbdy) = 1
[3294]	405	END DO
[911]	406
[3294]	407	! Work out upper bound of how many fields there are to read in and allocate arrays
	408	! ---------------------------------------------------------------------------
	409	ALLOCATE( nb_bdy_fld(nb_bdy) )
	410	nb_bdy_fld(:) = 0
[9019]	411	DO jbdy = 1, nb_bdy
	412	IF( cn_dyn2d(jbdy) /= 'none' .AND. ( nn_dyn2d_dta(jbdy) == 1 .or. nn_dyn2d_dta(jbdy) == 3 ) ) THEN
	413	nb_bdy_fld(jbdy) = nb_bdy_fld(jbdy) + 3
[3294]	414	ENDIF
[9019]	415	IF( cn_dyn3d(jbdy) /= 'none' .AND. nn_dyn3d_dta(jbdy) == 1 ) THEN
	416	nb_bdy_fld(jbdy) = nb_bdy_fld(jbdy) + 2
[3294]	417	ENDIF
[9019]	418	IF( cn_tra(jbdy) /= 'none' .AND. nn_tra_dta(jbdy) == 1 ) THEN
	419	nb_bdy_fld(jbdy) = nb_bdy_fld(jbdy) + 2
[3294]	420	ENDIF
[9570]	421	#if defined key_si3
[9657]	422	IF( cn_ice(jbdy) /= 'none' .AND. nn_ice_dta(jbdy) == 1 ) THEN
[9019]	423	nb_bdy_fld(jbdy) = nb_bdy_fld(jbdy) + 3
[3294]	424	ENDIF
	425	#endif
[9019]	426	IF(lwp) WRITE(numout,*) 'Maximum number of files to open =', nb_bdy_fld(jbdy)
[6140]	427	END DO
[2528]	428
[3294]	429	nb_bdy_fld_sum = SUM( nb_bdy_fld )
[911]	430
[3294]	431	ALLOCATE( bf(nb_bdy_fld_sum), STAT=ierror )
	432	IF( ierror > 0 ) THEN
	433	CALL ctl_stop( 'bdy_dta: unable to allocate bf structure' ) ; RETURN
[911]	434	ENDIF
[3294]	435	ALLOCATE( blf_i(nb_bdy_fld_sum), STAT=ierror )
	436	IF( ierror > 0 ) THEN
	437	CALL ctl_stop( 'bdy_dta: unable to allocate blf_i structure' ) ; RETURN
[1125]	438	ENDIF
[3294]	439	ALLOCATE( nbmap_ptr(nb_bdy_fld_sum), STAT=ierror )
	440	IF( ierror > 0 ) THEN
	441	CALL ctl_stop( 'bdy_dta: unable to allocate nbmap_ptr structure' ) ; RETURN
	442	ENDIF
	443	ALLOCATE( ilen1(nb_bdy_fld_sum), ilen3(nb_bdy_fld_sum) )
	444	ALLOCATE( ibdy(nb_bdy_fld_sum) )
	445	ALLOCATE( igrid(nb_bdy_fld_sum) )
[911]	446
[3294]	447	! Read namelists
	448	! --------------
[4147]	449	REWIND(numnam_ref)
	450	REWIND(numnam_cfg)
[3294]	451	jfld = 0
[9019]	452	DO jbdy = 1, nb_bdy
	453	IF( nn_dta(jbdy) == 1 ) THEN
[4147]	454	READ ( numnam_ref, nambdy_dta, IOSTAT = ios, ERR = 901)
[6140]	455	901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'nambdy_dta in reference namelist', lwp )
[4147]	456	READ ( numnam_cfg, nambdy_dta, IOSTAT = ios, ERR = 902 )
[9168]	457	902 IF( ios > 0 ) CALL ctl_nam ( ios , 'nambdy_dta in configuration namelist', lwp )
[6140]	458	IF(lwm) WRITE( numond, nambdy_dta )
[4147]	459
[9019]	460	cn_dir_array(jbdy) = cn_dir
	461	ln_full_vel_array(jbdy) = ln_full_vel
[911]	462
[9019]	463	nblen => idx_bdy(jbdy)%nblen
	464	nblenrim => idx_bdy(jbdy)%nblenrim
	465	dta => dta_bdy(jbdy)
[4292]	466	dta%nread(2) = 0
[911]	467
[3294]	468	! Only read in necessary fields for this set.
	469	! Important that barotropic variables come first.
[9019]	470	IF( nn_dyn2d_dta(jbdy) == 1 .or. nn_dyn2d_dta(jbdy) == 3 ) THEN
[911]	471
[4292]	472	IF( dta%ll_ssh ) THEN
	473	if(lwp) write(numout,*) '++++++ reading in ssh field'
[3294]	474	jfld = jfld + 1
	475	blf_i(jfld) = bn_ssh
[9019]	476	ibdy(jfld) = jbdy
[3294]	477	igrid(jfld) = 1
[3651]	478	ilen1(jfld) = nblen(igrid(jfld))
[3294]	479	ilen3(jfld) = 1
[4292]	480	dta%nread(2) = dta%nread(2) + 1
[3294]	481	ENDIF
[911]	482
[9019]	483	IF( dta%ll_u2d .and. .not. ln_full_vel_array(jbdy) ) THEN
[4292]	484	if(lwp) write(numout,*) '++++++ reading in u2d field'
[3294]	485	jfld = jfld + 1
	486	blf_i(jfld) = bn_u2d
[9019]	487	ibdy(jfld) = jbdy
[3294]	488	igrid(jfld) = 2
[3651]	489	ilen1(jfld) = nblen(igrid(jfld))
[3294]	490	ilen3(jfld) = 1
[4292]	491	dta%nread(2) = dta%nread(2) + 1
	492	ENDIF
[911]	493
[9019]	494	IF( dta%ll_v2d .and. .not. ln_full_vel_array(jbdy) ) THEN
[4292]	495	if(lwp) write(numout,*) '++++++ reading in v2d field'
[3294]	496	jfld = jfld + 1
	497	blf_i(jfld) = bn_v2d
[9019]	498	ibdy(jfld) = jbdy
[3294]	499	igrid(jfld) = 3
[3651]	500	ilen1(jfld) = nblen(igrid(jfld))
[3294]	501	ilen3(jfld) = 1
[4292]	502	dta%nread(2) = dta%nread(2) + 1
[3294]	503	ENDIF
[911]	504
[3294]	505	ENDIF
[1125]	506
[4292]	507	! read 3D velocities if baroclinic velocities require OR if
	508	! barotropic velocities required and ln_full_vel set to .true.
[9019]	509	IF( nn_dyn3d_dta(jbdy) == 1 .OR. &
	510	& ( ln_full_vel_array(jbdy) .AND. ( nn_dyn2d_dta(jbdy) == 1 .OR. nn_dyn2d_dta(jbdy) == 3 ) ) ) THEN
[911]	511
[9019]	512	IF( dta%ll_u3d .OR. ( ln_full_vel_array(jbdy) .and. dta%ll_u2d ) ) THEN
[4292]	513	if(lwp) write(numout,*) '++++++ reading in u3d field'
	514	jfld = jfld + 1
	515	blf_i(jfld) = bn_u3d
[9019]	516	ibdy(jfld) = jbdy
[4292]	517	igrid(jfld) = 2
	518	ilen1(jfld) = nblen(igrid(jfld))
	519	ilen3(jfld) = jpk
[9019]	520	IF( ln_full_vel_array(jbdy) .and. dta%ll_u2d ) dta%nread(2) = dta%nread(2) + 1
[4292]	521	ENDIF
[911]	522
[9019]	523	IF( dta%ll_v3d .OR. ( ln_full_vel_array(jbdy) .and. dta%ll_v2d ) ) THEN
[4292]	524	if(lwp) write(numout,*) '++++++ reading in v3d field'
	525	jfld = jfld + 1
	526	blf_i(jfld) = bn_v3d
[9019]	527	ibdy(jfld) = jbdy
[4292]	528	igrid(jfld) = 3
	529	ilen1(jfld) = nblen(igrid(jfld))
	530	ilen3(jfld) = jpk
[9019]	531	IF( ln_full_vel_array(jbdy) .and. dta%ll_v2d ) dta%nread(2) = dta%nread(2) + 1
[4292]	532	ENDIF
[911]	533
[3294]	534	ENDIF
[911]	535
[3294]	536	! temperature and salinity
[9019]	537	IF( nn_tra_dta(jbdy) == 1 ) THEN
[911]	538
[4292]	539	IF( dta%ll_tem ) THEN
	540	if(lwp) write(numout,*) '++++++ reading in tem field'
	541	jfld = jfld + 1
	542	blf_i(jfld) = bn_tem
[9019]	543	ibdy(jfld) = jbdy
[4292]	544	igrid(jfld) = 1
	545	ilen1(jfld) = nblen(igrid(jfld))
	546	ilen3(jfld) = jpk
	547	ENDIF
[911]	548
[4292]	549	IF( dta%ll_sal ) THEN
	550	if(lwp) write(numout,*) '++++++ reading in sal field'
	551	jfld = jfld + 1
	552	blf_i(jfld) = bn_sal
[9019]	553	ibdy(jfld) = jbdy
[4292]	554	igrid(jfld) = 1
	555	ilen1(jfld) = nblen(igrid(jfld))
	556	ilen3(jfld) = jpk
	557	ENDIF
[911]	558
	559	ENDIF
	560
[9570]	561	#if defined key_si3
[3294]	562	! sea ice
[9657]	563	IF( nn_ice_dta(jbdy) == 1 ) THEN
[9019]	564	! Test for types of ice input (1cat or Xcat)
[5919]	565	! Build file name to find dimensions
[7861]	566	clname=TRIM( cn_dir )//TRIM(bn_a_i%clname)
[5919]	567	IF( .NOT. bn_a_i%ln_clim ) THEN
[7861]	568	WRITE(clname, '(a,"_y",i4.4)' ) TRIM( clname ), nyear ! add year
	569	IF( bn_a_i%cltype /= 'yearly' ) WRITE(clname, '(a,"m" ,i2.2)' ) TRIM( clname ), nmonth ! add month
[5919]	570	ELSE
[7861]	571	IF( bn_a_i%cltype /= 'yearly' ) WRITE(clname, '(a,"_m",i2.2)' ) TRIM( clname ), nmonth ! add month
[5919]	572	ENDIF
	573	IF( bn_a_i%cltype == 'daily' .OR. bn_a_i%cltype(1:4) == 'week' ) &
[7861]	574	& WRITE(clname, '(a,"d" ,i2.2)' ) TRIM( clname ), nday ! add day
[5919]	575	!
	576	CALL iom_open ( clname, inum )
[9019]	577	id1 = iom_varid( inum, bn_a_i%clvar, kdimsz=kdimsz, kndims=kndims, ldstop = .FALSE. )
[5919]	578	CALL iom_close ( inum )
[4292]	579
[9019]	580	IF ( kndims == 4 ) THEN
	581	nice_cat = kdimsz(4) ! Xcat input
[4292]	582	ELSE
[9019]	583	nice_cat = 1 ! 1cat input
[4292]	584	ENDIF
	585	! End test
	586
	587	IF( dta%ll_a_i ) THEN
	588	jfld = jfld + 1
	589	blf_i(jfld) = bn_a_i
[9019]	590	ibdy(jfld) = jbdy
[4292]	591	igrid(jfld) = 1
	592	ilen1(jfld) = nblen(igrid(jfld))
[9019]	593	ilen3(jfld) = nice_cat
[4292]	594	ENDIF
	595
[9019]	596	IF( dta%ll_h_i ) THEN
[4292]	597	jfld = jfld + 1
[9019]	598	blf_i(jfld) = bn_h_i
	599	ibdy(jfld) = jbdy
[4292]	600	igrid(jfld) = 1
	601	ilen1(jfld) = nblen(igrid(jfld))
[9019]	602	ilen3(jfld) = nice_cat
[4292]	603	ENDIF
	604
[9019]	605	IF( dta%ll_h_s ) THEN
[4292]	606	jfld = jfld + 1
[9019]	607	blf_i(jfld) = bn_h_s
	608	ibdy(jfld) = jbdy
[4292]	609	igrid(jfld) = 1
	610	ilen1(jfld) = nblen(igrid(jfld))
[9019]	611	ilen3(jfld) = nice_cat
[4292]	612	ENDIF
	613
[4333]	614	ENDIF
[3294]	615	#endif
	616	! Recalculate field counts
	617	!-------------------------
[9019]	618	IF( jbdy == 1 ) THEN
[4148]	619	nb_bdy_fld_sum = 0
[9019]	620	nb_bdy_fld(jbdy) = jfld
[3294]	621	nb_bdy_fld_sum = jfld
	622	ELSE
[9019]	623	nb_bdy_fld(jbdy) = jfld - nb_bdy_fld_sum
	624	nb_bdy_fld_sum = nb_bdy_fld_sum + nb_bdy_fld(jbdy)
[3294]	625	ENDIF
[911]	626
[9019]	627	dta%nread(1) = nb_bdy_fld(jbdy)
[4292]	628
[6140]	629	ENDIF ! nn_dta == 1
[9019]	630	ENDDO ! jbdy
[911]	631
[3294]	632	DO jfld = 1, nb_bdy_fld_sum
	633	ALLOCATE( bf(jfld)%fnow(ilen1(jfld),1,ilen3(jfld)) )
	634	IF( blf_i(jfld)%ln_tint ) ALLOCATE( bf(jfld)%fdta(ilen1(jfld),1,ilen3(jfld),2) )
	635	nbmap_ptr(jfld)%ptr => idx_bdy(ibdy(jfld))%nbmap(:,igrid(jfld))
[5132]	636	nbmap_ptr(jfld)%ll_unstruc = ln_coords_file(ibdy(jfld))
[3294]	637	ENDDO
[911]	638
[3294]	639	! fill bf with blf_i and control print
	640	!-------------------------------------
	641	jstart = 1
[9019]	642	DO jbdy = 1, nb_bdy
	643	jend = jstart - 1 + nb_bdy_fld(jbdy)
	644	CALL fld_fill( bf(jstart:jend), blf_i(jstart:jend), cn_dir_array(jbdy), 'bdy_dta', &
[3294]	645	& 'open boundary conditions', 'nambdy_dta' )
	646	jstart = jend + 1
	647	ENDDO
[911]	648
[9629]	649	DO jfld = 1, nb_bdy_fld_sum
	650	bf(jfld)%igrd = igrid(jfld)
	651	bf(jfld)%ibdy = ibdy(jfld)
	652	ENDDO
	653
[3294]	654	! Initialise local boundary data arrays
	655	! nn_xxx_dta=0 : allocate space - will be filled from initial conditions later
	656	! nn_xxx_dta=1 : point to "fnow" arrays
	657	!-------------------------------------
[911]	658
[3294]	659	jfld = 0
[9019]	660	DO jbdy=1, nb_bdy
[911]	661
[9019]	662	nblen => idx_bdy(jbdy)%nblen
	663	dta => dta_bdy(jbdy)
[911]	664
[4292]	665	if(lwp) then
	666	write(numout,*) '++++++ dta%ll_ssh = ',dta%ll_ssh
	667	write(numout,*) '++++++ dta%ll_u2d = ',dta%ll_u2d
	668	write(numout,*) '++++++ dta%ll_v2d = ',dta%ll_v2d
	669	write(numout,*) '++++++ dta%ll_u3d = ',dta%ll_u3d
	670	write(numout,*) '++++++ dta%ll_v3d = ',dta%ll_v3d
	671	write(numout,*) '++++++ dta%ll_tem = ',dta%ll_tem
	672	write(numout,*) '++++++ dta%ll_sal = ',dta%ll_sal
	673	endif
	674
[9019]	675	IF ( nn_dyn2d_dta(jbdy) == 0 .or. nn_dyn2d_dta(jbdy) == 2 ) THEN
[4292]	676	if(lwp) write(numout,*) '++++++ dta%ssh/u2d/u3d allocated space'
	677	IF( dta%ll_ssh ) ALLOCATE( dta%ssh(nblen(1)) )
	678	IF( dta%ll_u2d ) ALLOCATE( dta%u2d(nblen(2)) )
	679	IF( dta%ll_v2d ) ALLOCATE( dta%v2d(nblen(3)) )
	680	ENDIF
[9019]	681	IF ( nn_dyn2d_dta(jbdy) == 1 .or. nn_dyn2d_dta(jbdy) == 3 ) THEN
[4292]	682	IF( dta%ll_ssh ) THEN
	683	if(lwp) write(numout,*) '++++++ dta%ssh pointing to fnow'
	684	jfld = jfld + 1
	685	dta%ssh => bf(jfld)%fnow(:,1,1)
	686	ENDIF
	687	IF ( dta%ll_u2d ) THEN
[9019]	688	IF ( ln_full_vel_array(jbdy) ) THEN
[4292]	689	if(lwp) write(numout,*) '++++++ dta%u2d allocated space'
	690	ALLOCATE( dta%u2d(nblen(2)) )
	691	ELSE
	692	if(lwp) write(numout,*) '++++++ dta%u2d pointing to fnow'
[3651]	693	jfld = jfld + 1
[4292]	694	dta%u2d => bf(jfld)%fnow(:,1,1)
	695	ENDIF
	696	ENDIF
	697	IF ( dta%ll_v2d ) THEN
[9019]	698	IF ( ln_full_vel_array(jbdy) ) THEN
[4292]	699	if(lwp) write(numout,*) '++++++ dta%v2d allocated space'
	700	ALLOCATE( dta%v2d(nblen(3)) )
[3294]	701	ELSE
[4292]	702	if(lwp) write(numout,*) '++++++ dta%v2d pointing to fnow'
[3294]	703	jfld = jfld + 1
[4292]	704	dta%v2d => bf(jfld)%fnow(:,1,1)
[3294]	705	ENDIF
	706	ENDIF
	707	ENDIF
[911]	708
[9019]	709	IF ( nn_dyn3d_dta(jbdy) == 0 ) THEN
[4292]	710	if(lwp) write(numout,*) '++++++ dta%u3d/v3d allocated space'
[9019]	711	IF( dta%ll_u3d ) ALLOCATE( dta_bdy(jbdy)%u3d(nblen(2),jpk) )
	712	IF( dta%ll_v3d ) ALLOCATE( dta_bdy(jbdy)%v3d(nblen(3),jpk) )
[3294]	713	ENDIF
[9019]	714	IF ( nn_dyn3d_dta(jbdy) == 1 .or. &
	715	& ( ln_full_vel_array(jbdy) .and. ( nn_dyn2d_dta(jbdy) == 1 .or. nn_dyn2d_dta(jbdy) == 3 ) ) ) THEN
	716	IF ( dta%ll_u3d .or. ( ln_full_vel_array(jbdy) .and. dta%ll_u2d ) ) THEN
[4292]	717	if(lwp) write(numout,*) '++++++ dta%u3d pointing to fnow'
	718	jfld = jfld + 1
[9019]	719	dta_bdy(jbdy)%u3d => bf(jfld)%fnow(:,1,:)
[4292]	720	ENDIF
[9019]	721	IF ( dta%ll_v3d .or. ( ln_full_vel_array(jbdy) .and. dta%ll_v2d ) ) THEN
[4292]	722	if(lwp) write(numout,*) '++++++ dta%v3d pointing to fnow'
	723	jfld = jfld + 1
[9019]	724	dta_bdy(jbdy)%v3d => bf(jfld)%fnow(:,1,:)
[4292]	725	ENDIF
[3294]	726	ENDIF
[911]	727
[9019]	728	IF( nn_tra_dta(jbdy) == 0 ) THEN
[4292]	729	if(lwp) write(numout,*) '++++++ dta%tem/sal allocated space'
[9019]	730	IF( dta%ll_tem ) ALLOCATE( dta_bdy(jbdy)%tem(nblen(1),jpk) )
	731	IF( dta%ll_sal ) ALLOCATE( dta_bdy(jbdy)%sal(nblen(1),jpk) )
[4292]	732	ELSE
	733	IF( dta%ll_tem ) THEN
	734	if(lwp) write(numout,*) '++++++ dta%tem pointing to fnow'
[3294]	735	jfld = jfld + 1
[9019]	736	dta_bdy(jbdy)%tem => bf(jfld)%fnow(:,1,:)
[4292]	737	ENDIF
	738	IF( dta%ll_sal ) THEN
	739	if(lwp) write(numout,*) '++++++ dta%sal pointing to fnow'
[3294]	740	jfld = jfld + 1
[9019]	741	dta_bdy(jbdy)%sal => bf(jfld)%fnow(:,1,:)
[3294]	742	ENDIF
	743	ENDIF
[911]	744
[9570]	745	#if defined key_si3
[9657]	746	IF (cn_ice(jbdy) /= 'none') THEN
	747	IF( nn_ice_dta(jbdy) == 0 ) THEN
[9019]	748	ALLOCATE( dta_bdy(jbdy)%a_i(nblen(1),jpl) )
	749	ALLOCATE( dta_bdy(jbdy)%h_i(nblen(1),jpl) )
	750	ALLOCATE( dta_bdy(jbdy)%h_s(nblen(1),jpl) )
[3294]	751	ELSE
[9019]	752	IF ( nice_cat == jpl ) THEN ! case input cat = jpl
[4292]	753	jfld = jfld + 1
[9019]	754	dta_bdy(jbdy)%a_i => bf(jfld)%fnow(:,1,:)
[4292]	755	jfld = jfld + 1
[9019]	756	dta_bdy(jbdy)%h_i => bf(jfld)%fnow(:,1,:)
[4292]	757	jfld = jfld + 1
[9019]	758	dta_bdy(jbdy)%h_s => bf(jfld)%fnow(:,1,:)
	759	ELSE ! case input cat = 1 OR (/=1 and /=jpl)
[9810]	760	jfld_ait(jbdy) = jfld + 1
	761	jfld_htit(jbdy) = jfld + 2
	762	jfld_htst(jbdy) = jfld + 3
[4292]	763	jfld = jfld + 3
[9019]	764	ALLOCATE( dta_bdy(jbdy)%a_i(nblen(1),jpl) )
	765	ALLOCATE( dta_bdy(jbdy)%h_i(nblen(1),jpl) )
	766	ALLOCATE( dta_bdy(jbdy)%h_s(nblen(1),jpl) )
	767	dta_bdy(jbdy)%a_i(:,:) = 0._wp
	768	dta_bdy(jbdy)%h_i(:,:) = 0._wp
	769	dta_bdy(jbdy)%h_s(:,:) = 0._wp
[4292]	770	ENDIF
	771
	772	ENDIF
	773	ENDIF
[3294]	774	#endif
[6140]	775	!
[9019]	776	END DO ! jbdy
[6140]	777	!
	778	END SUBROUTINE bdy_dta_init
[911]	779
	780	!!==============================================================================
	781	END MODULE bdydta

Note: See TracBrowser for help on using the repository browser.

Download in other formats: