New URL for NEMO forge! http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.

traadv_qck.F90 in NEMO/branches/2020/dev_r12377_KERNEL-06_techene_e3/src/OCE/TRA – NEMO

Context Navigation

source: NEMO/branches/2020/dev_r12377_KERNEL-06_techene_e3/src/OCE/TRA/traadv_qck.F90 @ 12732

Last change on this file since 12732 was 12606, checked in by techene, 4 years ago
all: add e3 substitute and limit precompiled files lines to about 130 character, OCE/TRA/traisf.F90: remove ONLY : e3t, r1_e1e2t
Property svn:keywords set to `Id`
File size: 20.9 KB

Rev	Line
[1231]	1	MODULE traadv_qck
	2	!!==============================================================================
	3	!! * MODULE traadv_qck *
[2528]	4	!! Ocean tracers: horizontal & vertical advective trend
[1231]	5	!!==============================================================================
[1559]	6	!! History : 3.0 ! 2008-07 (G. Reffray) Original code
[2528]	7	!! 3.3 ! 2010-05 (C.Ethe, G. Madec) merge TRC-TRA + switch from velocity to transport
[1231]	8	!!----------------------------------------------------------------------
	9
	10	!!----------------------------------------------------------------------
[2528]	11	!! tra_adv_qck : update the tracer trend with the horizontal advection
	12	!! trends using a 3rd order finite difference scheme
	13	!! tra_adv_qck_i : apply QUICK scheme in i-direction
	14	!! tra_adv_qck_j : apply QUICK scheme in j-direction
[1559]	15	!! tra_adv_cen2_k : 2nd centered scheme for the vertical advection
[1231]	16	!!----------------------------------------------------------------------
	17	USE oce ! ocean dynamics and active tracers
	18	USE dom_oce ! ocean space and time domain
[4990]	19	USE trc_oce ! share passive tracers/Ocean variables
	20	USE trd_oce ! trends: ocean variables
[12590]	21	USE trdtra ! trends manager: tracers
[4990]	22	USE diaptr ! poleward transport diagnostics
[12377]	23	USE iom
[4990]	24	!
[9124]	25	USE in_out_manager ! I/O manager
[1231]	26	USE lib_mpp ! distribued memory computing
	27	USE lbclnk ! ocean lateral boundary condition (or mpp link)
[12590]	28	USE lib_fortran ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
[1231]	29
	30	IMPLICIT NONE
	31	PRIVATE
	32
[1559]	33	PUBLIC tra_adv_qck ! routine called by step.F90
[1231]	34
[2528]	35	REAL(wp) :: r1_6 = 1./ 6. ! 1/6 ratio
[1559]	36
[7646]	37	LOGICAL :: l_trd ! flag to compute trends
	38	LOGICAL :: l_ptr ! flag to compute poleward transport
	39
	40
[1231]	41	!! * Substitutions
[12377]	42	# include "do_loop_substitute.h90"
[12590]	43	# include "domzgr_substitute.h90"
[1231]	44	!!----------------------------------------------------------------------
[9598]	45	!! NEMO/OCE 4.0 , NEMO Consortium (2018)
[1231]	46	!! $Id$
[10068]	47	!! Software governed by the CeCILL license (see ./LICENSE)
[1231]	48	!!----------------------------------------------------------------------
	49	CONTAINS
	50
[12377]	51	SUBROUTINE tra_adv_qck ( kt, kit000, cdtype, p2dt, pU, pV, pW, Kbb, Kmm, pt, kjpt, Krhs )
[1231]	52	!!----------------------------------------------------------------------
	53	!! * ROUTINE tra_adv_qck *
	54	!!
	55	!! ** Purpose : Compute the now trend due to the advection of tracers
	56	!! and add it to the general trend of passive tracer equations.
	57	!!
	58	!! ** Method : The advection is evaluated by a third order scheme
[1559]	59	!! For a positive velocity u : u(i)>0
	60	!! \|--FU--\|--FC--\|--FD--\|------\|
	61	!! i-1 i i+1 i+2
