New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
zpshde.F90 in NEMO/branches/2020/dev_r13383_HPC-02_Daley_Tiling/src/OCE/TRA – NEMO

source: NEMO/branches/2020/dev_r13383_HPC-02_Daley_Tiling/src/OCE/TRA/zpshde.F90 @ 13898

Last change on this file since 13898 was 13898, checked in by hadcv, 4 years ago

#2365: Merge in changes from dev_r13508_HPC-09_communications_cleanup up to [13701]
  • Property svn:keywords set to Id
File size: 28.5 KB
Line 
1MODULE zpshde
2   !!======================================================================
3   !!                       ***  MODULE zpshde   ***
4   !! z-coordinate + partial step : Horizontal Derivative at ocean bottom level
5   !!======================================================================
6   !! History :  OPA  !  2002-04  (A. Bozec)  Original code
7   !!   NEMO     1.0  !  2002-08  (G. Madec E. Durand)  Optimization and Free form
8   !!             -   !  2004-03  (C. Ethe)  adapted for passive tracers
9   !!            3.3  !  2010-05  (C. Ethe, G. Madec)  merge TRC-TRA
10   !!            3.6  !  2014-11  (P. Mathiot) Add zps_hde_isf (needed to open a cavity)
11   !!======================================================================
12   
13   !!----------------------------------------------------------------------
14   !!   zps_hde      :  Horizontal DErivative of T, S and rd at the last
15   !!                   ocean level (Z-coord. with Partial Steps)
16   !!----------------------------------------------------------------------
17   USE oce             ! ocean: dynamics and tracers variables
18   USE dom_oce         ! domain: ocean variables
19   USE domutl, ONLY : is_tile
20   USE phycst          ! physical constants
21   USE eosbn2          ! ocean equation of state
22   USE in_out_manager  ! I/O manager
23   USE lbclnk          ! lateral boundary conditions (or mpp link)
24   USE lib_mpp         ! MPP library
25   USE timing          ! Timing
26
27   IMPLICIT NONE
28   PRIVATE
29
30   PUBLIC   zps_hde     ! routine called by step.F90
31   PUBLIC   zps_hde_isf ! routine called by step.F90
32
33   !! * Substitutions
34#  include "do_loop_substitute.h90"
35#  include "domzgr_substitute.h90"
36   !!----------------------------------------------------------------------
37   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
38   !! $Id$
39   !! Software governed by the CeCILL license (see ./LICENSE)
40   !!----------------------------------------------------------------------
41CONTAINS
42
43   SUBROUTINE zps_hde( kt, Kmm, kjpt, pta, pgtu, pgtv,  &
44      &                               prd, pgru, pgrv )
45      !!
46      INTEGER                     , INTENT(in   )           ::  kt          ! ocean time-step index
47      INTEGER                     , INTENT(in   )           ::  Kmm         ! ocean time level index
48      INTEGER                     , INTENT(in   )           ::  kjpt        ! number of tracers
49      REAL(wp), DIMENSION(:,:,:,:), INTENT(inout)           ::  pta         ! 4D tracers fields
50      REAL(wp), DIMENSION(:,:,:)  , INTENT(  out)           ::  pgtu, pgtv  ! hor. grad. of ptra at u- & v-pts
51      REAL(wp), DIMENSION(:,:,:)  , INTENT(inout), OPTIONAL ::  prd         ! 3D density anomaly fields
52      REAL(wp), DIMENSION(:,:)    , INTENT(  out), OPTIONAL ::  pgru, pgrv  ! hor. grad of prd at u- & v-pts (bottom)
53      !
54      INTEGER :: itrd, itgr
55      !!
56      IF( PRESENT(prd)  ) THEN ; itrd = is_tile(prd)  ; ELSE ; itrd = 0 ; ENDIF
57      IF( PRESENT(pgru) ) THEN ; itgr = is_tile(pgru) ; ELSE ; itgr = 0 ; ENDIF
58
59      CALL zps_hde_t( kt, Kmm, kjpt, pta, is_tile(pta), pgtu, pgtv, is_tile(pgtu), &
60         &                           prd, itrd,         pgru, pgrv, itgr )
61   END SUBROUTINE zps_hde
62
63
64   SUBROUTINE zps_hde_t( kt, Kmm, kjpt, pta, ktta, pgtu, pgtv, ktgt,   &
65      &                                 prd, ktrd, pgru, pgrv, ktgr )
66      !!----------------------------------------------------------------------
67      !!                     ***  ROUTINE zps_hde  ***
68      !!                   
69      !! ** Purpose :   Compute the horizontal derivative of T, S and rho
70      !!      at u- and v-points with a linear interpolation for z-coordinate
71      !!      with partial steps.
72      !!
73      !! ** Method  :   In z-coord with partial steps, scale factors on last
74      !!      levels are different for each grid point, so that T, S and rd
75      !!      points are not at the same depth as in z-coord. To have horizontal
76      !!      gradients again, we interpolate T and S at the good depth :
77      !!      Linear interpolation of T, S   
78      !!         Computation of di(tb) and dj(tb) by vertical interpolation:
79      !!          di(t) = t~ - t(i,j,k) or t(i+1,j,k) - t~
80      !!          dj(t) = t~ - t(i,j,k) or t(i,j+1,k) - t~
81      !!         This formulation computes the two cases:
82      !!                 CASE 1                   CASE 2 
83      !!         k-1  ___ ___________   k-1   ___ ___________
84      !!                    Ti  T~                  T~  Ti+1
85      !!                  _____                        _____
86      !!         k        |   |Ti+1     k           Ti |   |
87      !!                  |   |____                ____|   |
88      !!              ___ |   |   |           ___  |   |   |
89      !!                 
90      !!      case 1->   e3w(i+1,:,:,Kmm) >= e3w(i,:,:,Kmm) ( and e3w(:,j+1,:,Kmm) >= e3w(:,j,:,Kmm) ) then
91      !!          t~ = t(i+1,j  ,k) + (e3w(i+1,j,k,Kmm) - e3w(i,j,k,Kmm)) * dk(Ti+1)/e3w(i+1,j,k,Kmm)
92      !!        ( t~ = t(i  ,j+1,k) + (e3w(i,j+1,k,Kmm) - e3w(i,j,k,Kmm)) * dk(Tj+1)/e3w(i,j+1,k,Kmm)  )
93      !!          or
94      !!      case 2->   e3w(i+1,:,:,Kmm) <= e3w(i,:,:,Kmm) ( and e3w(:,j+1,:,Kmm) <= e3w(:,j,:,Kmm) ) then
95      !!          t~ = t(i,j,k) + (e3w(i,j,k,Kmm) - e3w(i+1,j,k,Kmm)) * dk(Ti)/e3w(i,j,k,Kmm)
96      !!        ( t~ = t(i,j,k) + (e3w(i,j,k,Kmm) - e3w(i,j+1,k,Kmm)) * dk(Tj)/e3w(i,j,k,Kmm) )
97      !!          Idem for di(s) and dj(s)         
98      !!
99      !!      For rho, we call eos which will compute rd~(t~,s~) at the right
100      !!      depth zh from interpolated T and S for the different formulations
101      !!      of the equation of state (eos).
102      !!      Gradient formulation for rho :
103      !!          di(rho) = rd~ - rd(i,j,k)   or   rd(i+1,j,k) - rd~
104      !!
105      !! ** Action  : compute for top interfaces
106      !!              - pgtu, pgtv: horizontal gradient of tracer at u- & v-points
107      !!              - pgru, pgrv: horizontal gradient of rho (if present) at u- & v-points
108      !!----------------------------------------------------------------------
109      INTEGER                                , INTENT(in   )           ::  kt          ! ocean time-step index
110      INTEGER                                , INTENT(in   )           ::  Kmm         ! ocean time level index
111      INTEGER                                , INTENT(in   )           ::  kjpt        ! number of tracers
112      INTEGER                                , INTENT(in   )           ::  ktta, ktgt, ktrd, ktgr
113      REAL(wp), DIMENSION(A2D_T(ktta),JPK,KJPT), INTENT(inout)           ::  pta         ! 4D tracers fields
114      REAL(wp), DIMENSION(A2D_T(ktgt)    ,KJPT), INTENT(  out)           ::  pgtu, pgtv  ! hor. grad. of ptra at u- & v-pts
115      REAL(wp), DIMENSION(A2D_T(ktrd),JPK     ), INTENT(inout), OPTIONAL ::  prd         ! 3D density anomaly fields
116      REAL(wp), DIMENSION(A2D_T(ktgr)         ), INTENT(  out), OPTIONAL ::  pgru, pgrv  ! hor. grad of prd at u- & v-pts (bottom)
117      !
118      INTEGER  ::   ji, jj, jn                  ! Dummy loop indices
119      INTEGER  ::   iku, ikv, ikum1, ikvm1      ! partial step level (ocean bottom level) at u- and v-points
120      REAL(wp) ::   ze3wu, ze3wv, zmaxu, zmaxv  ! local scalars
121      REAL(wp), DIMENSION(A2D(nn_hls))      ::   zri, zrj, zhi, zhj   ! NB: 3rd dim=1 to use eos
122      REAL(wp), DIMENSION(A2D(nn_hls),kjpt) ::   zti, ztj             !
123      !!----------------------------------------------------------------------
124      !
125      IF( ln_timing )   CALL timing_start( 'zps_hde')
126      ! NOTE: [tiling-comms-merge] Some lbc_lnks in tra_adv and tra_ldf can be taken out in the zps case, because this lbc_lnk is called when zps_hde is called in the stp routine. In the zco case they are still needed.
127      IF (nn_hls.EQ.2) THEN ; CALL lbc_lnk( 'zpshde', pta, 'T', 1.0_wp)
128      IF(PRESENT(prd)) CALL lbc_lnk( 'zpshde', prd, 'T', 1.0_wp) ; END IF
129      !
130      pgtu(:,:,:) = 0._wp   ;   zti (:,:,:) = 0._wp   ;   zhi (:,:) = 0._wp
131      pgtv(:,:,:) = 0._wp   ;   ztj (:,:,:) = 0._wp   ;   zhj (:,:) = 0._wp
132      !
133      DO jn = 1, kjpt      !==   Interpolation of tracers at the last ocean level   ==!
134         !
135         DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )              ! Gradient of density at the last level
136            iku = mbku(ji,jj)   ;   ikum1 = MAX( iku - 1 , 1 )    ! last and before last ocean level at u- & v-points
137            ikv = mbkv(ji,jj)   ;   ikvm1 = MAX( ikv - 1 , 1 )    ! if level first is a p-step, ik.m1=1
138!!gm BUG ? when applied to before fields, e3w(:,:,k,Kbb) should be used....
139            ze3wu = e3w(ji+1,jj  ,iku,Kmm) - e3w(ji,jj,iku,Kmm)
140            ze3wv = e3w(ji  ,jj+1,ikv,Kmm) - e3w(ji,jj,ikv,Kmm)
141            !
142            ! i- direction
143            IF( ze3wu >= 0._wp ) THEN      ! case 1
144               zmaxu =  ze3wu / e3w(ji+1,jj,iku,Kmm)
145               ! interpolated values of tracers
146               zti (ji,jj,jn) = pta(ji+1,jj,iku,jn) + zmaxu * ( pta(ji+1,jj,ikum1,jn) - pta(ji+1,jj,iku,jn) )
147               ! gradient of  tracers
148               pgtu(ji,jj,jn) = umask(ji,jj,1) * ( zti(ji,jj,jn) - pta(ji,jj,iku,jn) )
149            ELSE                           ! case 2
150               zmaxu = -ze3wu / e3w(ji,jj,iku,Kmm)
151               ! interpolated values of tracers
152               zti (ji,jj,jn) = pta(ji,jj,iku,jn) + zmaxu * ( pta(ji,jj,ikum1,jn) - pta(ji,jj,iku,jn) )
153               ! gradient of tracers
154               pgtu(ji,jj,jn) = umask(ji,jj,1) * ( pta(ji+1,jj,iku,jn) - zti(ji,jj,jn) )
155            ENDIF
156            !
157            ! j- direction
158            IF( ze3wv >= 0._wp ) THEN      ! case 1
159               zmaxv =  ze3wv / e3w(ji,jj+1,ikv,Kmm)
160               ! interpolated values of tracers
161               ztj (ji,jj,jn) = pta(ji,jj+1,ikv,jn) + zmaxv * ( pta(ji,jj+1,ikvm1,jn) - pta(ji,jj+1,ikv,jn) )
162               ! gradient of tracers
163               pgtv(ji,jj,jn) = vmask(ji,jj,1) * ( ztj(ji,jj,jn) - pta(ji,jj,ikv,jn) )
164            ELSE                           ! case 2
165               zmaxv =  -ze3wv / e3w(ji,jj,ikv,Kmm)
166               ! interpolated values of tracers
167               ztj (ji,jj,jn) = pta(ji,jj,ikv,jn) + zmaxv * ( pta(ji,jj,ikvm1,jn) - pta(ji,jj,ikv,jn) )
168               ! gradient of tracers
169               pgtv(ji,jj,jn) = vmask(ji,jj,1) * ( pta(ji,jj+1,ikv,jn) - ztj(ji,jj,jn) )
170            ENDIF
171         END_2D
172      END DO
173      !
174      IF (nn_hls.EQ.1) CALL lbc_lnk_multi( 'zpshde', pgtu(:,:,:), 'U', -1.0_wp , pgtv(:,:,:), 'V', -1.0_wp )   ! Lateral boundary cond.
175      !               
176      IF( PRESENT( prd ) ) THEN    !==  horizontal derivative of density anomalies (rd)  ==!    (optional part)
177         pgru(:,:) = 0._wp
178         pgrv(:,:) = 0._wp                ! depth of the partial step level
179         DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )
180            iku = mbku(ji,jj)
181            ikv = mbkv(ji,jj)
182            ze3wu  = e3w(ji+1,jj  ,iku,Kmm) - e3w(ji,jj,iku,Kmm)
183            ze3wv  = e3w(ji  ,jj+1,ikv,Kmm) - e3w(ji,jj,ikv,Kmm)
184            IF( ze3wu >= 0._wp ) THEN   ;   zhi(ji,jj) = gdept(ji  ,jj,iku,Kmm)     ! i-direction: case 1
185            ELSE                        ;   zhi(ji,jj) = gdept(ji+1,jj,iku,Kmm)     ! -     -      case 2
186            ENDIF
187            IF( ze3wv >= 0._wp ) THEN   ;   zhj(ji,jj) = gdept(ji,jj  ,ikv,Kmm)     ! j-direction: case 1
188            ELSE                        ;   zhj(ji,jj) = gdept(ji,jj+1,ikv,Kmm)     ! -     -      case 2
189            ENDIF
190         END_2D
191         !
192         CALL eos( zti, zhi, zri )        ! interpolated density from zti, ztj
193         CALL eos( ztj, zhj, zrj )        ! at the partial step depth output in  zri, zrj
194         !
195         DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )              ! Gradient of density at the last level
196            iku = mbku(ji,jj)
197            ikv = mbkv(ji,jj)
198            ze3wu  = e3w(ji+1,jj  ,iku,Kmm) - e3w(ji,jj,iku,Kmm)
199            ze3wv  = e3w(ji  ,jj+1,ikv,Kmm) - e3w(ji,jj,ikv,Kmm)
200            IF( ze3wu >= 0._wp ) THEN   ;   pgru(ji,jj) = umask(ji,jj,1) * ( zri(ji  ,jj    ) - prd(ji,jj,iku) )   ! i: 1
201            ELSE                        ;   pgru(ji,jj) = umask(ji,jj,1) * ( prd(ji+1,jj,iku) - zri(ji,jj    ) )   ! i: 2
202            ENDIF
203            IF( ze3wv >= 0._wp ) THEN   ;   pgrv(ji,jj) = vmask(ji,jj,1) * ( zrj(ji,jj      ) - prd(ji,jj,ikv) )   ! j: 1
204            ELSE                        ;   pgrv(ji,jj) = vmask(ji,jj,1) * ( prd(ji,jj+1,ikv) - zrj(ji,jj    ) )   ! j: 2
205            ENDIF
206         END_2D
207         IF (nn_hls.EQ.1) CALL lbc_lnk_multi( 'zpshde', pgru , 'U', -1.0_wp , pgrv , 'V', -1.0_wp )   ! Lateral boundary conditions
208         !
209      END IF
210      !
211      IF( ln_timing )   CALL timing_stop( 'zps_hde')
212      !
213   END SUBROUTINE zps_hde_t
214
215
216   SUBROUTINE zps_hde_isf( kt, Kmm, kjpt, pta, pgtu, pgtv, pgtui, pgtvi,  &
217      &                                   prd, pgru, pgrv, pgrui, pgrvi )
218      !!
219      INTEGER                     , INTENT(in   )           ::  kt           ! ocean time-step index
220      INTEGER                     , INTENT(in   )           ::  Kmm          ! ocean time level index
221      INTEGER                     , INTENT(in   )           ::  kjpt         ! number of tracers
222      REAL(wp), DIMENSION(:,:,:,:), INTENT(inout)           ::  pta          ! 4D tracers fields
223      REAL(wp), DIMENSION(:,:,:)  , INTENT(  out)           ::  pgtu, pgtv   ! hor. grad. of ptra at u- & v-pts
224      REAL(wp), DIMENSION(:,:,:)  , INTENT(  out)           ::  pgtui, pgtvi ! hor. grad. of stra at u- & v-pts (ISF)
225      REAL(wp), DIMENSION(:,:,:)  , INTENT(inout), OPTIONAL ::  prd          ! 3D density anomaly fields
226      REAL(wp), DIMENSION(:,:)    , INTENT(  out), OPTIONAL ::  pgru, pgrv   ! hor. grad of prd at u- & v-pts (bottom)
227      REAL(wp), DIMENSION(:,:)    , INTENT(  out), OPTIONAL ::  pgrui, pgrvi ! hor. grad of prd at u- & v-pts (top)
228      !
229      INTEGER :: itrd, itgr, itgri
230      !!
231      IF( PRESENT(prd)   ) THEN ; itrd  = is_tile(prd)   ; ELSE ; itrd  = 0 ; ENDIF
232      IF( PRESENT(pgru)  ) THEN ; itgr  = is_tile(pgru)  ; ELSE ; itgr  = 0 ; ENDIF
233      IF( PRESENT(pgrui) ) THEN ; itgri = is_tile(pgrui) ; ELSE ; itgri = 0 ; ENDIF
234
235      CALL zps_hde_isf_t( kt, Kmm, kjpt, pta, is_tile(pta), pgtu, pgtv, is_tile(pgtu), pgtui, pgtvi, is_tile(pgtui),  &
236      &                                  prd, itrd,         pgru, pgrv, itgr,          pgrui, pgrvi, itgri )
237   END SUBROUTINE zps_hde_isf
238
239
240   SUBROUTINE zps_hde_isf_t( kt, Kmm, kjpt, pta, ktta, pgtu, pgtv, ktgt, pgtui, pgtvi, ktgti,  &
241      &                                     prd, ktrd, pgru, pgrv, ktgr, pgrui, pgrvi, ktgri )
242      !!----------------------------------------------------------------------
243      !!                     ***  ROUTINE zps_hde_isf  ***
244      !!                   
245      !! ** Purpose :   Compute the horizontal derivative of T, S and rho
246      !!      at u- and v-points with a linear interpolation for z-coordinate
247      !!      with partial steps for top (ice shelf) and bottom.
248      !!
249      !! ** Method  :   In z-coord with partial steps, scale factors on last
250      !!      levels are different for each grid point, so that T, S and rd
251      !!      points are not at the same depth as in z-coord. To have horizontal
252      !!      gradients again, we interpolate T and S at the good depth :
253      !!      For the bottom case:
254      !!      Linear interpolation of T, S   
255      !!         Computation of di(tb) and dj(tb) by vertical interpolation:
256      !!          di(t) = t~ - t(i,j,k) or t(i+1,j,k) - t~
257      !!          dj(t) = t~ - t(i,j,k) or t(i,j+1,k) - t~
258      !!         This formulation computes the two cases:
259      !!                 CASE 1                   CASE 2 
260      !!         k-1  ___ ___________   k-1   ___ ___________
261      !!                    Ti  T~                  T~  Ti+1
262      !!                  _____                        _____
263      !!         k        |   |Ti+1     k           Ti |   |
264      !!                  |   |____                ____|   |
265      !!              ___ |   |   |           ___  |   |   |
266      !!                 
267      !!      case 1->   e3w(i+1,j,k,Kmm) >= e3w(i,j,k,Kmm) ( and e3w(i,j+1,k,Kmm) >= e3w(i,j,k,Kmm) ) then
268      !!          t~ = t(i+1,j  ,k) + (e3w(i+1,j  ,k,Kmm) - e3w(i,j,k,Kmm)) * dk(Ti+1)/e3w(i+1,j  ,k,Kmm)
269      !!        ( t~ = t(i  ,j+1,k) + (e3w(i  ,j+1,k,Kmm) - e3w(i,j,k,Kmm)) * dk(Tj+1)/e3w(i  ,j+1,k,Kmm)  )
270      !!          or
271      !!      case 2->   e3w(i+1,j,k,Kmm) <= e3w(i,j,k,Kmm) ( and e3w(i,j+1,k,Kmm) <= e3w(i,j,k,Kmm) ) then
272      !!          t~ = t(i,j,k) + (e3w(i,j,k,Kmm) - e3w(i+1,j  ,k,Kmm)) * dk(Ti)/e3w(i,j,k,Kmm)
273      !!        ( t~ = t(i,j,k) + (e3w(i,j,k,Kmm) - e3w(i  ,j+1,k,Kmm)) * dk(Tj)/e3w(i,j,k,Kmm) )
274      !!          Idem for di(s) and dj(s)         
275      !!
276      !!      For rho, we call eos which will compute rd~(t~,s~) at the right
277      !!      depth zh from interpolated T and S for the different formulations
278      !!      of the equation of state (eos).
279      !!      Gradient formulation for rho :
280      !!          di(rho) = rd~ - rd(i,j,k)   or   rd(i+1,j,k) - rd~
281      !!
282      !!      For the top case (ice shelf): As for the bottom case but upside down
283      !!
284      !! ** Action  : compute for top and bottom interfaces
285      !!              - pgtu, pgtv, pgtui, pgtvi: horizontal gradient of tracer at u- & v-points
286      !!              - pgru, pgrv, pgrui, pgtvi: horizontal gradient of rho (if present) at u- & v-points
287      !!----------------------------------------------------------------------
288      INTEGER                                , INTENT(in   )           ::  kt           ! ocean time-step index
289      INTEGER                                , INTENT(in   )           ::  Kmm          ! ocean time level index
290      INTEGER                                , INTENT(in   )           ::  kjpt         ! number of tracers
291      INTEGER                                , INTENT(in   )           ::  ktta, ktgt, ktgti, ktrd, ktgr, ktgri
292      REAL(wp), DIMENSION(A2D_T(ktta),JPK,KJPT), INTENT(inout)           ::  pta          ! 4D tracers fields
293      REAL(wp), DIMENSION(A2D_T(ktgt)    ,KJPT), INTENT(  out)           ::  pgtu, pgtv   ! hor. grad. of ptra at u- & v-pts
294      REAL(wp), DIMENSION(A2D_T(ktgti)   ,KJPT), INTENT(  out)           ::  pgtui, pgtvi ! hor. grad. of stra at u- & v-pts (ISF)
295      REAL(wp), DIMENSION(A2D_T(ktrd),JPK     ), INTENT(inout), OPTIONAL ::  prd          ! 3D density anomaly fields
296      REAL(wp), DIMENSION(A2D_T(ktgr)         ), INTENT(  out), OPTIONAL ::  pgru, pgrv   ! hor. grad of prd at u- & v-pts (bottom)
297      REAL(wp), DIMENSION(A2D_T(ktgri)        ), INTENT(  out), OPTIONAL ::  pgrui, pgrvi ! hor. grad of prd at u- & v-pts (top)
298      !
299      INTEGER  ::   ji, jj, jn      ! Dummy loop indices
300      INTEGER  ::   iku, ikv, ikum1, ikvm1,ikup1, ikvp1   ! partial step level (ocean bottom level) at u- and v-points
301      REAL(wp) ::  ze3wu, ze3wv, zmaxu, zmaxv             ! temporary scalars
302      REAL(wp), DIMENSION(A2D(nn_hls))      ::  zri, zrj, zhi, zhj   ! NB: 3rd dim=1 to use eos
303      REAL(wp), DIMENSION(A2D(nn_hls),kjpt) ::  zti, ztj             !
304      !!----------------------------------------------------------------------
305      !
306      IF( ln_timing )   CALL timing_start( 'zps_hde_isf')
307      !
308      IF (nn_hls.EQ.2) THEN ; CALL lbc_lnk( 'zpshde', pta, 'T', 1.0_wp)
309      IF (PRESENT(prd)) CALL lbc_lnk( 'zpshde', prd, 'T', 1.0_wp) ; END IF
310
311      pgtu (:,:,:) = 0._wp   ;   pgtv (:,:,:) =0._wp
312      pgtui(:,:,:) = 0._wp   ;   pgtvi(:,:,:) =0._wp
313      zti  (:,:,:) = 0._wp   ;   ztj  (:,:,:) =0._wp
314      zhi  (:,:  ) = 0._wp   ;   zhj  (:,:  ) =0._wp
315      !
316      DO jn = 1, kjpt      !==   Interpolation of tracers at the last ocean level   ==!
317         !
318         DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )
319
320            iku = mbku(ji,jj); ikum1 = MAX( iku - 1 , 1 )    ! last and before last ocean level at u- & v-points
321            ikv = mbkv(ji,jj); ikvm1 = MAX( ikv - 1 , 1 )    ! if level first is a p-step, ik.m1=1
322            ze3wu = gdept(ji+1,jj,iku,Kmm) - gdept(ji,jj,iku,Kmm)
323            ze3wv = gdept(ji,jj+1,ikv,Kmm) - gdept(ji,jj,ikv,Kmm)
324            !
325            ! i- direction
326            IF( ze3wu >= 0._wp ) THEN      ! case 1
327               zmaxu =  ze3wu / e3w(ji+1,jj,iku,Kmm)
328               ! interpolated values of tracers
329               zti (ji,jj,jn) = pta(ji+1,jj,iku,jn) + zmaxu * ( pta(ji+1,jj,ikum1,jn) - pta(ji+1,jj,iku,jn) )
330               ! gradient of  tracers
331               pgtu(ji,jj,jn) = ssumask(ji,jj) * ( zti(ji,jj,jn) - pta(ji,jj,iku,jn) )
332            ELSE                           ! case 2
333               zmaxu = -ze3wu / e3w(ji,jj,iku,Kmm)
334               ! interpolated values of tracers
335               zti (ji,jj,jn) = pta(ji,jj,iku,jn) + zmaxu * ( pta(ji,jj,ikum1,jn) - pta(ji,jj,iku,jn) )
336               ! gradient of tracers
337               pgtu(ji,jj,jn) = ssumask(ji,jj) * ( pta(ji+1,jj,iku,jn) - zti(ji,jj,jn) )
338            ENDIF
339            !
340            ! j- direction
341            IF( ze3wv >= 0._wp ) THEN      ! case 1
342               zmaxv =  ze3wv / e3w(ji,jj+1,ikv,Kmm)
343               ! interpolated values of tracers
344               ztj (ji,jj,jn) = pta(ji,jj+1,ikv,jn) + zmaxv * ( pta(ji,jj+1,ikvm1,jn) - pta(ji,jj+1,ikv,jn) )
345               ! gradient of tracers
346               pgtv(ji,jj,jn) = ssvmask(ji,jj) * ( ztj(ji,jj,jn) - pta(ji,jj,ikv,jn) )
347            ELSE                           ! case 2
348               zmaxv =  -ze3wv / e3w(ji,jj,ikv,Kmm)
349               ! interpolated values of tracers
350               ztj (ji,jj,jn) = pta(ji,jj,ikv,jn) + zmaxv * ( pta(ji,jj,ikvm1,jn) - pta(ji,jj,ikv,jn) )
351               ! gradient of tracers
352               pgtv(ji,jj,jn) = ssvmask(ji,jj) * ( pta(ji,jj+1,ikv,jn) - ztj(ji,jj,jn) )
353            ENDIF
354
355         END_2D
356      END DO
357      !
358      IF (nn_hls.EQ.1) CALL lbc_lnk_multi( 'zpshde', pgtu(:,:,:), 'U', -1.0_wp , pgtv(:,:,:), 'V', -1.0_wp )   ! Lateral boundary cond.
359
360      ! horizontal derivative of density anomalies (rd)
361      IF( PRESENT( prd ) ) THEN         ! depth of the partial step level
362         pgru(:,:)=0.0_wp   ; pgrv(:,:)=0.0_wp ; 
363         !
364         DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )
365
366            iku = mbku(ji,jj)
367            ikv = mbkv(ji,jj)
368            ze3wu = gdept(ji+1,jj,iku,Kmm) - gdept(ji,jj,iku,Kmm)
369            ze3wv = gdept(ji,jj+1,ikv,Kmm) - gdept(ji,jj,ikv,Kmm)
370            !
371            IF( ze3wu >= 0._wp ) THEN   ;   zhi(ji,jj) = gdept(ji  ,jj,iku,Kmm)    ! i-direction: case 1
372            ELSE                        ;   zhi(ji,jj) = gdept(ji+1,jj,iku,Kmm)    ! -     -      case 2
373            ENDIF
374            IF( ze3wv >= 0._wp ) THEN   ;   zhj(ji,jj) = gdept(ji,jj  ,ikv,Kmm)    ! j-direction: case 1
375            ELSE                        ;   zhj(ji,jj) = gdept(ji,jj+1,ikv,Kmm)    ! -     -      case 2
376            ENDIF
377
378         END_2D
379
380         ! Compute interpolated rd from zti, ztj for the 2 cases at the depth of the partial
381         ! step and store it in  zri, zrj for each  case
382         CALL eos( zti, zhi, zri )
383         CALL eos( ztj, zhj, zrj )
384
385         DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )
386            iku = mbku(ji,jj)
387            ikv = mbkv(ji,jj)
388            ze3wu = gdept(ji+1,jj,iku,Kmm) - gdept(ji,jj,iku,Kmm)
389            ze3wv = gdept(ji,jj+1,ikv,Kmm) - gdept(ji,jj,ikv,Kmm)
390
391            IF( ze3wu >= 0._wp ) THEN   ;   pgru(ji,jj) = ssumask(ji,jj) * ( zri(ji  ,jj    ) - prd(ji,jj,iku) )   ! i: 1
392            ELSE                        ;   pgru(ji,jj) = ssumask(ji,jj) * ( prd(ji+1,jj,iku) - zri(ji,jj    ) )   ! i: 2
393            ENDIF
394            IF( ze3wv >= 0._wp ) THEN   ;   pgrv(ji,jj) = ssvmask(ji,jj) * ( zrj(ji,jj      ) - prd(ji,jj,ikv) )   ! j: 1
395            ELSE                        ;   pgrv(ji,jj) = ssvmask(ji,jj) * ( prd(ji,jj+1,ikv) - zrj(ji,jj    ) )   ! j: 2
396            ENDIF
397
398         END_2D
399
400         IF (nn_hls.EQ.1) CALL lbc_lnk_multi( 'zpshde', pgru , 'U', -1.0_wp , pgrv , 'V', -1.0_wp )   ! Lateral boundary conditions
401         !
402      END IF
403      !
404      !     !==  (ISH)  compute grui and gruvi  ==!
405      !
406      DO jn = 1, kjpt      !==   Interpolation of tracers at the last ocean level   ==!            !
407         DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )
408            iku = miku(ji,jj); ikup1 = miku(ji,jj) + 1
409            ikv = mikv(ji,jj); ikvp1 = mikv(ji,jj) + 1
410            !
411            ! (ISF) case partial step top and bottom in adjacent cell in vertical
412            ! cannot used e3w because if 2 cell water column, we have ps at top and bottom
413            ! in this case e3w(i,j,k,Kmm) - e3w(i,j+1,k,Kmm) is not the distance between Tj~ and Tj
414            ! the only common depth between cells (i,j) and (i,j+1) is gdepw_0
415            ze3wu  =  gdept(ji,jj,iku,Kmm) - gdept(ji+1,jj,iku,Kmm)
416            ze3wv  =  gdept(ji,jj,ikv,Kmm) - gdept(ji,jj+1,ikv,Kmm) 
417
418            ! i- direction
419            IF( ze3wu >= 0._wp ) THEN      ! case 1
420               zmaxu = ze3wu / e3w(ji+1,jj,ikup1,Kmm)
421               ! interpolated values of tracers
422               zti(ji,jj,jn) = pta(ji+1,jj,iku,jn) + zmaxu * ( pta(ji+1,jj,ikup1,jn) - pta(ji+1,jj,iku,jn) )
423               ! gradient of tracers
424               pgtui(ji,jj,jn) = ssumask(ji,jj) * ( zti(ji,jj,jn) - pta(ji,jj,iku,jn) )
425            ELSE                           ! case 2
426               zmaxu = - ze3wu / e3w(ji,jj,ikup1,Kmm)
427               ! interpolated values of tracers
428               zti(ji,jj,jn) = pta(ji,jj,iku,jn) + zmaxu * ( pta(ji,jj,ikup1,jn) - pta(ji,jj,iku,jn) )
429               ! gradient of  tracers
430               pgtui(ji,jj,jn) = ssumask(ji,jj) * ( pta(ji+1,jj,iku,jn) - zti(ji,jj,jn) )
431            ENDIF
432            !
433            ! j- direction
434            IF( ze3wv >= 0._wp ) THEN      ! case 1
435               zmaxv =  ze3wv / e3w(ji,jj+1,ikvp1,Kmm)
436               ! interpolated values of tracers
437               ztj(ji,jj,jn) = pta(ji,jj+1,ikv,jn) + zmaxv * ( pta(ji,jj+1,ikvp1,jn) - pta(ji,jj+1,ikv,jn) )
438               ! gradient of tracers
439               pgtvi(ji,jj,jn) = ssvmask(ji,jj) * ( ztj(ji,jj,jn) - pta(ji,jj,ikv,jn) )
440            ELSE                           ! case 2
441               zmaxv =  - ze3wv / e3w(ji,jj,ikvp1,Kmm)
442               ! interpolated values of tracers
443               ztj(ji,jj,jn) = pta(ji,jj,ikv,jn) + zmaxv * ( pta(ji,jj,ikvp1,jn) - pta(ji,jj,ikv,jn) )
444               ! gradient of tracers
445               pgtvi(ji,jj,jn) = ssvmask(ji,jj) * ( pta(ji,jj+1,ikv,jn) - ztj(ji,jj,jn) )
446            ENDIF
447
448         END_2D
449         !
450      END DO
451      IF (nn_hls.EQ.1) CALL lbc_lnk_multi( 'zpshde', pgtui(:,:,:), 'U', -1.0_wp , pgtvi(:,:,:), 'V', -1.0_wp )   ! Lateral boundary cond.
452
453      IF( PRESENT( prd ) ) THEN    !==  horizontal derivative of density anomalies (rd)  ==!    (optional part)
454         !
455         pgrui(:,:)  =0.0_wp; pgrvi(:,:)  =0.0_wp;
456         DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )
457
458            iku = miku(ji,jj)
459            ikv = mikv(ji,jj)
460            ze3wu  =  gdept(ji,jj,iku,Kmm) - gdept(ji+1,jj,iku,Kmm)
461            ze3wv  =  gdept(ji,jj,ikv,Kmm) - gdept(ji,jj+1,ikv,Kmm) 
462            !
463            IF( ze3wu >= 0._wp ) THEN   ;   zhi(ji,jj) = gdept(ji  ,jj,iku,Kmm)    ! i-direction: case 1
464            ELSE                        ;   zhi(ji,jj) = gdept(ji+1,jj,iku,Kmm)    ! -     -      case 2
465            ENDIF
466
467            IF( ze3wv >= 0._wp ) THEN   ;   zhj(ji,jj) = gdept(ji,jj  ,ikv,Kmm)    ! j-direction: case 1
468            ELSE                        ;   zhj(ji,jj) = gdept(ji,jj+1,ikv,Kmm)    ! -     -      case 2
469            ENDIF
470
471         END_2D
472         !
473         CALL eos( zti, zhi, zri )        ! interpolated density from zti, ztj
474         CALL eos( ztj, zhj, zrj )        ! at the partial step depth output in  zri, zrj
475         !
476         DO_2D( nn_hls-1, nn_hls-1, nn_hls-1, nn_hls-1 )
477            iku = miku(ji,jj) 
478            ikv = mikv(ji,jj) 
479            ze3wu  =  gdept(ji,jj,iku,Kmm) - gdept(ji+1,jj,iku,Kmm)
480            ze3wv  =  gdept(ji,jj,ikv,Kmm) - gdept(ji,jj+1,ikv,Kmm) 
481
482            IF( ze3wu >= 0._wp ) THEN ; pgrui(ji,jj) = ssumask(ji,jj) * ( zri(ji  ,jj      ) - prd(ji,jj,iku) ) ! i: 1
483            ELSE                      ; pgrui(ji,jj) = ssumask(ji,jj) * ( prd(ji+1,jj  ,iku) - zri(ji,jj    ) ) ! i: 2
484            ENDIF
485            IF( ze3wv >= 0._wp ) THEN ; pgrvi(ji,jj) = ssvmask(ji,jj) * ( zrj(ji  ,jj      ) - prd(ji,jj,ikv) ) ! j: 1
486            ELSE                      ; pgrvi(ji,jj) = ssvmask(ji,jj) * ( prd(ji  ,jj+1,ikv) - zrj(ji,jj    ) ) ! j: 2
487            ENDIF
488
489         END_2D
490         IF (nn_hls.EQ.1) CALL lbc_lnk_multi( 'zpshde', pgrui, 'U', -1.0_wp , pgrvi, 'V', -1.0_wp )   ! Lateral boundary conditions
491         !
492      END IF 
493      !
494      IF( ln_timing )   CALL timing_stop( 'zps_hde_isf')
495      !
496   END SUBROUTINE zps_hde_isf_t
497
498   !!======================================================================
499END MODULE zpshde
Note: See TracBrowser for help on using the repository browser.