New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcwave.F90 in NEMO/branches/2021/dev_r14886_VLD-03_Aimie_Moulin_Wave_Coupling_TestCase/tests/ADIAB_WAVE/MY_SRC – NEMO

source: NEMO/branches/2021/dev_r14886_VLD-03_Aimie_Moulin_Wave_Coupling_TestCase/tests/ADIAB_WAVE/MY_SRC/sbcwave.F90 @ 14953

Last change on this file since 14953 was 14953, checked in by amoulin, 3 years ago

read wnum in sbcwave.F90 of MY_SRC -ticket #2613
File size: 29.4 KB
Line 
1MODULE sbcwave
2   !!======================================================================
3   !!                       ***  MODULE  sbcwave  ***
4   !! Wave module
5   !!======================================================================
6   !! History :  3.3  !  2011-09  (M. Adani)  Original code: Drag Coefficient
7   !!         :  3.4  !  2012-10  (M. Adani)  Stokes Drift
8   !!            3.6  !  2014-09  (E. Clementi,P. Oddo) New Stokes Drift Computation
9   !!             -   !  2016-12  (G. Madec, E. Clementi) update Stoke drift computation
10   !!                                                    + add sbc_wave_ini routine
11   !!            4.2  !  2020-12  (G. Madec, E. Clementi) updates, new Stoke drift computation
12   !!                                                    according to Couvelard et al.,2019
13   !!----------------------------------------------------------------------
14
15   !!----------------------------------------------------------------------
16   !!   sbc_stokes    : calculate 3D Stokes-drift velocities
17   !!   sbc_wave      : wave data from wave model: forced (netcdf files) or coupled mode
18   !!   sbc_wave_init : initialisation fo surface waves
19   !!----------------------------------------------------------------------
20   USE phycst         ! physical constants
21   USE oce            ! ocean variables
22   USE dom_oce        ! ocean domain variables
23   USE sbc_oce        ! Surface boundary condition: ocean fields
24   USE bdy_oce        ! open boundary condition variables
25   USE domvvl         ! domain: variable volume layers
26   USE usrdef_nam , ONLY: ln_STOKES_ADIAB   
27   !
28   USE iom            ! I/O manager library
29   USE in_out_manager ! I/O manager
30   USE lib_mpp        ! distribued memory computing library
31   USE fldread        ! read input fields
32   IMPLICIT NONE
33   PRIVATE
34
35   PUBLIC   sbc_stokes      ! routine called in sbccpl
36   PUBLIC   sbc_wave        ! routine called in sbcmod
37   PUBLIC   sbc_wave_init   ! routine called in sbcmod
38
39   ! Variables checking if the wave parameters are coupled (if not, they are read from file)
40   LOGICAL, PUBLIC ::   cpl_hsig          = .FALSE.
41   LOGICAL, PUBLIC ::   cpl_phioc         = .FALSE.
42   LOGICAL, PUBLIC ::   cpl_sdrftx        = .FALSE.
43   LOGICAL, PUBLIC ::   cpl_sdrfty        = .FALSE.
44   LOGICAL, PUBLIC ::   cpl_wper          = .FALSE.
45   LOGICAL, PUBLIC ::   cpl_wnum          = .FALSE.
46   LOGICAL, PUBLIC ::   cpl_wstrf         = .FALSE.
47   LOGICAL, PUBLIC ::   cpl_wdrag         = .FALSE.
48   LOGICAL, PUBLIC ::   cpl_charn         = .FALSE.
49   LOGICAL, PUBLIC ::   cpl_taw           = .FALSE.
50   LOGICAL, PUBLIC ::   cpl_bhd           = .FALSE.
51   LOGICAL, PUBLIC ::   cpl_tusd          = .FALSE.
52   LOGICAL, PUBLIC ::   cpl_tvsd          = .FALSE.
53
54   INTEGER ::   jpfld    ! number of files to read for stokes drift
55   INTEGER ::   jp_usd   ! index of stokes drift  (i-component) (m/s)    at T-point
56   INTEGER ::   jp_vsd   ! index of stokes drift  (j-component) (m/s)    at T-point
57   INTEGER ::   jp_hsw   ! index of significant wave hight      (m)      at T-point
58   INTEGER ::   jp_wmp   ! index of mean wave period            (s)      at T-point
59
60   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_cd      ! structure of input fields (file informations, fields read) Drag Coefficient
61   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_sd      ! structure of input fields (file informations, fields read) Stokes Drift
62   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_wn      ! structure of input fields (file informations, fields read) wave number for Qiao
63   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_tauoc   ! structure of input fields (file informations, fields read) normalized wave stress into the ocean
64
65   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   cdn_wave        !: Neutral drag coefficient at t-point
66   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   hsw             !: Significant Wave Height at t-point
67   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   wmp             !: Wave Mean Period at t-point
68   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   wnum            !: Wave Number at t-point
69   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   tauoc_wave      !: stress reduction factor  at t-point
70   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   tsd2d           !: Surface Stokes Drift module at t-point
71   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   div_sd          !: barotropic stokes drift divergence
72   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   ut0sd, vt0sd    !: surface Stokes drift velocities at t-point
73   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:,:) ::   usd, vsd, wsd   !: Stokes drift velocities at u-, v- & w-points, resp.u
74!
75   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   charn           !: charnock coefficient at t-point
76   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   tawx            !: Net wave-supported stress, u
77   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   tawy            !: Net wave-supported stress, v
78   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   twox            !: wave-ocean momentum flux, u
79   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   twoy            !: wave-ocean momentum flux, v
80   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   tauoc_wavex     !: stress reduction factor  at, u component
81   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   tauoc_wavey     !: stress reduction factor  at, v component
82   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   phioc           !: tke flux from wave model
83   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   KZN2            !: Kz*N2
84   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   bhd_wave        !: Bernoulli head. wave induce pression
85   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:)   ::   tusd, tvsd      !: Stokes drift transport
86   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:,:) ::   ZMX             !: Kz*N2
87   !! * Substitutions
88#  include "do_loop_substitute.h90"
89#  include "domzgr_substitute.h90"
90   !!----------------------------------------------------------------------
91   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
92   !! $Id: sbcwave.F90 14433 2021-02-11 08:06:49Z smasson $
93   !! Software governed by the CeCILL license (see ./LICENSE)
94   !!----------------------------------------------------------------------
95CONTAINS
96
97   SUBROUTINE sbc_stokes( Kmm )
98      !!---------------------------------------------------------------------
99      !!                     ***  ROUTINE sbc_stokes  ***
100      !!
101      !! ** Purpose :   compute the 3d Stokes Drift according to Breivik et al.,
102      !!                2014 (DOI: 10.1175/JPO-D-14-0020.1)
103      !!
104      !! ** Method  : - Calculate the horizontal Stokes drift velocity (Breivik et al. 2014)
105      !!              - Calculate its horizontal divergence
106      !!              - Calculate the vertical Stokes drift velocity
107      !!              - Calculate the barotropic Stokes drift divergence
108      !!
109      !! ** action  : - tsd2d         : module of the surface Stokes drift velocity
110      !!              - usd, vsd, wsd : 3 components of the Stokes drift velocity
111      !!              - div_sd        : barotropic Stokes drift divergence
112      !!---------------------------------------------------------------------
113      INTEGER, INTENT(in) :: Kmm ! ocean time level index
114      INTEGER  ::   jj, ji, jk   ! dummy loop argument
115      INTEGER  ::   ik           ! local integer
116      REAL(wp) ::  ztransp, zfac, ztemp, zsp0, zsqrt, zbreiv16_w
117      REAL(wp) ::  zdep_u, zdep_v, zkh_u, zkh_v, zda_u, zda_v, sdtrp
118      REAL(wp) ::  zkd_u, zkd_v, zdep_ue, zdep_ve  ! variable for Stokes drift in SHALLOW/INTER WATER
119      REAL(wp), DIMENSION(:,:)  , ALLOCATABLE ::   zk_t, zk_u, zk_v, zu0_sd, zv0_sd ! 2D workspace
120      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::   ze3divh, zInt_w                  ! 3D workspace
121      !!---------------------------------------------------------------------
122      !
123      ALLOCATE( ze3divh(jpi,jpj,jpkm1) ) ! jpkm1 -> avoid lbc_lnk on jpk that is not defined
124      ALLOCATE( zInt_w(jpi,jpj,jpk) )
125      ALLOCATE( zk_t(jpi,jpj), zk_u(jpi,jpj), zk_v(jpi,jpj), zu0_sd(jpi,jpj), zv0_sd(jpi,jpj) )
126      zk_t    (:,:) = 0._wp
127      zk_u    (:,:) = 0._wp
128      zk_v    (:,:) = 0._wp
129      zu0_sd  (:,:) = 0._wp
130      zv0_sd  (:,:) = 0._wp
131      ze3divh (:,:,:) = 0._wp
132
133      !
134      ! select parameterization for the calculation of vertical Stokes drift
135      ! exp. wave number at t-point
136      IF( ln_breivikFV_2016 ) THEN
137      ! Assumptions :  ut0sd and vt0sd are surface Stokes drift at T-points
138      !                sdtrp is the norm of Stokes transport
139      !
140         zfac = 0.166666666667_wp
141         DO_2D( 1, 1, 1, 1 ) ! In the deep-water limit we have ke = ||ust0||/( 6 * ||transport|| )
142            zsp0          = SQRT( ut0sd(ji,jj)*ut0sd(ji,jj) + vt0sd(ji,jj)*vt0sd(ji,jj) ) !<-- norm of Surface Stokes drift
143            tsd2d(ji,jj)  = zsp0
144            IF( cpl_tusd .AND. cpl_tvsd ) THEN  !stokes transport is provided in coupled mode
145               sdtrp      = SQRT( tusd(ji,jj)*tusd(ji,jj) + tvsd(ji,jj)*tvsd(ji,jj) )  !<-- norm of Surface Stokes drift transport
146            ELSE
147               ! Stokes drift transport estimated from Hs and Tmean
148               sdtrp      = 2.0_wp * rpi / 16.0_wp *                             &
149                   &        hsw(ji,jj)*hsw(ji,jj) / MAX( wmp(ji,jj), 0.0000001_wp )
150            ENDIF
151            zk_t (ji,jj)  = zfac * zsp0 / MAX ( sdtrp, 0.0000001_wp ) !<-- ke = ||ust0||/( 6 * ||transport|| )
152         END_2D
153      !# define zInt_w ze3divh
154         DO_3D( 1, 1, 1, 1, 1, jpk ) ! Compute the primitive of Breivik 2016 function at W-points
155            zfac             = - 2._wp * zk_t (ji,jj) * gdepw(ji,jj,jk,Kmm)  !<-- zfac should be negative definite
156            ztemp            = EXP ( zfac )
157            zsqrt            = SQRT( -zfac )
158            zbreiv16_w       = ztemp - SQRT(rpi)*zsqrt*ERFC(zsqrt) !Eq. 16 Breivik 2016
159            zInt_w(ji,jj,jk) = ztemp - 4._wp * zk_t (ji,jj) * gdepw(ji,jj,jk,Kmm) * zbreiv16_w
160         END_3D
161!
162         DO jk = 1, jpkm1
163            zfac = 0.166666666667_wp
164            DO_2D( 1, 1, 1, 1 ) !++ Compute the FV Breivik 2016 function at T-points
165               zsp0          = zfac / MAX(zk_t (ji,jj),0.0000001_wp)
166               ztemp         = zInt_w(ji,jj,jk) - zInt_w(ji,jj,jk+1)
167               zu0_sd(ji,jj) = ut0sd(ji,jj) * zsp0 * ztemp * tmask(ji,jj,jk)
168               zv0_sd(ji,jj) = vt0sd(ji,jj) * zsp0 * ztemp * tmask(ji,jj,jk)
169            END_2D
170            DO_2D( 1, 0, 1, 0 ) ! ++ Interpolate at U/V points
171               zfac          =  1.0_wp / e3u(ji  ,jj,jk,Kmm)
172               usd(ji,jj,jk) =  0.5_wp * zfac * ( zu0_sd(ji,jj)+zu0_sd(ji+1,jj) ) * umask(ji,jj,jk)
173               zfac          =  1.0_wp / e3v(ji  ,jj,jk,Kmm)
174               vsd(ji,jj,jk) =  0.5_wp * zfac * ( zv0_sd(ji,jj)+zv0_sd(ji,jj+1) ) * vmask(ji,jj,jk)
175            END_2D
176         ENDDO
177      !# undef zInt_w
178      !
179      ELSE IF (ln_STOKES_ADIAB) THEN
180         DO_2D( 1, 0, 1, 0 )
181       !  velocity at u- & v-points
182           zk_u(ji,jj) = 0.5_wp * ( wnum(ji,jj) + wnum(ji+1,jj) )
183           zk_v(ji,jj) = 0.5_wp * ( wnum(ji,jj) + wnum(ji,jj+1) )
184            !
185           zu0_sd(ji,jj) = 0.5_wp * ( ut0sd(ji,jj) + ut0sd(ji+1,jj) )
186           zv0_sd(ji,jj) = 0.5_wp * ( vt0sd(ji,jj) + vt0sd(ji,jj+1) )
187         END_2D
188
189      !                       !==  horizontal Stokes Drift 3D velocity  ==!
190         DO_3D( 0, 0, 0, 0, 1, jpkm1 )
191            zdep_u = 0.5_wp * ( gdept(ji,jj,jk,Kmm) + gdept(ji+1,jj,jk,Kmm) )
192            zdep_v = 0.5_wp * ( gdept(ji,jj,jk,Kmm) + gdept(ji,jj+1,jk,Kmm) )
193            zdep_ue= 0.5_wp * ( gdept(ji,jj,jpkm1,Kmm) + gdept(ji+1,jj,jpkm1,Kmm) )
194            zdep_ve= 0.5_wp * ( gdept(ji,jj,jpkm1,Kmm) + gdept(ji+1,jj,jpkm1,Kmm) )
195            !
196            zkh_u = zk_u(ji,jj) * zdep_u     ! k * depth
197            zkh_v = zk_v(ji,jj) * zdep_v
198            zkd_u = zk_u(ji,jj) * zdep_ue
199            zkd_v = zk_v(ji,jj) * zdep_ve
200                                ! Depth attenuation
201            zda_u = COSH(-2.0_wp*zkh_u+2.0_wp*zkd_u)/COSH(2.0_wp*zkd_u)
202            zda_v = COSH(-2.0_wp*zkh_v+2.0_wp*zkd_v)/COSH(2.0_wp*zkd_v)
203            !
204            usd(ji,jj,jk) = zda_u * zu0_sd(ji,jj) * umask(ji,jj,jk)
205            vsd(ji,jj,jk) = zda_v * zv0_sd(ji,jj) * vmask(ji,jj,jk)
206         END_3D
207      ELSE
208         zfac = 2.0_wp * rpi / 16.0_wp
209         DO_2D( 1, 1, 1, 1 )
210            ! Stokes drift velocity estimated from Hs and Tmean
211            ztransp = zfac * hsw(ji,jj)*hsw(ji,jj) / MAX( wmp(ji,jj), 0.0000001_wp )
212            ! Stokes surface speed
213            tsd2d(ji,jj) = SQRT( ut0sd(ji,jj)*ut0sd(ji,jj) + vt0sd(ji,jj)*vt0sd(ji,jj))
214            ! Wavenumber scale
215            zk_t(ji,jj) = ABS( tsd2d(ji,jj) ) / MAX( ABS( 5.97_wp*ztransp ), 0.0000001_wp )
216         END_2D
217         DO_2D( 1, 0, 1, 0 )          ! exp. wave number & Stokes drift velocity at u- & v-points
218            zk_u(ji,jj) = 0.5_wp * ( zk_t(ji,jj) + zk_t(ji+1,jj) )
219            zk_v(ji,jj) = 0.5_wp * ( zk_t(ji,jj) + zk_t(ji,jj+1) )
220            !
221            zu0_sd(ji,jj) = 0.5_wp * ( ut0sd(ji,jj) + ut0sd(ji+1,jj) )
222            zv0_sd(ji,jj) = 0.5_wp * ( vt0sd(ji,jj) + vt0sd(ji,jj+1) )
223         END_2D
224
225      !                       !==  horizontal Stokes Drift 3D velocity  ==!
226
227         DO_3D( 0, 0, 0, 0, 1, jpkm1 )
228            zdep_u = 0.5_wp * ( gdept(ji,jj,jk,Kmm) + gdept(ji+1,jj,jk,Kmm) )
229            zdep_v = 0.5_wp * ( gdept(ji,jj,jk,Kmm) + gdept(ji,jj+1,jk,Kmm) )
230            !
231            zkh_u = zk_u(ji,jj) * zdep_u     ! k * depth
232            zkh_v = zk_v(ji,jj) * zdep_v
233            !                                ! Depth attenuation
234            zda_u = EXP( -2.0_wp*zkh_u ) / ( 1.0_wp + 8.0_wp*zkh_u )
235            zda_v = EXP( -2.0_wp*zkh_v ) / ( 1.0_wp + 8.0_wp*zkh_v )
236            !
237            usd(ji,jj,jk) = zda_u * zu0_sd(ji,jj) * umask(ji,jj,jk)
238            vsd(ji,jj,jk) = zda_v * zv0_sd(ji,jj) * vmask(ji,jj,jk)
239         END_3D
240      ENDIF
241
242      CALL lbc_lnk( 'sbcwave', usd, 'U', -1.0_wp, vsd, 'V', -1.0_wp )
243
244      !
245      !                       !==  vertical Stokes Drift 3D velocity  ==!
246      !
247      DO_3D( 0, 1, 0, 1, 1, jpkm1 )    ! Horizontal e3*divergence
248         ze3divh(ji,jj,jk) = (  e2u(ji  ,jj) * e3u(ji  ,jj,jk,Kmm) * usd(ji  ,jj,jk)    &
249            &                 - e2u(ji-1,jj) * e3u(ji-1,jj,jk,Kmm) * usd(ji-1,jj,jk)    &
250            &                 + e1v(ji,jj  ) * e3v(ji,jj  ,jk,Kmm) * vsd(ji,jj  ,jk)    &
251            &                 - e1v(ji,jj-1) * e3v(ji,jj-1,jk,Kmm) * vsd(ji,jj-1,jk)  ) &
252            &                * r1_e1e2t(ji,jj)
253      END_3D
254      !
255      CALL lbc_lnk( 'sbcwave', ze3divh, 'T', 1.0_wp )
256      !
257      IF( ln_linssh ) THEN   ;   ik = 1   ! none zero velocity through the sea surface
258      ELSE                   ;   ik = 2   ! w=0 at the surface (set one for all in sbc_wave_init)
259      ENDIF
260      DO jk = jpkm1, ik, -1          ! integrate from the bottom the hor. divergence (NB: at k=jpk w is always zero)
261         wsd(:,:,jk) = wsd(:,:,jk+1) - ze3divh(:,:,jk)
262      END DO
263      !
264      IF( ln_bdy ) THEN
265         DO jk = 1, jpkm1
266            wsd(:,:,jk) = wsd(:,:,jk) * bdytmask(:,:)
267         END DO
268      ENDIF
269      !                       !==  Horizontal divergence of barotropic Stokes transport  ==!
270      div_sd(:,:) = 0._wp
271      DO jk = 1, jpkm1                                 !
272        div_sd(:,:) = div_sd(:,:) + ze3divh(:,:,jk)
273      END DO
274      !
275      CALL iom_put( "ustokes",  usd  )
276      CALL iom_put( "vstokes",  vsd  )
277      CALL iom_put( "wstokes",  wsd  )
278!      !
279      DEALLOCATE( ze3divh, zInt_w )
280      DEALLOCATE( zk_t, zk_u, zk_v, zu0_sd, zv0_sd )
281      !
282   END SUBROUTINE sbc_stokes
283!
284!
285   SUBROUTINE sbc_wave( kt, Kmm )
286      !!---------------------------------------------------------------------
287      !!                     ***  ROUTINE sbc_wave  ***
288      !!
289      !! ** Purpose :   read wave parameters from wave model in netcdf files
290      !!                or from a coupled wave mdoel
291      !!
292      !!---------------------------------------------------------------------
293      INTEGER, INTENT(in   ) ::   kt   ! ocean time step
294      INTEGER, INTENT(in   ) ::   Kmm  ! ocean time index
295      !!---------------------------------------------------------------------
296      !
297      IF( kt == nit000 .AND. lwp ) THEN
298         WRITE(numout,*)
299         WRITE(numout,*) 'sbc_wave : update the read waves fields'
300         WRITE(numout,*) '~~~~~~~~ '
301      ENDIF
302      !
303      IF( ln_cdgw .AND. .NOT. cpl_wdrag ) THEN     !==  Neutral drag coefficient  ==!
304         CALL fld_read( kt, nn_fsbc, sf_cd )             ! read from external forcing
305         cdn_wave(:,:) = sf_cd(1)%fnow(:,:,1) * tmask(:,:,1)
306      ENDIF
307
308      IF( ln_tauoc .AND. .NOT. cpl_wstrf ) THEN    !==  Wave induced stress  ==!
309         CALL fld_read( kt, nn_fsbc, sf_tauoc )          ! read stress reduction factor due to wave from external forcing
310         tauoc_wave(:,:) = sf_tauoc(1)%fnow(:,:,1) * tmask(:,:,1)
311      ELSEIF ( ln_taw .AND. cpl_taw ) THEN
312         IF (kt < 1) THEN ! The first fields gave by OASIS have very high erroneous values ....
313            twox(:,:)=0._wp
314            twoy(:,:)=0._wp
315            tawx(:,:)=0._wp
316            tawy(:,:)=0._wp
317            tauoc_wavex(:,:) = 1._wp
318            tauoc_wavey(:,:) = 1._wp
319         ELSE
320            tauoc_wavex(:,:) = abs(twox(:,:)/tawx(:,:))
321            tauoc_wavey(:,:) = abs(twoy(:,:)/tawy(:,:))
322         ENDIF
323      ENDIF
324
325      ! Read also wave number if needed, so that it is available in coupling routines
326      IF( ln_STOKES_ADIAB .AND. .NOT. cpl_wnum ) THEN     !==wavenumber==!
327         CALL fld_read( kt, nn_fsbc, sf_wn )             ! read wave parameters from external forcing
328         wnum(:,:) = sf_wn(1)%fnow(:,:,1) * tmask(:,:,1)
329      ENDIF
330
331      IF ( ln_phioc .and. cpl_phioc .and.  kt == nit000 ) THEN
332         WRITE(numout,*)
333         WRITE(numout,*) 'sbc_wave : PHIOC from wave model'
334         WRITE(numout,*) '~~~~~~~~ '
335      ENDIF
336
337      IF( ln_sdw .AND. .NOT. cpl_sdrftx)  THEN       !==  Computation of the 3d Stokes Drift  ==!
338         !
339         IF( jpfld > 0 ) THEN                            ! Read from file only if the field is not coupled
340            CALL fld_read( kt, nn_fsbc, sf_sd )          ! read wave parameters from external forcing
341            !                                            ! NB: test case mode, not read as jpfld=0
342            IF( jp_hsw > 0 )   hsw  (:,:) = sf_sd(jp_hsw)%fnow(:,:,1) * tmask(:,:,1)  ! significant wave height
343            IF( jp_wmp > 0 )   wmp  (:,:) = sf_sd(jp_wmp)%fnow(:,:,1) * tmask(:,:,1)  ! wave mean period
344            IF( jp_usd > 0 )   ut0sd(:,:) = sf_sd(jp_usd)%fnow(:,:,1) * tmask(:,:,1)  ! 2D zonal Stokes Drift at T point
345            IF( jp_vsd > 0 )   vt0sd(:,:) = sf_sd(jp_vsd)%fnow(:,:,1) * tmask(:,:,1)  ! 2D meridional Stokes Drift at T point
346         ENDIF
347         !
348         IF( jpfld == 4 .OR. ln_wave_test )   &
349            &      CALL sbc_stokes( Kmm )                 ! Calculate only if all required fields are read
350            !                                            ! or in wave test case
351         !  !                                            ! In coupled case the call is done after (in sbc_cpl)
352      ENDIF
353         !
354   END SUBROUTINE sbc_wave
355
356
357   SUBROUTINE sbc_wave_init
358      !!---------------------------------------------------------------------
359      !!                     ***  ROUTINE sbc_wave_init  ***
360      !!
361      !! ** Purpose :   Initialisation fo surface waves
362      !!
363      !! ** Method  : - Read namelist namsbc_wave
364      !!              - create the structure used to read required wave fields
365      !!                (its size depends on namelist options)
366      !! ** action
367      !!---------------------------------------------------------------------
368      INTEGER ::   ierror, ios   ! local integer
369      INTEGER ::   ifpr
370      !!
371      CHARACTER(len=100)     ::  cn_dir                            ! Root directory for location of drag coefficient files
372      TYPE(FLD_N), ALLOCATABLE, DIMENSION(:) ::   slf_i            ! array of namelist informations on the fields to read
373      TYPE(FLD_N)            ::  sn_cdg, sn_usd, sn_vsd,  &
374                             &   sn_hsw, sn_wmp, sn_wnum, sn_tauoc    ! informations about the fields to be read
375      !
376      NAMELIST/namsbc_wave/ cn_dir, sn_cdg, sn_usd, sn_vsd, sn_hsw, sn_wmp, sn_wnum, sn_tauoc,   &
377         &                  ln_cdgw, ln_sdw, ln_tauoc, ln_stcor, ln_charn, ln_taw, ln_phioc,     &
378         &                  ln_wave_test, ln_bern_srfc, ln_breivikFV_2016, ln_vortex_force, ln_stshear
379      !!---------------------------------------------------------------------
380      IF(lwp) THEN
381         WRITE(numout,*)
382         WRITE(numout,*) 'sbc_wave_init : surface waves in the system'
383         WRITE(numout,*) '~~~~~~~~~~~~~ '
384      ENDIF
385      !
386      READ  ( numnam_ref, namsbc_wave, IOSTAT = ios, ERR = 901)
387901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namsbc_wave in reference namelist')
388
389      READ  ( numnam_cfg, namsbc_wave, IOSTAT = ios, ERR = 902 )
390902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namsbc_wave in configuration namelist' )
391      IF(lwm) WRITE ( numond, namsbc_wave )
392      !
393      IF(lwp) THEN
394         WRITE(numout,*) '   Namelist namsbc_wave'
395         WRITE(numout,*) '      Stokes drift                                  ln_sdw = ', ln_sdw
396         WRITE(numout,*) '      Breivik 2016                       ln_breivikFV_2016 = ', ln_breivikFV_2016
397         WRITE(numout,*) '      Stokes Coriolis & tracer advection terms    ln_stcor = ', ln_stcor
398         WRITE(numout,*) '      Vortex Force                         ln_vortex_force = ', ln_vortex_force
399         WRITE(numout,*) '      Bernouilli Head Pressure                ln_bern_srfc = ', ln_bern_srfc
400         WRITE(numout,*) '      wave modified ocean stress                  ln_tauoc = ', ln_tauoc
401         WRITE(numout,*) '      neutral drag coefficient (CORE bulk only)    ln_cdgw = ', ln_cdgw
402         WRITE(numout,*) '      charnock coefficient                        ln_charn = ', ln_charn
403         WRITE(numout,*) '      Stress modificated by wave                    ln_taw = ', ln_taw
404         WRITE(numout,*) '      TKE flux from wave                          ln_phioc = ', ln_phioc
405         WRITE(numout,*) '      Surface shear with Stokes drift           ln_stshear = ', ln_stshear
406         WRITE(numout,*) '      Test with constant wave fields          ln_wave_test = ', ln_wave_test
407      ENDIF
408
409      !                                ! option check
410      IF( .NOT.( ln_cdgw .OR. ln_sdw .OR. ln_tauoc .OR. ln_stcor .OR. ln_charn) )   &
411         &     CALL ctl_warn( 'Ask for wave coupling but ln_cdgw=F, ln_sdw=F, ln_tauoc=F, ln_stcor=F')
412      IF( ln_cdgw .AND. ln_blk )   &
413         &     CALL ctl_stop( 'drag coefficient read from wave model NOT available yet with aerobulk package')
414      IF( ln_stcor .AND. .NOT.ln_sdw )   &
415         &     CALL ctl_stop( 'Stokes-Coriolis term calculated only if activated Stokes Drift ln_sdw=T')
416
417      !                             !==  Allocate wave arrays  ==!
418      ALLOCATE( ut0sd (jpi,jpj)    , vt0sd (jpi,jpj) )
419      ALLOCATE( hsw   (jpi,jpj)    , wmp   (jpi,jpj) )
420      ALLOCATE( wnum  (jpi,jpj) )
421      ALLOCATE( tsd2d (jpi,jpj)    , div_sd(jpi,jpj)    , bhd_wave(jpi,jpj)     )
422      ALLOCATE( usd   (jpi,jpj,jpk), vsd   (jpi,jpj,jpk), wsd     (jpi,jpj,jpk) )
423      ALLOCATE( tusd  (jpi,jpj)    , tvsd  (jpi,jpj)    , ZMX     (jpi,jpj,jpk) )
424      usd   (:,:,:) = 0._wp
425      vsd   (:,:,:) = 0._wp
426      wsd   (:,:,:) = 0._wp
427      hsw     (:,:) = 0._wp
428      wmp     (:,:) = 0._wp
429      ut0sd   (:,:) = 0._wp
430      vt0sd   (:,:) = 0._wp
431      tusd    (:,:) = 0._wp
432      tvsd    (:,:) = 0._wp
433      bhd_wave(:,:) = 0._wp
434      ZMX   (:,:,:) = 0._wp
435!
436      IF( ln_wave_test ) THEN       !==  Wave TEST case  ==!   set uniform waves fields
437         jpfld    = 0                   ! No field read
438         ln_cdgw  = .FALSE.             ! No neutral wave drag input
439         ln_tauoc = .FALSE.             ! No wave induced drag reduction factor
440         ut0sd(:,:) = 0.13_wp * tmask(:,:,1)   ! m/s
441         vt0sd(:,:) = 0.00_wp                  ! m/s
442         hsw  (:,:) = 2.80_wp                  ! meters
443         wmp  (:,:) = 8.00_wp                  ! seconds
444         !
445      ELSE                          !==  create the structure associated with fields to be read  ==!
446         IF( ln_cdgw ) THEN                       ! wave drag
447            IF( .NOT. cpl_wdrag ) THEN
448               ALLOCATE( sf_cd(1), STAT=ierror )               !* allocate and fill sf_wave with sn_cdg
449               IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_wave_init: unable to allocate sf_wave structure' )
450               !
451                                      ALLOCATE( sf_cd(1)%fnow(jpi,jpj,1)   )
452               IF( sn_cdg%ln_tint )   ALLOCATE( sf_cd(1)%fdta(jpi,jpj,1,2) )
453               CALL fld_fill( sf_cd, (/ sn_cdg /), cn_dir, 'sbc_wave_init', 'Wave module ', 'namsbc_wave' )
454            ENDIF
455            ALLOCATE( cdn_wave(jpi,jpj) )
456            cdn_wave(:,:) = 0._wp
457         ENDIF
458         IF( ln_charn ) THEN                     ! wave drag
459            IF( .NOT. cpl_charn ) THEN
460               CALL ctl_stop( 'STOP', 'Charnock based wind stress can be used in coupled mode only' )
461            ENDIF
462            ALLOCATE( charn(jpi,jpj) )
463            charn(:,:) = 0._wp
464         ENDIF
465         IF( ln_taw ) THEN                     ! wind stress
466            IF( .NOT. cpl_taw ) THEN
467               CALL ctl_stop( 'STOP', 'wind stress from wave model can be used in coupled mode only, use ln_cdgw instead' )
468            ENDIF
469            ALLOCATE( tawx(jpi,jpj) )
470            ALLOCATE( tawy(jpi,jpj) )
471            ALLOCATE( twox(jpi,jpj) )
472            ALLOCATE( twoy(jpi,jpj) )
473            ALLOCATE( tauoc_wavex(jpi,jpj) )
474            ALLOCATE( tauoc_wavey(jpi,jpj) )
475            tawx(:,:) = 0._wp
476            tawy(:,:) = 0._wp
477            twox(:,:) = 0._wp
478            twoy(:,:) = 0._wp
479            tauoc_wavex(:,:) = 1._wp
480            tauoc_wavey(:,:) = 1._wp
481         ENDIF
482
483         IF( ln_phioc ) THEN                     ! TKE flux
484            IF( .NOT. cpl_phioc ) THEN
485                CALL ctl_stop( 'STOP', 'phioc can be used in coupled mode only' )
486            ENDIF
487            ALLOCATE( phioc(jpi,jpj) )
488            phioc(:,:) = 0._wp
489         ENDIF
490
491         IF( ln_tauoc ) THEN                    ! normalized wave stress into the ocean
492            IF( .NOT. cpl_wstrf ) THEN
493               ALLOCATE( sf_tauoc(1), STAT=ierror )           !* allocate and fill sf_wave with sn_tauoc
494               IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_wave_init: unable to allocate sf_tauoc structure' )
495               !
496                                       ALLOCATE( sf_tauoc(1)%fnow(jpi,jpj,1)   )
497               IF( sn_tauoc%ln_tint )  ALLOCATE( sf_tauoc(1)%fdta(jpi,jpj,1,2) )
498               CALL fld_fill( sf_tauoc, (/ sn_tauoc /), cn_dir, 'sbc_wave_init', 'Wave module', 'namsbc_wave' )
499            ENDIF
500            ALLOCATE( tauoc_wave(jpi,jpj) )
501            tauoc_wave(:,:) = 0._wp
502         ENDIF
503
504         IF( ln_sdw ) THEN                      ! Stokes drift
505            ! 1. Find out how many fields have to be read from file if not coupled
506            jpfld=0
507            jp_usd=0   ;   jp_vsd=0   ;   jp_hsw=0   ;   jp_wmp=0
508            IF( .NOT. cpl_sdrftx ) THEN
509               jpfld  = jpfld + 1
510               jp_usd = jpfld
511            ENDIF
512            IF( .NOT. cpl_sdrfty ) THEN
513               jpfld  = jpfld + 1
514               jp_vsd = jpfld
515            ENDIF
516            IF( .NOT. cpl_hsig ) THEN
517               jpfld  = jpfld + 1
518               jp_hsw = jpfld
519            ENDIF
520            IF( .NOT. cpl_wper ) THEN
521               jpfld  = jpfld + 1
522               jp_wmp = jpfld
523            ENDIF
524            ! 2. Read from file only the non-coupled fields
525            IF( jpfld > 0 ) THEN
526               ALLOCATE( slf_i(jpfld) )
527               IF( jp_usd > 0 )   slf_i(jp_usd) = sn_usd
528               IF( jp_vsd > 0 )   slf_i(jp_vsd) = sn_vsd
529               IF( jp_hsw > 0 )   slf_i(jp_hsw) = sn_hsw
530               IF( jp_wmp > 0 )   slf_i(jp_wmp) = sn_wmp
531               ALLOCATE( sf_sd(jpfld), STAT=ierror )   !* allocate and fill sf_sd with stokes drift
532               IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_wave_init: unable to allocate sf_wave structure' )
533               !
534               DO ifpr= 1, jpfld
535                  ALLOCATE( sf_sd(ifpr)%fnow(jpi,jpj,1) )
536                  IF( slf_i(ifpr)%ln_tint )   ALLOCATE( sf_sd(ifpr)%fdta(jpi,jpj,1,2) )
537               END DO
538               !
539               CALL fld_fill( sf_sd, slf_i, cn_dir, 'sbc_wave_init', 'Wave module ', 'namsbc_wave' )
540               sf_sd(jp_usd)%zsgn = -1._wp   ;  sf_sd(jp_vsd)%zsgn = -1._wp   ! vector field at T point: overwrite default definition of zsgn
541            ENDIF
542                       !
543            ! 3. Wave number (only needed for Qiao parametrisation,
544            ! ln_zdfqiao=T)
545            IF( ln_STOKES_ADIAB ) THEN
546             IF( .NOT. cpl_wnum ) THEN
547                ALLOCATE( sf_wn(1), STAT=ierror )           !* allocate and fill sf_wave with sn_wnum
548                IF( ierror > 0 )   CALL ctl_stop( 'STOP', 'sbc_wave_init: unable to allocate sf_wn structure' )
549                                       ALLOCATE( sf_wn(1)%fnow(jpi,jpj,1)   )
550                IF( sn_wnum%ln_tint )  ALLOCATE( sf_wn(1)%fdta(jpi,jpj,1,2) )
551                CALL fld_fill( sf_wn, (/ sn_wnum /), cn_dir, 'sbc_wave', 'Wave module', 'namsbc_wave' )
552             ENDIF
553            ENDIF
554            !
555            !
556         ENDIF
557         !
558      ENDIF
559      !
560   END SUBROUTINE sbc_wave_init
561
562   !!======================================================================
563END MODULE sbcwave
Note: See TracBrowser for help on using the repository browser.