[1231]	62	!!
[1559]	63	!! For a negative velocity u : u(i)<0
	64	!! \|------\|--FD--\|--FC--\|--FU--\|
	65	!! i-1 i i+1 i+2
	66	!! where FU is the second upwind point
	67	!! FD is the first douwning point
	68	!! FC is the central point (or the first upwind point)
[1231]	69	!!
[1559]	70	!! Flux(i) = u(i) * { 0.5(FC+FD) -0.5C(i)(FD-FC) -((1-C(i))/6)(FU+FD-2FC) }
	71	!! with C(i)=\|u(i)\|dx(i)/dt (=Courant number)
[1231]	72	!!
	73	!! dt = 2*rdtra and the scalar values are tb and sb
	74	!!
[12377]	75	!! On the vertical, the simple centered scheme used pt(:,:,:,:,Kmm)
[1231]	76	!!
[1559]	77	!! The fluxes are bounded by the ULTIMATE limiter to
	78	!! guarantee the monotonicity of the solution and to
[1231]	79	!! prevent the appearance of spurious numerical oscillations
	80	!!
[12377]	81	!! ** Action : - update pt(:,:,:,:,Krhs) with the now advective tracer trends
[6140]	82	!! - send trends to trdtra module for further diagnostcs (l_trdtra=T)
[12377]	83	!! - poleward advective heat and salt transport (ln_diaptr=T)
[1231]	84	!!
	85	!! ** Reference : Leonard (1979, 1991)
	86	!!----------------------------------------------------------------------
[12377]	87	INTEGER , INTENT(in ) :: kt ! ocean time-step index
	88	INTEGER , INTENT(in ) :: Kbb, Kmm, Krhs ! ocean time level indices
	89	INTEGER , INTENT(in ) :: kit000 ! first time step index
	90	CHARACTER(len=3) , INTENT(in ) :: cdtype ! =TRA or TRC (tracer indicator)
	91	INTEGER , INTENT(in ) :: kjpt ! number of tracers
	92	REAL(wp) , INTENT(in ) :: p2dt ! tracer time-step
	93	REAL(wp), DIMENSION(jpi,jpj,jpk ), INTENT(in ) :: pU, pV, pW ! 3 ocean volume transport components
	94	REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt,jpt), INTENT(inout) :: pt ! tracers and RHS of tracer equation
[1231]	95	!!----------------------------------------------------------------------
[3294]	96	!
	97	IF( kt == kit000 ) THEN
[1231]	98	IF(lwp) WRITE(numout,*)
[2528]	99	IF(lwp) WRITE(numout,*) 'tra_adv_qck : 3rd order quickest advection scheme on ', cdtype
[1231]	100	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~'
	101	IF(lwp) WRITE(numout,*)
	102	ENDIF
[5836]	103	!
[4990]	104	l_trd = .FALSE.
[7646]	105	l_ptr = .FALSE.
[12377]	106	IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR. ( cdtype == 'TRC' .AND. l_trdtrc ) ) l_trd = .TRUE.
[12590]	107	IF( cdtype == 'TRA' .AND. ( iom_use( 'sophtadv' ) .OR. iom_use( 'sophtadv' ) ) ) l_ptr = .TRUE.
[4499]	108	!
[7646]	109	!
[6140]	110	! ! horizontal fluxes are computed with the QUICKEST + ULTIMATE scheme
[12590]	111	CALL tra_adv_qck_i( kt, cdtype, p2dt, pU, Kbb, Kmm, pt, kjpt, Krhs )
	112	CALL tra_adv_qck_j( kt, cdtype, p2dt, pV, Kbb, Kmm, pt, kjpt, Krhs )
[1231]	113
[6140]	114	! ! vertical fluxes are computed with the 2nd order centered scheme
[12377]	115	CALL tra_adv_cen2_k( kt, cdtype, pW, Kmm, pt, kjpt, Krhs )
[1231]	116	!
	117	END SUBROUTINE tra_adv_qck
	118
	119
[12377]	120	SUBROUTINE tra_adv_qck_i( kt, cdtype, p2dt, pU, Kbb, Kmm, pt, kjpt, Krhs )
[1231]	121	!!----------------------------------------------------------------------
	122	!!
	123	!!----------------------------------------------------------------------
