source: NEMO/trunk/src/OCE/IOM/iom_nf90.F90

Last change on this file was 13286, checked in by smasson, 5 months ago

trunk: merge extra halos branch in trunk, see #2366

  • Property svn:keywords set to Id
File size: 44.0 KB
Line 
1MODULE iom_nf90
2   !!======================================================================
3   !!                    ***  MODULE  iom_nf90 ***
4   !! Input/Output manager :  Library to read input files with NF90 (only fliocom module)
5   !!======================================================================
6   !! History :  9.0  ! 05 12  (J. Belier) Original code
7   !!            9.0  ! 06 02  (S. Masson) Adaptation to NEMO
8   !!             "   ! 07 07  (D. Storkey) Changes to iom_nf90_gettime
9   !!            3.6  ! 2015-15  (J. Harle) Added procedure to read REAL attributes
10   !!            4.0  ! 2017-11 (M. Andrejczuk) Extend IOM interface to write any 3D fields
11   !!----------------------------------------------------------------------
12
13   !!----------------------------------------------------------------------
14   !!   iom_open       : open a file read only
15   !!   iom_close      : close a file or all files opened by iom
16   !!   iom_get        : read a field (interfaced to several routines)
17   !!   iom_varid      : get the id of a variable in a file
18   !!   iom_rstput     : write a field in a restart file (interfaced to several routines)
19   !!----------------------------------------------------------------------
20   USE dom_oce         ! ocean space and time domain
21   USE sbc_oce, ONLY: ght_abl ! abl vertical level number and height
22   USE lbclnk          ! lateal boundary condition / mpp exchanges
23   USE iom_def         ! iom variables definitions
24   USE netcdf          ! NetCDF library
25   USE in_out_manager  ! I/O manager
26   USE lib_mpp         ! MPP library
27
28   IMPLICIT NONE
29   PRIVATE
30
31   PUBLIC iom_nf90_open  , iom_nf90_close, iom_nf90_varid, iom_nf90_get, iom_nf90_rstput
32   PUBLIC iom_nf90_chkatt, iom_nf90_getatt, iom_nf90_putatt
33
34   INTERFACE iom_nf90_get
35      MODULE PROCEDURE iom_nf90_g0d_sp                   
36      MODULE PROCEDURE iom_nf90_g0d_dp, iom_nf90_g123d_dp
37   END INTERFACE
38   INTERFACE iom_nf90_rstput
39      MODULE PROCEDURE iom_nf90_rp0123d_dp
40   END INTERFACE
41
42   !!----------------------------------------------------------------------
43   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
44   !! $Id$
45   !! Software governed by the CeCILL license (see ./LICENSE)
46   !!----------------------------------------------------------------------
47CONTAINS
48
49   SUBROUTINE iom_nf90_open( cdname, kiomid, ldwrt, ldok, kdlev, cdcomp )
50      !!---------------------------------------------------------------------
51      !!                   ***  SUBROUTINE  iom_open  ***
52      !!
53      !! ** Purpose : open an input file with NF90
54      !!---------------------------------------------------------------------
55      CHARACTER(len=*)       , INTENT(inout)           ::   cdname      ! File name
56      INTEGER                , INTENT(  out)           ::   kiomid      ! nf90 identifier of the opened file
57      LOGICAL                , INTENT(in   )           ::   ldwrt       ! read or write the file?
58      LOGICAL                , INTENT(in   )           ::   ldok        ! check the existence
59      INTEGER                , INTENT(in   ), OPTIONAL ::   kdlev       ! size of the ice/abl third dimension
60      CHARACTER(len=3)       , INTENT(in   ), OPTIONAL ::   cdcomp      ! name of component calling iom_nf90_open
61
62      CHARACTER(LEN=256) ::   clinfo           ! info character
63      CHARACTER(LEN=256) ::   cltmp            ! temporary character
64      CHARACTER(LEN=12 ) ::   clfmt            ! writing format
65      CHARACTER(LEN=3  ) ::   clcomp           ! name of component calling iom_nf90_open
66      INTEGER            ::   idg              ! number of digits
67      INTEGER            ::   iln              ! lengths of character
68      INTEGER            ::   istop            ! temporary storage of nstop
69      INTEGER            ::   if90id           ! nf90 identifier of the opened file
70      INTEGER            ::   idmy             ! dummy variable
71      INTEGER            ::   jl               ! loop variable
72      INTEGER            ::   ichunk           ! temporary storage of nn_chunksz
73      INTEGER            ::   imode            ! creation mode flag: NF90_CLOBBER or NF90_NOCLOBBER or NF90_HDF5
74      INTEGER            ::   ihdf5            ! local variable for retrieval of value for NF90_HDF5
75      LOGICAL            ::   llclobber        ! local definition of ln_clobber
76      !---------------------------------------------------------------------
77      !
78      clinfo = '                    iom_nf90_open ~~~  '
79      istop = nstop     ! store the actual value of nstop
80      !
81      !                 !number of vertical levels
82      IF( PRESENT(cdcomp) )   THEN
83         IF( .NOT. PRESENT(kdlev) ) CALL ctl_stop( 'iom_nf90_open: cdcomp and kdlev must both be present' )
84         clcomp = cdcomp    ! use input value
85      ELSE
86         clcomp = 'OCE'     ! by default
87      ENDIF
88      !
89      IF( nn_chunksz > 0 ) THEN   ;   ichunk = nn_chunksz
90      ELSE                        ;   ichunk = NF90_SIZEHINT_DEFAULT
91      ENDIF
92      !
93      llclobber = ldwrt .AND. ln_clobber
94      IF( ldok .AND. .NOT. llclobber ) THEN      !==  Open existing file ==!
95         !                                       !=========================!
96         IF( ldwrt ) THEN  ! ... in write mode
97            IF(lwp) WRITE(numout,*) TRIM(clinfo)//' open existing file: '//TRIM(cdname)//' in WRITE mode'
98            IF( snc4set%luse ) THEN
99               CALL iom_nf90_check(NF90_OPEN( TRIM(cdname), NF90_WRITE  , if90id ), clinfo)
100            ELSE
101               CALL iom_nf90_check(NF90_OPEN( TRIM(cdname), NF90_WRITE  , if90id, chunksize = ichunk ), clinfo)
102            ENDIF
103            CALL iom_nf90_check(NF90_SET_FILL( if90id, NF90_NOFILL, idmy                          ), clinfo)
104         ELSE              ! ... in read mode
105            IF(lwp) WRITE(numout,*) TRIM(clinfo)//' open existing file: '//TRIM(cdname)//' in READ mode'
106            CALL iom_nf90_check(NF90_OPEN( TRIM(cdname), NF90_NOWRITE, if90id, chunksize = ichunk ), clinfo)
107         ENDIF
108      ELSE                                       !== the file doesn't exist ==!   (or we overwrite it)
109         !                                       !============================!
110         iln = INDEX( cdname, '.nc' )
111         IF( ldwrt ) THEN              !* the file should be open in write mode so we create it...
112            IF( jpnij > 1 ) THEN
113               idg = MAX( INT(LOG10(REAL(MAX(1,jpnij-1),wp))) + 1, 4 )          ! how many digits to we need to write? min=4, max=9
114               WRITE(clfmt, "('(a,a,i', i1, '.', i1, ',a)')") idg, idg          ! '(a,a,ix.x,a)'
115               WRITE(cltmp,clfmt) cdname(1:iln-1), '_', narea-1, '.nc'
116               cdname = TRIM(cltmp)
117            ENDIF
118            IF(lwp) WRITE(numout,*) TRIM(clinfo)//' create new file: '//TRIM(cdname)//' in WRITE mode'
119
120            IF( llclobber ) THEN   ;   imode = IOR( NF90_64BIT_OFFSET, NF90_CLOBBER   )
121            ELSE                   ;   imode = IOR( NF90_64BIT_OFFSET, NF90_NOCLOBBER ) 
122            ENDIF
123            IF( snc4set%luse ) THEN
124               IF(lwp) WRITE(numout,*) TRIM(clinfo)//' creating file: '//TRIM(cdname)//' in hdf5 (netcdf4) mode'
125               CALL GET_NF90_SYMBOL("NF90_HDF5", ihdf5)
126               IF( llclobber ) THEN   ;   imode = IOR(ihdf5, NF90_CLOBBER)
127               ELSE                   ;   imode = IOR(ihdf5, NF90_NOCLOBBER)
128               ENDIF
129               CALL iom_nf90_check(NF90_CREATE( TRIM(cdname), imode, if90id ), clinfo)
130            ELSE
131               CALL iom_nf90_check(NF90_CREATE( TRIM(cdname), imode, if90id, chunksize = ichunk ), clinfo)
132            ENDIF
133            CALL iom_nf90_check(NF90_SET_FILL( if90id, NF90_NOFILL,                   idmy ), clinfo)
134            ! define dimensions
135                               CALL iom_nf90_check(NF90_DEF_DIM( if90id,            'x',  Ni_0, idmy ), clinfo)
136                               CALL iom_nf90_check(NF90_DEF_DIM( if90id,            'y',  Nj_0, idmy ), clinfo)
137            SELECT CASE (clcomp)
138            CASE ('OCE')   ;   CALL iom_nf90_check(NF90_DEF_DIM( if90id,      'nav_lev',   jpk, idmy ), clinfo)
139            CASE ('ICE')   ;   CALL iom_nf90_check(NF90_DEF_DIM( if90id,       'numcat', kdlev, idmy ), clinfo)
140            CASE ('ABL')   ;   CALL iom_nf90_check(NF90_DEF_DIM( if90id,      'nav_lev', kdlev, idmy ), clinfo)
141            CASE ('SED')   ;   CALL iom_nf90_check(NF90_DEF_DIM( if90id,       'numsed', kdlev, idmy ), clinfo)
142            CASE DEFAULT   ;   CALL ctl_stop( 'iom_nf90_open unknown component type' )
143            END SELECT
144                               CALL iom_nf90_check(NF90_DEF_DIM( if90id, 'time_counter', NF90_UNLIMITED, idmy ), clinfo)
145            ! global attributes
146            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_number_total'   , jpnij                        ), clinfo)
147            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_number'         , narea-1                      ), clinfo)
148            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_dimensions_ids' , (/ 1        , 2           /) ), clinfo)
149            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_size_global'    , (/ Ni0glo    , Nj0glo     /) ), clinfo)
150            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_size_local'     , (/ Ni_0      , Nj_0       /) ), clinfo)
151            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_position_first' , (/ mig0(Nis0), mjg0(Njs0) /) ), clinfo)
152            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_position_last'  , (/ mig0(Nie0), mjg0(Nje0) /) ), clinfo)
153            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_halo_size_start', (/ 0         , 0          /) ), clinfo)
154            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_halo_size_end'  , (/ 0         , 0          /) ), clinfo)
155            CALL iom_nf90_check(NF90_PUT_ATT( if90id, NF90_GLOBAL, 'DOMAIN_type'           , 'BOX'                        ), clinfo)
156         ELSE                          !* the file should be open for read mode so it must exist...
157            CALL ctl_stop( TRIM(clinfo), ' should be impossible case...' )
158         ENDIF
159      ENDIF
160      !
161      ! start to fill file informations
162      ! =============
163      IF( istop == nstop ) THEN   ! no error within this routine
164!does not work with some compilers         kiomid = MINLOC(iom_file(:)%nfid, dim = 1)
165         kiomid = 0
166         DO jl = jpmax_files, 1, -1
167            IF( iom_file(jl)%nfid == 0 )   kiomid = jl
168         ENDDO
169         iom_file(kiomid)%name   = TRIM(cdname)
170         iom_file(kiomid)%comp   = clcomp
171         iom_file(kiomid)%nfid   = if90id
172         iom_file(kiomid)%nvars  = 0
173         iom_file(kiomid)%irec   = -1   ! useless for NetCDF files, used to know if the file is in define mode
174         CALL iom_nf90_check(NF90_Inquire(if90id, unlimitedDimId = iom_file(kiomid)%iduld), clinfo)
175         IF( iom_file(kiomid)%iduld .GE. 0 ) THEN
176            CALL iom_nf90_check(NF90_Inquire_Dimension(if90id, iom_file(kiomid)%iduld,    & 
177               &                                       name = iom_file(kiomid)%uldname,   &
178               &                                       len  = iom_file(kiomid)%lenuld ), clinfo )
179         ENDIF
180         IF(lwp) WRITE(numout,*) '                   ---> '//TRIM(cdname)//' OK'
181      ELSE
182         kiomid = 0               ! return error flag
183      ENDIF
184      !
185   END SUBROUTINE iom_nf90_open
186
187
188   SUBROUTINE iom_nf90_close( kiomid )
189      !!--------------------------------------------------------------------
190      !!                   ***  SUBROUTINE  iom_nf90_close  ***
191      !!
192      !! ** Purpose : close an input file with NF90
193      !!--------------------------------------------------------------------
194      INTEGER, INTENT(in) ::   kiomid   ! iom identifier of the file to be closed
195      CHARACTER(LEN=100)  ::   clinfo   ! info character
196      !---------------------------------------------------------------------
197      clinfo = '      iom_nf90_close    , file: '//TRIM(iom_file(kiomid)%name)
198      CALL iom_nf90_check(NF90_CLOSE(iom_file(kiomid)%nfid), clinfo)
199   END SUBROUTINE iom_nf90_close
200
201
202   FUNCTION iom_nf90_varid ( kiomid, cdvar, kiv, kdimsz, kndims, lduld ) 
203      !!-----------------------------------------------------------------------
204      !!                  ***  FUNCTION  iom_varid  ***
205      !!
206      !! ** Purpose : get the id of a variable in a file with NF90
207      !!-----------------------------------------------------------------------
208      INTEGER              , INTENT(in   )           ::   kiomid   ! file Identifier
209      CHARACTER(len=*)     , INTENT(in   )           ::   cdvar    ! name of the variable
210      INTEGER              , INTENT(in   )           ::   kiv   !
211      INTEGER, DIMENSION(:), INTENT(  out), OPTIONAL ::   kdimsz   ! size of each dimension
212      INTEGER              , INTENT(  out), OPTIONAL ::   kndims   ! number of dimensions
213      LOGICAL              , INTENT(  out), OPTIONAL ::   lduld    ! true if the last dimension is unlimited (time)
214      !
215      INTEGER                        ::   iom_nf90_varid   ! iom variable Id
216      INTEGER                        ::   if90id           ! nf90 file identifier
217      INTEGER                        ::   ji               ! dummy loop index
218      INTEGER                        ::   ivarid           ! NetCDF  variable Id
219      INTEGER                        ::   i_nvd            ! number of dimension of the variable
220      INTEGER, DIMENSION(jpmax_dims) ::   idimid           ! dimension ids of the variable
221      LOGICAL                        ::   llok             ! ok  test
222      CHARACTER(LEN=100)             ::   clinfo           ! info character
223      !!-----------------------------------------------------------------------
224      clinfo = '          iom_nf90_varid, file: '//TRIM(iom_file(kiomid)%name)//', var: '//TRIM(cdvar)
225      iom_nf90_varid = 0                    ! default definition
226      IF( PRESENT(kdimsz) ) kdimsz(:) = 0   ! default definition
227      if90id = iom_file(kiomid)%nfid        ! get back NetCDF file id
228      !
229      llok = NF90_INQ_VARID( if90id, TRIM(cdvar), ivarid ) == nf90_noerr   ! does the variable exist in the file
230      IF( llok ) THEN
231         iom_nf90_varid = kiv
232         iom_file(kiomid)%nvars       = kiv
233         iom_file(kiomid)%nvid(kiv)   = ivarid
234         iom_file(kiomid)%cn_var(kiv) = TRIM(cdvar)
235         CALL iom_nf90_check(NF90_Inquire_Variable(if90id, ivarid, ndims = i_nvd), clinfo)   ! number of dimensions
236         iom_file(kiomid)%ndims(kiv)  = i_nvd
237         CALL iom_nf90_check(NF90_Inquire_Variable(if90id, ivarid, dimids = idimid(1:i_nvd)), clinfo)   ! dimensions ids
238         iom_file(kiomid)%luld(kiv) = .FALSE.   ! default value
239         iom_file(kiomid)%dimsz(:,kiv) = 0      ! reset dimsz in case previously used
240         DO ji = 1, i_nvd                       ! dimensions size
241            CALL iom_nf90_check(NF90_Inquire_Dimension(if90id, idimid(ji), len = iom_file(kiomid)%dimsz(ji,kiv)), clinfo)   
242            IF( idimid(ji) == iom_file(kiomid)%iduld ) iom_file(kiomid)%luld(kiv) = .TRUE.   ! unlimited dimension?
243         END DO
244         !---------- Deal with scale_factor and add_offset
245         llok = NF90_Inquire_attribute(if90id, ivarid, 'scale_factor') == nf90_noerr
246         IF( llok) THEN
247            CALL iom_nf90_check(NF90_GET_ATT(if90id, ivarid, 'scale_factor', iom_file(kiomid)%scf(kiv)), clinfo)
248         ELSE
249            iom_file(kiomid)%scf(kiv) = 1.
250         END IF
251         llok = NF90_Inquire_attribute(if90id, ivarid, 'add_offset') == nf90_noerr
252         IF( llok ) THEN
253            CALL iom_nf90_check(NF90_GET_ATT(if90id, ivarid, 'add_offset', iom_file(kiomid)%ofs(kiv)), clinfo)
254         ELSE
255            iom_file(kiomid)%ofs(kiv) = 0.
256         END IF
257         ! return the simension size
258         IF( PRESENT(kdimsz) ) THEN
259            IF( i_nvd <= SIZE(kdimsz) ) THEN
260               kdimsz(1:i_nvd) = iom_file(kiomid)%dimsz(1:i_nvd,kiv)
261            ELSE
262               WRITE(ctmp1,*) i_nvd, SIZE(kdimsz)
263               CALL ctl_stop( TRIM(clinfo), 'error in kdimsz size'//TRIM(ctmp1) )
264            ENDIF
265         ENDIF
266         IF( PRESENT(kndims) )  kndims = iom_file(kiomid)%ndims(kiv)
267         IF( PRESENT( lduld) )  lduld  = iom_file(kiomid)%luld(kiv)
268      ELSE 
269         iom_nf90_varid = -1   !   variable not found, return error code: -1
270      ENDIF
271      !
272   END FUNCTION iom_nf90_varid
273
274   !!----------------------------------------------------------------------
275   !!                   INTERFACE iom_nf90_get
276   !!----------------------------------------------------------------------
277
278   SUBROUTINE iom_nf90_g0d_sp( kiomid, kvid, pvar, kstart )
279      !!-----------------------------------------------------------------------
280      !!                  ***  ROUTINE  iom_nf90_g0d  ***
281      !!
282      !! ** Purpose : read a scalar with NF90
283      !!-----------------------------------------------------------------------
284      INTEGER ,               INTENT(in   )            ::   kiomid   ! Identifier of the file
285      INTEGER ,               INTENT(in   )            ::   kvid     ! variable id
286      REAL(sp),               INTENT(  out)            ::   pvar     ! read field
287      INTEGER , DIMENSION(1), INTENT(in   ), OPTIONAL  ::   kstart   ! start position of the reading in each axis
288      !
289      CHARACTER(LEN=100)      ::   clinfo   ! info character
290      !---------------------------------------------------------------------
291      clinfo = 'iom_nf90_g0d , file: '//TRIM(iom_file(kiomid)%name)//', var: '//TRIM(iom_file(kiomid)%cn_var(kvid))
292      CALL iom_nf90_check(NF90_GET_VAR(iom_file(kiomid)%nfid, iom_file(kiomid)%nvid(kvid), pvar, start = kstart), clinfo )
293   END SUBROUTINE iom_nf90_g0d_sp
294
295   SUBROUTINE iom_nf90_g0d_dp( kiomid, kvid, pvar, kstart )
296      !!-----------------------------------------------------------------------
297      !!                  ***  ROUTINE  iom_nf90_g0d  ***
298      !!
299      !! ** Purpose : read a scalar with NF90
300      !!-----------------------------------------------------------------------
301      INTEGER ,               INTENT(in   )            ::   kiomid   ! Identifier of the file
302      INTEGER ,               INTENT(in   )            ::   kvid     ! variable id
303      REAL(dp),               INTENT(  out)            ::   pvar     ! read field
304      INTEGER , DIMENSION(1), INTENT(in   ), OPTIONAL  ::   kstart   ! start position of the reading in each axis
305      !
306      CHARACTER(LEN=100)      ::   clinfo   ! info character
307      !---------------------------------------------------------------------
308      clinfo = 'iom_nf90_g0d , file: '//TRIM(iom_file(kiomid)%name)//', var: '//TRIM(iom_file(kiomid)%cn_var(kvid))
309      CALL iom_nf90_check(NF90_GET_VAR(iom_file(kiomid)%nfid, iom_file(kiomid)%nvid(kvid), pvar, start = kstart), clinfo )
310   END SUBROUTINE iom_nf90_g0d_dp
311
312   SUBROUTINE iom_nf90_g123d_dp( kiomid, kvid, knbdim, kstart, kcount, kx1, kx2, ky1, ky2,   &
313         &                    pv_r1d, pv_r2d, pv_r3d )
314      !!-----------------------------------------------------------------------
315      !!                  ***  ROUTINE  iom_nf90_g123d  ***
316      !!
317      !! ** Purpose : read a 1D/2D/3D variable with NF90
318      !!
319      !! ** Method : read ONE record at each CALL
320      !!-----------------------------------------------------------------------
321      INTEGER                    , INTENT(in   )           ::   kiomid    ! iom identifier of the file
322      INTEGER                    , INTENT(in   )           ::   kvid      ! Name of the variable
323      INTEGER                    , INTENT(in   )           ::   knbdim    ! number of dimensions of the variable
324      INTEGER , DIMENSION(:)     , INTENT(in   )           ::   kstart    ! start position of the reading in each axis
325      INTEGER , DIMENSION(:)     , INTENT(in   )           ::   kcount    ! number of points to be read in each axis
326      INTEGER ,                    INTENT(in   )           ::   kx1, kx2, ky1, ky2   ! subdomain indexes
327      REAL(dp), DIMENSION(:)     , INTENT(  out), OPTIONAL ::   pv_r1d    ! read field (1D case)
328      REAL(dp), DIMENSION(:,:)   , INTENT(  out), OPTIONAL ::   pv_r2d    ! read field (2D case)
329      REAL(dp), DIMENSION(:,:,:) , INTENT(  out), OPTIONAL ::   pv_r3d    ! read field (3D case)
330      !
331      CHARACTER(LEN=100) ::   clinfo               ! info character
332      INTEGER            ::   if90id               ! nf90 identifier of the opened file
333      INTEGER            ::   ivid                 ! nf90 variable id
334      !---------------------------------------------------------------------
335      clinfo = 'iom_nf90_g123d , file: '//TRIM(iom_file(kiomid)%name)//', var: '//TRIM(iom_file(kiomid)%cn_var(kvid))
336      if90id = iom_file(kiomid)%nfid         ! get back NetCDF file id
337      ivid   = iom_file(kiomid)%nvid(kvid)   ! get back NetCDF var id
338      !
339      IF(     PRESENT(pv_r1d) ) THEN
340         CALL iom_nf90_check( NF90_GET_VAR(if90id, ivid, pv_r1d(:                ), start = kstart(1:knbdim),   &
341            &                                                                       count = kcount(1:knbdim)), clinfo )
342      ELSEIF( PRESENT(pv_r2d) ) THEN
343         CALL iom_nf90_check( NF90_GET_VAR(if90id, ivid, pv_r2d(kx1:kx2,ky1:ky2  ), start = kstart(1:knbdim),   &
344            &                                                                       count = kcount(1:knbdim)), clinfo )
345      ELSEIF( PRESENT(pv_r3d) ) THEN
346         CALL iom_nf90_check( NF90_GET_VAR(if90id, ivid, pv_r3d(kx1:kx2,ky1:ky2,:), start = kstart(1:knbdim),   &
347            &                                                                       count = kcount(1:knbdim)), clinfo )
348      ENDIF
349      !
350   END SUBROUTINE iom_nf90_g123d_dp
351
352
353
354   SUBROUTINE iom_nf90_chkatt( kiomid, cdatt, llok, ksize, cdvar )
355      !!-----------------------------------------------------------------------
356      !!                  ***  ROUTINE  iom_nf90_chkatt  ***
357      !!
358      !! ** Purpose : check existence of attribute with NF90
359      !!              (either a global attribute (default) or a variable
360      !!               attribute if optional variable name is supplied (cdvar))
361      !!-----------------------------------------------------------------------
362      INTEGER         , INTENT(in   ) ::   kiomid   ! Identifier of the file
363      CHARACTER(len=*), INTENT(in   ) ::   cdatt    ! attribute name
364      LOGICAL         , INTENT(  out) ::   llok     ! error code
365      INTEGER         , INTENT(  out), OPTIONAL     &
366                      &               ::   ksize    ! attribute size
367      CHARACTER(len=*), INTENT(in   ), OPTIONAL     &
368                      &               ::   cdvar    ! name of the variable
369      !
370      INTEGER                         ::   if90id   ! temporary integer
371      INTEGER                         ::   isize    ! temporary integer
372      INTEGER                         ::   ivarid   ! NetCDF variable Id
373      !---------------------------------------------------------------------
374      !
375      if90id = iom_file(kiomid)%nfid
376      IF( PRESENT(cdvar) ) THEN
377         ! check the variable exists in the file
378         llok = NF90_INQ_VARID( if90id, TRIM(cdvar), ivarid ) == nf90_noerr
379         IF( llok ) &
380            ! check the variable has the attribute required
381            llok = NF90_Inquire_attribute(if90id, ivarid, cdatt, len=isize ) == nf90_noerr
382      ELSE
383         llok = NF90_Inquire_attribute(if90id, NF90_GLOBAL, cdatt, len=isize ) == nf90_noerr
384      ENDIF
385      !
386      IF( PRESENT(ksize) ) ksize = isize
387      !
388      IF( .not. llok) &
389         CALL ctl_warn('iom_nf90_chkatt: no attribute '//cdatt//' found')
390      !
391   END SUBROUTINE iom_nf90_chkatt
392
393
394   !!----------------------------------------------------------------------
395   !!                   INTERFACE iom_nf90_getatt
396   !!----------------------------------------------------------------------
397
398   SUBROUTINE iom_nf90_getatt( kiomid, cdatt, katt0d, katt1d, patt0d, patt1d, cdatt0d, cdvar)
399      !!-----------------------------------------------------------------------
400      !!                  ***  ROUTINE  iom_nf90_getatt  ***
401      !!
402      !! ** Purpose : read an attribute with NF90
403      !!              (either a global attribute (default) or a variable
404      !!               attribute if optional variable name is supplied (cdvar))
405      !!-----------------------------------------------------------------------
406      INTEGER               , INTENT(in   )           ::   kiomid   ! Identifier of the file
407      CHARACTER(len=*)      , INTENT(in   )           ::   cdatt    ! attribute name
408      INTEGER               , INTENT(  out), OPTIONAL ::   katt0d   ! read scalar integer
409      INTEGER, DIMENSION(:) , INTENT(  out), OPTIONAL ::   katt1d   ! read 1d array integer
410      REAL(wp)              , INTENT(  out), OPTIONAL ::   patt0d   ! read scalar  real
411      REAL(wp), DIMENSION(:), INTENT(  out), OPTIONAL ::   patt1d   ! read 1d array real
412      CHARACTER(len=*)      , INTENT(  out), OPTIONAL ::   cdatt0d  ! read character
413      CHARACTER(len=*)      , INTENT(in   ), OPTIONAL ::   cdvar    ! name of the variable
414      !
415      INTEGER                         ::   if90id   ! temporary integer
416      INTEGER                         ::   ivarid   ! NetCDF variable Id
417      LOGICAL                         ::   llok     ! temporary logical
418      CHARACTER(LEN=100)              ::   clinfo   ! info character
419      !---------------------------------------------------------------------
420      !
421      if90id = iom_file(kiomid)%nfid
422      IF( PRESENT(cdvar) ) THEN
423         ! check the variable exists in the file
424         llok = NF90_INQ_VARID( if90id, TRIM(cdvar), ivarid ) == nf90_noerr
425         IF( llok ) THEN
426            ! check the variable has the attribute required
427            llok = NF90_Inquire_attribute(if90id, ivarid, cdatt) == nf90_noerr
428         ELSE
429            CALL ctl_warn('iom_nf90_getatt: no variable '//TRIM(cdvar)//' found')
430         ENDIF
431      ELSE
432         llok = NF90_Inquire_attribute(if90id, NF90_GLOBAL, cdatt) == nf90_noerr
433         ivarid = NF90_GLOBAL
434      ENDIF
435      !
436      IF( llok) THEN
437         clinfo = 'iom_nf90_getatt, file: '//TRIM(iom_file(kiomid)%name)//', att: '//TRIM(cdatt)
438         IF(PRESENT( katt0d))   CALL iom_nf90_check(NF90_GET_ATT(if90id, ivarid, cdatt, values =  katt0d), clinfo)
439         IF(PRESENT( katt1d))   CALL iom_nf90_check(NF90_GET_ATT(if90id, ivarid, cdatt, values =  katt1d), clinfo)
440         IF(PRESENT( patt0d))   CALL iom_nf90_check(NF90_GET_ATT(if90id, ivarid, cdatt, values =  patt0d), clinfo)
441         IF(PRESENT( patt1d))   CALL iom_nf90_check(NF90_GET_ATT(if90id, ivarid, cdatt, values =  patt1d), clinfo)
442         IF(PRESENT(cdatt0d))   CALL iom_nf90_check(NF90_GET_ATT(if90id, ivarid, cdatt, values = cdatt0d), clinfo)
443      ELSE
444         CALL ctl_warn('iom_nf90_getatt: no attribute '//TRIM(cdatt)//' found')
445         IF(PRESENT( katt0d))    katt0d    = -999
446         IF(PRESENT( katt1d))    katt1d(:) = -999
447         IF(PRESENT( patt0d))    patt0d    = -999._wp
448         IF(PRESENT( patt1d))    patt1d(:) = -999._wp
449         IF(PRESENT(cdatt0d))   cdatt0d    = '!'
450      ENDIF
451      !
452   END SUBROUTINE iom_nf90_getatt
453
454
455   SUBROUTINE iom_nf90_putatt( kiomid, cdatt, katt0d, katt1d, patt0d, patt1d, cdatt0d, cdvar)
456      !!-----------------------------------------------------------------------
457      !!                  ***  ROUTINE  iom_nf90_putatt  ***
458      !!
459      !! ** Purpose : write an attribute with NF90
460      !!              (either a global attribute (default) or a variable
461      !!               attribute if optional variable name is supplied (cdvar))
462      !!-----------------------------------------------------------------------
463      INTEGER               , INTENT(in   )           ::   kiomid   ! Identifier of the file
464      CHARACTER(len=*)      , INTENT(in   )           ::   cdatt    ! attribute name
465      INTEGER               , INTENT(in   ), OPTIONAL ::   katt0d   ! read scalar integer
466      INTEGER, DIMENSION(:) , INTENT(in   ), OPTIONAL ::   katt1d   ! read 1d array integer
467      REAL(wp)              , INTENT(in   ), OPTIONAL ::   patt0d   ! read scalar  real
468      REAL(wp), DIMENSION(:), INTENT(in   ), OPTIONAL ::   patt1d   ! read 1d array real
469      CHARACTER(len=*)      , INTENT(in   ), OPTIONAL ::   cdatt0d  ! read character
470      CHARACTER(len=*)      , INTENT(in   ), OPTIONAL ::   cdvar    ! name of the variable
471      !
472      INTEGER                         ::   if90id   ! temporary integer
473      INTEGER                         ::   ivarid   ! NetCDF variable Id
474      INTEGER                         ::   isize    ! Attribute size
475      INTEGER                         ::   itype    ! Attribute type
476      LOGICAL                         ::   llok     ! temporary logical
477      LOGICAL                         ::   llatt     ! temporary logical
478      LOGICAL                         ::   lldata   ! temporary logical
479      CHARACTER(LEN=100)              ::   clinfo   ! info character
480      !---------------------------------------------------------------------
481      !
482      if90id = iom_file(kiomid)%nfid
483      IF( PRESENT(cdvar) ) THEN
484         llok = NF90_INQ_VARID( if90id, TRIM(cdvar), ivarid ) == nf90_noerr   ! is the variable in the file?
485         IF( .NOT. llok ) THEN
486            CALL ctl_warn('iom_nf90_putatt: no variable '//TRIM(cdvar)//' found'   &
487               &        , '                 no attribute '//cdatt//' written' )
488            RETURN
489         ENDIF
490      ELSE
491         ivarid = NF90_GLOBAL
492      ENDIF
493      llatt = NF90_Inquire_attribute(if90id, ivarid, cdatt, len = isize, xtype = itype ) == nf90_noerr
494      !
495      ! trick: irec used to know if the file is in define mode or not
496      lldata = iom_file(kiomid)%irec /= -1   ! default: go back in define mode if in data mode
497      IF( lldata .AND. llatt ) THEN          ! attribute already there. Do we really need to go back in define mode?
498         ! do we have the appropriate type?
499         IF(PRESENT( katt0d) .OR. PRESENT( katt1d))   llok = itype == NF90_INT
500         IF(PRESENT( patt0d) .OR. PRESENT( patt1d))   llok = itype == NF90_DOUBLE
501         IF(PRESENT(cdatt0d)                      )   llok = itype == NF90_CHAR
502         ! and do we have the appropriate size?
503         IF(PRESENT( katt0d))   llok = llok .AND. isize == 1
504         IF(PRESENT( katt1d))   llok = llok .AND. isize == SIZE(katt1d)
505         IF(PRESENT( patt0d))   llok = llok .AND. isize == 1
506         IF(PRESENT( patt1d))   llok = llok .AND. isize == SIZE(patt1d)
507         IF(PRESENT(cdatt0d))   llok = llok .AND. isize == LEN_TRIM(cdatt0d)
508         !
509         lldata = .NOT. llok
510      ENDIF
511      !
512      clinfo = 'iom_nf90_putatt, file: '//TRIM(iom_file(kiomid)%name)//', att: '//TRIM(cdatt)
513      IF(lldata)   CALL iom_nf90_check(NF90_REDEF( if90id ), clinfo)   ! leave data mode to define mode
514      !
515      IF(PRESENT( katt0d))   CALL iom_nf90_check(NF90_PUT_ATT(if90id, ivarid, cdatt, values =       katt0d) , clinfo)
516      IF(PRESENT( katt1d))   CALL iom_nf90_check(NF90_PUT_ATT(if90id, ivarid, cdatt, values =       katt1d) , clinfo)
517      IF(PRESENT( patt0d))   CALL iom_nf90_check(NF90_PUT_ATT(if90id, ivarid, cdatt, values =       patt0d) , clinfo)
518      IF(PRESENT( patt1d))   CALL iom_nf90_check(NF90_PUT_ATT(if90id, ivarid, cdatt, values =       patt1d) , clinfo)
519      IF(PRESENT(cdatt0d))   CALL iom_nf90_check(NF90_PUT_ATT(if90id, ivarid, cdatt, values = trim(cdatt0d)), clinfo)
520      !
521      IF(lldata)   CALL iom_nf90_check(NF90_ENDDEF( if90id ), clinfo)   ! leave define mode to data mode
522      !
523   END SUBROUTINE iom_nf90_putatt
524
525   SUBROUTINE iom_nf90_rp0123d_dp( kt, kwrite, kiomid, cdvar , kvid  , ktype,   &
526         &                                  pv_r0d, pv_r1d, pv_r2d, pv_r3d )
527      !!--------------------------------------------------------------------
528      !!                   ***  SUBROUTINE  iom_nf90_rstput  ***
529      !!
530      !! ** Purpose : read the time axis cdvar in the file
531      !!--------------------------------------------------------------------
532      INTEGER                     , INTENT(in)           ::   kt       ! ocean time-step
533      INTEGER                     , INTENT(in)           ::   kwrite   ! writing time-step
534      INTEGER                     , INTENT(in)           ::   kiomid   ! Identifier of the file
535      CHARACTER(len=*)            , INTENT(in)           ::   cdvar    ! variable name
536      INTEGER                     , INTENT(in)           ::   kvid     ! variable id
537      INTEGER                     , INTENT(in), OPTIONAL ::   ktype    ! variable type (default R8)
538      REAL(dp)                    , INTENT(in), OPTIONAL ::   pv_r0d   ! written Od field
539      REAL(dp), DIMENSION(      :), INTENT(in), OPTIONAL ::   pv_r1d   ! written 1d field
540      REAL(dp), DIMENSION(:, :   ), INTENT(in), OPTIONAL ::   pv_r2d   ! written 2d field
541      REAL(dp), DIMENSION(:, :, :), INTENT(in), OPTIONAL ::   pv_r3d   ! written 3d field
542      !
543      INTEGER               :: idims                ! number of dimension
544      INTEGER               :: idvar                ! variable id
545      INTEGER               :: jd                   ! dimension loop counter   
546      INTEGER               :: ix1, ix2, iy1, iy2   ! subdomain indexes   
547      INTEGER, DIMENSION(4) :: idimsz               ! dimensions size 
548      INTEGER, DIMENSION(4) :: idimid               ! dimensions id
549      CHARACTER(LEN=256)    :: clinfo               ! info character
550      INTEGER               :: if90id               ! nf90 file identifier
551      INTEGER               :: itype                ! variable type
552      INTEGER, DIMENSION(4) :: ichunksz             ! NetCDF4 chunk sizes. Will be computed using
553      !                                             ! nn_nchunks_[i,j,k,t] namelist parameters
554      INTEGER               :: ichunkalg, ishuffle, ideflate, ideflate_level
555      !                                             ! NetCDF4 internally fixed parameters
556      LOGICAL               :: lchunk               ! logical switch to activate chunking and compression
557      !                                             ! when appropriate (currently chunking is applied to 4d fields only)
558      INTEGER               :: idlv                 ! local variable
559      !---------------------------------------------------------------------
560      !
561      clinfo = '          iom_nf90_rp0123d, file: '//TRIM(iom_file(kiomid)%name)//', var: '//TRIM(cdvar)
562      if90id = iom_file(kiomid)%nfid
563      !
564      ! define dimension variables if it is not already done
565      ! ==========================
566      IF( iom_file(kiomid)%nvars == 0 ) THEN
567         ! are we in define mode?
568         IF( iom_file(kiomid)%irec /= -1 ) THEN   ! trick: irec used to know if the file is in define mode or not
569            CALL iom_nf90_check(NF90_REDEF( if90id ), clinfo)   ;   iom_file(kiomid)%irec = -1
570         ENDIF
571         ! define the dimension variables if it is not already done
572         DO jd = 1, 2
573            CALL iom_nf90_check(NF90_INQUIRE_DIMENSION(if90id,jd,iom_file(kiomid)%cn_var(jd),iom_file(kiomid)%dimsz(jd,jd)),clinfo)
574            CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(iom_file(kiomid)%cn_var(jd)), NF90_FLOAT , (/ 1, 2 /),   &
575               &                              iom_file(kiomid)%nvid(jd) ), clinfo)
576         END DO
577         iom_file(kiomid)%dimsz(2,1) = iom_file(kiomid)%dimsz(2,2)   ! second dim of first  variable
578         iom_file(kiomid)%dimsz(1,2) = iom_file(kiomid)%dimsz(1,1)   ! first  dim of second variable
579         DO jd = 3, 4
580            CALL iom_nf90_check(NF90_INQUIRE_DIMENSION(if90id,jd,iom_file(kiomid)%cn_var(jd),iom_file(kiomid)%dimsz(1,jd)), clinfo)
581            CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(iom_file(kiomid)%cn_var(jd)), NF90_FLOAT , (/ jd   /),   &
582               &                              iom_file(kiomid)%nvid(jd) ), clinfo)
583         END DO
584         ! update informations structure related the dimension variable we just added...
585         iom_file(kiomid)%nvars       = 4
586         iom_file(kiomid)%luld(1:4)   = (/ .FALSE., .FALSE., .FALSE., .TRUE. /)
587         iom_file(kiomid)%ndims(1:4)  = (/ 2, 2, 1, 1 /)
588         IF(lwp) WRITE(numout,*) TRIM(clinfo)//' define dimension variables done'
589      ENDIF
590      ! define the data if it is not already done
591      ! ===============
592      IF( kvid <= 0 ) THEN
593         !
594         ! NetCDF4 chunking and compression fixed settings
595         ichunkalg = 0
596         ishuffle = 1
597         ideflate = 1
598         ideflate_level = 1
599         !
600         idvar = iom_file(kiomid)%nvars + 1
601         ! are we in define mode?
602         IF( iom_file(kiomid)%irec /= -1 ) THEN   ! trick: irec used to know if the file is in define mode or not
603            CALL iom_nf90_check(NF90_REDEF( if90id ), clinfo)   ;   iom_file(kiomid)%irec = -1
604         ENDIF
605         ! variable definition
606         IF(     PRESENT(pv_r0d) ) THEN   ;   idims = 0
607         ELSEIF( PRESENT(pv_r1d) ) THEN
608                                              idims = 2   ;   idimid(1:idims) = (/3,4/)
609         ELSEIF( PRESENT(pv_r2d) ) THEN   ;   idims = 3   ;   idimid(1:idims) = (/1,2,4/)
610         ELSEIF( PRESENT(pv_r3d) ) THEN
611                                              idims = 4   ;   idimid(1:idims) = (/1,2,3,4/)
612         ENDIF
613         IF( PRESENT(ktype) ) THEN   ! variable external type
614            SELECT CASE (ktype)
615            CASE (jp_r8)   ;   itype = NF90_DOUBLE
616            CASE (jp_r4)   ;   itype = NF90_FLOAT
617            CASE (jp_i4)   ;   itype = NF90_INT
618            CASE (jp_i2)   ;   itype = NF90_SHORT
619            CASE (jp_i1)   ;   itype = NF90_BYTE
620            CASE DEFAULT   ;   CALL ctl_stop( TRIM(clinfo)//' unknown variable type' )
621            END SELECT
622         ELSE
623            itype = NF90_DOUBLE
624         ENDIF
625         IF( PRESENT(pv_r0d) ) THEN
626            CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(cdvar), itype,                    &
627               &                              iom_file(kiomid)%nvid(idvar) ), clinfo )
628         ELSE
629            CALL iom_nf90_check(NF90_DEF_VAR( if90id, TRIM(cdvar), itype, idimid(1:idims),   &
630               &                              iom_file(kiomid)%nvid(idvar) ), clinfo )
631         ENDIF
632         lchunk = .false.
633         IF( snc4set%luse .AND. idims == 4 )   lchunk = .true.
634         ! update informations structure related the new variable we want to add...
635         iom_file(kiomid)%nvars         = idvar
636         iom_file(kiomid)%cn_var(idvar) = TRIM(cdvar)
637         iom_file(kiomid)%scf(idvar)    = 1.
638         iom_file(kiomid)%ofs(idvar)    = 0.
639         iom_file(kiomid)%ndims(idvar)  = idims
640         IF( .NOT. PRESENT(pv_r0d) ) THEN   ;   iom_file(kiomid)%luld(idvar) = .TRUE.
641         ELSE                               ;   iom_file(kiomid)%luld(idvar) = .FALSE.
642         ENDIF
643         DO jd = 1, idims
644            CALL iom_nf90_check(NF90_INQUIRE_DIMENSION( if90id, idimid(jd), len = iom_file(kiomid)%dimsz(jd,idvar) ), clinfo)
645            IF ( lchunk ) ichunksz(jd) = iom_file(kiomid)%dimsz(jd,idvar)
646         END DO
647         IF ( lchunk ) THEN
648            ! Calculate chunk sizes by partitioning each dimension as requested in namnc4 namelist
649            ! Disallow very small chunk sizes and prevent chunk sizes larger than each individual dimension
650            ichunksz(1) = MIN( ichunksz(1),MAX( (ichunksz(1)-1)/snc4set%ni + 1 ,16 ) ) ! Suggested default nc4set%ni=4
651            ichunksz(2) = MIN( ichunksz(2),MAX( (ichunksz(2)-1)/snc4set%nj + 1 ,16 ) ) ! Suggested default nc4set%nj=2
652            ichunksz(3) = MIN( ichunksz(3),MAX( (ichunksz(3)-1)/snc4set%nk + 1 , 1 ) ) ! Suggested default nc4set%nk=6
653            ichunksz(4) = 1                                                            ! Do not allow chunks to span the
654            !                                                                          ! unlimited dimension
655            CALL iom_nf90_check(SET_NF90_DEF_VAR_CHUNKING(if90id, idvar, ichunkalg, ichunksz), clinfo)
656            CALL iom_nf90_check(SET_NF90_DEF_VAR_DEFLATE(if90id, idvar, ishuffle, ideflate, ideflate_level), clinfo)
657            IF(lwp) WRITE(numout,*) TRIM(clinfo)//' chunked ok. Chunks sizes: ', ichunksz
658         ENDIF
659         IF(lwp) WRITE(numout,*) TRIM(clinfo)//' defined ok'
660      ELSE
661         idvar = kvid
662      ENDIF
663      !
664      ! time step kwrite : write the variable
665      IF( kt == kwrite ) THEN
666         ! are we in write mode?
667         IF( iom_file(kiomid)%irec == -1 ) THEN   ! trick: irec used to know if the file is in define mode or not
668            CALL iom_nf90_check(NF90_ENDDEF( if90id ), clinfo)   ;   iom_file(kiomid)%irec = 0
669         ENDIF
670         ! on what kind of domain must the data be written?
671         IF( PRESENT(pv_r2d) .OR. PRESENT(pv_r3d) ) THEN
672            idimsz(1:2) = iom_file(kiomid)%dimsz(1:2,idvar)
673            IF(     idimsz(1) == Ni_0 .AND. idimsz(2) == Nj_0 ) THEN
674               ix1 = Nis0   ;   ix2 = Nie0   ;   iy1 = Njs0   ;   iy2 = Nje0
675            ELSEIF( idimsz(1) == jpi  .AND. idimsz(2) == jpj  ) THEN
676               ix1 = 1      ;   ix2 = jpi    ;   iy1 = 1      ;   iy2 = jpj
677            ELSEIF( idimsz(1) == jpi  .AND. idimsz(2) == jpj  ) THEN
678               ix1 = 1      ;   ix2 = jpi    ;   iy1 = 1      ;   iy2 = jpj
679            ELSE
680               CALL ctl_stop( 'iom_nf90_rp0123d: should have been an impossible case...' )
681            ENDIF
682
683            ! write dimension variables if it is not already done
684            ! =============
685            ! trick: is defined to 0 => dimension variable are defined but not yet written
686            IF( iom_file(kiomid)%dimsz(1, 4) == 0 ) THEN   ! time_counter = 0
687               CALL iom_nf90_check(    NF90_PUT_VAR( if90id, 1,                            glamt(ix1:ix2, iy1:iy2) ), clinfo )
688               CALL iom_nf90_check(    NF90_PUT_VAR( if90id, 2,                            gphit(ix1:ix2, iy1:iy2) ), clinfo )
689               SELECT CASE (iom_file(kiomid)%comp)
690               CASE ('OCE') 
691                  CALL iom_nf90_check( NF90_PUT_VAR( if90id, 3,                                           gdept_1d ), clinfo )
692               CASE ('ABL')
693                  CALL iom_nf90_check( NF90_PUT_VAR( if90id, 3,                                            ght_abl ), clinfo )
694               CASE DEFAULT
695                  CALL iom_nf90_check( NF90_PUT_VAR( if90id, 3, (/ (idlv, idlv = 1,iom_file(kiomid)%dimsz(1,3)) /) ), clinfo )
696               END SELECT
697               ! "wrong" value: to be improved but not really useful...
698               CALL iom_nf90_check(   NF90_PUT_VAR( if90id, 4,                                                  kt ), clinfo )   
699               ! update the size of the variable corresponding to the unlimited dimension
700               iom_file(kiomid)%dimsz(1, 4) = 1   ! so we don't enter this IF case any more...
701               IF(lwp) WRITE(numout,*) TRIM(clinfo)//' write dimension variables done'
702            ENDIF
703         ENDIF
704
705         ! write the data
706         ! =============
707         IF(     PRESENT(pv_r0d) ) THEN
708            CALL iom_nf90_check( NF90_PUT_VAR( if90id, idvar, pv_r0d                    ), clinfo )
709         ELSEIF( PRESENT(pv_r1d) ) THEN
710            CALL iom_nf90_check( NF90_PUT_VAR( if90id, idvar, pv_r1d(:)                 ), clinfo )
711         ELSEIF( PRESENT(pv_r2d) ) THEN
712            CALL iom_nf90_check( NF90_PUT_VAR( if90id, idvar, pv_r2d(ix1:ix2,iy1:iy2)   ), clinfo )
713         ELSEIF( PRESENT(pv_r3d) ) THEN
714            CALL iom_nf90_check( NF90_PUT_VAR( if90id, idvar, pv_r3d(ix1:ix2,iy1:iy2,:) ), clinfo )
715         ENDIF
716         ! add 1 to the size of the temporal dimension (not really useful...)
717         IF( iom_file(kiomid)%luld(idvar) )   iom_file(kiomid)%dimsz(iom_file(kiomid)%ndims(idvar), idvar)    &
718               &                            = iom_file(kiomid)%dimsz(iom_file(kiomid)%ndims(idvar), idvar) + 1
719         IF(lwp) WRITE(numout,*) TRIM(clinfo)//' written ok'
720      ENDIF
721      !     
722   END SUBROUTINE iom_nf90_rp0123d_dp
723
724
725   SUBROUTINE iom_nf90_check( kstatus, cdinfo )
726      !!--------------------------------------------------------------------
727      !!                   ***  SUBROUTINE iom_nf90_check  ***
728      !!
729      !! ** Purpose :   check nf90 errors
730      !!--------------------------------------------------------------------
731      INTEGER,          INTENT(in) :: kstatus
732      CHARACTER(LEN=*), INTENT(in) :: cdinfo
733      !---------------------------------------------------------------------
734      IF(kstatus /= nf90_noerr)   CALL ctl_stop( 'iom_nf90_check : '//TRIM(nf90_strerror(kstatus)), TRIM(cdinfo) )
735   END SUBROUTINE iom_nf90_check
736
737   !!======================================================================
738END MODULE iom_nf90
Note: See TracBrowser for help on using the repository browser.