New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trazdf.F90 in NEMO/branches/2020/dev_r13383_HPC-02_Daley_Tiling/src/OCE/TRA – NEMO

source: NEMO/branches/2020/dev_r13383_HPC-02_Daley_Tiling/src/OCE/TRA/trazdf.F90 @ 13551

Last change on this file since 13551 was 13551, checked in by hadcv, 4 years ago

#2365: Replace trd_tra workarounds with ctl_warn if using tiling
  • Property svn:keywords set to Id
File size: 13.0 KB
RevLine 
[458]1MODULE trazdf
2   !!==============================================================================
3   !!                 ***  MODULE  trazdf  ***
4   !! Ocean active tracers:  vertical component of the tracer mixing trend
5   !!==============================================================================
[9019]6   !! History :  1.0  !  2005-11  (G. Madec)  Original code
7   !!            3.0  !  2008-01  (C. Ethe, G. Madec)  merge TRC-TRA
8   !!            4.0  !  2017-06  (G. Madec)  remove explict time-stepping option
[458]9   !!----------------------------------------------------------------------
[503]10
11   !!----------------------------------------------------------------------
[6140]12   !!   tra_zdf       : Update the tracer trend with the vertical diffusion
[458]13   !!----------------------------------------------------------------------
[6140]14   USE oce            ! ocean dynamics and tracers variables
[13551]15   USE dom_oce        ! ocean space and time domain variables
[6140]16   USE domvvl         ! variable volume
17   USE phycst         ! physical constant
18   USE zdf_oce        ! ocean vertical physics variables
19   USE sbc_oce        ! surface boundary condition: ocean
20   USE ldftra         ! lateral diffusion: eddy diffusivity
21   USE ldfslp         ! lateral diffusion: iso-neutral slope
22   USE trd_oce        ! trends: ocean variables
23   USE trdtra         ! trends: tracer trend manager
[5836]24   !
[6140]25   USE in_out_manager ! I/O manager
26   USE prtctl         ! Print control
27   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
28   USE lib_mpp        ! MPP library
29   USE timing         ! Timing
[592]30
[458]31   IMPLICIT NONE
32   PRIVATE
33
[9019]34   PUBLIC   tra_zdf       ! called by step.F90
35   PUBLIC   tra_zdf_imp   ! called by trczdf.F90
[458]36
37   !! * Substitutions
[12377]38#  include "do_loop_substitute.h90"
[13237]39#  include "domzgr_substitute.h90"
[458]40   !!----------------------------------------------------------------------
[9598]41   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
[888]42   !! $Id$
[10068]43   !! Software governed by the CeCILL license (see ./LICENSE)
[458]44   !!----------------------------------------------------------------------
[2715]45CONTAINS
[458]46
[12377]47   SUBROUTINE tra_zdf( kt, Kbb, Kmm, Krhs, pts, Kaa )
[458]48      !!----------------------------------------------------------------------
49      !!                  ***  ROUTINE tra_zdf  ***
50      !!
51      !! ** Purpose :   compute the vertical ocean tracer physics.
52      !!---------------------------------------------------------------------
[12377]53      INTEGER                                  , INTENT(in)    :: kt                  ! ocean time-step index
54      INTEGER                                  , INTENT(in)    :: Kbb, Kmm, Krhs, Kaa ! time level indices
55      REAL(wp), DIMENSION(jpi,jpj,jpk,jpts,jpt), INTENT(inout) :: pts                 ! active tracers and RHS of tracer equation
[6140]56      !
[13517]57      INTEGER  ::   ji, jj, jk   ! Dummy loop indices
[13551]58      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::   ztrdt, ztrds   ! 3D workspace
[458]59      !!---------------------------------------------------------------------
[3294]60      !
[9019]61      IF( ln_timing )   CALL timing_start('tra_zdf')
[3294]62      !
[9124]63      IF( kt == nit000 )  THEN
[13517]64         IF( ntile == 0 .OR. ntile == 1 )  THEN                   ! Do only on the first tile
65            IF(lwp)WRITE(numout,*)
66            IF(lwp)WRITE(numout,*) 'tra_zdf : implicit vertical mixing on T & S'
67            IF(lwp)WRITE(numout,*) '~~~~~~~ '
68         ENDIF
[9124]69      ENDIF
70      !
[9019]71      IF( l_trdtra )   THEN                  !* Save ta and sa trends
[13551]72         ALLOCATE( ztrdt(jpi,jpj,jpk), ztrds(jpi,jpj,jpk) )
73         ztrdt(:,:,:) = pts(:,:,:,jp_tem,Kaa)
74         ztrds(:,:,:) = pts(:,:,:,jp_sal,Kaa)
[458]75      ENDIF
[6140]76      !
[9019]77      !                                      !* compute lateral mixing trend and add it to the general trend
[12489]78      CALL tra_zdf_imp( kt, nit000, 'TRA', rDt, Kbb, Kmm, Krhs, pts, Kaa, jpts ) 
[9019]79
[5836]80!!gm WHY here !   and I don't like that !
[5385]81      ! DRAKKAR SSS control {
82      ! JMM avoid negative salinities near river outlet ! Ugly fix
83      ! JMM : restore negative salinities to small salinities:
[13517]84      WHERE( pts(ST_2D(0),:,jp_sal,Kaa) < 0._wp )   pts(ST_2D(0),:,jp_sal,Kaa) = 0.1_wp
[5836]85!!gm
[458]86
[1110]87      IF( l_trdtra )   THEN                      ! save the vertical diffusive trends for further diagnostics
[13551]88         DO jk = 1, jpk
89            ztrdt(:,:,jk) = (   (  pts(:,:,jk,jp_tem,Kaa)*e3t(:,:,jk,Kaa)     &
90               &                 - pts(:,:,jk,jp_tem,Kbb)*e3t(:,:,jk,Kbb)  )  &
91               &              / (  e3t(:,:,jk,Kmm)*rDt  )   )                 &
92               &          - ztrdt(:,:,jk)
93            ztrds(:,:,jk) = (   (  pts(:,:,jk,jp_sal,Kaa)*e3t(:,:,jk,Kaa)     &
94               &                 - pts(:,:,jk,jp_sal,Kbb)*e3t(:,:,jk,Kbb)  )  &
95               &             / (   e3t(:,:,jk,Kmm)*rDt  )   )                 &
96               &          - ztrds(:,:,jk)
97         END DO
98         CALL trd_tra( kt, Kmm, Krhs, 'TRA', jp_tem, jptra_zdf, ztrdt )
99         CALL trd_tra( kt, Kmm, Krhs, 'TRA', jp_sal, jptra_zdf, ztrds )
100         DEALLOCATE( ztrdt , ztrds )
[1110]101      ENDIF
102      !                                          ! print mean trends (used for debugging)
[12377]103      IF(sn_cfctl%l_prtctl)   CALL prt_ctl( tab3d_1=pts(:,:,:,jp_tem,Kaa), clinfo1=' zdf  - Ta: ', mask1=tmask,               &
104         &                                  tab3d_2=pts(:,:,:,jp_sal,Kaa), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
[2715]105      !
[9019]106      IF( ln_timing )   CALL timing_stop('tra_zdf')
[3294]107      !
[458]108   END SUBROUTINE tra_zdf
109
[9019]110 
[12377]111   SUBROUTINE tra_zdf_imp( kt, kit000, cdtype, p2dt, Kbb, Kmm, Krhs, pt, Kaa, kjpt ) 
[458]112      !!----------------------------------------------------------------------
[9019]113      !!                  ***  ROUTINE tra_zdf_imp  ***
[458]114      !!
[9019]115      !! ** Purpose :   Compute the after tracer through a implicit computation
116      !!     of the vertical tracer diffusion (including the vertical component
117      !!     of lateral mixing (only for 2nd order operator, for fourth order
118      !!     it is already computed and add to the general trend in traldf)
[458]119      !!
[9019]120      !! ** Method  :  The vertical diffusion of a tracer ,t , is given by:
121      !!          difft = dz( avt dz(t) ) = 1/e3t dk+1( avt/e3w dk(t) )
122      !!      It is computed using a backward time scheme (t=after field)
123      !!      which provide directly the after tracer field.
124      !!      If ln_zdfddm=T, use avs for salinity or for passive tracers
125      !!      Surface and bottom boundary conditions: no diffusive flux on
126      !!      both tracers (bottom, applied through the masked field avt).
127      !!      If iso-neutral mixing, add to avt the contribution due to lateral mixing.
128      !!
[12377]129      !! ** Action  : - pt(:,:,:,:,Kaa)  becomes the after tracer
[9019]130      !!---------------------------------------------------------------------
[12377]131      INTEGER                                  , INTENT(in   ) ::   kt       ! ocean time-step index
132      INTEGER                                  , INTENT(in   ) ::   Kbb, Kmm, Krhs, Kaa  ! ocean time level indices
133      INTEGER                                  , INTENT(in   ) ::   kit000   ! first time step index
134      CHARACTER(len=3)                         , INTENT(in   ) ::   cdtype   ! =TRA or TRC (tracer indicator)
135      INTEGER                                  , INTENT(in   ) ::   kjpt     ! number of tracers
136      REAL(wp)                                 , INTENT(in   ) ::   p2dt     ! tracer time-step
137      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt,jpt), INTENT(inout) ::   pt       ! tracers and RHS of tracer equation
[6140]138      !
[9019]139      INTEGER  ::  ji, jj, jk, jn   ! dummy loop indices
[10364]140      REAL(wp) ::  zrhs, zzwi, zzws ! local scalars
[13517]141      REAL(wp), DIMENSION(ST_2D(nn_hls),jpk) ::  zwi, zwt, zwd, zws
[9019]142      !!---------------------------------------------------------------------
143      !
144      !                                               ! ============= !
145      DO jn = 1, kjpt                                 !  tracer loop  !
146         !                                            ! ============= !
147         !  Matrix construction
148         ! --------------------
149         ! Build matrix if temperature or salinity (only in double diffusion case) or first passive tracer
150         !
151         IF(  ( cdtype == 'TRA' .AND. ( jn == jp_tem .OR. ( jn == jp_sal .AND. ln_zdfddm ) ) ) .OR.   &
152            & ( cdtype == 'TRC' .AND. jn == 1 )  )  THEN
[6140]153            !
[9019]154            ! vertical mixing coef.: avt for temperature, avs for salinity and passive tracers
[13517]155            IF( cdtype == 'TRA' .AND. jn == jp_tem ) THEN
156               DO_3D( 1, 1, 1, 1, 2, jpk )
157                  zwt(ji,jj,jk) = avt(ji,jj,jk)
158               END_3D
159            ELSE
160               DO_3D( 1, 1, 1, 1, 2, jpk )
161                  zwt(ji,jj,jk) = avs(ji,jj,jk)
162               END_3D
[9019]163            ENDIF
164            zwt(:,:,1) = 0._wp
165            !
166            IF( l_ldfslp ) THEN            ! isoneutral diffusion: add the contribution
167               IF( ln_traldf_msc  ) THEN     ! MSC iso-neutral operator
[13295]168                  DO_3D( 0, 0, 0, 0, 2, jpkm1 )
[12377]169                     zwt(ji,jj,jk) = zwt(ji,jj,jk) + akz(ji,jj,jk) 
170                  END_3D
[9019]171               ELSE                          ! standard or triad iso-neutral operator
[13295]172                  DO_3D( 0, 0, 0, 0, 2, jpkm1 )
[12377]173                     zwt(ji,jj,jk) = zwt(ji,jj,jk) + ah_wslp2(ji,jj,jk)
174                  END_3D
[9019]175               ENDIF
176            ENDIF
177            !
178            ! Diagonal, lower (i), upper (s)  (including the bottom boundary condition since avt is masked)
[10364]179            IF( ln_zad_Aimp ) THEN         ! Adaptive implicit vertical advection
[13295]180               DO_3D( 0, 0, 0, 0, 1, jpkm1 )
[12377]181                  zzwi = - p2dt * zwt(ji,jj,jk  ) / e3w(ji,jj,jk  ,Kmm)
182                  zzws = - p2dt * zwt(ji,jj,jk+1) / e3w(ji,jj,jk+1,Kmm)
183                  zwd(ji,jj,jk) = e3t(ji,jj,jk,Kaa) - zzwi - zzws   &
184                     &                 + p2dt * ( MAX( wi(ji,jj,jk  ) , 0._wp ) - MIN( wi(ji,jj,jk+1) , 0._wp ) )
185                  zwi(ji,jj,jk) = zzwi + p2dt *   MIN( wi(ji,jj,jk  ) , 0._wp )
186                  zws(ji,jj,jk) = zzws - p2dt *   MAX( wi(ji,jj,jk+1) , 0._wp )
187               END_3D
[10364]188            ELSE
[13295]189               DO_3D( 0, 0, 0, 0, 1, jpkm1 )
[12377]190                  zwi(ji,jj,jk) = - p2dt * zwt(ji,jj,jk  ) / e3w(ji,jj,jk,Kmm)
191                  zws(ji,jj,jk) = - p2dt * zwt(ji,jj,jk+1) / e3w(ji,jj,jk+1,Kmm)
192                  zwd(ji,jj,jk) = e3t(ji,jj,jk,Kaa) - zwi(ji,jj,jk) - zws(ji,jj,jk)
193               END_3D
[10364]194            ENDIF
[9019]195            !
196            !! Matrix inversion from the first level
197            !!----------------------------------------------------------------------
198            !   solve m.x = y  where m is a tri diagonal matrix ( jpk*jpk )
199            !
200            !        ( zwd1 zws1   0    0    0  )( zwx1 ) ( zwy1 )
201            !        ( zwi2 zwd2 zws2   0    0  )( zwx2 ) ( zwy2 )
202            !        (  0   zwi3 zwd3 zws3   0  )( zwx3 )=( zwy3 )
203            !        (        ...               )( ...  ) ( ...  )
204            !        (  0    0    0   zwik zwdk )( zwxk ) ( zwyk )
205            !
206            !   m is decomposed in the product of an upper and lower triangular matrix.
207            !   The 3 diagonal terms are in 3d arrays: zwd, zws, zwi.
208            !   Suffices i,s and d indicate "inferior" (below diagonal), diagonal
209            !   and "superior" (above diagonal) components of the tridiagonal system.
210            !   The solution will be in the 4d array pta.
211            !   The 3d array zwt is used as a work space array.
[12377]212            !   En route to the solution pt(:,:,:,:,Kaa) is used a to evaluate the rhs and then
[9019]213            !   used as a work space array: its value is modified.
214            !
[13295]215            DO_2D( 0, 0, 0, 0 )
[12377]216               zwt(ji,jj,1) = zwd(ji,jj,1)
217            END_2D
[13295]218            DO_3D( 0, 0, 0, 0, 2, jpkm1 )
[12377]219               zwt(ji,jj,jk) = zwd(ji,jj,jk) - zwi(ji,jj,jk) * zws(ji,jj,jk-1) / zwt(ji,jj,jk-1)
220            END_3D
[9019]221            !
222         ENDIF 
223         !         
[13295]224         DO_2D( 0, 0, 0, 0 )
[13237]225            pt(ji,jj,1,jn,Kaa) =        e3t(ji,jj,1,Kbb) * pt(ji,jj,1,jn,Kbb)    &
226               &               + p2dt * e3t(ji,jj,1,Kmm) * pt(ji,jj,1,jn,Krhs)
[12377]227         END_2D
[13295]228         DO_3D( 0, 0, 0, 0, 2, jpkm1 )
[13517]229            zrhs =        e3t(ji,jj,jk,Kbb) * pt(ji,jj,jk,jn,Kbb)    &
[13237]230               & + p2dt * e3t(ji,jj,jk,Kmm) * pt(ji,jj,jk,jn,Krhs)   ! zrhs=right hand side
[12377]231            pt(ji,jj,jk,jn,Kaa) = zrhs - zwi(ji,jj,jk) / zwt(ji,jj,jk-1) * pt(ji,jj,jk-1,jn,Kaa)
232         END_3D
[9019]233         !
[13295]234         DO_2D( 0, 0, 0, 0 )
[12377]235            pt(ji,jj,jpkm1,jn,Kaa) = pt(ji,jj,jpkm1,jn,Kaa) / zwt(ji,jj,jpkm1) * tmask(ji,jj,jpkm1)
236         END_2D
[13295]237         DO_3DS( 0, 0, 0, 0, jpk-2, 1, -1 )
[12377]238            pt(ji,jj,jk,jn,Kaa) = ( pt(ji,jj,jk,jn,Kaa) - zws(ji,jj,jk) * pt(ji,jj,jk+1,jn,Kaa) )   &
239               &             / zwt(ji,jj,jk) * tmask(ji,jj,jk)
240         END_3D
[9019]241         !                                            ! ================= !
242      END DO                                          !  end tracer loop  !
243      !                                               ! ================= !
244   END SUBROUTINE tra_zdf_imp
[458]245
246   !!==============================================================================
247END MODULE trazdf
Note: See TracBrowser for help on using the repository browser.