[12377]	124	INTEGER , INTENT(in ) :: kt ! ocean time-step index
	125	INTEGER , INTENT(in ) :: Kbb, Kmm, Krhs ! ocean time level indices
	126	CHARACTER(len=3) , INTENT(in ) :: cdtype ! =TRA or TRC (tracer indicator)
	127	INTEGER , INTENT(in ) :: kjpt ! number of tracers
	128	REAL(wp) , INTENT(in ) :: p2dt ! tracer time-step
	129	REAL(wp), DIMENSION(jpi,jpj,jpk ), INTENT(in ) :: pU ! i-velocity components
	130	REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt,jpt), INTENT(inout) :: pt ! active tracers and RHS of tracer equation
[2528]	131	!!
[5836]	132	INTEGER :: ji, jj, jk, jn ! dummy loop indices
[6140]	133	REAL(wp) :: ztra, zbtr, zdir, zdx, zmsk ! local scalars
[9019]	134	REAL(wp), DIMENSION(jpi,jpj,jpk) :: zwx, zfu, zfc, zfd
[1231]	135	!----------------------------------------------------------------------
[2715]	136	!
[2528]	137	! ! ===========
	138	DO jn = 1, kjpt ! tracer loop
	139	! ! ===========
[12590]	140	zfu(:,:,:) = 0._wp ; zfc(:,:,:) = 0._wp
	141	zfd(:,:,:) = 0._wp ; zwx(:,:,:) = 0._wp
[5836]	142	!
	143	!!gm why not using a SHIFT instruction...
[12377]	144	DO_3D_00_00( 1, jpkm1 )
	145	zfc(ji,jj,jk) = pt(ji-1,jj,jk,jn,Kbb) ! Upstream in the x-direction for the tracer
	146	zfd(ji,jj,jk) = pt(ji+1,jj,jk,jn,Kbb) ! Downstream in the x-direction for the tracer
	147	END_3D
[12590]	148	CALL lbc_lnk_multi( 'traadv_qck', zfc(:,:,:), 'T', 1. , zfd(:,:,:), 'T', 1. ) ! Lateral boundary conditions
	149
[1231]	150	!
	151	! Horizontal advective fluxes
	152	! ---------------------------
[12377]	153	DO_3D_00_00( 1, jpkm1 )
[12590]	154	zdir = 0.5 + SIGN( 0.5, pU(ji,jj,jk) ) ! if pU > 0 : zdir = 1 otherwise zdir = 0
	155	zfu(ji,jj,jk) = zdir * zfc(ji,jj,jk ) + ( 1. - zdir ) * zfd(ji+1,jj,jk) ! FU in the x-direction for T
[12377]	156	END_3D
[1231]	157	!
[12377]	158	DO_3D_00_00( 1, jpkm1 )
[12590]	159	zdir = 0.5 + SIGN( 0.5, pU(ji,jj,jk) ) ! if pU > 0 : zdir = 1 otherwise zdir = 0
[12606]	160	zdx = ( zdir * e1t(ji,jj) + ( 1. - zdir ) * e1t(ji+1,jj) ) &
	161	& * e2u(ji,jj) * e3u(ji,jj,jk,Kmm)
[12377]	162	zwx(ji,jj,jk) = ABS( pU(ji,jj,jk) ) * p2dt / zdx ! (0<zc_cfl<1 : Courant number on x-direction)
	163	zfc(ji,jj,jk) = zdir * pt(ji ,jj,jk,jn,Kbb) + ( 1. - zdir ) * pt(ji+1,jj,jk,jn,Kbb) ! FC in the x-direction for T
	164	zfd(ji,jj,jk) = zdir * pt(ji+1,jj,jk,jn,Kbb) + ( 1. - zdir ) * pt(ji ,jj,jk,jn,Kbb) ! FD in the x-direction for T
	165	END_3D
