New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcwave.F90 in NEMO/branches/2021/dev_r14886_VLD-03_Aimie_Moulin_Wave_Coupling_TestCase/tests/ADIAB_WAVE/MY_SRC – NEMO

source: NEMO/branches/2021/dev_r14886_VLD-03_Aimie_Moulin_Wave_Coupling_TestCase/tests/ADIAB_WAVE/MY_SRC/sbcwave.F90 @ 14936

Last change on this file since 14936 was 14936, checked in by amoulin, 3 years ago

add ADIABATIC WAVE TESTCASE folder -ticket #2613
File size: 29.4 KB
Line 
1MODULE sbcwave
2   !!======================================================================
3   !!                       ***  MODULE  sbcwave  ***
4   !! Wave module
5   !!======================================================================
6   !! History :  3.3  !  2011-09  (M. Adani)  Original code: Drag Coefficient
7   !!         :  3.4  !  2012-10  (M. Adani)  Stokes Drift
8   !!            3.6  !  2014-09  (E. Clementi,P. Oddo) New Stokes Drift Computation
9   !!             -   !  2016-12  (G. Madec, E. Clementi) update Stoke drift computation
10   !!                                                    + add sbc_wave_ini routine
11   !!            4.2  !  2020-12  (G. Madec, E. Clementi) updates, new Stoke drift computation
12   !!                                                    according to Couvelard et al.,2019
13   !!----------------------------------------------------------------------
14
15   !!----------------------------------------------------------------------
16   !!   sbc_stokes    : calculate 3D Stokes-drift velocities
17   !!   sbc_wave      : wave data from wave model: forced (netcdf files) or coupled mode
18   !!   sbc_wave_init : initialisation fo surface waves
19   !!----------------------------------------------------------------------
20   USE phycst         ! physical constants
21   USE oce            ! ocean variables
22   USE dom_oce        ! ocean domain variables
23   USE sbc_oce        ! Surface boundary condition: ocean fields
24   USE bdy_oce        ! open boundary condition variables
25   USE domvvl         ! domain: variable volume layers
26   USE zdf_oce,  ONLY : ln_zdfswm
27   USE usrdef_nam , ONLY: ln_STOKES_ADIAB   
28   !
29   USE iom            ! I/O manager library
30   USE in_out_manager ! I/O manager
31   USE lib_mpp        ! distribued memory computing library
32   USE fldread        ! read input fields
33   IMPLICIT NONE
34   PRIVATE
35
36   PUBLIC   sbc_stokes      ! routine called in sbccpl
37   PUBLIC   sbc_wave        ! routine called in sbcmod
38   PUBLIC   sbc_wave_init   ! routine called in sbcmod
39
40   ! Variables checking if the wave parameters are coupled (if not, they are read from file)
41   LOGICAL, PUBLIC ::   cpl_hsig          = .FALSE.
42   LOGICAL, PUBLIC ::   cpl_phioc         = .FALSE.
43   LOGICAL, PUBLIC ::   cpl_sdrftx        = .FALSE.
44   LOGICAL, PUBLIC ::   cpl_sdrfty        = .FALSE.
45   LOGICAL, PUBLIC ::   cpl_wper          = .FALSE.
46   LOGICAL, PUBLIC ::   cpl_wnum          = .FALSE.
47   LOGICAL, PUBLIC ::   cpl_wstrf         = .FALSE.
48   LOGICAL, PUBLIC ::   cpl_wdrag         = .FALSE.
49   LOGICAL, PUBLIC ::   cpl_charn         = .FALSE.
50   LOGICAL, PUBLIC ::   cpl_taw           = .FALSE.
51   LOGICAL, PUBLIC ::   cpl_bhd           = .FALSE.
52   LOGICAL, PUBLIC ::   cpl_tusd          = .FALSE.
53   LOGICAL, PUBLIC ::   cpl_tvsd          = .FALSE.
54
55   INTEGER ::   jpfld    ! number of files to read for stokes drift
56   INTEGER ::   jp_usd   ! index of stokes drift  (i-component) (m/s)    at T-point
57   INTEGER ::   jp_vsd   ! index of stokes drift  (j-component) (m/s)    at T-point
58   INTEGER ::   jp_hsw   ! index of significant wave hight      (m)      at T-point
59   INTEGER ::   jp_wmp   ! index of mean wave period            (s)      at T-point
60
61   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_cd      ! structure of input fields (file informations, fields read) Drag Coefficient
62   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_sd      ! structure of input fields (file informations, fields read) Stokes Drift
63   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_wn      ! structure of input fields (file informations, fields read) wave number for Qiao
64   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_tauoc   ! structure of input fields (file informations, fields read) normalized wave stress into the ocean
65
66   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   cdn_wave        !: Neutral drag coefficient at t-point
67   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   hsw             !: Significant Wave Height at t-point
68   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   wmp             !: Wave Mean Period at t-point
69   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   wnum            !: Wave Number at t-point
70   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   tauoc_wave      !: stress reduction factor  at t-point
71   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   tsd2d           !: Surface Stokes Drift module at t-point
72   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   div_sd          !: barotropic stokes drift divergence
73   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   ut0sd, vt0sd    !: surface Stokes drift velocities at t-point
74   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:,:) ::   usd, vsd, wsd   !: Stokes drift velocities at u-, v- & w-points, resp.u
75!
76   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   charn           !: charnock coefficient at t-point
77   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   tawx            !: Net wave-supported stress, u
78   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   tawy            !: Net wave-supported stress, v
79   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   twox            !: wave-ocean momentum flux, u
80   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   twoy            !: wave-ocean momentum flux, v
81   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   tauoc_wavex     !: stress reduction factor  at, u component
82   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   tauoc_wavey     !: stress reduction factor  at, v component
83   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   phioc           !: tke flux from wave model
84   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   KZN2            !: Kz*N2
85   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   bhd_wave        !: Bernoulli head. wave induce pression
86   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   tusd, tvsd      !: Stokes drift transport
87   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:,:) ::   ZMX             !: Kz*N2
88   !! * Substitutions
89#  include "do_loop_substitute.h90"
90#  include "domzgr_substitute.h90"
91   !!----------------------------------------------------------------------
92   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
93   !! $Id: sbcwave.F90 14433 2021-02-11 08:06:49Z smasson $
94   !! Software governed by the CeCILL license (see ./LICENSE)
95   !!----------------------------------------------------------------------
96CONTAINS
97
98   SUBROUTINE sbc_stokes( Kmm )
99      !!---------------------------------------------------------------------
100      !!                     ***  ROUTINE sbc_stokes  ***
101      !!
102      !! ** Purpose :   compute the 3d Stokes Drift according to Breivik et al.,
103      !!                2014 (DOI: 10.1175/JPO-D-14-0020.1)
104      !!
105      !! ** Method  : - Calculate the horizontal Stokes drift velocity (Breivik et al. 2014)
106      !!              - Calculate its horizontal divergence
107      !!              - Calculate the vertical Stokes drift velocity
108      !!              - Calculate the barotropic Stokes drift divergence
109      !!
110      !! ** action  : - tsd2d         : module of the surface Stokes drift velocity
111      !!              - usd, vsd, wsd : 3 components of the Stokes drift velocity
112      !!              - div_sd        : barotropic Stokes drift divergence
113      !!---------------------------------------------------------------------
114      INTEGER, INTENT(in) :: Kmm ! ocean time level index
115      INTEGER  ::   jj, ji, jk   ! dummy loop argument
116      INTEGER  ::   ik           ! local integer
117      REAL(wp) ::  ztransp, zfac, ztemp, zsp0, zsqrt, zbreiv16_w
118      REAL(wp) ::  zdep_u, zdep_v, zkh_u, zkh_v, zda_u, zda_v, sdtrp
119      REAL(wp) ::  zkd_u, zkd_v, zdep_ue, zdep_ve  ! variable for Stokes drift in SHALLOW/INTER WATER
120      REAL(wp), DIMENSION(:,:)  , ALLOCATABLE ::   zk_t, zk_u, zk_v, zu0_sd, zv0_sd ! 2D workspace
121      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::   ze3divh, zInt_w                  ! 3D workspace
122      !!---------------------------------------------------------------------
123      !
124      ALLOCATE( ze3divh(jpi,jpj,jpkm1) ) ! jpkm1 -> avoid lbc_lnk on jpk that is not defined
125      ALLOCATE( zInt_w(jpi,jpj,jpk) )
126      ALLOCATE( zk_t(jpi,jpj), zk_u(jpi,jpj), zk_v(jpi,jpj), zu0_sd(jpi,jpj), zv0_sd(jpi,jpj) )
127      zk_t    (:,:) = 0._wp
128      zk_u    (:,:) = 0._wp
129      zk_v    (:,:) = 0._wp
130      zu0_sd  (:,:) = 0._wp
131      zv0_sd  (:,:) = 0._wp
132      ze3divh (:,:,:) = 0._wp
133
134      !
135      ! select parameterization for the calculation of vertical Stokes drift
136      ! exp. wave number at t-point
137      IF( ln_breivikFV_2016 ) THEN
138      ! Assumptions :  ut0sd and vt0sd are surface Stokes drift at T-points
139      !                sdtrp is the norm of Stokes transport
140      !
141         zfac = 0.166666666667_wp
142         DO_2D( 1, 1, 1, 1 ) ! In the deep-water limit we have ke = ||ust0||/( 6 * ||transport|| )
143            zsp0          = SQRT( ut0sd(ji,jj)*ut0sd(ji,jj) + vt0sd(ji,jj)*vt0sd(ji,jj) ) !<-- norm of Surface Stokes drift
144            tsd2d(ji,jj)  = zsp0
145            IF( cpl_tusd .AND. cpl_tvsd ) THEN  !stokes transport is provided in coupled mode
146               sdtrp      = SQRT( tusd(ji,jj)*tusd(ji,jj) + tvsd(ji,jj)*tvsd(ji,jj) )  !<-- norm of Surface Stokes drift transport
147            ELSE
148               ! Stokes drift transport estimated from Hs and Tmean
149               sdtrp      = 2.0_wp * rpi / 16.0_wp *                             &
150                   &        hsw(ji,jj)*hsw(ji,jj) / MAX( wmp(ji,jj), 0.0000001_wp )
151            ENDIF
152            zk_t (ji,jj)  = zfac * zsp0 / MAX ( sdtrp, 0.0000001_wp ) !<-- ke = ||ust0||/( 6 * ||transport|| )
153         END_2D
154      !# define zInt_w ze3divh
155         DO_3D( 1, 1, 1, 1, 1, jpk ) ! Compute the primitive of Breivik 2016 function at W-points
156            zfac             = - 2._wp * zk_t (ji,jj) * gdepw(ji,jj,jk,Kmm)  !<-- zfac should be negative definite
157            ztemp            = EXP ( zfac )
158            zsqrt            = SQRT( -zfac )
159            zbreiv16_w       = ztemp - SQRT(rpi)*zsqrt*ERFC(zsqrt) !Eq. 16 Breivik 2016
160            zInt_w(ji,jj,jk) = ztemp - 4._wp * zk_t (ji,jj) * gdepw(ji,jj,jk,Kmm) * zbreiv16_w
161         END_3D
162!
163         DO jk = 1, jpkm1
164            zfac = 0.166666666667_wp
165            DO_2D( 1, 1, 1, 1 ) !++ Compute the FV Breivik 2016 function at T-points
166               zsp0          = zfac / MAX(zk_t (ji,jj),0.0000001_wp)
167               ztemp         = zInt_w(ji,jj,jk) - zInt_w(ji,jj,jk+1)
168               zu0_sd(ji,jj) = ut0sd(ji,jj) * zsp0 * ztemp * tmask(ji,jj,jk)
169               zv0_sd(ji,jj) = vt0sd(ji,jj) * zsp0 * ztemp * tmask(ji,jj,jk)
170            END_2D
171            DO_2D( 1, 0, 1, 0 ) ! ++ Interpolate at U/V points
172               zfac          =  1.0_wp / e3u(ji  ,jj,jk,Kmm)
173               usd(ji,jj,jk) =  0.5_wp * zfac * ( zu0_sd(ji,jj)+zu0_sd(ji+1,jj) ) * umask(ji,jj,jk)
174               zfac          =  1.0_wp / e3v(ji  ,jj,jk,Kmm)
175               vsd(ji,jj,jk) =  0.5_wp * zfac * ( zv0_sd(ji,jj)+zv0_sd(ji,jj+1) ) * vmask(ji,jj,jk)
176            END_2D
177         ENDDO
178      !# undef zInt_w
179      !
180      ELSE IF (ln_STOKES_ADIAB) THEN
181         DO_2D( 1, 0, 1, 0 )
182       !  velocity at u- & v-points
183           zk_u(ji,jj) = 0.5_wp * ( wnum(ji,jj) + wnum(ji+1,jj) )
184           zk_v(ji,jj) = 0.5_wp * ( wnum(ji,jj) + wnum(ji,jj+1) )
185            !
186           zu0_sd(ji,jj) = 0.5_wp * ( ut0sd(ji,jj) + ut0sd(ji+1,jj) )
187           zv0_sd(ji,jj) = 0.5_wp * ( vt0sd(ji,jj) + vt0sd(ji,jj+1) )
188         END_2D
189
190      !                       !==  horizontal Stokes Drift 3D velocity  ==!
191         DO_3D( 0, 0, 0, 0, 1, jpkm1 )
192            zdep_u = 0.5_wp * ( gdept(ji,jj,jk,Kmm) + gdept(ji+1,jj,jk,Kmm) )
193            zdep_v = 0.5_wp * ( gdept(ji,jj,jk,Kmm) + gdept(ji,jj+1,jk,Kmm) )
194            zdep_ue= 0.5_wp * ( gdept(ji,jj,jpkm1,Kmm) + gdept(ji+1,jj,jpkm1,Kmm) )
195            zdep_ve= 0.5_wp * ( gdept(ji,jj,jpkm1,Kmm) + gdept(ji+1,jj,jpkm1,Kmm) )
196            !
197            zkh_u = zk_u(ji,jj) * zdep_u     ! k * depth
198            zkh_v = zk_v(ji,jj) * zdep_v
199            zkd_u = zk_u(ji,jj) * zdep_ue
200            zkd_v = zk_v(ji,jj) * zdep_ve
201                                ! Depth attenuation
202            zda_u = COSH(-2.0_wp*zkh_u+2.0_wp*zkd_u)/COSH(2.0_wp*zkd_u)
203            zda_v = COSH(-2.0_wp*zkh_v+2.0_wp*zkd_v)/COSH(2.0_wp*zkd_v)
204            !
205            usd(ji,jj,jk) = zda_u * zu0_sd(ji,jj) * umask(ji,jj,jk)
206            vsd(ji,jj,jk) = zda_v * zv0_sd(ji,jj) * vmask(ji,jj,jk)
207         END_3D
208      ELSE
209         zfac = 2.0_wp * rpi / 16.0_wp
210         DO_2D( 1, 1, 1, 1 )
211            ! Stokes drift velocity estimated from Hs and Tmean
212            ztransp = zfac * hsw(ji,jj)*hsw(ji,jj) / MAX( wmp(ji,jj), 0.0000001_wp )
213            ! Stokes surface speed
214            tsd2d(ji,jj) = SQRT( ut0sd(ji,jj)*ut0sd(ji,jj) + vt0sd(ji,jj)*vt0sd(ji,jj))
215            ! Wavenumber scale
216            zk_t(ji,jj) = ABS( tsd2d(ji,jj) ) / MAX( ABS( 5.97_wp*ztransp ), 0.0000001_wp )
217         END_2D
218         DO_2D( 1, 0, 1, 0 )          ! exp. wave number & Stokes drift velocity at u- & v-points
219            zk_u(ji,jj) = 0.5_wp * ( zk_t(ji,jj) + zk_t(ji+1,jj) )
220            zk_v(ji,jj) = 0.5_wp * ( zk_t(ji,jj) + zk_t(ji,jj+1) )
221            !
222            zu0_sd(ji,jj) = 0.5_wp * ( ut0sd(ji,jj) + ut0sd(ji+1,jj) )
223            zv0_sd(ji,jj) = 0.5_wp * ( vt0sd(ji,jj) + vt0sd(ji,jj+1) )
224         END_2D
225
226      !                       !==  horizontal Stokes Drift 3D velocity  ==!
227
228         DO_3D( 0, 0, 0, 0, 1, jpkm1 )
229            zdep_u = 0.5_wp * ( gdept(ji,jj,jk,Kmm) + gdept(ji+1,jj,jk,Kmm) )
230            zdep_v = 0.5_wp * ( gdept(ji,jj,jk,Kmm) + gdept(ji,jj+1,jk,Kmm) )
231            !
232            zkh_u = zk_u(ji,jj) * zdep_u     ! k * depth
233            zkh_v = zk_v(ji,jj) * zdep_v
234            !                                ! Depth attenuation
235            zda_u = EXP( -2.0_wp*zkh_u ) / ( 1.0_wp + 8.0_wp*zkh_u )
236            zda_v = EXP( -2.0_wp*zkh_v ) / ( 1.0_wp + 8.0_wp*zkh_v )
237            !
238            usd(ji,jj,jk) = zda_u * zu0_sd(ji,jj) * umask(ji,jj,jk)
239            vsd(ji,jj,jk) = zda_v * zv0_sd(ji,jj) * vmask(ji,jj,jk)
240         END_3D
241      ENDIF
242
243      CALL lbc_lnk( 'sbcwave', usd, 'U', -1.0_wp, vsd, 'V', -1.0_wp )
244
245      !
246      !                       !==  vertical Stokes Drift 3D velocity  ==!
247      !
248      DO_3D( 0, 1, 0, 1, 1, jpkm1 )    ! Horizontal e3*divergence
249         ze3divh(ji,jj,jk) = (  e2u(ji  ,jj) * e3u(ji  ,jj,jk,Kmm) * usd(ji  ,jj,jk)    &
250            &                 - e2u(ji-1,jj) * e3u(ji-1,jj,jk,Kmm) * usd(ji-1,jj,jk)    &
251            &                 + e1v(ji,jj  ) * e3v(ji,jj  ,jk,Kmm) * vsd(ji,jj  ,jk)    &
252            &                 - e1v(ji,jj-1) * e3v(ji,jj-1,jk,Kmm) * vsd(ji,jj-1,jk)  ) &
253            &                * r1_e1e2t(ji,jj)
254      END_3D
255      !
256      CALL lbc_lnk( 'sbcwave', ze3divh, 'T', 1.0_wp )
257      !
258      IF( ln_linssh ) THEN   ;   ik = 1   ! none zero velocity through the sea surface
259      ELSE                   ;   ik = 2   ! w=0 at the surface (set one for all in sbc_wave_init)
260      ENDIF
261      DO jk = jpkm1, ik, -1          ! integrate from the bottom the hor. divergence (NB: at k=jpk w is always zero)
262         wsd(:,:,jk) = wsd(:,:,jk+1) - ze3divh(:,:,jk)
263      END DO
264      !
265      IF( ln_bdy ) THEN
266         DO jk = 1, jpkm1
267            wsd(:,:,jk) = wsd(:,:,jk) * bdytmask(:,:)
268         END DO
269      ENDIF
270      !                       !==  Horizontal divergence of barotropic Stokes transport  ==!
271      div_sd(:,:) = 0._wp
272      DO jk = 1, jpkm1                                 !
273        div_sd(:,:) = div_sd(:,:) + ze3divh(:,:,jk)
274      END DO
275      !
276      CALL iom_put( "ustokes",  usd  )
277      CALL iom_put( "vstokes",  vsd  )
278      CALL iom_put( "wstokes",  wsd  )
279!      !
280      DEALLOCATE( ze3divh, zInt_w )
281      DEALLOCATE( zk_t, zk_u, zk_v, zu0_sd, zv0_sd )
282      !
283   END SUBROUTINE sbc_stokes
284!
285!
286   SUBROUTINE sbc_wave( kt, Kmm )
287      !!---------------------------------------------------------------------
288      !!                     ***  ROUTINE sbc_wave  ***
289      !!
290      !! ** Purpose :   read wave parameters from wave model in netcdf files
291      !!                or from a coupled wave mdoel
292      !!
293      !!---------------------------------------------------------------------
294      INTEGER, INTENT(in   ) ::   kt   ! ocean time step
295      INTEGER, INTENT(in   ) ::   Kmm  ! ocean time index
296      !!---------------------------------------------------------------------
297      !
298      IF( kt == nit000 .AND. lwp ) THEN
299         WRITE(numout,*)
300         WRITE(numout,*) 'sbc_wave : update the read waves fields'
301         WRITE(numout,*) '~~~~~~~~ '
302      ENDIF
303      !
304      IF( ln_cdgw .AND. .NOT. cpl_wdrag ) THEN     !==  Neutral drag coefficient  ==!
305         CALL fld_read( kt, nn_fsbc, sf_cd )             ! read from external forcing
306         cdn_wave(:,:) = sf_cd(1)%fnow(:,:,1) * tmask(:,:,1)
307      ENDIF
308
309      IF( ln_tauoc .AND. .NOT. cpl_wstrf ) THEN    !==  Wave induced stress  ==!
310         CALL fld_read( kt, nn_fsbc, sf_tauoc )          ! read stress reduction factor due to wave from external forcing
311         tauoc_wave(:,:) = sf_tauoc(1)%fnow(:,:,1) * tmask(:,:,1)
312      ELSEIF ( ln_taw .AND. cpl_taw ) THEN
313         IF (kt < 1) THEN ! The first fields gave by OASIS have very high erroneous values ....
314            twox(:,:)=0._wp
315            twoy(:,:)=0._wp
316            tawx(:,:)=0._wp
317            tawy(:,:)=0._wp
318            tauoc_wavex(:,:) = 1._wp
319            tauoc_wavey(:,:) = 1._wp
320         ELSE
321            tauoc_wavex(:,:) = abs(twox(:,:)/tawx(:,:))
322            tauoc_wavey(:,:) = abs(twoy(:,:)/tawy(:,:))
323         ENDIF
324      ENDIF
325
326      ! Read also wave number if needed, so that it is available in coupling routines
327      IF( ln_zdfswm .OR. ln_STOKES_ADIAB .AND. .NOT. cpl_wnum ) THEN     !==wavenumber==!
328         CALL fld_read( kt, nn_fsbc, sf_wn )             ! read wave parameters from external forcing
329         wnum(:,:) = sf_wn(1)%fnow(:,:,1) * tmask(:,:,1)
330      ENDIF
331
332      IF ( ln_phioc .and. cpl_phioc .and.  kt == nit000 ) THEN
333         WRITE(numout,*)
334         WRITE(numout,*) 'sbc_wave : PHIOC from wave model'
335         WRITE(numout,*) '~~~~~~~~ '
336      ENDIF
337
338      IF( ln_sdw .AND. .NOT. cpl_sdrftx)  THEN       !==  Computation of the 3d Stokes Drift  ==!
339         !
340         IF( jpfld > 0 ) THEN                            ! Read from file only if the field is not coupled
341            CALL fld_read( kt, nn_fsbc, sf_sd )          ! read wave parameters from external forcing
342            !                                            ! NB: test case mode, not read as jpfld=0
343            IF( jp_hsw > 0 )   hsw  (:,:) = sf_sd(jp_hsw)%fnow(:,:,1) * tmask(:,:,1)  ! significant wave height
344            IF( jp_wmp > 0 )   wmp  (:,:) = sf_sd(jp_wmp)%fnow(:,:,1) * tmask(:,:,1)  ! wave mean period
345            IF( jp_usd > 0 )   ut0sd(:,:) = sf_sd(jp_usd)%fnow(:,:,1) * tmask(:,:,1)  ! 2D zonal Stokes Drift at T point
346            IF( jp_vsd > 0 )   vt0sd(:,:) = sf_sd(jp_vsd)%fnow(:,:,1) * tmask(:,:,1)  ! 2D meridional Stokes Drift at T point
347         ENDIF
348         !
349         IF( jpfld == 4 .OR. ln_wave_test )   &
350            &      CALL sbc_stokes( Kmm )                 ! Calculate only if all required fields are read
351            !                                            ! or in wave test case
352         !  !                                            ! In coupled case the call is done after (in sbc_cpl)
353      ENDIF
354         !
355   END SUBROUTINE sbc_wave
356
357
358   SUBROUTINE sbc_wave_init
359      !!---------------------------------------------------------------------
360      !!                     ***  ROUTINE sbc_wave_init  ***
361      !!
362      !! ** Purpose :   Initialisation fo surface waves
363      !!
364      !! ** Method  : - Read namelist namsbc_wave
365      !!              - create the structure used to read required wave fields
366      !!                (its size depends on namelist options)
367      !! ** action
368      !!---------------------------------------------------------------------
369      INTEGER ::   ierror, ios   ! local integer
370      INTEGER ::   ifpr
371      !!
372      CHARACTER(len=100)     ::  cn_dir                            ! Root directory for location of drag coefficient files
373      TYPE(FLD_N), ALLOCATABLE, DIMENSION(:) ::   slf_i            ! array of namelist informations on the fields to read
374      TYPE(FLD_N)            ::  sn_cdg, sn_usd, sn_vsd,  &
375                             &   sn_hsw, sn_wmp, sn_wnum, sn_tauoc    ! informations about the fields to be read
376      !
377      NAMELIST/namsbc_wave/ cn_dir, sn_cdg, sn_usd, sn_vsd, sn_hsw, sn_wmp, sn_wnum, sn_tauoc,   &
378         &                  ln_cdgw, ln_sdw, ln_tauoc, ln_stcor, ln_charn, ln_taw, ln_phioc,     &
379         &                  ln_wave_test, ln_bern_srfc, ln_breivikFV_2016, ln_vortex_force, ln_stshear
380      !!---------------------------------------------------------------------
381      IF(lwp) THEN
382         WRITE(numout,*)
383         WRITE(numout,*) 'sbc_wave_init : surface waves in the system'
384         WRITE(numout,*) '~~~~~~~~~~~~~ '
385      ENDIF
386      !
387      READ  ( numnam_ref, namsbc_wave, IOSTAT = ios, ERR = 901)
388901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namsbc_wave in reference namelist')
389
390      READ  ( numnam_cfg, namsbc_wave, IOSTAT = ios, ERR = 902 )
391902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namsbc_wave in configuration namelist' )
392      IF(lwm) WRITE ( numond, namsbc_wave )
393      !
394      IF(lwp) THEN
395         WRITE(numout,*) '   Namelist namsbc_wave'
396         WRITE(numout,*) '      Stokes drift                                  ln_sdw = ', ln_sdw
397         WRITE(numout,*) '      Breivik 2016                       ln_breivikFV_2016 = ', ln_breivikFV_2016
398         WRITE(numout,*) '      Stokes Coriolis & tracer advection terms    ln_stcor = ', ln_stcor
399         WRITE(numout,*) '      Vortex Force                         ln_vortex_force = ', ln_vortex_force
400         WRITE(numout,*) '      Bernouilli Head Pressure                ln_bern_srfc = ', ln_bern_srfc
401         WRITE(numout,*) '      wave modified ocean stress                  ln_tauoc = ', ln_tauoc
402         WRITE(numout,*) '      neutral drag coefficient (CORE bulk only)    ln_cdgw = ', ln_cdgw
403         WRITE(numout,*) '      charnock coefficient                        ln_charn = ', ln_charn
404         WRITE(numout,*) '      Stress modificated by wave                    ln_taw = ', ln_taw
405         WRITE(numout,*) '      TKE flux from wave                          ln_phioc = ', ln_phioc
406         WRITE(numout,*) '      Surface shear with Stokes drift           ln_stshear = ', ln_stshear
407         WRITE(numout,*) '      Test with constant wave fields          ln_wave_test = ', ln_wave_test
408      ENDIF
409
410      !                                ! option check
411      IF( .NOT.( ln_cdgw .OR. ln_sdw .OR. ln_tauoc .OR. ln_stcor .OR. ln_charn) )   &
412         &     CALL ctl_warn( 'Ask for wave coupling but ln_cdgw=F, ln_sdw=F, ln_tauoc=F, ln_stcor=F')
413      IF( ln_cdgw .AND. ln_blk )   &
414         &     CALL ctl_stop( 'drag coefficient read from wave model NOT available yet with aerobulk package')
415      IF( ln_stcor .AND. .NOT.ln_sdw )   &
416         &     CALL ctl_stop( 'Stokes-Coriolis term calculated only if activated Stokes Drift ln_sdw=T')
417
418      !                             !==  Allocate wave arrays  ==!
419      ALLOCATE( ut0sd (jpi,jpj)    , vt0sd (jpi,jpj) )
420      ALLOCATE( hsw   (jpi,jpj)    , wmp   (jpi,jpj) )
421      ALLOCATE( wnum  (jpi,jpj) )
422      ALLOCATE( tsd2d (jpi,jpj)    , div_sd(jpi,jpj)    , bhd_wave(jpi,jpj)     )
423      ALLOCATE( usd   (jpi,jpj,jpk), vsd   (jpi,jpj,jpk), wsd     (jpi,jpj,jpk) )
424      ALLOCATE( tusd  (jpi,jpj)    , tvsd  (jpi,jpj)    , ZMX     (jpi,jpj,jpk) )
425      usd   (:,:,:) = 0._wp
426      vsd   (:,:,:) = 0._wp
427      wsd   (:,:,:) = 0._wp
428      hsw     (:,:) = 0._wp
429      wmp     (:,:) = 0._wp
430      ut0sd   (:,:) = 0._wp
431      vt0sd   (:,:) = 0._wp
432      tusd    (:,:) = 0._wp
433      tvsd    (:,:) = 0._wp
434      bhd_wave(:,:) = 0._wp
435      ZMX   (:,:,:) = 0._wp
436!
437      IF( ln_wave_test ) THEN       !==  Wave TEST case  ==!   set uniform waves fields
438         jpfld    = 0                   ! No field read
439         ln_cdgw  = .FALSE.             ! No neutral wave drag input
440         ln_tauoc = .FALSE.             ! No wave induced drag reduction factor
441         ut0sd(:,:) = 0.13_wp * tmask(:,:,1)   ! m/s
442         vt0sd(:,:) = 0.00_wp                  ! m/s
443         hsw  (:,:) = 2.80_wp                  ! meters
444         wmp  (:,:) = 8.00_wp                  ! seconds
445         !
446      ELSE                          !==  create the structure associated with fields to be read  ==!
447         IF( ln_cdgw ) THEN                       ! wave drag
448            IF( .NOT. cpl_wdrag ) THEN
449               ALLOCATE( sf_cd(1), STAT=ierror )               !* allocate and fill sf_wave with sn_cdg
450               IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_wave_init: unable to allocate sf_wave structure' )
451               !
452                                      ALLOCATE( sf_cd(1)%fnow(jpi,jpj,1)   )
453               IF( sn_cdg%ln_tint )   ALLOCATE( sf_cd(1)%fdta(jpi,jpj,1,2) )
454               CALL fld_fill( sf_cd, (/ sn_cdg /), cn_dir, 'sbc_wave_init', 'Wave module ', 'namsbc_wave' )
455            ENDIF
456            ALLOCATE( cdn_wave(jpi,jpj) )
457            cdn_wave(:,:) = 0._wp
458         ENDIF
459         IF( ln_charn ) THEN                     ! wave drag
460            IF( .NOT. cpl_charn ) THEN
461               CALL ctl_stop( 'STOP', 'Charnock based wind stress can be used in coupled mode only' )
462            ENDIF
463            ALLOCATE( charn(jpi,jpj) )
464            charn(:,:) = 0._wp
465         ENDIF
466         IF( ln_taw ) THEN                     ! wind stress
467            IF( .NOT. cpl_taw ) THEN
468               CALL ctl_stop( 'STOP', 'wind stress from wave model can be used in coupled mode only, use ln_cdgw instead' )
469            ENDIF
470            ALLOCATE( tawx(jpi,jpj) )
471            ALLOCATE( tawy(jpi,jpj) )
472            ALLOCATE( twox(jpi,jpj) )
473            ALLOCATE( twoy(jpi,jpj) )
474            ALLOCATE( tauoc_wavex(jpi,jpj) )
475            ALLOCATE( tauoc_wavey(jpi,jpj) )
476            tawx(:,:) = 0._wp
477            tawy(:,:) = 0._wp
478            twox(:,:) = 0._wp
479            twoy(:,:) = 0._wp
480            tauoc_wavex(:,:) = 1._wp
481            tauoc_wavey(:,:) = 1._wp
482         ENDIF
483
484         IF( ln_phioc ) THEN                     ! TKE flux
485            IF( .NOT. cpl_phioc ) THEN
486                CALL ctl_stop( 'STOP', 'phioc can be used in coupled mode only' )
487            ENDIF
488            ALLOCATE( phioc(jpi,jpj) )
489            phioc(:,:) = 0._wp
490         ENDIF
491
492         IF( ln_tauoc ) THEN                    ! normalized wave stress into the ocean
493            IF( .NOT. cpl_wstrf ) THEN
494               ALLOCATE( sf_tauoc(1), STAT=ierror )           !* allocate and fill sf_wave with sn_tauoc
495               IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_wave_init: unable to allocate sf_tauoc structure' )
496               !
497                                       ALLOCATE( sf_tauoc(1)%fnow(jpi,jpj,1)   )
498               IF( sn_tauoc%ln_tint )  ALLOCATE( sf_tauoc(1)%fdta(jpi,jpj,1,2) )
499               CALL fld_fill( sf_tauoc, (/ sn_tauoc /), cn_dir, 'sbc_wave_init', 'Wave module', 'namsbc_wave' )
500            ENDIF
501            ALLOCATE( tauoc_wave(jpi,jpj) )
502            tauoc_wave(:,:) = 0._wp
503         ENDIF
504
505         IF( ln_zdfswm .OR. ln_STOKES_ADIAB ) THEN         ! Wave number (only needed for Qiao parametrisation,ln_zdfswm=T)
506            IF( .NOT. cpl_wnum ) THEN
507               ALLOCATE( sf_wn(1), STAT=ierror )           !* allocate and fill sf_wave with sn_wnum
508               IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_wave_init: unable to allocate sf_wn structure' )
509                                      ALLOCATE( sf_wn(1)%fnow(jpi,jpj,1)   )
510               IF( sn_wnum%ln_tint )  ALLOCATE( sf_wn(1)%fdta(jpi,jpj,1,2) )
511               CALL fld_fill( sf_wn, (/ sn_wnum /), cn_dir, 'sbc_wave', 'Wave module', 'namsbc_wave' )
512            ENDIF
513         ENDIF
514
515         IF( ln_sdw ) THEN                      ! Stokes drift
516            ! 1. Find out how many fields have to be read from file if not coupled
517            jpfld=0
518            jp_usd=0   ;   jp_vsd=0   ;   jp_hsw=0   ;   jp_wmp=0
519            IF( .NOT. cpl_sdrftx ) THEN
520               jpfld  = jpfld + 1
521               jp_usd = jpfld
522            ENDIF
523            IF( .NOT. cpl_sdrfty ) THEN
524               jpfld  = jpfld + 1
525               jp_vsd = jpfld
526            ENDIF
527            IF( .NOT. cpl_hsig ) THEN
528               jpfld  = jpfld + 1
529               jp_hsw = jpfld
530            ENDIF
531            IF( .NOT. cpl_wper ) THEN
532               jpfld  = jpfld + 1
533               jp_wmp = jpfld
534            ENDIF
535            ! 2. Read from file only the non-coupled fields
536            IF( jpfld > 0 ) THEN
537               ALLOCATE( slf_i(jpfld) )
538               IF( jp_usd > 0 )   slf_i(jp_usd) = sn_usd
539               IF( jp_vsd > 0 )   slf_i(jp_vsd) = sn_vsd
540               IF( jp_hsw > 0 )   slf_i(jp_hsw) = sn_hsw
541               IF( jp_wmp > 0 )   slf_i(jp_wmp) = sn_wmp
542               ALLOCATE( sf_sd(jpfld), STAT=ierror )   !* allocate and fill sf_sd with stokes drift
543               IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_wave_init: unable to allocate sf_wave structure' )
544               !
545               DO ifpr= 1, jpfld
546                  ALLOCATE( sf_sd(ifpr)%fnow(jpi,jpj,1) )
547                  IF( slf_i(ifpr)%ln_tint )   ALLOCATE( sf_sd(ifpr)%fdta(jpi,jpj,1,2) )
548               END DO
549               !
550               CALL fld_fill( sf_sd, slf_i, cn_dir, 'sbc_wave_init', 'Wave module ', 'namsbc_wave' )
551               sf_sd(jp_usd)%zsgn = -1._wp   ;  sf_sd(jp_vsd)%zsgn = -1._wp   ! vector field at T point: overwrite default definition of zsgn
552            ENDIF
553            !
554         ENDIF
555         !
556      ENDIF
557      !
558   END SUBROUTINE sbc_wave_init
559
560   !!======================================================================
561END MODULE sbcwave
Note: See TracBrowser for help on using the repository browser.