| 1 | MODULE step |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE step *** |
|---|
| 4 | !! Time-stepping : manager of the ocean, tracer and ice time stepping |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : OPA ! 1991-03 (G. Madec) Original code |
|---|
| 7 | !! - ! 1991-11 (G. Madec) |
|---|
| 8 | !! - ! 1992-06 (M. Imbard) add a first output record |
|---|
| 9 | !! - ! 1996-04 (G. Madec) introduction of dynspg |
|---|
| 10 | !! - ! 1996-04 (M.A. Foujols) introduction of passive tracer |
|---|
| 11 | !! 8.0 ! 1997-06 (G. Madec) new architecture of call |
|---|
| 12 | !! 8.2 ! 1997-06 (G. Madec, M. Imbard, G. Roullet) free surface |
|---|
| 13 | !! - ! 1999-02 (G. Madec, N. Grima) hpg implicit |
|---|
| 14 | !! - ! 2000-07 (J-M Molines, M. Imbard) Open Bondary Conditions |
|---|
| 15 | !! NEMO 1.0 ! 2002-06 (G. Madec) free form, suppress macro-tasking |
|---|
| 16 | !! - ! 2004-08 (C. Talandier) New trends organization |
|---|
| 17 | !! - ! 2005-01 (C. Ethe) Add the KPP closure scheme |
|---|
| 18 | !! - ! 2005-11 (G. Madec) Reorganisation of tra and dyn calls |
|---|
| 19 | !! - ! 2006-01 (L. Debreu, C. Mazauric) Agrif implementation |
|---|
| 20 | !! - ! 2006-07 (S. Masson) restart using iom |
|---|
| 21 | !! 3.2 ! 2009-02 (G. Madec, R. Benshila) reintroduicing z*-coordinate |
|---|
| 22 | !! - ! 2009-06 (S. Masson, G. Madec) TKE restart compatible with key_cpl |
|---|
| 23 | !! 3.3 ! 2010-05 (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface |
|---|
| 24 | !! - ! 2010-10 (C. Ethe, G. Madec) reorganisation of initialisation phase + merge TRC-TRA |
|---|
| 25 | !! 3.4 ! 2011-04 (G. Madec, C. Ethe) Merge of dtatem and dtasal |
|---|
| 26 | !! 3.6 ! 2012-07 (J. Simeon, G. Madec. C. Ethe) Online coarsening of outputs |
|---|
| 27 | !! 3.6 ! 2014-04 (F. Roquet, G. Madec) New equations of state |
|---|
| 28 | !! 3.6 ! 2014-10 (E. Clementi, P. Oddo) Add Qiao vertical mixing in case of waves |
|---|
| 29 | !! 3.7 ! 2014-10 (G. Madec) LDF simplication |
|---|
| 30 | !! - ! 2014-12 (G. Madec) remove KPP scheme |
|---|
| 31 | !! - ! 2015-11 (J. Chanut) free surface simplification (remove filtered free surface) |
|---|
| 32 | !! 4.0 ! 2017-05 (G. Madec) introduction of the vertical physics manager (zdfphy) |
|---|
| 33 | !! 4.1 ! 2019-08 (A. Coward, D. Storkey) rewrite in preparation for new timestepping scheme |
|---|
| 34 | !!---------------------------------------------------------------------- |
|---|
| 35 | #if defined key_qco || defined key_linssh |
|---|
| 36 | !!---------------------------------------------------------------------- |
|---|
| 37 | !! 'key_qco' EMPTY MODULE Quasi-Eulerian vertical coordinate |
|---|
| 38 | !! OR |
|---|
| 39 | !! 'key_linssh EMPTY MODULE Fixed in time vertical coordinate |
|---|
| 40 | !!---------------------------------------------------------------------- |
|---|
| 41 | #else |
|---|
| 42 | !!---------------------------------------------------------------------- |
|---|
| 43 | !! stp : OPA system time-stepping |
|---|
| 44 | !!---------------------------------------------------------------------- |
|---|
| 45 | USE step_oce ! time stepping definition modules |
|---|
| 46 | |
|---|
| 47 | IMPLICIT NONE |
|---|
| 48 | PRIVATE |
|---|
| 49 | |
|---|
| 50 | PUBLIC stp ! called by nemogcm.F90 |
|---|
| 51 | |
|---|
| 52 | !!---------------------------------------------------------------------- |
|---|
| 53 | !! time level indices |
|---|
| 54 | !!---------------------------------------------------------------------- |
|---|
| 55 | INTEGER, PUBLIC :: Nbb, Nnn, Naa, Nrhs !! used by nemo_init |
|---|
| 56 | |
|---|
| 57 | !! * Substitutions |
|---|
| 58 | # include "do_loop_substitute.h90" |
|---|
| 59 | # include "single_precision_substitute.h90" |
|---|
| 60 | |
|---|
| 61 | !!---------------------------------------------------------------------- |
|---|
| 62 | !! NEMO/OCE 4.0 , NEMO Consortium (2018) |
|---|
| 63 | !! $Id$ |
|---|
| 64 | !! Software governed by the CeCILL license (see ./LICENSE) |
|---|
| 65 | !!---------------------------------------------------------------------- |
|---|
| 66 | CONTAINS |
|---|
| 67 | |
|---|
| 68 | #if defined key_agrif |
|---|
| 69 | RECURSIVE SUBROUTINE stp( ) |
|---|
| 70 | INTEGER :: kstp ! ocean time-step index |
|---|
| 71 | #else |
|---|
| 72 | SUBROUTINE stp( kstp ) |
|---|
| 73 | INTEGER, INTENT(in) :: kstp ! ocean time-step index |
|---|
| 74 | #endif |
|---|
| 75 | !!---------------------------------------------------------------------- |
|---|
| 76 | !! *** ROUTINE stp *** |
|---|
| 77 | !! |
|---|
| 78 | !! ** Purpose : - Time stepping of OPA (momentum and active tracer eqs.) |
|---|
| 79 | !! - Time stepping of SI3 (dynamic and thermodynamic eqs.) |
|---|
| 80 | !! - Time stepping of TRC (passive tracer eqs.) |
|---|
| 81 | !! |
|---|
| 82 | !! ** Method : -1- Update forcings and data |
|---|
| 83 | !! -2- Update ocean physics |
|---|
| 84 | !! -3- Compute the t and s trends |
|---|
| 85 | !! -4- Update t and s |
|---|
| 86 | !! -5- Compute the momentum trends |
|---|
| 87 | !! -6- Update the horizontal velocity |
|---|
| 88 | !! -7- Compute the diagnostics variables (rd,N2, hdiv,w) |
|---|
| 89 | !! -8- Outputs and diagnostics |
|---|
| 90 | !!---------------------------------------------------------------------- |
|---|
| 91 | INTEGER :: ji, jj, jk, jtile ! dummy loop indice |
|---|
| 92 | !!gm kcall can be removed, I guess |
|---|
| 93 | INTEGER :: kcall ! optional integer argument (dom_vvl_sf_nxt) |
|---|
| 94 | !! --------------------------------------------------------------------- |
|---|
| 95 | #if defined key_agrif |
|---|
| 96 | IF( nstop > 0 ) RETURN ! avoid to go further if an error was detected during previous time step (child grid) |
|---|
| 97 | kstp = nit000 + Agrif_Nb_Step() |
|---|
| 98 | Kbb_a = Nbb; Kmm_a = Nnn; Krhs_a = Nrhs ! agrif_oce module copies of time level indices |
|---|
| 99 | IF( lk_agrif_debug ) THEN |
|---|
| 100 | IF( Agrif_Root() .and. lwp) WRITE(*,*) '---' |
|---|
| 101 | IF(lwp) WRITE(*,*) 'Grid Number', Agrif_Fixed(),' time step ', kstp, 'int tstep', Agrif_NbStepint() |
|---|
| 102 | ENDIF |
|---|
| 103 | IF( kstp == nit000 + 1 ) lk_agrif_fstep = .FALSE. |
|---|
| 104 | # if defined key_iomput |
|---|
| 105 | IF( Agrif_Nbstepint() == 0 ) CALL iom_swap( cxios_context ) |
|---|
| 106 | # endif |
|---|
| 107 | #endif |
|---|
| 108 | ! |
|---|
| 109 | IF( ln_timing ) CALL timing_start('stp') |
|---|
| 110 | ! |
|---|
| 111 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 112 | ! model timestep |
|---|
| 113 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 114 | ! |
|---|
| 115 | IF( l_1st_euler ) THEN |
|---|
| 116 | ! start or restart with Euler 1st time-step |
|---|
| 117 | rDt = rn_Dt |
|---|
| 118 | r1_Dt = 1._wp / rDt |
|---|
| 119 | ENDIF |
|---|
| 120 | ! |
|---|
| 121 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 122 | ! update I/O and calendar |
|---|
| 123 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 124 | IF( kstp == nit000 ) THEN ! initialize IOM context (must be done after nemo_init for AGRIF+XIOS+OASIS) |
|---|
| 125 | CALL iom_init( cxios_context, ld_closedef=.FALSE. ) ! for model grid (including possible AGRIF zoom) |
|---|
| 126 | IF( lk_diamlr ) CALL dia_mlr_iom_init ! with additional setup for multiple-linear-regression analysis |
|---|
| 127 | CALL iom_init_closedef |
|---|
| 128 | IF( ln_crs ) CALL iom_init( TRIM(cxios_context)//"_crs" ) ! for coarse grid |
|---|
| 129 | ENDIF |
|---|
| 130 | IF((kstp == nitrst) .AND. lwxios) THEN |
|---|
| 131 | CALL iom_swap( cw_ocerst_cxt ) |
|---|
| 132 | CALL iom_init_closedef(cw_ocerst_cxt) |
|---|
| 133 | CALL iom_setkt( kstp - nit000 + 1, cw_ocerst_cxt ) |
|---|
| 134 | #if defined key_top |
|---|
| 135 | CALL iom_swap( cw_toprst_cxt ) |
|---|
| 136 | CALL iom_init_closedef(cw_toprst_cxt) |
|---|
| 137 | CALL iom_setkt( kstp - nit000 + 1, cw_toprst_cxt ) |
|---|
| 138 | #endif |
|---|
| 139 | ENDIF |
|---|
| 140 | #if defined key_si3 |
|---|
| 141 | IF(((kstp + nn_fsbc - 1) == nitrst) .AND. lwxios) THEN |
|---|
| 142 | CALL iom_swap( cw_icerst_cxt ) |
|---|
| 143 | CALL iom_init_closedef(cw_icerst_cxt) |
|---|
| 144 | CALL iom_setkt( kstp - nit000 + 1, cw_icerst_cxt ) |
|---|
| 145 | ENDIF |
|---|
| 146 | #endif |
|---|
| 147 | IF( kstp /= nit000 ) CALL day( kstp ) ! Calendar (day was already called at nit000 in day_init) |
|---|
| 148 | CALL iom_setkt( kstp - nit000 + 1, cxios_context ) ! tell IOM we are at time step kstp |
|---|
| 149 | IF( ln_crs ) CALL iom_setkt( kstp - nit000 + 1, TRIM(cxios_context)//"_crs" ) ! tell IOM we are at time step kstp |
|---|
| 150 | |
|---|
| 151 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 152 | ! Update external forcing (tides, open boundaries, ice shelf interaction and surface boundary condition (including sea-ice) |
|---|
| 153 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 154 | IF( ln_tide ) CALL tide_update( kstp ) ! update tide potential |
|---|
| 155 | IF( ln_apr_dyn ) CALL sbc_apr ( kstp ) ! atmospheric pressure (NB: call before bdy_dta which needs ssh_ib) |
|---|
| 156 | IF( ln_bdy ) CALL bdy_dta ( kstp, Nnn ) ! update dynamic & tracer data at open boundaries |
|---|
| 157 | IF( ln_isf ) CALL isf_stp ( kstp, Nnn ) |
|---|
| 158 | CALL sbc ( kstp, Nbb, Nnn ) ! Sea Boundary Condition (including sea-ice) |
|---|
| 159 | |
|---|
| 160 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 161 | ! Update stochastic parameters and random T/S fluctuations |
|---|
| 162 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 163 | IF( ln_sto_eos ) CALL sto_par( kstp ) ! Stochastic parameters |
|---|
| 164 | IF( ln_sto_eos ) CALL sto_pts( ts(:,:,:,:,Nnn) ) ! Random T/S fluctuations |
|---|
| 165 | |
|---|
| 166 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 167 | ! Ocean physics update |
|---|
| 168 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 169 | ! THERMODYNAMICS |
|---|
| 170 | CALL eos_rab( CASTWP(ts(:,:,:,:,Nbb)), rab_b, Nnn ) ! before local thermal/haline expension ratio at T-points |
|---|
| 171 | CALL eos_rab( CASTWP(ts(:,:,:,:,Nnn)), rab_n, Nnn ) ! now local thermal/haline expension ratio at T-points |
|---|
| 172 | CALL bn2 ( CASTWP(ts(:,:,:,:,Nbb)), rab_b, rn2b, Nnn ) ! before Brunt-Vaisala frequency |
|---|
| 173 | CALL bn2 ( CASTWP(ts(:,:,:,:,Nnn)), rab_n, rn2, Nnn ) ! now Brunt-Vaisala frequency |
|---|
| 174 | |
|---|
| 175 | ! VERTICAL PHYSICS |
|---|
| 176 | CALL zdf_phy( kstp, Nbb, Nnn, Nrhs ) ! vertical physics update (top/bot drag, avt, avs, avm + MLD) |
|---|
| 177 | |
|---|
| 178 | ! LATERAL PHYSICS |
|---|
| 179 | ! |
|---|
| 180 | IF( l_ldfslp ) THEN ! slope of lateral mixing |
|---|
| 181 | CALL eos( CASTWP(ts(:,:,:,:,Nbb)), rhd, gdept_0(:,:,:) ) ! before in situ density |
|---|
| 182 | |
|---|
| 183 | IF( ln_zps .AND. .NOT. ln_isfcav) & |
|---|
| 184 | & CALL zps_hde ( kstp, Nnn, jpts, ts(:,:,:,:,Nbb), gtsu, gtsv, & ! Partial steps: before horizontal gradient |
|---|
| 185 | & rhd, gru , grv ) ! of t, s, rd at the last ocean level |
|---|
| 186 | |
|---|
| 187 | IF( ln_zps .AND. ln_isfcav) & |
|---|
| 188 | & CALL zps_hde_isf( kstp, Nnn, jpts, ts(:,:,:,:,Nbb), gtsu, gtsv, gtui, gtvi, & ! Partial steps for top cell (ISF) |
|---|
| 189 | & rhd, gru , grv , grui, grvi ) ! of t, s, rd at the first ocean level |
|---|
| 190 | IF( ln_traldf_triad ) THEN |
|---|
| 191 | CALL ldf_slp_triad( kstp, Nbb, Nnn ) ! before slope for triad operator |
|---|
| 192 | ELSE |
|---|
| 193 | CALL ldf_slp ( kstp, rhd, rn2b, Nbb, Nnn ) ! before slope for standard operator |
|---|
| 194 | ENDIF |
|---|
| 195 | ENDIF |
|---|
| 196 | ! ! eddy diffusivity coeff. |
|---|
| 197 | IF( l_ldftra_time .OR. l_ldfeiv_time ) CALL ldf_tra( kstp, Nbb, Nnn ) ! and/or eiv coeff. |
|---|
| 198 | IF( l_ldfdyn_time ) CALL ldf_dyn( kstp, Nbb ) ! eddy viscosity coeff. |
|---|
| 199 | |
|---|
| 200 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 201 | ! Ocean dynamics : hdiv, ssh, e3, u, v, w |
|---|
| 202 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 203 | |
|---|
| 204 | CALL ssh_nxt ( kstp, Nbb, Nnn, ssh, Naa ) ! after ssh (includes call to div_hor) |
|---|
| 205 | IF( .NOT.ln_linssh ) CALL dom_vvl_sf_nxt( kstp, Nbb, Nnn, Naa ) ! after vertical scale factors |
|---|
| 206 | CALL wzv ( kstp, Nbb, Nnn, Naa, ww ) ! now cross-level velocity |
|---|
| 207 | IF( ln_zad_Aimp ) CALL wAimp ( kstp, Nnn ) ! Adaptive-implicit vertical advection partitioning |
|---|
| 208 | CALL eos ( CASTWP(ts(:,:,:,:,Nnn)), rhd, rhop, CASTWP(gdept(:,:,:,Nnn)) ) ! now in situ density for hpg computation |
|---|
| 209 | |
|---|
| 210 | |
|---|
| 211 | uu(:,:,:,Nrhs) = 0._wp ! set dynamics trends to zero |
|---|
| 212 | vv(:,:,:,Nrhs) = 0._wp |
|---|
| 213 | |
|---|
| 214 | IF( lk_asminc .AND. ln_asmiau .AND. ln_dyninc ) & |
|---|
| 215 | & CALL dyn_asm_inc ( kstp, Nbb, Nnn, uu, vv, Nrhs ) ! apply dynamics assimilation increment |
|---|
| 216 | IF( ln_bdy ) CALL bdy_dyn3d_dmp ( kstp, Nbb, uu, vv, Nrhs ) ! bdy damping trends |
|---|
| 217 | #if defined key_agrif |
|---|
| 218 | IF(.NOT. Agrif_Root()) & |
|---|
| 219 | & CALL Agrif_Sponge_dyn ! momentum sponge |
|---|
| 220 | #endif |
|---|
| 221 | CALL dyn_adv( kstp, Nbb, Nnn , uu, vv, Nrhs ) ! advection (VF or FF) ==> RHS |
|---|
| 222 | CALL dyn_vor( kstp, Nnn , uu, vv, Nrhs ) ! vorticity ==> RHS |
|---|
| 223 | CALL dyn_ldf( kstp, Nbb, Nnn , uu, vv, Nrhs ) ! lateral mixing |
|---|
| 224 | IF( ln_zdfosm ) CALL dyn_osm( kstp, Nnn , uu, vv, Nrhs ) ! OSMOSIS non-local velocity fluxes ==> RHS |
|---|
| 225 | CALL dyn_hpg( kstp, Nnn , uu, vv, Nrhs ) ! horizontal gradient of Hydrostatic pressure |
|---|
| 226 | CALL dyn_spg( kstp, Nbb, Nnn, Nrhs, uu, vv, ssh, uu_b, vv_b, Naa ) ! surface pressure gradient |
|---|
| 227 | |
|---|
| 228 | ! With split-explicit free surface, since now transports have been updated and ssh(:,:,Nrhs) as well |
|---|
| 229 | IF( ln_dynspg_ts ) THEN ! vertical scale factors and vertical velocity need to be updated |
|---|
| 230 | CALL div_hor ( kstp, Nbb, Nnn ) ! Horizontal divergence (2nd call in time-split case) |
|---|
| 231 | IF(.NOT.ln_linssh) CALL dom_vvl_sf_nxt( kstp, Nbb, Nnn, Naa, kcall=2 ) ! after vertical scale factors (update depth average component) |
|---|
| 232 | ENDIF |
|---|
| 233 | CALL dyn_zdf ( kstp, Nbb, Nnn, Nrhs, uu, vv, Naa ) ! vertical diffusion |
|---|
| 234 | IF( ln_dynspg_ts ) THEN ! vertical scale factors and vertical velocity need to be updated |
|---|
| 235 | CALL wzv ( kstp, Nbb, Nnn, Naa, ww ) ! now cross-level velocity |
|---|
| 236 | IF( ln_zad_Aimp ) CALL wAimp ( kstp, Nnn ) ! Adaptive-implicit vertical advection partitioning |
|---|
| 237 | ENDIF |
|---|
| 238 | |
|---|
| 239 | |
|---|
| 240 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 241 | ! cool skin |
|---|
| 242 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 243 | IF ( ln_diurnal ) CALL diurnal_layers( kstp ) |
|---|
| 244 | |
|---|
| 245 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 246 | ! diagnostics and outputs |
|---|
| 247 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 248 | IF( ln_floats ) CALL flo_stp ( kstp, Nbb, Nnn ) ! drifting Floats |
|---|
| 249 | IF( ln_diacfl ) CALL dia_cfl ( kstp, Nnn ) ! Courant number diagnostics |
|---|
| 250 | CALL dia_hth ( kstp, Nnn ) ! Thermocline depth (20 degres isotherm depth) |
|---|
| 251 | IF( ln_diadct ) CALL dia_dct ( kstp, Nnn ) ! Transports |
|---|
| 252 | CALL dia_ar5 ( kstp, Nnn ) ! ar5 diag |
|---|
| 253 | CALL dia_ptr ( kstp, Nnn ) ! Poleward adv/ldf TRansports diagnostics |
|---|
| 254 | CALL dia_wri ( kstp, Nnn ) ! ocean model: outputs |
|---|
| 255 | IF( ln_crs ) CALL crs_fld ( kstp, Nnn ) ! ocean model: online field coarsening & output |
|---|
| 256 | IF( lk_diadetide ) CALL dia_detide( kstp ) ! Weights computation for daily detiding of model diagnostics |
|---|
| 257 | IF( lk_diamlr ) CALL dia_mlr ! Update time used in multiple-linear-regression analysis |
|---|
| 258 | |
|---|
| 259 | #if defined key_top |
|---|
| 260 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 261 | ! Passive Tracer Model |
|---|
| 262 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 263 | CALL trc_stp ( kstp, Nbb, Nnn, Nrhs, Naa ) ! time-stepping |
|---|
| 264 | #endif |
|---|
| 265 | |
|---|
| 266 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 267 | ! Active tracers |
|---|
| 268 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 269 | ! Loop over tile domains |
|---|
| 270 | DO jtile = 1, nijtile |
|---|
| 271 | IF( ln_tile ) CALL dom_tile( ntsi, ntsj, ntei, ntej, ktile = jtile ) |
|---|
| 272 | |
|---|
| 273 | DO_3D( 0, 0, 0, 0, 1, jpk ) |
|---|
| 274 | ts(ji,jj,jk,:,Nrhs) = 0._wp ! set tracer trends to zero |
|---|
| 275 | END_3D |
|---|
| 276 | |
|---|
| 277 | IF( lk_asminc .AND. ln_asmiau .AND. & |
|---|
| 278 | & ln_trainc ) CALL tra_asm_inc( kstp, Nbb, Nnn, ts, Nrhs ) ! apply tracer assimilation increment |
|---|
| 279 | CALL tra_sbc ( kstp, Nnn, ts, Nrhs ) ! surface boundary condition |
|---|
| 280 | IF( ln_traqsr ) CALL tra_qsr ( kstp, Nnn, ts, Nrhs ) ! penetrative solar radiation qsr |
|---|
| 281 | IF( ln_isf ) CALL tra_isf ( kstp, Nnn, ts, Nrhs ) ! ice shelf heat flux |
|---|
| 282 | IF( ln_trabbc ) CALL tra_bbc ( kstp, Nnn, ts, Nrhs ) ! bottom heat flux |
|---|
| 283 | IF( ln_trabbl ) CALL tra_bbl ( kstp, Nbb, Nnn, ts, Nrhs ) ! advective (and/or diffusive) bottom boundary layer scheme |
|---|
| 284 | IF( ln_tradmp ) CALL tra_dmp ( kstp, Nbb, Nnn, ts, Nrhs ) ! internal damping trends |
|---|
| 285 | IF( ln_bdy ) CALL bdy_tra_dmp( kstp, Nbb, ts, Nrhs ) ! bdy damping trends |
|---|
| 286 | END DO |
|---|
| 287 | |
|---|
| 288 | #if defined key_agrif |
|---|
| 289 | IF(.NOT. Agrif_Root()) THEN |
|---|
| 290 | IF( ln_tile ) CALL dom_tile( ntsi, ntsj, ntei, ntej, ktile = 0 ) |
|---|
| 291 | CALL Agrif_Sponge_tra ! tracers sponge |
|---|
| 292 | ENDIF |
|---|
| 293 | #endif |
|---|
| 294 | |
|---|
| 295 | ! TEMP: [tiling] Separate loop over tile domains (due to tra_adv workarounds for tiling) |
|---|
| 296 | DO jtile = 1, nijtile |
|---|
| 297 | IF( ln_tile ) CALL dom_tile( ntsi, ntsj, ntei, ntej, ktile = jtile ) |
|---|
| 298 | |
|---|
| 299 | CALL tra_adv ( kstp, Nbb, Nnn, ts, Nrhs ) ! hor. + vert. advection ==> RHS |
|---|
| 300 | IF( ln_zdfmfc ) CALL tra_mfc ( kstp, Nbb, ts, Nrhs ) ! Mass Flux Convection |
|---|
| 301 | IF( ln_zdfosm ) CALL tra_osm ( kstp, Nnn, ts, Nrhs ) ! OSMOSIS non-local tracer fluxes ==> RHS |
|---|
| 302 | IF( lrst_oce .AND. ln_zdfosm ) & |
|---|
| 303 | & CALL osm_rst ( kstp, Nnn, 'WRITE' ) ! write OSMOSIS outputs + ww (so must do here) to restarts |
|---|
| 304 | CALL tra_ldf ( kstp, Nbb, Nnn, ts, Nrhs ) ! lateral mixing |
|---|
| 305 | |
|---|
| 306 | CALL tra_zdf ( kstp, Nbb, Nnn, Nrhs, ts, Naa ) ! vertical mixing and after tracer fields |
|---|
| 307 | IF( ln_zdfnpc ) CALL tra_npc ( kstp, Nnn, Nrhs, ts, Naa ) ! update after fields by non-penetrative convection |
|---|
| 308 | END DO |
|---|
| 309 | |
|---|
| 310 | IF( ln_tile ) CALL dom_tile( ntsi, ntsj, ntei, ntej, ktile = 0 ) ! Revert to tile over full domain |
|---|
| 311 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 312 | ! Set boundary conditions, time filter and swap time levels |
|---|
| 313 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 314 | !!jc1: For agrif, it would be much better to finalize tracers/momentum here (e.g. bdy conditions) and move the swap |
|---|
| 315 | !! (and time filtering) after Agrif update. Then restart would be done after and would contain updated fields. |
|---|
| 316 | !! If so: |
|---|
| 317 | !! (i) no need to call agrif update at initialization time |
|---|
| 318 | !! (ii) no need to update "before" fields |
|---|
| 319 | !! |
|---|
| 320 | !! Apart from creating new tra_swp/dyn_swp routines, this however: |
|---|
| 321 | !! (i) makes boundary conditions at initialization time computed from updated fields which is not the case between |
|---|
| 322 | !! two restarts => restartability issue. One can circumvent this, maybe, by assuming "interface separation", |
|---|
| 323 | !! e.g. a shift of the feedback interface inside child domain. |
|---|
| 324 | !! (ii) requires that all restart outputs of updated variables by agrif (e.g. passive tracers/tke/barotropic arrays) are done at the same |
|---|
| 325 | !! place. |
|---|
| 326 | !! |
|---|
| 327 | !!jc2: dynnxt must be the latest call. e3t(:,:,:,Nbb) are indeed updated in that routine |
|---|
| 328 | CALL tra_atf ( kstp, Nbb, Nnn, Naa, ts ) ! time filtering of "now" tracer arrays |
|---|
| 329 | CALL dyn_atf ( kstp, Nbb, Nnn, Naa, uu, vv, e3t, e3u, e3v ) ! time filtering of "now" velocities and scale factors |
|---|
| 330 | CALL ssh_atf ( kstp, Nbb, Nnn, Naa, ssh ) ! time filtering of "now" sea surface height |
|---|
| 331 | ! |
|---|
| 332 | ! Swap time levels |
|---|
| 333 | Nrhs = Nbb |
|---|
| 334 | Nbb = Nnn |
|---|
| 335 | Nnn = Naa |
|---|
| 336 | Naa = Nrhs |
|---|
| 337 | ! |
|---|
| 338 | IF(.NOT.ln_linssh) CALL dom_vvl_sf_update( kstp, Nbb, Nnn, Naa ) ! recompute vertical scale factors |
|---|
| 339 | ! |
|---|
| 340 | IF( ln_diahsb ) CALL dia_hsb ( kstp, Nbb, Nnn ) ! - ML - global conservation diagnostics |
|---|
| 341 | |
|---|
| 342 | !!gm : This does not only concern the dynamics ==>>> add a new title |
|---|
| 343 | !!gm2: why ouput restart before AGRIF update? |
|---|
| 344 | !! |
|---|
| 345 | !!jc: That would be better, but see comment above |
|---|
| 346 | !! |
|---|
| 347 | IF( lrst_oce ) CALL rst_write ( kstp, Nbb, Nnn ) ! write output ocean restart file |
|---|
| 348 | IF( ln_sto_eos ) CALL sto_rst_write( kstp ) ! write restart file for stochastic parameters |
|---|
| 349 | |
|---|
| 350 | #if defined key_agrif |
|---|
| 351 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 352 | ! AGRIF recursive integration |
|---|
| 353 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 354 | Kbb_a = Nbb; Kmm_a = Nnn; Krhs_a = Nrhs ! agrif_oce module copies of time level indices |
|---|
| 355 | CALL Agrif_Integrate_ChildGrids( stp ) ! allows to finish all the Child Grids before updating |
|---|
| 356 | |
|---|
| 357 | #endif |
|---|
| 358 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 359 | ! Control |
|---|
| 360 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 361 | CALL stp_ctl ( kstp, Nnn ) |
|---|
| 362 | |
|---|
| 363 | #if defined key_agrif |
|---|
| 364 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 365 | ! AGRIF update |
|---|
| 366 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 367 | IF( Agrif_NbStepint() == 0 .AND. nstop == 0 ) THEN |
|---|
| 368 | CALL Agrif_update_all( ) ! Update all components |
|---|
| 369 | ENDIF |
|---|
| 370 | |
|---|
| 371 | #endif |
|---|
| 372 | IF( ln_diaobs .AND. nstop == 0 ) CALL dia_obs( kstp, Nnn ) ! obs-minus-model (assimilation) diags (after dynamics update) |
|---|
| 373 | |
|---|
| 374 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 375 | ! File manipulation at the end of the first time step |
|---|
| 376 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 377 | IF( kstp == nit000 ) THEN ! 1st time step only |
|---|
| 378 | CALL iom_close( numror ) ! close input ocean restart file |
|---|
| 379 | IF( lrxios ) CALL iom_context_finalize( cr_ocerst_cxt ) |
|---|
| 380 | IF(lwm) CALL FLUSH ( numond ) ! flush output namelist oce |
|---|
| 381 | IF(lwm .AND. numoni /= -1 ) CALL FLUSH ( numoni ) ! flush output namelist ice (if exist) |
|---|
| 382 | ENDIF |
|---|
| 383 | |
|---|
| 384 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 385 | ! Coupled mode |
|---|
| 386 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 387 | IF( lk_oasis .AND. nstop == 0 ) CALL sbc_cpl_snd( kstp, Nbb, Nnn ) ! coupled mode : field exchanges |
|---|
| 388 | ! |
|---|
| 389 | #if defined key_iomput |
|---|
| 390 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 391 | ! Finalize contextes if end of simulation or error detected |
|---|
| 392 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 393 | IF( kstp == nitend .OR. nstop > 0 ) THEN |
|---|
| 394 | CALL iom_context_finalize( cxios_context ) ! needed for XIOS+AGRIF |
|---|
| 395 | IF( ln_crs ) CALL iom_context_finalize( trim(cxios_context)//"_crs" ) ! |
|---|
| 396 | ENDIF |
|---|
| 397 | #endif |
|---|
| 398 | ! |
|---|
| 399 | IF( l_1st_euler ) THEN ! recover Leap-frog timestep |
|---|
| 400 | rDt = 2._wp * rn_Dt |
|---|
| 401 | r1_Dt = 1._wp / rDt |
|---|
| 402 | l_1st_euler = .FALSE. |
|---|
| 403 | ENDIF |
|---|
| 404 | ! |
|---|
| 405 | IF( ln_timing ) CALL timing_stop('stp') |
|---|
| 406 | ! |
|---|
| 407 | END SUBROUTINE stp |
|---|
| 408 | ! |
|---|
| 409 | #endif |
|---|
| 410 | !!====================================================================== |
|---|
| 411 | END MODULE step |
|---|