[12590]	166	!--- Lateral boundary conditions
[10425]	167	CALL lbc_lnk_multi( 'traadv_qck', zfu(:,:,:), 'T', 1. , zfd(:,:,:), 'T', 1., zfc(:,:,:), 'T', 1., zwx(:,:,:), 'T', 1. )
[2528]	168
[1231]	169	!--- QUICKEST scheme
[2528]	170	CALL quickest( zfu, zfd, zfc, zwx )
[1231]	171	!
[2528]	172	! Mask at the T-points in the x-direction (mask=0 or mask=1)
[12377]	173	DO_3D_00_00( 1, jpkm1 )
	174	zfu(ji,jj,jk) = tmask(ji-1,jj,jk) + tmask(ji,jj,jk) + tmask(ji+1,jj,jk) - 2.
	175	END_3D
[12590]	176	CALL lbc_lnk( 'traadv_qck', zfu(:,:,:), 'T', 1. ) ! Lateral boundary conditions
[2528]	177
[1231]	178	!
[2528]	179	! Tracer flux on the x-direction
[12590]	180	DO jk = 1, jpkm1
[2528]	181	!
[12377]	182	DO_2D_00_00
[12590]	183	zdir = 0.5 + SIGN( 0.5, pU(ji,jj,jk) ) ! if pU > 0 : zdir = 1 otherwise zdir = 0
[12377]	184	!--- If the second ustream point is a land point
	185	!--- the flux is computed by the 1st order UPWIND scheme
	186	zmsk = zdir * zfu(ji,jj,jk) + ( 1. - zdir ) * zfu(ji+1,jj,jk)
	187	zwx(ji,jj,jk) = zmsk * zwx(ji,jj,jk) + ( 1. - zmsk ) * zfc(ji,jj,jk)
	188	zwx(ji,jj,jk) = zwx(ji,jj,jk) * pU(ji,jj,jk)
	189	END_2D
[3300]	190	END DO
	191	!
[10425]	192	CALL lbc_lnk( 'traadv_qck', zwx(:,:,:), 'T', 1. ) ! Lateral boundary conditions
[3300]	193	!
	194	! Computation of the trend
[12377]	195	DO_3D_00_00( 1, jpkm1 )
	196	zbtr = r1_e1e2t(ji,jj) / e3t(ji,jj,jk,Kmm)
	197	! horizontal advective trends
	198	ztra = - zbtr * ( zwx(ji,jj,jk) - zwx(ji-1,jj,jk) )
	199	!--- add it to the general tracer trends
	200	pt(ji,jj,jk,jn,Krhs) = pt(ji,jj,jk,jn,Krhs) + ztra
	201	END_3D
[6140]	202	! ! trend diagnostics
[12377]	203	IF( l_trd ) CALL trd_tra( kt, Kmm, Krhs, cdtype, jn, jptra_xad, zwx, pU, pt(:,:,:,jn,Kmm) )
[2528]	204	!
	205	END DO
	206	!
[1559]	207	END SUBROUTINE tra_adv_qck_i
[1231]	208
	209
[12377]	210	SUBROUTINE tra_adv_qck_j( kt, cdtype, p2dt, pV, Kbb, Kmm, pt, kjpt, Krhs )
[1231]	211	!!----------------------------------------------------------------------
	212	!!
	213	!!----------------------------------------------------------------------
[12377]	214	INTEGER , INTENT(in ) :: kt ! ocean time-step index
	215	INTEGER , INTENT(in ) :: Kbb, Kmm, Krhs ! ocean time level indices
	216	CHARACTER(len=3) , INTENT(in ) :: cdtype ! =TRA or TRC (tracer indicator)
	217	INTEGER , INTENT(in ) :: kjpt ! number of tracers
	218	REAL(wp) , INTENT(in ) :: p2dt ! tracer time-step
	219	REAL(wp), DIMENSION(jpi,jpj,jpk ), INTENT(in ) :: pV ! j-velocity components
	220	REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt,jpt), INTENT(inout) :: pt ! active tracers and RHS of tracer equation
[1559]	221	!!
[9019]	222	INTEGER :: ji, jj, jk, jn ! dummy loop indices
[6140]	223	REAL(wp) :: ztra, zbtr, zdir, zdx, zmsk ! local scalars
[9019]	224	REAL(wp), DIMENSION(jpi,jpj,jpk) :: zwy, zfu, zfc, zfd ! 3D workspace
[1231]	225	!----------------------------------------------------------------------
[2715]	226	!
[2528]	227	! ! ===========
	228	DO jn = 1, kjpt ! tracer loop
	229	! ! ===========
