source: NEMO/branches/2019/dev_r12072_MERGE_OPTION2_2019/src/TOP/PISCES/P4Z/p4zbc.F90 @ 12257

Last change on this file since 12257 was 12257, checked in by cetlod, 10 months ago

dev_r12072_MERGE_OPTION2_2019: Cleaning PISCES diagnostics output ; fully sette tested

File size: 16.5 KB
Line 
1MODULE p4zbc
2   !!======================================================================
3   !!                         ***  MODULE p4sbc  ***
4   !! TOP :   PISCES surface boundary conditions of external inputs of nutrients
5   !!======================================================================
6   !! History :   3.5  !  2012-07 (O. Aumont, C. Ethe) Original code
7   !!----------------------------------------------------------------------
8   !!   p4z_bc        :  Read and interpolate time-varying nutrients fluxes
9   !!   p4z_bc_init   :  Initialization of p4z_bc
10   !!----------------------------------------------------------------------
11   USE oce_trc         !  shared variables between ocean and passive tracers
12   USE trc             !  passive tracers common variables
13   USE sms_pisces      !  PISCES Source Minus Sink variables
14   USE iom             !  I/O manager
15   USE fldread         !  time interpolation
16   USE trcbc
17
18   IMPLICIT NONE
19   PRIVATE
20
21   PUBLIC   p4z_bc
22   PUBLIC   p4z_bc_init   
23
24   LOGICAL , PUBLIC ::   ln_ironsed   !: boolean for Fe input from sediments
25   LOGICAL , PUBLIC ::   ln_hydrofe   !: boolean for Fe input from hydrothermal vents
26   REAL(wp), PUBLIC ::   sedfeinput   !: Coastal release of Iron
27   REAL(wp), PUBLIC ::   icefeinput   !: Iron concentration in sea ice
28   REAL(wp), PUBLIC ::   wdust        !: Sinking speed of the dust
29   REAL(wp), PUBLIC ::   mfrac        !: Mineral Content of the dust
30   REAL(wp)         ::   hratio       !: Fe:3He ratio assumed for vent iron supply
31   REAL(wp)         ::   distcoast    !: Distance off the coast for Iron from sediments
32   REAL(wp), PUBLIC ::   lgw_rath     !: Weak ligand ratio from hydro sources
33
34   LOGICAL , PUBLIC ::   ll_bc
35   LOGICAL , PUBLIC ::   ll_dust      !: boolean for dust input from the atmosphere
36   LOGICAL , PUBLIC ::   ll_river     !: boolean for river input of nutrients
37   LOGICAL , PUBLIC ::   ll_ndepo     !: boolean for atmospheric deposition of N
38   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_dust      ! structure of input dust
39   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_ironsed   ! structure of input iron from sediment
40   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_hydrofe   ! structure of input iron from sediment
41
42   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   dust    !: dust fields
43   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   ironsed          !: Coastal supply of iron
44   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   hydrofe          !: Hydrothermal vent supply of iron
45
46   REAL(wp), PUBLIC :: sedsilfrac, sedcalfrac
47
48   !! * Substitutions
49#  include "vectopt_loop_substitute.h90"
50   !!----------------------------------------------------------------------
51   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
52   !! $Id: p4zbc.F90 10869 2019-04-15 10:34:03Z cetlod $
53   !! Software governed by the CeCILL license (see ./LICENSE)
54   !!----------------------------------------------------------------------
55CONTAINS
56
57   SUBROUTINE p4z_bc( kt )
58      !!----------------------------------------------------------------------
59      !!                  ***  routine p4z_bc  ***
60      !!
61      !! ** purpose :   read and interpolate the external sources of nutrients
62      !!
63      !! ** method  :   read the files and interpolate the appropriate variables
64      !!
65      !! ** input   :   external netcdf files
66      !!
67      !!----------------------------------------------------------------------
68      INTEGER, INTENT(in) ::   kt   ! ocean time step
69      !
70      INTEGER  ::  ji, jj, jk, jl 
71      REAL(wp) ::  zcoef, zyyss
72      REAL(wp) ::  zdep, ztrfer, zwdust, zwflux, zrivdin
73      !
74      CHARACTER (len=25) :: charout
75      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) :: zirondep
76      REAL(wp), ALLOCATABLE, DIMENSION(:,:  ) :: zironice, zndep
77      !!---------------------------------------------------------------------
78      !
79      IF( ln_timing )   CALL timing_start('p4z_bc')
80      !
81      IF( ll_dust )  THEN
82         ALLOCATE(  zirondep(jpi,jpj,jpk) )
83         !
84         CALL fld_read( kt, 1, sf_dust )
85         dust(:,:) = MAX( rtrn, sf_dust(1)%fnow(:,:,1) )
86         !
87         jl = n_trc_indsbc(jpfer)
88         zirondep(:,:,1) = rf_trsfac(jl) * sf_trcsbc(jl)%fnow(:,:,1) / e3t_n(:,:,1) / rn_sbc_time
89         !                                              ! Iron solubilization of particles in the water column
90         !                                              ! dust in kg/m2/s ---> 1/55.85 to put in mol/Fe ;  wdust in m/j
91         zwdust = 0.03 / ( wdust / rday ) / ( 270. * rday )
92         DO jk = 2, jpkm1
93            zirondep(:,:,jk) = ( mfrac * dust(:,:) * zwdust / mMass_Fe ) * rfact * EXP( -gdept_n(:,:,jk) / 540. )
94            tra(:,:,jk,jpfer) = tra(:,:,jk,jpfer) + zirondep(:,:,jk)
95            tra(:,:,jk,jppo4) = tra(:,:,jk,jppo4) + zirondep(:,:,jk) * 0.023
96         ENDDO
97         !
98         IF( lk_iomput ) THEN
99             CALL iom_put( "Irondep", zirondep(:,:,1) * 1.e+3 * rfactr * e3t_n(:,:,1) * tmask(:,:,1) ) ! surface downward dust depo of iron
100             CALL iom_put( "pdust"  , dust(:,:) / ( wdust * rday ) * tmask(:,:,1) ) ! dust concentration at surface
101         ENDIF
102         DEALLOCATE( zirondep )
103      ENDIF
104
105      ! N/P and Si releases due to coastal rivers
106      ! Compute river at nit000 or only if there is more than 1 time record in river file
107      ! -----------------------------------------
108            ! Add the external input of nutrients from river
109      ! ----------------------------------------------------------
110      IF( ll_river ) THEN
111          jl = n_trc_indcbc(jpno3)
112          DO jj = 1, jpj
113             DO ji = 1, jpi
114                DO jk = 1, nk_rnf(ji,jj)
115                   zcoef = rn_rfact / ( e1e2t(ji,jj) * h_rnf(ji,jj) * rn_cbc_time ) * tmask(ji,jj,1)
116                   zrivdin = rf_trcfac(jl) * sf_trccbc(jl)%fnow(ji,jj,1) * zcoef
117                   tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) - rno3 * zrivdin * rfact
118               ENDDO
119             END DO
120          END DO
121      ENDIF
122     
123      ! Add the external input of nutrients from nitrogen deposition
124      ! ----------------------------------------------------------
125      IF( ll_ndepo ) THEN
126         ALLOCATE( zndep(jpi,jpj) )
127         IF( ln_trc_sbc(jpno3) ) THEN
128            jl = n_trc_indsbc(jpno3)
129            zndep(:,:) = rf_trsfac(jl) * sf_trcsbc(jl)%fnow(:,:,1) / e3t_n(:,:,1) / rn_sbc_time
130            tra(:,:,1,jptal) = tra(:,:,1,jptal) - rno3 * zndep(:,:) * rfact
131         ENDIF
132         IF( ln_trc_sbc(jpnh4) ) THEN
133            jl = n_trc_indsbc(jpnh4)
134            zndep(:,:) = rf_trsfac(jl) * sf_trcsbc(jl)%fnow(:,:,1) / e3t_n(:,:,1) / rn_sbc_time
135            tra(:,:,1,jptal) = tra(:,:,1,jptal) - rno3 * zndep(:,:) * rfact
136         ENDIF
137         DEALLOCATE( zndep )
138      ENDIF
139      !
140      ! Iron input/uptake due to sea ice : Crude parameterization based on
141      ! Lancelot et al.
142      ! ----------------------------------------------------
143      IF( ln_ironice ) THEN
144         !
145         ALLOCATE( zironice(jpi,jpj) )
146         !
147         DO jj = 1, jpj
148            DO ji = 1, jpi
149               zdep    = rfact / e3t_n(ji,jj,1)
150               zwflux  = fmmflx(ji,jj) / 1000._wp
151               zironice(ji,jj) =  MAX( -0.99 * trb(ji,jj,1,jpfer), -zwflux * icefeinput * zdep )
152            END DO
153         END DO
154         !
155         tra(:,:,1,jpfer) = tra(:,:,1,jpfer) + zironice(:,:)
156         !
157         IF( lk_iomput )  CALL iom_put( "Ironice", zironice(:,:) * 1.e+3 * rfactr * e3t_n(:,:,1) * tmask(:,:,1) ) ! iron flux from ice
158         !
159         DEALLOCATE( zironice )
160         !
161      ENDIF
162
163      ! Add the external input of iron from sediment mobilization
164      ! ------------------------------------------------------
165      IF( ln_ironsed .AND. .NOT.lk_sed ) THEN
166          tra(:,:,:,jpfer) = tra(:,:,:,jpfer) + ironsed(:,:,:) * rfact
167          !
168          IF( lk_iomput )  CALL iom_put( "Ironsed", ironsed(:,:,:) * 1.e+3 * tmask(:,:,:) ) 
169      ENDIF
170
171      ! Add the external input of iron from hydrothermal vents
172      ! ------------------------------------------------------
173      IF( ln_hydrofe ) THEN
174         CALL fld_read( kt, 1, sf_hydrofe )
175         DO jk = 1, jpk
176            hydrofe(:,:,jk) = ( MAX( rtrn, sf_hydrofe(1)%fnow(:,:,jk) ) * hratio ) &
177              &              / ( e1e2t(:,:) * e3t_n(:,:,jk) * ryyss + rtrn ) / 1000._wp &
178              &              * tmask(:,:,jk)
179         ENDDO
180                         tra(:,:,:,jpfer) = tra(:,:,:,jpfer) + hydrofe(:,:,:) * rfact
181         IF( ln_ligand ) tra(:,:,:,jplgw) = tra(:,:,:,jplgw) + ( hydrofe(:,:,:) * lgw_rath ) * rfact
182         !
183         IF( lk_iomput ) CALL iom_put( "HYDR", hydrofe(:,:,:) * 1.e+3 * tmask(:,:,:) ) ! hydrothermal iron input
184      ENDIF
185      IF( ln_timing )  CALL timing_stop('p4z_bc')
186      !
187   END SUBROUTINE p4z_bc
188
189
190   SUBROUTINE p4z_bc_init
191      !!----------------------------------------------------------------------
192      !!                  ***  routine p4z_bc_init  ***
193      !!
194      !! ** purpose :   initialization of the external sources of nutrients
195      !!
196      !! ** method  :   read the files and compute the budget
197      !!                called at the first timestep (nittrc000)
198      !!
199      !! ** input   :   external netcdf files
200      !!
201      !!----------------------------------------------------------------------
202      INTEGER  :: ji, jj, jk, jm
203      INTEGER  :: ii0, ii1, ij0, ij1
204      INTEGER  :: numiron
205      INTEGER  :: ierr, ierr1, ierr2, ierr3
206      INTEGER  :: ios                 ! Local integer output status for namelist read
207      INTEGER  :: ik50                !  last level where depth less than 50 m
208      REAL(wp) :: zexpide, zdenitide, zmaskt, zsurfc, zsurfp,ze3t, ze3t2, zcslp
209      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE :: zriver, zcmask
210      !
211      CHARACTER(len=100) ::  cn_dir          ! Root directory for location of ssr files
212      TYPE(FLD_N) ::   sn_dust, sn_ironsed, sn_hydrofe   ! informations about the fields to be read
213      !!
214      NAMELIST/nampisbc/cn_dir, sn_dust, sn_ironsed, sn_hydrofe, &
215        &                ln_ironsed, ln_ironice, ln_hydrofe,    &
216        &                sedfeinput, distcoast, icefeinput, wdust, mfrac,  &
217        &                hratio, lgw_rath
218      !!----------------------------------------------------------------------
219      !
220      IF(lwp) THEN
221         WRITE(numout,*)
222         WRITE(numout,*) 'p4z_bc_init : initialization of the external sources of nutrients '
223         WRITE(numout,*) '~~~~~~~~~~~~ '
224      ENDIF
225      !                            !* set file information
226      READ  ( numnatp_ref, nampisbc, IOSTAT = ios, ERR = 901)
227901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'nampisbc in reference namelist' )
228      READ  ( numnatp_cfg, nampisbc, IOSTAT = ios, ERR = 902 )
229902   IF( ios >  0 )   CALL ctl_nam ( ios , 'nampisbc in configuration namelist' )
230      IF(lwm) WRITE ( numonp, nampisbc )
231
232
233      IF(lwp) THEN
234         WRITE(numout,*) '   Namelist : nampissbc '
235         WRITE(numout,*) '      Fe input from sediments                  ln_ironsed  = ', ln_ironsed
236         WRITE(numout,*) '      Fe input from seaice                     ln_ironice  = ', ln_ironice
237         WRITE(numout,*) '      fe input from hydrothermal vents         ln_hydrofe  = ', ln_hydrofe
238         IF( ln_ironsed ) THEN
239            WRITE(numout,*) '      coastal release of iron                  sedfeinput  = ', sedfeinput
240            WRITE(numout,*) '      distance off the coast                   distcoast   = ', distcoast
241         ENDIF
242         IF( ln_ligand ) THEN
243            WRITE(numout,*) '      Weak ligand ratio from sed hydro sources  lgw_rath   = ', lgw_rath
244         ENDIF
245         IF( ln_ironice ) THEN
246            WRITE(numout,*) '      Iron concentration in sea ice            icefeinput  = ', icefeinput
247         ENDIF
248         IF( ln_trc_sbc(jpfer) ) THEN
249            WRITE(numout,*) '      Mineral Fe content of the dust           mfrac       = ', mfrac
250            WRITE(numout,*) '      sinking speed of the dust                wdust       = ', wdust
251         ENDIF
252         IF( ln_hydrofe ) THEN
253            WRITE(numout,*) '      Fe to 3He ratio assumed for vent iron supply hratio  = ', hratio
254         ENDIF
255      END IF
256
257      ll_bc    = ( ln_trcbc .AND. lltrcbc )  .OR. ln_hydrofe .OR. ln_ironsed .OR. ln_ironice
258      ll_dust  =  ln_trc_sbc(jpfer)   
259      ll_ndepo =  ln_trc_sbc(jpno3) .OR. ln_trc_sbc(jpnh4)   
260      ll_river =  ln_trc_cbc(jpno3) 
261
262      ! dust input from the atmosphere
263      ! ------------------------------
264      IF( ll_dust ) THEN
265         !
266         IF(lwp) WRITE(numout,*) '    initialize dust input from atmosphere '
267         IF(lwp) WRITE(numout,*) '    ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~ '
268         !
269         ALLOCATE( dust(jpi,jpj) ) 
270         !
271         ALLOCATE( sf_dust(1), STAT=ierr )           !* allocate and fill sf_sst (forcing structure) with sn_sst
272         IF( ierr > 0 )   CALL ctl_stop( 'STOP', 'p4z_sed_init: unable to allocate sf_dust structure' )
273         !
274         CALL fld_fill( sf_dust, (/ sn_dust /), cn_dir, 'p4z_sed_init', 'Atmospheric dust deposition', 'nampissed' )
275                                   ALLOCATE( sf_dust(1)%fnow(jpi,jpj,1)   )
276         IF( sn_dust%ln_tint )     ALLOCATE( sf_dust(1)%fdta(jpi,jpj,1,2) )
277         !
278      END IF
279
280      ! coastal and island masks
281      ! ------------------------
282      IF( ln_ironsed ) THEN     
283         !
284         IF(lwp) WRITE(numout,*)
285         IF(lwp) WRITE(numout,*) '   ==>>>   ln_ironsed=T , computation of an island mask to enhance coastal supply of iron'
286         !
287         ALLOCATE( ironsed(jpi,jpj,jpk) )    ! allocation
288         !
289         CALL iom_open ( TRIM( sn_ironsed%clname ), numiron )
290         ALLOCATE( zcmask(jpi,jpj,jpk) )
291         CALL iom_get  ( numiron, jpdom_data, TRIM( sn_ironsed%clvar ), zcmask(:,:,:), 1 )
292         CALL iom_close( numiron )
293         !
294         ik50 = 5        !  last level where depth less than 50 m
295         DO jk = jpkm1, 1, -1
296            IF( gdept_1d(jk) > 50. )   ik50 = jk - 1
297         END DO
298         IF(lwp) WRITE(numout,*)
299         IF(lwp) WRITE(numout,*) ' Level corresponding to 50m depth ',  ik50,' ', gdept_1d(ik50+1)
300         DO jk = 1, ik50
301            DO jj = 2, jpjm1
302               DO ji = fs_2, fs_jpim1
303                  ze3t   = e3t_0(ji,jj,jk)
304                  zsurfc =  e1u(ji,jj) * ( 1. - umask(ji  ,jj  ,jk) )   &
305                          + e1u(ji,jj) * ( 1. - umask(ji-1,jj  ,jk) )   &
306                          + e2v(ji,jj) * ( 1. - vmask(ji  ,jj  ,jk) )   &
307                          + e2v(ji,jj) * ( 1. - vmask(ji  ,jj-1,jk) )
308                  zsurfp = zsurfc * ze3t / e1e2t(ji,jj)
309                  ! estimation of the coastal slope : 5 km off the coast
310                  ze3t2 = ze3t * ze3t
311                  zcslp = SQRT( ( distcoast*distcoast + ze3t2 ) / ze3t2 )
312                  !
313                  zcmask(ji,jj,jk) = zcmask(ji,jj,jk) + zcslp * zsurfp
314               END DO
315            END DO
316         END DO
317         !
318         CALL lbc_lnk( 'p4zbc', zcmask , 'T', 1. )      ! lateral boundary conditions on cmask   (sign unchanged)
319         !
320         DO jk = 1, jpk
321            DO jj = 1, jpj
322               DO ji = 1, jpi
323                  zexpide   = MIN( 8.,( gdept_n(ji,jj,jk) / 500. )**(-1.5) )
324                  zdenitide = -0.9543 + 0.7662 * LOG( zexpide ) - 0.235 * LOG( zexpide )**2
325                  zcmask(ji,jj,jk) = zcmask(ji,jj,jk) * MIN( 1., EXP( zdenitide ) / 0.5 )
326               END DO
327            END DO
328         END DO
329         ! Coastal supply of iron
330         ! -------------------------
331         ironsed(:,:,jpk) = 0._wp
332         DO jk = 1, jpkm1
333            ironsed(:,:,jk) = sedfeinput * zcmask(:,:,jk) / ( e3t_0(:,:,jk) * rday )
334         END DO
335         DEALLOCATE( zcmask)
336      ENDIF
337      !
338      ! Iron from Hydrothermal vents
339      ! ------------------------
340      IF( ln_hydrofe ) THEN
341         !
342         IF(lwp) WRITE(numout,*)
343         IF(lwp) WRITE(numout,*) '   ==>>>   ln_hydrofe=T , Input of iron from hydrothermal vents'
344         !
345         ALLOCATE( hydrofe(jpi,jpj,jpk) )    ! allocation
346         !
347         ALLOCATE( sf_hydrofe(1), STAT=ierr )           !* allocate and fill sf_sst (forcing structure) with sn_sst
348         IF( ierr > 0 )   CALL ctl_stop( 'STOP', 'p4z_sed_init: unable to allocate sf_hydro structure' )
349         !
350         CALL fld_fill( sf_hydrofe, (/ sn_hydrofe /), cn_dir, 'p4z_sed_init', 'Input of iron from hydrothermal vents', 'nampisbc' )
351                                   ALLOCATE( sf_hydrofe(1)%fnow(jpi,jpj,jpk)   )
352         IF( sn_hydrofe%ln_tint )    ALLOCATE( sf_hydrofe(1)%fdta(jpi,jpj,jpk,2) )
353         !
354      ENDIF
355      !
356   END SUBROUTINE p4z_bc_init
357
358   !!======================================================================
359END MODULE p4zbc
Note: See TracBrowser for help on using the repository browser.