New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
icethd.F90 in NEMO/releases/r4.0/r4.0-HEAD/src/ICE – NEMO

source: NEMO/releases/r4.0/r4.0-HEAD/src/ICE/icethd.F90 @ 13589

Last change on this file since 13589 was 13589, checked in by clem, 4 years ago

4.0-HEAD: rewrite heat budget of sea ice to make it perfectly conservative by construction. Also, activating ln_icediachk now gives an ascii file (icedrift_diagnostics.ascii) containing mass, salt and heat global conservation issues (if any). In addition, 2D drift files can be outputed (icedrift_mass...) but since I did not want to change the xml files, one has to uncomment some lines in icectl.F90 and add the corresponding fields in field_def_oce.xml
  • Property svn:keywords set to Id
File size: 35.6 KB
Line 
1MODULE icethd
2   !!======================================================================
3   !!                  ***  MODULE icethd   ***
4   !!   sea-ice : master routine for thermodynamics
5   !!======================================================================
6   !! History :  1.0  !  2000-01  (M.A. Morales Maqueda, H. Goosse, T. Fichefet) original code 1D
7   !!            4.0  !  2018     (many people)       SI3 [aka Sea Ice cube]
8   !!----------------------------------------------------------------------
9#if defined key_si3
10   !!----------------------------------------------------------------------
11   !!   'key_si3'                                       SI3 sea-ice model
12   !!----------------------------------------------------------------------
13   !!   ice_thd       : thermodynamics of sea ice
14   !!   ice_thd_init  : initialisation of sea-ice thermodynamics
15   !!----------------------------------------------------------------------
16   USE phycst         ! physical constants
17   USE dom_oce        ! ocean space and time domain variables
18   USE ice            ! sea-ice: variables
19!!gm list trop longue ==>>> why not passage en argument d'appel ?
20   USE sbc_oce , ONLY : sss_m, sst_m, e3t_m, utau, vtau, ssu_m, ssv_m, frq_m, sprecip, ln_cpl
21   USE sbc_ice , ONLY : qsr_oce, qns_oce, qemp_oce, qsr_ice, qns_ice, dqns_ice, evap_ice, qprec_ice, qevap_ice, &
22      &                 qml_ice, qcn_ice, qtr_ice_top
23   USE ice1D          ! sea-ice: thermodynamics variables
24   USE icethd_zdf     ! sea-ice: vertical heat diffusion
25   USE icethd_dh      ! sea-ice: ice-snow growth and melt
26   USE icethd_da      ! sea-ice: lateral melting
27   USE icethd_sal     ! sea-ice: salinity
28   USE icethd_ent     ! sea-ice: enthalpy redistribution
29   USE icethd_do      ! sea-ice: growth in open water
30   USE icethd_pnd     ! sea-ice: melt ponds
31   USE iceitd         ! sea-ice: remapping thickness distribution
32   USE icetab         ! sea-ice: 1D <==> 2D transformation
33   USE icevar         ! sea-ice: operations
34   USE icectl         ! sea-ice: control print
35   !
36   USE in_out_manager ! I/O manager
37   USE iom            ! I/O manager library
38   USE lib_mpp        ! MPP library
39   USE lib_fortran    ! fortran utilities (glob_sum + no signed zero)
40   USE lbclnk         ! lateral boundary conditions (or mpp links)
41   USE timing         ! Timing
42
43   IMPLICIT NONE
44   PRIVATE
45
46   PUBLIC   ice_thd         ! called by limstp module
47   PUBLIC   ice_thd_init    ! called by ice_init
48
49   !!** namelist (namthd) **
50   LOGICAL ::   ln_icedH         ! activate ice thickness change from growing/melting (T) or not (F)
51   LOGICAL ::   ln_icedA         ! activate lateral melting param. (T) or not (F)
52   LOGICAL ::   ln_icedO         ! activate ice growth in open-water (T) or not (F)
53   LOGICAL ::   ln_icedS         ! activate gravity drainage and flushing (T) or not (F)
54   LOGICAL ::   ln_leadhfx       ! heat in the leads is used to melt sea-ice before warming the ocean
55
56   !! for convergence tests
57   REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) ::   ztice_cvgerr, ztice_cvgstp
58
59   !! * Substitutions
60#  include "vectopt_loop_substitute.h90"
61   !!----------------------------------------------------------------------
62   !! NEMO/ICE 4.0 , NEMO Consortium (2018)
63   !! $Id$
64   !! Software governed by the CeCILL license (see ./LICENSE)
65   !!----------------------------------------------------------------------
66CONTAINS
67
68   SUBROUTINE ice_thd( kt )
69      !!-------------------------------------------------------------------
70      !!                ***  ROUTINE ice_thd  ***       
71      !! 
72      !! ** Purpose : This routine manages ice thermodynamics
73      !!         
74      !! ** Action : - computation of oceanic sensible heat flux at the ice base
75      !!                              energy budget in the leads
76      !!                              net fluxes on top of ice and of ocean
77      !!             - selection of grid cells with ice
78      !!                - call ice_thd_zdf  for vertical heat diffusion
79      !!                - call ice_thd_dh   for vertical ice growth and melt
80      !!                - call ice_thd_pnd  for melt ponds
81      !!                - call ice_thd_ent  for enthalpy remapping
82      !!                - call ice_thd_sal  for ice desalination
83      !!                - call ice_thd_temp to  retrieve temperature from ice enthalpy
84      !!                - call ice_thd_mono for extra lateral ice melt if active virtual thickness distribution
85      !!                - call ice_thd_da   for lateral ice melt
86      !!             - back to the geographic grid
87      !!                - call ice_thd_rem  for remapping thickness distribution
88      !!                - call ice_thd_do   for ice growth in leads
89      !!-------------------------------------------------------------------
90      INTEGER, INTENT(in) :: kt    ! number of iteration
91      !
92      INTEGER  :: ji, jj, jk, jl   ! dummy loop indices
93      REAL(wp) :: zfric_u, zqld, zqfr, zqfr_neg, zqfr_pos
94      REAL(wp), PARAMETER :: zfric_umin = 0._wp       ! lower bound for the friction velocity (cice value=5.e-04)
95      REAL(wp), PARAMETER :: zch        = 0.0057_wp   ! heat transfer coefficient
96      REAL(wp), DIMENSION(jpi,jpj) ::   zu_io, zv_io, zfric, zvel   ! ice-ocean velocity (m/s) and frictional velocity (m2/s2)
97      !
98      !!-------------------------------------------------------------------
99      ! controls
100      IF( ln_timing    )   CALL timing_start('icethd')                                                             ! timing
101      IF( ln_icediachk )   CALL ice_cons_hsm(0, 'icethd', rdiag_v, rdiag_s, rdiag_t, rdiag_fv, rdiag_fs, rdiag_ft) ! conservation
102      IF( ln_icediachk )   CALL ice_cons2D  (0, 'icethd',  diag_v,  diag_s,  diag_t,  diag_fv,  diag_fs,  diag_ft) ! conservation
103
104      IF( kt == nit000 .AND. lwp ) THEN
105         WRITE(numout,*)
106         WRITE(numout,*) 'ice_thd: sea-ice thermodynamics'
107         WRITE(numout,*) '~~~~~~~'
108      ENDIF
109
110      ! convergence tests
111      IF( ln_zdf_chkcvg ) THEN
112         ALLOCATE( ztice_cvgerr(jpi,jpj,jpl) , ztice_cvgstp(jpi,jpj,jpl) )
113         ztice_cvgerr = 0._wp ; ztice_cvgstp = 0._wp
114      ENDIF
115     
116      !---------------------------------------------!
117      ! computation of friction velocity at T points
118      !---------------------------------------------!
119      IF( ln_icedyn ) THEN
120         zu_io(:,:) = u_ice(:,:) - ssu_m(:,:)
121         zv_io(:,:) = v_ice(:,:) - ssv_m(:,:)
122         DO jj = 2, jpjm1 
123            DO ji = fs_2, fs_jpim1
124               zfric(ji,jj) = rn_cio * ( 0.5_wp *  &
125                  &                    (  zu_io(ji,jj) * zu_io(ji,jj) + zu_io(ji-1,jj) * zu_io(ji-1,jj)   &
126                  &                     + zv_io(ji,jj) * zv_io(ji,jj) + zv_io(ji,jj-1) * zv_io(ji,jj-1) ) ) * tmask(ji,jj,1)
127               zvel(ji,jj) = 0.5_wp * SQRT( ( u_ice(ji-1,jj) + u_ice(ji,jj) ) * ( u_ice(ji-1,jj) + u_ice(ji,jj) ) + &
128                  &                         ( v_ice(ji,jj-1) + v_ice(ji,jj) ) * ( v_ice(ji,jj-1) + v_ice(ji,jj) ) )
129            END DO
130         END DO
131      ELSE      !  if no ice dynamics => transfer directly the atmospheric stress to the ocean
132         DO jj = 2, jpjm1
133            DO ji = fs_2, fs_jpim1
134               zfric(ji,jj) = r1_rau0 * SQRT( 0.5_wp *  &
135                  &                         (  utau(ji,jj) * utau(ji,jj) + utau(ji-1,jj) * utau(ji-1,jj)   &
136                  &                          + vtau(ji,jj) * vtau(ji,jj) + vtau(ji,jj-1) * vtau(ji,jj-1) ) ) * tmask(ji,jj,1)
137               zvel(ji,jj) = 0._wp
138            END DO
139         END DO
140      ENDIF
141      CALL lbc_lnk_multi( 'icethd', zfric, 'T',  1._wp, zvel, 'T', 1._wp )
142      !
143      !--------------------------------------------------------------------!
144      ! Partial computation of forcing for the thermodynamic sea ice model
145      !--------------------------------------------------------------------!
146      DO jj = 1, jpj
147         DO ji = 1, jpi
148            rswitch  = tmask(ji,jj,1) * MAX( 0._wp , SIGN( 1._wp , at_i(ji,jj) - epsi10 ) ) ! 0 if no ice
149            !
150            ! --- Energy received in the lead from atm-oce exchanges, zqld is defined everywhere (J.m-2) --- !
151            zqld =  tmask(ji,jj,1) * rdt_ice *  &
152               &    ( ( 1._wp - at_i_b(ji,jj) ) * qsr_oce(ji,jj) * frq_m(ji,jj) +  &
153               &      ( 1._wp - at_i_b(ji,jj) ) * qns_oce(ji,jj) + qemp_oce(ji,jj) )
154
155            ! --- Energy needed to bring ocean surface layer until its freezing, zqfr is defined everywhere (J.m-2) --- !
156            !     (mostly<0 but >0 if supercooling)
157            zqfr     = rau0 * rcp * e3t_m(ji,jj) * ( t_bo(ji,jj) - ( sst_m(ji,jj) + rt0 ) ) * tmask(ji,jj,1)  ! both < 0 (t_bo < sst) and > 0 (t_bo > sst)
158            zqfr_neg = MIN( zqfr , 0._wp )                                                                    ! only < 0
159            zqfr_pos = MAX( zqfr , 0._wp )                                                                    ! only > 0
160
161            ! --- Sensible ocean-to-ice heat flux (W/m2) --- !
162            !     (mostly>0 but <0 if supercooling)
163            zfric_u            = MAX( SQRT( zfric(ji,jj) ), zfric_umin ) 
164            qsb_ice_bot(ji,jj) = rswitch * rau0 * rcp * zch * zfric_u * ( ( sst_m(ji,jj) + rt0 ) - t_bo(ji,jj) )
165
166            ! upper bound for qsb_ice_bot: the heat retrieved from the ocean must be smaller than the heat necessary to reach
167            !                              the freezing point, so that we do not have SST < T_freeze
168            !                              This implies: qsb_ice_bot(ji,jj) * at_i(ji,jj) * rtdice <= - zqfr_neg
169            !                              The following formulation is ok for both normal conditions and supercooling
170            qsb_ice_bot(ji,jj) = rswitch * MIN( qsb_ice_bot(ji,jj), - zqfr_neg * r1_rdtice / MAX( at_i(ji,jj), epsi10 ) )
171
172            ! --- Energy Budget of the leads (qlead, J.m-2) --- !
173            !     qlead is the energy received from the atm. in the leads.
174            !     If warming (zqld >= 0), then the energy in the leads is used to melt ice (bottom melting) => fhld  (W/m2)
175            !     If cooling (zqld <  0), then the energy in the leads is used to grow ice in open water    => qlead (J.m-2)
176            IF( zqld >= 0._wp .AND. at_i(ji,jj) > 0._wp ) THEN
177               ! upper bound for fhld: fhld should be equal to zqld
178               !                        but we have to make sure that this heat will not make the sst drop below the freezing point
179               !                        so the max heat that can be pulled out of the ocean is zqld - qsb - zqfr_pos
180               !                        The following formulation is ok for both normal conditions and supercooling
181               fhld (ji,jj) = rswitch * MAX( 0._wp, ( zqld - zqfr_pos ) * r1_rdtice / MAX( at_i(ji,jj), epsi10 ) &  ! divided by at_i since this is (re)multiplied by a_i in icethd_dh.F90
182                  &                                 - qsb_ice_bot(ji,jj) )
183               qlead(ji,jj) = 0._wp
184            ELSE
185               fhld (ji,jj) = 0._wp
186               ! upper bound for qlead: qlead should be equal to zqld
187               !                        but before using this heat for ice formation, we suppose that the ocean cools down till the freezing point.
188               !                        The energy for this cooling down is zqfr. Also some heat will be removed from the ocean from turbulent fluxes (qsb)
189               !                        and freezing point is reached if zqfr = zqld - qsb*a/dt
190               !                        so the max heat that can be pulled out of the ocean is zqld - qsb - zqfr
191               !                        The following formulation is ok for both normal conditions and supercooling
192               qlead(ji,jj) = MIN( 0._wp , zqld - ( qsb_ice_bot(ji,jj) * at_i(ji,jj) * rdt_ice ) - zqfr )
193            ENDIF
194            !
195            ! If ice is landfast and ice concentration reaches its max
196            ! => stop ice formation in open water
197            IF(  zvel(ji,jj) <= 5.e-04_wp .AND. at_i(ji,jj) >= rn_amax_2d(ji,jj)-epsi06 )   qlead(ji,jj) = 0._wp
198            !
199            ! If the grid cell is almost fully covered by ice (no leads)
200            ! => stop ice formation in open water
201            IF( at_i(ji,jj) >= (1._wp - epsi10) )   qlead(ji,jj) = 0._wp
202            !
203            ! If ln_leadhfx is false
204            ! => do not use energy of the leads to melt sea-ice
205            IF( .NOT.ln_leadhfx )   fhld(ji,jj) = 0._wp
206            !
207         END DO
208      END DO
209     
210      ! In case we bypass open-water ice formation
211      IF( .NOT. ln_icedO )  qlead(:,:) = 0._wp
212      ! In case we bypass growing/melting from top and bottom
213      IF( .NOT. ln_icedH ) THEN
214         qsb_ice_bot(:,:) = 0._wp
215         fhld       (:,:) = 0._wp
216      ENDIF
217
218      !-------------------------------------------------------------------------------------------!
219      ! Thermodynamic computation (only on grid points covered by ice) => loop over ice categories
220      !-------------------------------------------------------------------------------------------!
221      DO jl = 1, jpl
222
223         ! select ice covered grid points
224         npti = 0 ; nptidx(:) = 0
225         DO jj = 1, jpj
226            DO ji = 1, jpi
227               IF ( a_i(ji,jj,jl) > epsi10 ) THEN     
228                  npti         = npti  + 1
229                  nptidx(npti) = (jj - 1) * jpi + ji
230               ENDIF
231            END DO
232         END DO
233
234         IF( npti > 0 ) THEN  ! If there is no ice, do nothing.
235            !                                                               
236                              CALL ice_thd_1d2d( jl, 1 )            ! --- Move to 1D arrays --- !
237            !                                                       ! --- & Change units of e_i, e_s from J/m2 to J/m3 --- !
238            !
239            s_i_new   (1:npti) = 0._wp ; dh_s_tot(1:npti) = 0._wp   ! --- some init --- !  (important to have them here)
240            dh_i_sum  (1:npti) = 0._wp ; dh_i_bom(1:npti) = 0._wp ; dh_i_itm  (1:npti) = 0._wp 
241            dh_i_sub  (1:npti) = 0._wp ; dh_i_bog(1:npti) = 0._wp
242            dh_snowice(1:npti) = 0._wp ; dh_s_mlt(1:npti) = 0._wp
243            !                                     
244                              CALL ice_thd_zdf                      ! --- Ice-Snow temperature --- !
245            !
246            IF( ln_icedH ) THEN                                     ! --- Growing/Melting --- !
247                              CALL ice_thd_dh                           ! Ice-Snow thickness   
248                              CALL ice_thd_pnd                          ! Melt ponds formation
249                              CALL ice_thd_ent( e_i_1d(1:npti,:) )      ! Ice enthalpy remapping
250            ENDIF
251                              CALL ice_thd_sal( ln_icedS )          ! --- Ice salinity --- !   
252            !
253                              CALL ice_thd_temp                     ! --- Temperature update --- !
254            !
255            IF( ln_icedH .AND. ln_virtual_itd ) &
256               &              CALL ice_thd_mono                     ! --- Extra lateral melting if virtual_itd --- !
257            !
258            IF( ln_icedA )    CALL ice_thd_da                       ! --- Lateral melting --- !
259            !
260                              CALL ice_thd_1d2d( jl, 2 )            ! --- Change units of e_i, e_s from J/m3 to J/m2 --- !
261            !                                                       ! --- & Move to 2D arrays --- !
262         ENDIF
263         !
264      END DO
265      !
266      IF( ln_icediachk )   CALL ice_cons_hsm(1, 'icethd', rdiag_v, rdiag_s, rdiag_t, rdiag_fv, rdiag_fs, rdiag_ft)
267      IF( ln_icediachk )   CALL ice_cons2D  (1, 'icethd',  diag_v,  diag_s,  diag_t,  diag_fv,  diag_fs,  diag_ft)
268      !                   
269      IF( jpl > 1  )          CALL ice_itd_rem( kt )                ! --- Transport ice between thickness categories --- !
270      !
271      IF( ln_icedO )          CALL ice_thd_do                       ! --- Frazil ice growth in leads --- !
272      !
273      ! convergence tests
274      IF( ln_zdf_chkcvg ) THEN
275         CALL iom_put( 'tice_cvgerr', ztice_cvgerr ) ; DEALLOCATE( ztice_cvgerr )
276         CALL iom_put( 'tice_cvgstp', ztice_cvgstp ) ; DEALLOCATE( ztice_cvgstp )
277      ENDIF
278      !
279      ! controls
280      IF( ln_icectl )   CALL ice_prt    (kt, iiceprt, jiceprt, 1, ' - ice thermodyn. - ') ! prints
281      IF( ln_ctl    )   CALL ice_prt3D  ('icethd')                                        ! prints
282      IF( ln_timing )   CALL timing_stop('icethd')                                        ! timing
283      !
284   END SUBROUTINE ice_thd 
285
286 
287   SUBROUTINE ice_thd_temp
288      !!-----------------------------------------------------------------------
289      !!                   ***  ROUTINE ice_thd_temp ***
290      !!                 
291      !! ** Purpose :   Computes sea ice temperature (Kelvin) from enthalpy
292      !!
293      !! ** Method  :   Formula (Bitz and Lipscomb, 1999)
294      !!-------------------------------------------------------------------
295      INTEGER  ::   ji, jk   ! dummy loop indices
296      REAL(wp) ::   ztmelts, zbbb, zccc  ! local scalar
297      !!-------------------------------------------------------------------
298      ! Recover ice temperature
299      DO jk = 1, nlay_i
300         DO ji = 1, npti
301            ztmelts       = -rTmlt * sz_i_1d(ji,jk)
302            ! Conversion q(S,T) -> T (second order equation)
303            zbbb          = ( rcp - rcpi ) * ztmelts + e_i_1d(ji,jk) * r1_rhoi - rLfus
304            zccc          = SQRT( MAX( zbbb * zbbb - 4._wp * rcpi * rLfus * ztmelts, 0._wp ) )
305            t_i_1d(ji,jk) = rt0 - ( zbbb + zccc ) * 0.5_wp * r1_rcpi
306           
307            ! mask temperature
308            rswitch       = 1._wp - MAX( 0._wp , SIGN( 1._wp , - h_i_1d(ji) ) ) 
309            t_i_1d(ji,jk) = rswitch * t_i_1d(ji,jk) + ( 1._wp - rswitch ) * rt0
310         END DO
311      END DO 
312      !
313   END SUBROUTINE ice_thd_temp
314
315
316   SUBROUTINE ice_thd_mono
317      !!-----------------------------------------------------------------------
318      !!                   ***  ROUTINE ice_thd_mono ***
319      !!                 
320      !! ** Purpose :   Lateral melting in case virtual_itd
321      !!                          ( dA = A/2h dh )
322      !!-----------------------------------------------------------------------
323      INTEGER  ::   ji                 ! dummy loop indices
324      REAL(wp) ::   zhi_bef            ! ice thickness before thermo
325      REAL(wp) ::   zdh_mel, zda_mel   ! net melting
326      REAL(wp) ::   zvi, zvs           ! ice/snow volumes
327      !!-----------------------------------------------------------------------
328      !
329      DO ji = 1, npti
330         zdh_mel = MIN( 0._wp, dh_i_itm(ji) + dh_i_sum(ji) + dh_i_bom(ji) + dh_snowice(ji) + dh_i_sub(ji) )
331         IF( zdh_mel < 0._wp .AND. a_i_1d(ji) > 0._wp )  THEN
332            zvi          = a_i_1d(ji) * h_i_1d(ji)
333            zvs          = a_i_1d(ji) * h_s_1d(ji)
334            ! lateral melting = concentration change
335            zhi_bef     = h_i_1d(ji) - zdh_mel
336            rswitch     = MAX( 0._wp , SIGN( 1._wp , zhi_bef - epsi20 ) )
337            zda_mel     = rswitch * a_i_1d(ji) * zdh_mel / ( 2._wp * MAX( zhi_bef, epsi20 ) )
338            a_i_1d(ji)  = MAX( epsi20, a_i_1d(ji) + zda_mel ) 
339            ! adjust thickness
340            h_i_1d(ji) = zvi / a_i_1d(ji)           
341            h_s_1d(ji) = zvs / a_i_1d(ji)           
342            ! retrieve total concentration
343            at_i_1d(ji) = a_i_1d(ji)
344         END IF
345      END DO
346      !
347   END SUBROUTINE ice_thd_mono
348
349
350   SUBROUTINE ice_thd_1d2d( kl, kn )
351      !!-----------------------------------------------------------------------
352      !!                   ***  ROUTINE ice_thd_1d2d ***
353      !!                 
354      !! ** Purpose :   move arrays from 1d to 2d and the reverse
355      !!-----------------------------------------------------------------------
356      INTEGER, INTENT(in) ::   kl   ! index of the ice category
357      INTEGER, INTENT(in) ::   kn   ! 1= from 2D to 1D   ;   2= from 1D to 2D
358      !
359      INTEGER ::   jk   ! dummy loop indices
360      !!-----------------------------------------------------------------------
361      !
362      SELECT CASE( kn )
363      !                    !---------------------!
364      CASE( 1 )            !==  from 2D to 1D  ==!
365         !                 !---------------------!
366         CALL tab_2d_1d( npti, nptidx(1:npti), at_i_1d(1:npti), at_i             )
367         CALL tab_2d_1d( npti, nptidx(1:npti), a_i_1d (1:npti), a_i (:,:,kl)     )
368         CALL tab_2d_1d( npti, nptidx(1:npti), h_i_1d (1:npti), h_i (:,:,kl)     )
369         CALL tab_2d_1d( npti, nptidx(1:npti), h_s_1d (1:npti), h_s (:,:,kl)     )
370         CALL tab_2d_1d( npti, nptidx(1:npti), t_su_1d(1:npti), t_su(:,:,kl)     )
371         CALL tab_2d_1d( npti, nptidx(1:npti), s_i_1d (1:npti), s_i (:,:,kl)     )
372         DO jk = 1, nlay_s
373            CALL tab_2d_1d( npti, nptidx(1:npti), t_s_1d(1:npti,jk), t_s(:,:,jk,kl)    )
374            CALL tab_2d_1d( npti, nptidx(1:npti), e_s_1d(1:npti,jk), e_s(:,:,jk,kl)    )
375         END DO
376         DO jk = 1, nlay_i
377            CALL tab_2d_1d( npti, nptidx(1:npti), t_i_1d (1:npti,jk), t_i (:,:,jk,kl)  )
378            CALL tab_2d_1d( npti, nptidx(1:npti), e_i_1d (1:npti,jk), e_i (:,:,jk,kl)  )
379            CALL tab_2d_1d( npti, nptidx(1:npti), sz_i_1d(1:npti,jk), sz_i(:,:,jk,kl)  )
380         END DO
381         CALL tab_2d_1d( npti, nptidx(1:npti), a_ip_1d     (1:npti), a_ip     (:,:,kl) )
382         CALL tab_2d_1d( npti, nptidx(1:npti), h_ip_1d     (1:npti), h_ip     (:,:,kl) )
383         CALL tab_2d_1d( npti, nptidx(1:npti), h_il_1d     (1:npti), h_il     (:,:,kl) )
384         !
385         CALL tab_2d_1d( npti, nptidx(1:npti), qprec_ice_1d  (1:npti), qprec_ice            )
386         CALL tab_2d_1d( npti, nptidx(1:npti), qsr_ice_1d    (1:npti), qsr_ice (:,:,kl)     )
387         CALL tab_2d_1d( npti, nptidx(1:npti), qns_ice_1d    (1:npti), qns_ice (:,:,kl)     )
388         CALL tab_2d_1d( npti, nptidx(1:npti), evap_ice_1d   (1:npti), evap_ice(:,:,kl)     )
389         CALL tab_2d_1d( npti, nptidx(1:npti), dqns_ice_1d   (1:npti), dqns_ice(:,:,kl)     )
390         CALL tab_2d_1d( npti, nptidx(1:npti), t_bo_1d       (1:npti), t_bo                 )
391         CALL tab_2d_1d( npti, nptidx(1:npti), sprecip_1d    (1:npti), sprecip              ) 
392         CALL tab_2d_1d( npti, nptidx(1:npti), qsb_ice_bot_1d(1:npti), qsb_ice_bot          )
393         CALL tab_2d_1d( npti, nptidx(1:npti), fhld_1d       (1:npti), fhld                 )
394         
395         CALL tab_2d_1d( npti, nptidx(1:npti), qml_ice_1d    (1:npti), qml_ice    (:,:,kl) )
396         CALL tab_2d_1d( npti, nptidx(1:npti), qcn_ice_1d    (1:npti), qcn_ice    (:,:,kl) )
397         CALL tab_2d_1d( npti, nptidx(1:npti), qtr_ice_top_1d(1:npti), qtr_ice_top(:,:,kl) )
398         !
399         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_snw_sni_1d(1:npti), wfx_snw_sni   )
400         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_snw_sum_1d(1:npti), wfx_snw_sum   )
401         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_sub_1d    (1:npti), wfx_sub       )
402         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_snw_sub_1d(1:npti), wfx_snw_sub   )
403         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_ice_sub_1d(1:npti), wfx_ice_sub   )
404         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_err_sub_1d(1:npti), wfx_err_sub   )
405         !
406         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_bog_1d (1:npti), wfx_bog          )
407         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_bom_1d (1:npti), wfx_bom          )
408         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_sum_1d (1:npti), wfx_sum          )
409         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_sni_1d (1:npti), wfx_sni          )
410         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_res_1d (1:npti), wfx_res          )
411         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_spr_1d (1:npti), wfx_spr          )
412         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_lam_1d (1:npti), wfx_lam          )
413         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_pnd_1d (1:npti), wfx_pnd          )
414         !
415         CALL tab_2d_1d( npti, nptidx(1:npti), sfx_bog_1d (1:npti), sfx_bog          )
416         CALL tab_2d_1d( npti, nptidx(1:npti), sfx_bom_1d (1:npti), sfx_bom          )
417         CALL tab_2d_1d( npti, nptidx(1:npti), sfx_sum_1d (1:npti), sfx_sum          )
418         CALL tab_2d_1d( npti, nptidx(1:npti), sfx_sni_1d (1:npti), sfx_sni          )
419         CALL tab_2d_1d( npti, nptidx(1:npti), sfx_bri_1d (1:npti), sfx_bri          )
420         CALL tab_2d_1d( npti, nptidx(1:npti), sfx_res_1d (1:npti), sfx_res          )
421         CALL tab_2d_1d( npti, nptidx(1:npti), sfx_sub_1d (1:npti), sfx_sub          )
422         CALL tab_2d_1d( npti, nptidx(1:npti), sfx_lam_1d (1:npti), sfx_lam          )
423         !
424         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_thd_1d    (1:npti), hfx_thd       )
425         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_spr_1d    (1:npti), hfx_spr       )
426         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_sum_1d    (1:npti), hfx_sum       )
427         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_bom_1d    (1:npti), hfx_bom       )
428         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_bog_1d    (1:npti), hfx_bog       )
429         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_dif_1d    (1:npti), hfx_dif       )
430         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_opw_1d    (1:npti), hfx_opw       )
431         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_snw_1d    (1:npti), hfx_snw       )
432         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_sub_1d    (1:npti), hfx_sub       )
433         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_res_1d    (1:npti), hfx_res       )
434         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_err_dif_1d(1:npti), hfx_err_dif   )
435         !
436         ! ocean surface fields
437         CALL tab_2d_1d( npti, nptidx(1:npti), sst_1d(1:npti), sst_m )
438         CALL tab_2d_1d( npti, nptidx(1:npti), sss_1d(1:npti), sss_m )
439         !
440         ! to update ice age
441         CALL tab_2d_1d( npti, nptidx(1:npti), o_i_1d (1:npti), o_i (:,:,kl) )
442         CALL tab_2d_1d( npti, nptidx(1:npti), oa_i_1d(1:npti), oa_i(:,:,kl) )
443         !
444         ! --- Change units of e_i, e_s from J/m2 to J/m3 --- !
445         DO jk = 1, nlay_i
446            WHERE( h_i_1d(1:npti)>0._wp ) e_i_1d(1:npti,jk) = e_i_1d(1:npti,jk) / (h_i_1d(1:npti) * a_i_1d(1:npti)) * nlay_i
447         END DO
448         DO jk = 1, nlay_s
449            WHERE( h_s_1d(1:npti)>0._wp ) e_s_1d(1:npti,jk) = e_s_1d(1:npti,jk) / (h_s_1d(1:npti) * a_i_1d(1:npti)) * nlay_s
450         END DO
451         !
452         !                 !---------------------!
453      CASE( 2 )            !==  from 1D to 2D  ==!
454         !                 !---------------------!
455         ! --- Change units of e_i, e_s from J/m3 to J/m2 --- !
456         DO jk = 1, nlay_i
457            e_i_1d(1:npti,jk) = e_i_1d(1:npti,jk) * h_i_1d(1:npti) * a_i_1d(1:npti) * r1_nlay_i
458         END DO
459         DO jk = 1, nlay_s
460            e_s_1d(1:npti,jk) = e_s_1d(1:npti,jk) * h_s_1d(1:npti) * a_i_1d(1:npti) * r1_nlay_s
461         END DO
462         !
463         ! Change thickness to volume (replaces routine ice_var_eqv2glo)
464         v_i_1d (1:npti) = h_i_1d (1:npti) * a_i_1d (1:npti)
465         v_s_1d (1:npti) = h_s_1d (1:npti) * a_i_1d (1:npti)
466         sv_i_1d(1:npti) = s_i_1d (1:npti) * v_i_1d (1:npti)
467         v_ip_1d(1:npti) = h_ip_1d(1:npti) * a_ip_1d(1:npti)
468         v_il_1d(1:npti) = h_il_1d(1:npti) * a_ip_1d(1:npti)
469         oa_i_1d(1:npti) = o_i_1d (1:npti) * a_i_1d (1:npti)
470         
471         CALL tab_1d_2d( npti, nptidx(1:npti), at_i_1d(1:npti), at_i             )
472         CALL tab_1d_2d( npti, nptidx(1:npti), a_i_1d (1:npti), a_i (:,:,kl)     )
473         CALL tab_1d_2d( npti, nptidx(1:npti), h_i_1d (1:npti), h_i (:,:,kl)     )
474         CALL tab_1d_2d( npti, nptidx(1:npti), h_s_1d (1:npti), h_s (:,:,kl)     )
475         CALL tab_1d_2d( npti, nptidx(1:npti), t_su_1d(1:npti), t_su(:,:,kl)     )
476         CALL tab_1d_2d( npti, nptidx(1:npti), s_i_1d (1:npti), s_i (:,:,kl)     )
477         DO jk = 1, nlay_s
478            CALL tab_1d_2d( npti, nptidx(1:npti), t_s_1d(1:npti,jk), t_s(:,:,jk,kl)    )
479            CALL tab_1d_2d( npti, nptidx(1:npti), e_s_1d(1:npti,jk), e_s(:,:,jk,kl)    )
480         END DO
481         DO jk = 1, nlay_i
482            CALL tab_1d_2d( npti, nptidx(1:npti), t_i_1d (1:npti,jk), t_i (:,:,jk,kl)  )
483            CALL tab_1d_2d( npti, nptidx(1:npti), e_i_1d (1:npti,jk), e_i (:,:,jk,kl)  )
484            CALL tab_1d_2d( npti, nptidx(1:npti), sz_i_1d(1:npti,jk), sz_i(:,:,jk,kl)  )
485         END DO
486         CALL tab_1d_2d( npti, nptidx(1:npti), a_ip_1d     (1:npti), a_ip     (:,:,kl) )
487         CALL tab_1d_2d( npti, nptidx(1:npti), h_ip_1d     (1:npti), h_ip     (:,:,kl) )
488         CALL tab_1d_2d( npti, nptidx(1:npti), h_il_1d     (1:npti), h_il     (:,:,kl) )
489         !
490         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_snw_sni_1d(1:npti), wfx_snw_sni )
491         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_snw_sum_1d(1:npti), wfx_snw_sum )
492         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_sub_1d    (1:npti), wfx_sub     )
493         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_snw_sub_1d(1:npti), wfx_snw_sub )
494         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_ice_sub_1d(1:npti), wfx_ice_sub )
495         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_err_sub_1d(1:npti), wfx_err_sub )
496         !
497         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_bog_1d (1:npti), wfx_bog        )
498         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_bom_1d (1:npti), wfx_bom        )
499         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_sum_1d (1:npti), wfx_sum        )
500         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_sni_1d (1:npti), wfx_sni        )
501         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_res_1d (1:npti), wfx_res        )
502         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_spr_1d (1:npti), wfx_spr        )
503         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_lam_1d (1:npti), wfx_lam        )
504         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_pnd_1d (1:npti), wfx_pnd        )
505         !
506         CALL tab_1d_2d( npti, nptidx(1:npti), sfx_bog_1d (1:npti), sfx_bog        )
507         CALL tab_1d_2d( npti, nptidx(1:npti), sfx_bom_1d (1:npti), sfx_bom        )
508         CALL tab_1d_2d( npti, nptidx(1:npti), sfx_sum_1d (1:npti), sfx_sum        )
509         CALL tab_1d_2d( npti, nptidx(1:npti), sfx_sni_1d (1:npti), sfx_sni        )
510         CALL tab_1d_2d( npti, nptidx(1:npti), sfx_bri_1d (1:npti), sfx_bri        )
511         CALL tab_1d_2d( npti, nptidx(1:npti), sfx_res_1d (1:npti), sfx_res        )
512         CALL tab_1d_2d( npti, nptidx(1:npti), sfx_sub_1d (1:npti), sfx_sub        )
513         CALL tab_1d_2d( npti, nptidx(1:npti), sfx_lam_1d (1:npti), sfx_lam        )
514         !
515         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_thd_1d    (1:npti), hfx_thd     )
516         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_spr_1d    (1:npti), hfx_spr     )
517         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_sum_1d    (1:npti), hfx_sum     )
518         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_bom_1d    (1:npti), hfx_bom     )
519         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_bog_1d    (1:npti), hfx_bog     )
520         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_dif_1d    (1:npti), hfx_dif     )
521         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_opw_1d    (1:npti), hfx_opw     )
522         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_snw_1d    (1:npti), hfx_snw     )
523         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_sub_1d    (1:npti), hfx_sub     )
524         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_res_1d    (1:npti), hfx_res     )
525         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_err_dif_1d(1:npti), hfx_err_dif )
526         !
527         CALL tab_1d_2d( npti, nptidx(1:npti), qns_ice_1d    (1:npti), qns_ice    (:,:,kl) )
528         CALL tab_1d_2d( npti, nptidx(1:npti), qtr_ice_bot_1d(1:npti), qtr_ice_bot(:,:,kl) )
529         ! effective conductivity and 1st layer temperature (ln_cndflx=T)
530         CALL tab_1d_2d( npti, nptidx(1:npti), cnd_ice_1d(1:npti), cnd_ice(:,:,kl) )
531         CALL tab_1d_2d( npti, nptidx(1:npti), t1_ice_1d (1:npti), t1_ice (:,:,kl) )
532         ! SIMIP diagnostics         
533         CALL tab_1d_2d( npti, nptidx(1:npti), t_si_1d       (1:npti), t_si       (:,:,kl) )
534         CALL tab_1d_2d( npti, nptidx(1:npti), qcn_ice_bot_1d(1:npti), qcn_ice_bot(:,:,kl) )
535         CALL tab_1d_2d( npti, nptidx(1:npti), qcn_ice_top_1d(1:npti), qcn_ice_top(:,:,kl) )
536         ! extensive variables
537         CALL tab_1d_2d( npti, nptidx(1:npti), v_i_1d (1:npti), v_i (:,:,kl) )
538         CALL tab_1d_2d( npti, nptidx(1:npti), v_s_1d (1:npti), v_s (:,:,kl) )
539         CALL tab_1d_2d( npti, nptidx(1:npti), sv_i_1d(1:npti), sv_i(:,:,kl) )
540         CALL tab_1d_2d( npti, nptidx(1:npti), v_ip_1d(1:npti), v_ip(:,:,kl) )
541         CALL tab_1d_2d( npti, nptidx(1:npti), v_il_1d(1:npti), v_il(:,:,kl) )
542         CALL tab_1d_2d( npti, nptidx(1:npti), oa_i_1d(1:npti), oa_i(:,:,kl) )
543         ! check convergence of heat diffusion scheme
544         IF( ln_zdf_chkcvg ) THEN
545            CALL tab_1d_2d( npti, nptidx(1:npti), tice_cvgerr_1d(1:npti), ztice_cvgerr(:,:,kl) )
546            CALL tab_1d_2d( npti, nptidx(1:npti), tice_cvgstp_1d(1:npti), ztice_cvgstp(:,:,kl) )
547         ENDIF
548         !
549      END SELECT
550      !
551   END SUBROUTINE ice_thd_1d2d
552
553
554   SUBROUTINE ice_thd_init
555      !!-------------------------------------------------------------------
556      !!                   ***  ROUTINE ice_thd_init ***
557      !!                 
558      !! ** Purpose :   Physical constants and parameters associated with
559      !!                ice thermodynamics
560      !!
561      !! ** Method  :   Read the namthd namelist and check the parameters
562      !!                called at the first timestep (nit000)
563      !!
564      !! ** input   :   Namelist namthd
565      !!-------------------------------------------------------------------
566      INTEGER  ::   ios   ! Local integer output status for namelist read
567      !!
568      NAMELIST/namthd/ ln_icedH, ln_icedA, ln_icedO, ln_icedS, ln_leadhfx
569      !!-------------------------------------------------------------------
570      !
571      REWIND( numnam_ice_ref )              ! Namelist namthd in reference namelist : Ice thermodynamics
572      READ  ( numnam_ice_ref, namthd, IOSTAT = ios, ERR = 901)
573901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namthd in reference namelist' )
574      REWIND( numnam_ice_cfg )              ! Namelist namthd in configuration namelist : Ice thermodynamics
575      READ  ( numnam_ice_cfg, namthd, IOSTAT = ios, ERR = 902 )
576902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namthd in configuration namelist' )
577      IF(lwm) WRITE( numoni, namthd )
578      !
579      IF(lwp) THEN                          ! control print
580         WRITE(numout,*)
581         WRITE(numout,*) 'ice_thd_init: Ice Thermodynamics'
582         WRITE(numout,*) '~~~~~~~~~~~~'
583         WRITE(numout,*) '   Namelist namthd:'
584         WRITE(numout,*) '      activate ice thick change from top/bot (T) or not (F)                ln_icedH   = ', ln_icedH
585         WRITE(numout,*) '      activate lateral melting (T) or not (F)                              ln_icedA   = ', ln_icedA
586         WRITE(numout,*) '      activate ice growth in open-water (T) or not (F)                     ln_icedO   = ', ln_icedO
587         WRITE(numout,*) '      activate gravity drainage and flushing (T) or not (F)                ln_icedS   = ', ln_icedS
588         WRITE(numout,*) '      heat in the leads is used to melt sea-ice before warming the ocean   ln_leadhfx = ', ln_leadhfx
589     ENDIF
590      !
591                       CALL ice_thd_zdf_init   ! set ice heat diffusion parameters
592      IF( ln_icedA )   CALL ice_thd_da_init    ! set ice lateral melting parameters
593      IF( ln_icedO )   CALL ice_thd_do_init    ! set ice growth in open water parameters
594                       CALL ice_thd_sal_init   ! set ice salinity parameters
595                       CALL ice_thd_pnd_init   ! set melt ponds parameters
596      !
597   END SUBROUTINE ice_thd_init
598
599#else
600   !!----------------------------------------------------------------------
601   !!   Default option         Dummy module          NO  SI3 sea-ice model
602   !!----------------------------------------------------------------------
603#endif
604
605   !!======================================================================
606END MODULE icethd
Note: See TracBrowser for help on using the repository browser.