[12590]	230	zfu(:,:,:) = 0.0 ; zfc(:,:,:) = 0.0
	231	zfd(:,:,:) = 0.0 ; zwy(:,:,:) = 0.0
	232	!
	233	DO jk = 1, jpkm1
	234	!
[2528]	235	!--- Computation of the ustream and downstream value of the tracer and the mask
[12377]	236	DO_2D_00_00
	237	! Upstream in the x-direction for the tracer
	238	zfc(ji,jj,jk) = pt(ji,jj-1,jk,jn,Kbb)
	239	! Downstream in the x-direction for the tracer
	240	zfd(ji,jj,jk) = pt(ji,jj+1,jk,jn,Kbb)
	241	END_2D
[1559]	242	END DO
[12590]	243	CALL lbc_lnk_multi( 'traadv_qck', zfc(:,:,:), 'T', 1. , zfd(:,:,:), 'T', 1. ) ! Lateral boundary conditions
[2528]	244
[12590]	245
[1231]	246	!
	247	! Horizontal advective fluxes
	248	! ---------------------------
	249	!
[12377]	250	DO_3D_00_00( 1, jpkm1 )
[12590]	251	zdir = 0.5 + SIGN( 0.5, pV(ji,jj,jk) ) ! if pU > 0 : zdir = 1 otherwise zdir = 0
	252	zfu(ji,jj,jk) = zdir * zfc(ji,jj,jk ) + ( 1. - zdir ) * zfd(ji,jj+1,jk) ! FU in the x-direction for T
[12377]	253	END_3D
[1231]	254	!
[12377]	255	DO_3D_00_00( 1, jpkm1 )
[12590]	256	zdir = 0.5 + SIGN( 0.5, pV(ji,jj,jk) ) ! if pU > 0 : zdir = 1 otherwise zdir = 0
	257	zdx = ( zdir * e2t(ji,jj) + ( 1. - zdir ) * e2t(ji,jj+1) ) &
	258	& * e1v(ji,jj) * e3v(ji,jj,jk,Kmm)
[12377]	259	zwy(ji,jj,jk) = ABS( pV(ji,jj,jk) ) * p2dt / zdx ! (0<zc_cfl<1 : Courant number on x-direction)
	260	zfc(ji,jj,jk) = zdir * pt(ji,jj ,jk,jn,Kbb) + ( 1. - zdir ) * pt(ji,jj+1,jk,jn,Kbb) ! FC in the x-direction for T
	261	zfd(ji,jj,jk) = zdir * pt(ji,jj+1,jk,jn,Kbb) + ( 1. - zdir ) * pt(ji,jj ,jk,jn,Kbb) ! FD in the x-direction for T
	262	END_3D
[2528]	263
[12590]	264	!--- Lateral boundary conditions
[10425]	265	CALL lbc_lnk_multi( 'traadv_qck', zfu(:,:,:), 'T', 1. , zfd(:,:,:), 'T', 1., zfc(:,:,:), 'T', 1., zwy(:,:,:), 'T', 1. )
[2528]	266
[1231]	267	!--- QUICKEST scheme
[2528]	268	CALL quickest( zfu, zfd, zfc, zwy )
[1231]	269	!
[2528]	270	! Mask at the T-points in the x-direction (mask=0 or mask=1)
[12377]	271	DO_3D_00_00( 1, jpkm1 )
	272	zfu(ji,jj,jk) = tmask(ji,jj-1,jk) + tmask(ji,jj,jk) + tmask(ji,jj+1,jk) - 2.
	273	END_3D
[12590]	274	CALL lbc_lnk( 'traadv_qck', zfu(:,:,:), 'T', 1. ) !--- Lateral boundary conditions
[2528]	275	!
	276	! Tracer flux on the x-direction
