New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zrem.F90 in NEMO/branches/2019/dev_r11708_aumont_PISCES_QUOTA/src/TOP/PISCES/P4Z – NEMO

source: NEMO/branches/2019/dev_r11708_aumont_PISCES_QUOTA/src/TOP/PISCES/P4Z/p4zrem.F90 @ 12682

Last change on this file since 12682 was 12682, checked in by aumont, 4 years ago

small bug fix
  • Property svn:keywords set to Id
File size: 20.4 KB
Line 
1MODULE p4zrem
2   !!======================================================================
3   !!                         ***  MODULE p4zrem  ***
4   !! TOP :   PISCES Compute remineralization/dissolution of organic compounds
5   !!         except for POC which is treated in p4zpoc.F90
6   !!         This module is common to both PISCES and PISCES-QUOTA
7   !!=========================================================================
8   !! History :   1.0  !  2004     (O. Aumont) Original code
9   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
10   !!             3.4  !  2011-06  (O. Aumont, C. Ethe) Quota model for iron
11   !!----------------------------------------------------------------------
12   !!   p4z_rem       :  Compute remineralization/dissolution of organic compounds
13   !!   p4z_rem_init  :  Initialisation of parameters for remineralisation
14   !!   p4z_rem_alloc :  Allocate remineralisation variables
15   !!----------------------------------------------------------------------
16   USE oce_trc         !  shared variables between ocean and passive tracers
17   USE trc             !  passive tracers common variables
18   USE sms_pisces      !  PISCES Source Minus Sink variables
19   USE p4zche          !  chemical model
20   USE p4zprod         !  Growth rate of the 2 phyto groups
21   USE p4zlim          !  Nutrient limitation terms
22   USE prtctl_trc      !  print control for debugging
23   USE iom             !  I/O manager
24
25
26   IMPLICIT NONE
27   PRIVATE
28
29   PUBLIC   p4z_rem         ! called in p4zbio.F90
30   PUBLIC   p4z_rem_init    ! called in trcini_pisces.F90
31   PUBLIC   p4z_rem_alloc   ! called in trcini_pisces.F90
32
33   !! * Shared module variables
34   REAL(wp), PUBLIC ::   xremikc    !: remineralisation rate of DOC (p5z)
35   REAL(wp), PUBLIC ::   xremikn    !: remineralisation rate of DON (p5z)
36   REAL(wp), PUBLIC ::   xremikp    !: remineralisation rate of DOP (p5z)
37   REAL(wp), PUBLIC ::   xremik     !: remineralisation rate of DOC (p4z)
38   REAL(wp), PUBLIC ::   nitrif     !: NH4 nitrification rate
39   REAL(wp), PUBLIC ::   xsirem     !: remineralisation rate of biogenic silica
40   REAL(wp), PUBLIC ::   xsiremlab  !: fast remineralisation rate of BSi
41   REAL(wp), PUBLIC ::   xsilab     !: fraction of labile biogenic silica
42   REAL(wp), PUBLIC ::   feratb     !: Fe/C quota in bacteria
43   REAL(wp), PUBLIC ::   xkferb     !: Half-saturation constant for bacterial Fe/C
44
45   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   denitr   !: denitrification array
46
47   !!----------------------------------------------------------------------
48   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
49   !! $Id$
50   !! Software governed by the CeCILL license (see ./LICENSE)
51   !!----------------------------------------------------------------------
52CONTAINS
53
54   SUBROUTINE p4z_rem( kt, knt )
55      !!---------------------------------------------------------------------
56      !!                     ***  ROUTINE p4z_rem  ***
57      !!
58      !! ** Purpose :   Compute remineralization/dissolution of organic compounds
59      !!                Computes also nitrification of ammonium
60      !!                The solubilization/remineralization of POC is treated
61      !!                in p4zpoc.F90. The dissolution of calcite is processed
62      !!                in p4zlys.F90.
63      !!
64      !! ** Method  : - Bacterial biomass is computed implicitely based on a
65      !!                parameterization developed from an explicit modeling
66      !!                of PISCES in an alternative version
67      !!---------------------------------------------------------------------
68      INTEGER, INTENT(in) ::   kt, knt ! ocean time step
69      !
70      INTEGER  ::   ji, jj, jk
71      REAL(wp) ::   zremik, zremikc, zremikn, zremikp, zsiremin, zfact 
72      REAL(wp) ::   zsatur, zsatur2, znusil, znusil2, zdep, zdepmin, zfactdep
73      REAL(wp) ::   zbactfer, zolimit, zonitr, zrfact2
74      REAL(wp) ::   zammonic, zoxyremc, zoxyremn, zoxyremp
75      REAL(wp) ::   zosil, ztem, zdenitnh4, zolimic, zolimin, zolimip, zdenitrn, zdenitrp
76      CHARACTER (len=25) :: charout
77      REAL(wp), DIMENSION(jpi,jpj    ) :: ztempbac
78      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zdepbac, zolimi, zdepprod, zfacsi, zfacsib, zdepeff, zfebact
79      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) :: zw3d
80      !!---------------------------------------------------------------------
81      !
82      IF( ln_timing )   CALL timing_start('p4z_rem')
83      !
84      ! Initialisation of arrays
85      zdepprod(:,:,:) = 1._wp
86      zdepeff (:,:,:) = 0.3_wp
87      ztempbac(:,:)   = 0._wp
88      zfacsib(:,:,:)  = xsilab / ( 1.0 - xsilab )
89      zfebact(:,:,:)  = 0._wp
90      zfacsi(:,:,:)   = xsilab
91
92      ! Computation of the mean bacterial concentration
93      ! this parameterization has been deduced from a model version
94      ! that was modeling explicitely bacteria
95      ! -------------------------------------------------------
96      DO jk = 1, jpkm1
97         DO jj = 1, jpj
98            DO ji = 1, jpi
99               zdep = MAX( hmld(ji,jj), heup(ji,jj) )
100               IF( gdept_n(ji,jj,jk) < zdep ) THEN
101                  zdepbac(ji,jj,jk) = MIN( 0.7 * ( trb(ji,jj,jk,jpzoo) + 2.* trb(ji,jj,jk,jpmes) ), 4.e-6 )
102                  ztempbac(ji,jj)   = zdepbac(ji,jj,jk)
103               ELSE
104                  zdepmin = MIN( 1., zdep / gdept_n(ji,jj,jk) )
105                  zdepbac (ji,jj,jk) = zdepmin**0.683 * ztempbac(ji,jj)
106                  zdepprod(ji,jj,jk) = zdepmin**0.273
107                  zdepeff (ji,jj,jk) = zdepeff(ji,jj,jk) * zdepmin**0.3
108               ENDIF
109            END DO
110         END DO
111      END DO
112
113      IF( ln_p4z ) THEN
114         DO jk = 1, jpkm1
115            DO jj = 1, jpj
116               DO ji = 1, jpi
117                  ! DOC ammonification. Depends on a limitation term of the bacterial activity
118                  ! and on the implicit bacteria concentration
119                  ! --------------------------------------------------------------------------
120                  zremik = xremik * xstep / 1.e-6 * xlimbac(ji,jj,jk) * zdepbac(ji,jj,jk) 
121                  zremik = MAX( zremik, 2.74e-4 * xstep )
122
123                  ! Ammonification in oxic waters with oxygen consumption
124                  ! -----------------------------------------------------
125                  zolimit = zremik * ( 1.- nitrfac(ji,jj,jk) ) * trb(ji,jj,jk,jpdoc) 
126                  zolimi(ji,jj,jk) = MIN( ( trb(ji,jj,jk,jpoxy) - rtrn ) / o2ut, zolimit ) 
127
128                  ! Ammonification in suboxic waters with denitrification
129                  ! -----------------------------------------------------
130                  zammonic = zremik * nitrfac(ji,jj,jk) * trb(ji,jj,jk,jpdoc)
131                  denitr(ji,jj,jk)  = zammonic * ( 1. - nitrfac2(ji,jj,jk) )
132                  denitr(ji,jj,jk)  = MIN( ( trb(ji,jj,jk,jpno3) - rtrn ) / rdenit, denitr(ji,jj,jk) )
133
134                  ! Ammonification in waters depleted in O2 and NO3 based on
135                  ! other redox processes
136                  ! --------------------------------------------------------
137                  zoxyremc          = zammonic - denitr(ji,jj,jk)
138                  !
139                  zolimi (ji,jj,jk) = MAX( 0.e0, zolimi (ji,jj,jk) )
140                  denitr (ji,jj,jk) = MAX( 0.e0, denitr (ji,jj,jk) )
141                  zoxyremc          = MAX( 0.e0, zoxyremc )
142                  ! Update of the TRA arrays
143                  tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) + zolimi (ji,jj,jk) + denitr(ji,jj,jk) + zoxyremc
144                  tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) + zolimi (ji,jj,jk) + denitr(ji,jj,jk) + zoxyremc
145                  tra(ji,jj,jk,jpno3) = tra(ji,jj,jk,jpno3) - denitr (ji,jj,jk) * rdenit
146                  tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) - zolimi (ji,jj,jk) - denitr(ji,jj,jk) - zoxyremc
147                  tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) - zolimi (ji,jj,jk) * o2ut
148                  tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) + zolimi (ji,jj,jk) + denitr(ji,jj,jk) + zoxyremc
149                  tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + rno3 * ( zolimi(ji,jj,jk) + zoxyremc    &
150                  &                     + ( rdenit + 1.) * denitr(ji,jj,jk) )
151               END DO
152            END DO
153         END DO
154      ELSE
155         DO jk = 1, jpkm1
156            DO jj = 1, jpj
157               DO ji = 1, jpi
158                  ! DOC ammonification. Depends on a limitation term of the bacterial activity
159                  ! and on the implicit bacteria concentration
160                  ! ---------------------------------------------------------------
161                  zremik = xstep / 1.e-6 * MAX(0.01, xlimbac(ji,jj,jk)) * zdepbac(ji,jj,jk) 
162                  zremik = MAX( zremik, 2.74e-4 * xstep / xremikc )
163
164                  zremikc = xremikc * zremik
165                  zremikn = xremikn / xremikc
166                  zremikp = xremikp / xremikc
167
168                  ! Ammonification in oxic waters with oxygen consumption
169                  ! -----------------------------------------------------
170                  zolimit = zremikc * ( 1.- nitrfac(ji,jj,jk) ) * trb(ji,jj,jk,jpdoc) 
171                  zolimic = MAX( 0.e0, MIN( ( trb(ji,jj,jk,jpoxy) - rtrn ) / o2ut, zolimit ) ) 
172                  zolimi(ji,jj,jk) = zolimic
173                  zolimin = zremikn * zolimic * trb(ji,jj,jk,jpdon) / ( trb(ji,jj,jk,jpdoc) + rtrn )
174                  zolimip = zremikp * zolimic * trb(ji,jj,jk,jpdop) / ( trb(ji,jj,jk,jpdoc) + rtrn ) 
175
176                  ! Ammonification in suboxic waters with denitrification
177                  ! -------------------------------------------------------
178                  zammonic = zremikc * nitrfac(ji,jj,jk) * trb(ji,jj,jk,jpdoc)
179                  denitr(ji,jj,jk)  = zammonic * ( 1. - nitrfac2(ji,jj,jk) )
180                  denitr(ji,jj,jk)  = MAX(0., MIN(  ( trb(ji,jj,jk,jpno3) - rtrn ) / rdenit, denitr(ji,jj,jk) ) )
181                  zoxyremc          = MAX(0., zammonic - denitr(ji,jj,jk))
182                  zdenitrn  = zremikn * denitr(ji,jj,jk) * trb(ji,jj,jk,jpdon) / ( trb(ji,jj,jk,jpdoc) + rtrn )
183                  zdenitrp  = zremikp * denitr(ji,jj,jk) * trb(ji,jj,jk,jpdop) / ( trb(ji,jj,jk,jpdoc) + rtrn )
184                  zoxyremn  = zremikn * zoxyremc * trb(ji,jj,jk,jpdon) / ( trb(ji,jj,jk,jpdoc) + rtrn )
185                  zoxyremp  = zremikp * zoxyremc * trb(ji,jj,jk,jpdop) / ( trb(ji,jj,jk,jpdoc) + rtrn )
186                  ! Update of the TRA arrays
187                  tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) + zolimip + zdenitrp + zoxyremp
188                  tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) + zolimin + zdenitrn + zoxyremn
189                  tra(ji,jj,jk,jpno3) = tra(ji,jj,jk,jpno3) - denitr(ji,jj,jk) * rdenit
190                  tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) - zolimic - denitr(ji,jj,jk) - zoxyremc
191                  tra(ji,jj,jk,jpdon) = tra(ji,jj,jk,jpdon) - zolimin - zdenitrn - zoxyremn
192                  tra(ji,jj,jk,jpdop) = tra(ji,jj,jk,jpdop) - zolimip - zdenitrp - zoxyremp
193                  tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) - zolimic * o2ut
194                  tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) + zolimic + denitr(ji,jj,jk) + zoxyremc
195                  tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + rno3 * ( zolimin + zoxyremn + ( rdenit + 1.) * zdenitrn )
196               END DO
197            END DO
198         END DO
199         !
200      ENDIF
201
202      DO jk = 1, jpkm1
203         DO jj = 1, jpj
204            DO ji = 1, jpi
205               ! NH4 nitrification to NO3. Ceased for oxygen concentrations
206               ! below 2 umol/L. Inhibited at strong light
207               ! ----------------------------------------------------------
208               zonitr  = nitrif * xstep * trb(ji,jj,jk,jpnh4) * ( 1.- nitrfac(ji,jj,jk) )  &
209               &         / ( 1.+ emoy(ji,jj,jk) ) * ( 1. + fr_i(ji,jj) * emoy(ji,jj,jk) ) 
210               zdenitnh4 = nitrif * xstep * trb(ji,jj,jk,jpnh4) * nitrfac(ji,jj,jk)
211               zdenitnh4 = MIN(  ( trb(ji,jj,jk,jpno3) - rtrn ) / rdenita, zdenitnh4 ) 
212               ! Update of the tracers trends
213               ! ----------------------------
214               tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) - zonitr - zdenitnh4
215               tra(ji,jj,jk,jpno3) = tra(ji,jj,jk,jpno3) + zonitr - rdenita * zdenitnh4
216               tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) - o2nit * zonitr
217               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) - 2 * rno3 * zonitr + rno3 * ( rdenita - 1. ) * zdenitnh4
218            END DO
219         END DO
220      END DO
221
222       IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
223         WRITE(charout, FMT="('rem1')")
224         CALL prt_ctl_trc_info(charout)
225         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
226       ENDIF
227
228      DO jk = 1, jpkm1
229         DO jj = 1, jpj
230            DO ji = 1, jpi
231
232               ! Bacterial uptake of iron. No iron is available in DOC. So
233               ! Bacteries are obliged to take up iron from the water. Some
234               ! studies (especially at Papa) have shown this uptake to be significant
235               ! ---------------------------------------------------------------------
236               zbactfer = feratb *  rfact2 * 0.6_wp / rday * tgfunc(ji,jj,jk) * xlimbacl(ji,jj,jk)     &
237                  &              * trb(ji,jj,jk,jpfer) / ( xkferb + trb(ji,jj,jk,jpfer) )    &
238                  &              * zdepeff(ji,jj,jk) * zdepbac(ji,jj,jk)
239
240               ! Only the transfer of iron from its dissolved form to particles
241               ! is treated here. The GGE of bacteria supposed to be equal to
242               ! 0.33. This is hard-coded.
243               tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) - zbactfer*0.33
244               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + zbactfer*0.25
245               tra(ji,jj,jk,jpbfe) = tra(ji,jj,jk,jpbfe) + zbactfer*0.08
246               zfebact(ji,jj,jk)   = zbactfer * 0.33
247               blim(ji,jj,jk)      = xlimbacl(ji,jj,jk)  * zdepbac(ji,jj,jk) / 1.e-6
248            END DO
249         END DO
250      END DO
251
252       IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
253         WRITE(charout, FMT="('rem2')")
254         CALL prt_ctl_trc_info(charout)
255         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
256       ENDIF
257
258      ! Initialization of the array which contains the labile fraction
259      ! of bSi. Set to a constant in the upper ocean
260      ! ---------------------------------------------------------------
261      DO jk = 1, jpkm1
262         DO jj = 1, jpj
263            DO ji = 1, jpi
264               ! Remineralization rate of BSi depedant on T and saturation
265               ! The parameterization is taken from Ridgwell et al. (2002)
266               ! ---------------------------------------------------------
267               zdep     = MAX( hmld(ji,jj), heup_01(ji,jj) )
268               zsatur   = MAX( rtrn, ( sio3eq(ji,jj,jk) - trb(ji,jj,jk,jpsil) ) / ( sio3eq(ji,jj,jk) + rtrn ) )
269               zsatur2  = ( 1. + tsn(ji,jj,jk,jp_tem) / 400.)**37
270               znusil   = 0.225  * ( 1. + tsn(ji,jj,jk,jp_tem) / 15.) * zsatur + 0.775 * zsatur2 * zsatur**9.25
271               ! Computation of the vertical evolution of the labile fraction
272               ! of bSi. This is computed assuming steady state.
273               IF ( gdept_n(ji,jj,jk) > zdep ) THEN
274                  zfacsib(ji,jj,jk) = zfacsib(ji,jj,jk-1) * EXP( -0.5 * ( xsiremlab - xsirem )  &
275                  &                   * znusil * e3t_n(ji,jj,jk) / wsbio4(ji,jj,jk) )
276                  zfacsi(ji,jj,jk)  = zfacsib(ji,jj,jk) / ( 1.0 + zfacsib(ji,jj,jk) )
277                  zfacsib(ji,jj,jk) = zfacsib(ji,jj,jk) * EXP( -0.5 * ( xsiremlab - xsirem )    &
278                  &                   * znusil * e3t_n(ji,jj,jk) / wsbio4(ji,jj,jk) )
279               ENDIF
280               zsiremin = ( xsiremlab * zfacsi(ji,jj,jk) + xsirem * ( 1. - zfacsi(ji,jj,jk) ) ) * xstep * znusil
281               zosil    = zsiremin * trb(ji,jj,jk,jpgsi)
282               ! Update of the TRA arrays
283               tra(ji,jj,jk,jpgsi) = tra(ji,jj,jk,jpgsi) - zosil
284               tra(ji,jj,jk,jpsil) = tra(ji,jj,jk,jpsil) + zosil
285            END DO
286         END DO
287      END DO
288
289      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
290         WRITE(charout, FMT="('rem3')")
291         CALL prt_ctl_trc_info(charout)
292         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
293       ENDIF
294
295      IF( knt == nrdttrc ) THEN
296          zrfact2 = 1.e3 * rfact2r
297          ALLOCATE( zw3d(jpi,jpj,jpk) )
298          zfact = 1.e+3 * rfact2r  !  conversion from mol/l/kt to  mol/m3/s
299          !
300          IF( iom_use( "REMIN" ) )  THEN
301              zw3d(:,:,:) = zolimi(:,:,:) * tmask(:,:,:) * zfact !  Remineralisation rate
302              CALL iom_put( "REMIN"  , zw3d )
303          ENDIF
304          IF( iom_use( "DENIT" ) )  THEN
305              zw3d(:,:,:) = denitr(:,:,:) * rdenit * rno3 * tmask(:,:,:) * zfact ! Denitrification
306              CALL iom_put( "DENIT"  , zw3d )
307          ENDIF
308          IF( iom_use( "BACT" ) )  THEN
309               zw3d(:,:,:) = zdepbac(:,:,:) * 1.E6 * tmask(:,:,:)  ! Bacterial biomass
310               CALL iom_put( "BACT", zw3d )
311          ENDIF
312          IF( iom_use( "FEBACT" ) )  THEN
313               zw3d(:,:,:) = zfebact(:,:,:) * 1E9 * tmask(:,:,:) * zrfact2   ! Bacterial iron consumption
314               CALL iom_put( "FEBACT" , zw3d )
315          ENDIF
316          !
317          DEALLOCATE( zw3d )
318       ENDIF
319      !
320      IF( ln_timing )   CALL timing_stop('p4z_rem')
321      !
322   END SUBROUTINE p4z_rem
323
324
325   SUBROUTINE p4z_rem_init
326      !!----------------------------------------------------------------------
327      !!                  ***  ROUTINE p4z_rem_init  ***
328      !!
329      !! ** Purpose :   Initialization of remineralization parameters
330      !!
331      !! ** Method  :   Read the nampisrem namelist and check the parameters
332      !!      called at the first timestep
333      !!
334      !! ** input   :   Namelist nampisrem
335      !!
336      !!----------------------------------------------------------------------
337      NAMELIST/nampisrem/ xremik, nitrif, xsirem, xsiremlab, xsilab, feratb, xkferb, & 
338         &                xremikc, xremikn, xremikp
339      INTEGER :: ios                 ! Local integer output status for namelist read
340      !!----------------------------------------------------------------------
341      !
342      IF(lwp) THEN
343         WRITE(numout,*)
344         WRITE(numout,*) 'p4z_rem_init : Initialization of remineralization parameters'
345         WRITE(numout,*) '~~~~~~~~~~~~'
346      ENDIF
347      !
348      REWIND( numnatp_ref )              ! Namelist nampisrem in reference namelist : Pisces remineralization
349      READ  ( numnatp_ref, nampisrem, IOSTAT = ios, ERR = 901)
350901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'nampisrem in reference namelist' )
351      REWIND( numnatp_cfg )              ! Namelist nampisrem in configuration namelist : Pisces remineralization
352      READ  ( numnatp_cfg, nampisrem, IOSTAT = ios, ERR = 902 )
353902   IF( ios >  0 )   CALL ctl_nam ( ios , 'nampisrem in configuration namelist' )
354      IF(lwm) WRITE( numonp, nampisrem )
355
356      IF(lwp) THEN                         ! control print
357         WRITE(numout,*) '   Namelist parameters for remineralization, nampisrem'
358         IF( ln_p4z ) THEN
359            WRITE(numout,*) '      remineralization rate of DOC              xremik    =', xremik
360         ELSE
361            WRITE(numout,*) '      remineralization rate of DOC              xremikc   =', xremikc
362            WRITE(numout,*) '      remineralization rate of DON              xremikn   =', xremikn
363            WRITE(numout,*) '      remineralization rate of DOP              xremikp   =', xremikp
364         ENDIF
365         WRITE(numout,*) '      remineralization rate of Si               xsirem    =', xsirem
366         WRITE(numout,*) '      fast remineralization rate of Si          xsiremlab =', xsiremlab
367         WRITE(numout,*) '      fraction of labile biogenic silica        xsilab    =', xsilab
368         WRITE(numout,*) '      NH4 nitrification rate                    nitrif    =', nitrif
369         WRITE(numout,*) '      Bacterial Fe/C ratio                      feratb    =', feratb
370         WRITE(numout,*) '      Half-saturation constant for bact. Fe/C   xkferb    =', xkferb
371      ENDIF
372      !
373      denitr(:,:,:) = 0._wp
374      !
375   END SUBROUTINE p4z_rem_init
376
377
378   INTEGER FUNCTION p4z_rem_alloc()
379      !!----------------------------------------------------------------------
380      !!                     ***  ROUTINE p4z_rem_alloc  ***
381      !!----------------------------------------------------------------------
382      ALLOCATE( denitr(jpi,jpj,jpk), STAT=p4z_rem_alloc )
383      !
384      IF( p4z_rem_alloc /= 0 )   CALL ctl_stop( 'STOP', 'p4z_rem_alloc: failed to allocate arrays' )
385      !
386   END FUNCTION p4z_rem_alloc
387
388   !!======================================================================
389END MODULE p4zrem
Note: See TracBrowser for help on using the repository browser.