[12590]	277	DO jk = 1, jpkm1
[2528]	278	!
[12377]	279	DO_2D_00_00
[12590]	280	zdir = 0.5 + SIGN( 0.5, pV(ji,jj,jk) ) ! if pU > 0 : zdir = 1 otherwise zdir = 0
[12377]	281	!--- If the second ustream point is a land point
	282	!--- the flux is computed by the 1st order UPWIND scheme
	283	zmsk = zdir * zfu(ji,jj,jk) + ( 1. - zdir ) * zfu(ji,jj+1,jk)
	284	zwy(ji,jj,jk) = zmsk * zwy(ji,jj,jk) + ( 1. - zmsk ) * zfc(ji,jj,jk)
	285	zwy(ji,jj,jk) = zwy(ji,jj,jk) * pV(ji,jj,jk)
	286	END_2D
[3300]	287	END DO
	288	!
[10425]	289	CALL lbc_lnk( 'traadv_qck', zwy(:,:,:), 'T', 1. ) ! Lateral boundary conditions
[3300]	290	!
	291	! Computation of the trend
[12377]	292	DO_3D_00_00( 1, jpkm1 )
	293	zbtr = r1_e1e2t(ji,jj) / e3t(ji,jj,jk,Kmm)
	294	! horizontal advective trends
	295	ztra = - zbtr * ( zwy(ji,jj,jk) - zwy(ji,jj-1,jk) )
	296	!--- add it to the general tracer trends
	297	pt(ji,jj,jk,jn,Krhs) = pt(ji,jj,jk,jn,Krhs) + ztra
	298	END_3D
[6140]	299	! ! trend diagnostics
[12377]	300	IF( l_trd ) CALL trd_tra( kt, Kmm, Krhs, cdtype, jn, jptra_yad, zwy, pV, pt(:,:,:,jn,Kmm) )
[2528]	301	! ! "Poleward" heat and salt transports (contribution of upstream fluxes)
[9019]	302	IF( l_ptr ) CALL dia_ptr_hst( jn, 'adv', zwy(:,:,:) )
[2528]	303	!
	304	END DO
	305	!
[1559]	306	END SUBROUTINE tra_adv_qck_j
[1231]	307
	308
[12377]	309	SUBROUTINE tra_adv_cen2_k( kt, cdtype, pW, Kmm, pt, kjpt, Krhs )
[1231]	310	!!----------------------------------------------------------------------
	311	!!
	312	!!----------------------------------------------------------------------
[12377]	313	INTEGER , INTENT(in ) :: kt ! ocean time-step index
	314	INTEGER , INTENT(in ) :: Kmm, Krhs ! ocean time level indices
	315	CHARACTER(len=3) , INTENT(in ) :: cdtype ! =TRA or TRC (tracer indicator)
	316	INTEGER , INTENT(in ) :: kjpt ! number of tracers
[12590]	317	REAL(wp), DIMENSION(jpi,jpj,jpk ), INTENT(in ) :: pW ! vertical velocity
[12377]	318	REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt,jpt), INTENT(inout) :: pt ! active tracers and RHS of tracer equation
[2715]	319	!
[2528]	320	INTEGER :: ji, jj, jk, jn ! dummy loop indices
[9019]	321	REAL(wp), DIMENSION(jpi,jpj,jpk) :: zwz ! 3D workspace
[1559]	322	!!----------------------------------------------------------------------
[4990]	323	!
[6140]	324	zwz(:,:, 1 ) = 0._wp ! surface & bottom values set to zero for all tracers
	325	zwz(:,:,jpk) = 0._wp
[5836]	326	!
[2528]	327	! ! ===========
	328	DO jn = 1, kjpt ! tracer loop
	329	! ! ===========
	330	!
[12377]	331	DO_3D_00_00( 2, jpkm1 )
	332	zwz(ji,jj,jk) = 0.5 * pW(ji,jj,jk) * ( pt(ji,jj,jk-1,jn,Kmm) + pt(ji,jj,jk,jn,Kmm) ) * wmask(ji,jj,jk)
	333	END_3D
[6140]	334	IF( ln_linssh ) THEN !* top value (only in linear free surf. as zwz is multiplied by wmask)
[5836]	335	IF( ln_isfcav ) THEN ! ice-shelf cavities (top of the ocean)
[12377]	336	DO_2D_11_11
[12590]	337	zwz(ji,jj, mikt(ji,jj) ) = pW(ji,jj,mikt(ji,jj)) * pt(ji,jj,mikt(ji,jj),jn,Kmm) ! linear free surface
[12377]	338	END_2D
[6140]	339	ELSE ! no ocean cavities (only ocean surface)
[12377]	340	zwz(:,:,1) = pW(:,:,1) * pt(:,:,1,jn,Kmm)
[5836]	341	ENDIF
	342	ENDIF
[2528]	343	!
[12377]	344	DO_3D_00_00( 1, jpkm1 )
	345	pt(ji,jj,jk,jn,Krhs) = pt(ji,jj,jk,jn,Krhs) - ( zwz(ji,jj,jk) - zwz(ji,jj,jk+1) ) &
	346	& * r1_e1e2t(ji,jj) / e3t(ji,jj,jk,Kmm)
	347	END_3D
[6140]	348	! ! Send trends for diagnostic
[12377]	349	IF( l_trd ) CALL trd_tra( kt, Kmm, Krhs, cdtype, jn, jptra_zad, zwz, pW, pt(:,:,:,jn,Kmm) )
[2528]	350	!
[1231]	351	END DO
	352	!
[1559]	353	END SUBROUTINE tra_adv_cen2_k
[1231]	354
	355
[2528]	356	SUBROUTINE quickest( pfu, pfd, pfc, puc )
[1231]	357	!!----------------------------------------------------------------------
	358	!!
[2528]	359	!! ** Purpose : Computation of advective flux with Quickest scheme
	360	!!
[12590]	361	!! ** Method :
[1231]	362	!!----------------------------------------------------------------------
[2528]	363	REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(in ) :: pfu ! second upwind point
	364	REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(in ) :: pfd ! first douwning point
	365	REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(in ) :: pfc ! the central point (or the first upwind point)
	366	REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) :: puc ! input as Courant number ; output as flux
	367	!!
[12590]	368	INTEGER :: ji, jj, jk ! dummy loop indices
	369	REAL(wp) :: zcoef1, zcoef2, zcoef3 ! local scalars
[2528]	370	REAL(wp) :: zc, zcurv, zfho ! - -
	371	!----------------------------------------------------------------------
[3294]	372	!
[12377]	373	DO_3D_11_11( 1, jpkm1 )
	374	zc = puc(ji,jj,jk) ! Courant number
	375	zcurv = pfd(ji,jj,jk) + pfu(ji,jj,jk) - 2. * pfc(ji,jj,jk)
	376	zcoef1 = 0.5 * ( pfc(ji,jj,jk) + pfd(ji,jj,jk) )
	377	zcoef2 = 0.5 * zc * ( pfd(ji,jj,jk) - pfc(ji,jj,jk) )
	378	zcoef3 = ( 1. - ( zc * zc ) ) * r1_6 * zcurv
[12590]	379	zfho = zcoef1 - zcoef2 - zcoef3 ! phi_f QUICKEST
[12377]	380	!
	381	zcoef1 = pfd(ji,jj,jk) - pfu(ji,jj,jk)
	382	zcoef2 = ABS( zcoef1 )
	383	zcoef3 = ABS( zcurv )
	384	IF( zcoef3 >= zcoef2 ) THEN
[12590]	385	zfho = pfc(ji,jj,jk)
[12377]	386	ELSE
	387	zcoef3 = pfu(ji,jj,jk) + ( ( pfc(ji,jj,jk) - pfu(ji,jj,jk) ) / MAX( zc, 1.e-9 ) ) ! phi_REF
	388	IF( zcoef1 >= 0. ) THEN
[12590]	389	zfho = MAX( pfc(ji,jj,jk), zfho )
	390	zfho = MIN( zfho, MIN( zcoef3, pfd(ji,jj,jk) ) )
[12377]	391	ELSE
[12590]	392	zfho = MIN( pfc(ji,jj,jk), zfho )
	393	zfho = MAX( zfho, MAX( zcoef3, pfd(ji,jj,jk) ) )
[12377]	394	ENDIF
	395	ENDIF
	396	puc(ji,jj,jk) = zfho
	397	END_3D
[1231]	398	!
	399	END SUBROUTINE quickest
	400
	401	!!======================================================================
	402	END MODULE traadv_qck

Note: See TracBrowser for help on using the repository browser.

Download in other formats: