source: NEMO/trunk/src/OCE/SBC/sbcmod.F90 @ 10425

Last change on this file since 10425 was 10425, checked in by smasson, 23 months ago

trunk: merge back dev_r10164_HPC09_ESIWACE_PREP_MERGE@10424 into the trunk

  • Property svn:keywords set to Id
File size: 32.9 KB
Line 
1MODULE sbcmod
2   !!======================================================================
3   !!                       ***  MODULE  sbcmod  ***
4   !! Surface module :  provide to the ocean its surface boundary condition
5   !!======================================================================
6   !! History :  3.0  ! 2006-07  (G. Madec)  Original code
7   !!            3.1  ! 2008-08  (S. Masson, A. Caubel, E. Maisonnave, G. Madec) coupled interface
8   !!            3.3  ! 2010-04  (M. Leclair, G. Madec)  Forcing averaged over 2 time steps
9   !!            3.3  ! 2010-10  (S. Masson)  add diurnal cycle
10   !!            3.3  ! 2010-09  (D. Storkey) add ice boundary conditions (BDY)
11   !!             -   ! 2010-11  (G. Madec) ice-ocean stress always computed at each ocean time-step
12   !!             -   ! 2010-10  (J. Chanut, C. Bricaud, G. Madec)  add the surface pressure forcing
13   !!            3.4  ! 2011-11  (C. Harris) CICE added as an option
14   !!            3.5  ! 2012-11  (A. Coward, G. Madec) Rethink of heat, mass and salt surface fluxes
15   !!            3.6  ! 2014-11  (P. Mathiot, C. Harris) add ice shelves melting
16   !!            4.0  ! 2016-06  (L. Brodeau) new general bulk formulation
17   !!----------------------------------------------------------------------
18
19   !!----------------------------------------------------------------------
20   !!   sbc_init      : read namsbc namelist
21   !!   sbc           : surface ocean momentum, heat and freshwater boundary conditions
22   !!   sbc_final     : Finalize CICE ice model (if used)
23   !!----------------------------------------------------------------------
24   USE oce            ! ocean dynamics and tracers
25   USE dom_oce        ! ocean space and time domain
26   USE phycst         ! physical constants
27   USE sbc_oce        ! Surface boundary condition: ocean fields
28   USE trc_oce        ! shared ocean-passive tracers variables
29   USE sbc_ice        ! Surface boundary condition: ice fields
30   USE sbcdcy         ! surface boundary condition: diurnal cycle
31   USE sbcssm         ! surface boundary condition: sea-surface mean variables
32   USE sbcflx         ! surface boundary condition: flux formulation
33   USE sbcblk         ! surface boundary condition: bulk formulation
34   USE sbcice_if      ! surface boundary condition: ice-if sea-ice model
35#if defined key_si3
36   USE icestp         ! surface boundary condition: SI3 sea-ice model
37#endif
38   USE sbcice_cice    ! surface boundary condition: CICE sea-ice model
39   USE sbcisf         ! surface boundary condition: ice-shelf
40   USE sbccpl         ! surface boundary condition: coupled formulation
41   USE cpl_oasis3     ! OASIS routines for coupling
42   USE sbcssr         ! surface boundary condition: sea surface restoring
43   USE sbcrnf         ! surface boundary condition: runoffs
44   USE sbcapr         ! surface boundary condition: atmo pressure
45   USE sbcisf         ! surface boundary condition: ice shelf
46   USE sbcfwb         ! surface boundary condition: freshwater budget
47   USE icbstp         ! Icebergs
48   USE icb_oce  , ONLY : ln_passive_mode      ! iceberg interaction mode
49   USE traqsr         ! active tracers: light penetration
50   USE sbcwave        ! Wave module
51   USE bdy_oce   , ONLY: ln_bdy
52   USE usrdef_sbc     ! user defined: surface boundary condition
53   USE closea         ! closed sea
54   !
55   USE prtctl         ! Print control                    (prt_ctl routine)
56   USE iom            ! IOM library
57   USE in_out_manager ! I/O manager
58   USE lib_mpp        ! MPP library
59   USE timing         ! Timing
60   USE diurnal_bulk, ONLY:   ln_diurnal_only   ! diurnal SST diagnostic
61
62   IMPLICIT NONE
63   PRIVATE
64
65   PUBLIC   sbc        ! routine called by step.F90
66   PUBLIC   sbc_init   ! routine called by opa.F90
67
68   INTEGER ::   nsbc   ! type of surface boundary condition (deduced from namsbc informations)
69
70   !!----------------------------------------------------------------------
71   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
72   !! $Id$
73   !! Software governed by the CeCILL license (see ./LICENSE)
74   !!----------------------------------------------------------------------
75CONTAINS
76
77   SUBROUTINE sbc_init
78      !!---------------------------------------------------------------------
79      !!                    ***  ROUTINE sbc_init ***
80      !!
81      !! ** Purpose :   Initialisation of the ocean surface boundary computation
82      !!
83      !! ** Method  :   Read the namsbc namelist and set derived parameters
84      !!                Call init routines for all other SBC modules that have one
85      !!
86      !! ** Action  : - read namsbc parameters
87      !!              - nsbc: type of sbc
88      !!----------------------------------------------------------------------
89      INTEGER ::   ios, icpt                         ! local integer
90      LOGICAL ::   ll_purecpl, ll_opa, ll_not_nemo   ! local logical
91      !!
92      NAMELIST/namsbc/ nn_fsbc  ,                                                    &
93         &             ln_usr   , ln_flx   , ln_blk       ,                          &
94         &             ln_cpl   , ln_mixcpl, nn_components,                          &
95         &             nn_ice   , ln_ice_embd,                                       &
96         &             ln_traqsr, ln_dm2dc ,                                         &
97         &             ln_rnf   , nn_fwb   , ln_ssr   , ln_isf    , ln_apr_dyn ,     &
98         &             ln_wave  , ln_cdgw  , ln_sdw   , ln_tauwoc  , ln_stcor   ,     &
99         &             ln_tauw  , nn_lsm, nn_sdrift
100      !!----------------------------------------------------------------------
101      !
102      IF(lwp) THEN
103         WRITE(numout,*)
104         WRITE(numout,*) 'sbc_init : surface boundary condition setting'
105         WRITE(numout,*) '~~~~~~~~ '
106      ENDIF
107      !
108      !                       !**  read Surface Module namelist
109      REWIND( numnam_ref )          !* Namelist namsbc in reference namelist : Surface boundary
110      READ  ( numnam_ref, namsbc, IOSTAT = ios, ERR = 901)
111901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namsbc in reference namelist', lwp )
112      REWIND( numnam_cfg )          !* Namelist namsbc in configuration namelist : Parameters of the run
113      READ  ( numnam_cfg, namsbc, IOSTAT = ios, ERR = 902 )
114902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namsbc in configuration namelist', lwp )
115      IF(lwm) WRITE( numond, namsbc )
116      !
117#if defined key_mpp_mpi
118      ncom_fsbc = nn_fsbc    ! make nn_fsbc available for lib_mpp
119#endif
120      !                             !* overwrite namelist parameter using CPP key information
121#if defined key_agrif
122      IF( Agrif_Root() ) THEN                ! AGRIF zoom (cf r1242: possibility to run without ice in fine grid)
123         IF( lk_si3  )   nn_ice      = 2
124         IF( lk_cice )   nn_ice      = 3
125      ENDIF
126#else
127      IF( lk_si3  )   nn_ice      = 2
128      IF( lk_cice )   nn_ice      = 3
129#endif
130      !
131      IF(lwp) THEN                  !* Control print
132         WRITE(numout,*) '   Namelist namsbc (partly overwritten with CPP key setting)'
133         WRITE(numout,*) '      frequency update of sbc (and ice)             nn_fsbc       = ', nn_fsbc
134         WRITE(numout,*) '      Type of air-sea fluxes : '
135         WRITE(numout,*) '         user defined formulation                   ln_usr        = ', ln_usr
136         WRITE(numout,*) '         flux         formulation                   ln_flx        = ', ln_flx
137         WRITE(numout,*) '         bulk         formulation                   ln_blk        = ', ln_blk
138         WRITE(numout,*) '      Type of coupling (Ocean/Ice/Atmosphere) : '
139         WRITE(numout,*) '         ocean-atmosphere coupled formulation       ln_cpl        = ', ln_cpl
140         WRITE(numout,*) '         mixed forced-coupled     formulation       ln_mixcpl     = ', ln_mixcpl
141!!gm  lk_oasis is controlled by key_oasis3  ===>>>  It shoud be removed from the namelist
142         WRITE(numout,*) '         OASIS coupling (with atm or sas)           lk_oasis      = ', lk_oasis
143         WRITE(numout,*) '         components of your executable              nn_components = ', nn_components
144         WRITE(numout,*) '      Sea-ice : '
145         WRITE(numout,*) '         ice management in the sbc (=0/1/2/3)       nn_ice        = ', nn_ice
146         WRITE(numout,*) '         ice embedded into ocean                    ln_ice_embd   = ', ln_ice_embd
147         WRITE(numout,*) '      Misc. options of sbc : '
148         WRITE(numout,*) '         Light penetration in temperature Eq.       ln_traqsr     = ', ln_traqsr
149         WRITE(numout,*) '            daily mean to diurnal cycle qsr            ln_dm2dc   = ', ln_dm2dc
150         WRITE(numout,*) '         Sea Surface Restoring on SST and/or SSS    ln_ssr        = ', ln_ssr
151         WRITE(numout,*) '         FreshWater Budget control  (=0/1/2)        nn_fwb        = ', nn_fwb
152         WRITE(numout,*) '         Patm gradient added in ocean & ice Eqs.    ln_apr_dyn    = ', ln_apr_dyn
153         WRITE(numout,*) '         runoff / runoff mouths                     ln_rnf        = ', ln_rnf
154         WRITE(numout,*) '         iceshelf formulation                       ln_isf        = ', ln_isf
155         WRITE(numout,*) '         nb of iterations if land-sea-mask applied  nn_lsm        = ', nn_lsm
156         WRITE(numout,*) '         surface wave                               ln_wave       = ', ln_wave
157         WRITE(numout,*) '               Stokes drift corr. to vert. velocity ln_sdw        = ', ln_sdw
158         WRITE(numout,*) '                  vertical parametrization          nn_sdrift     = ', nn_sdrift
159         WRITE(numout,*) '               wave modified ocean stress           ln_tauwoc     = ', ln_tauwoc
160         WRITE(numout,*) '               wave modified ocean stress component ln_tauw       = ', ln_tauw
161         WRITE(numout,*) '               Stokes coriolis term                 ln_stcor      = ', ln_stcor
162         WRITE(numout,*) '               neutral drag coefficient (CORE,NCAR) ln_cdgw       = ', ln_cdgw
163      ENDIF
164      !
165      IF( .NOT.ln_wave ) THEN
166         ln_sdw = .false. ; ln_cdgw = .false. ; ln_tauwoc = .false. ; ln_tauw = .false. ; ln_stcor = .false.
167      ENDIF
168      IF( ln_sdw ) THEN
169         IF( .NOT.(nn_sdrift==jp_breivik_2014 .OR. nn_sdrift==jp_li_2017 .OR. nn_sdrift==jp_peakfr) ) &
170            CALL ctl_stop( 'The chosen nn_sdrift for Stokes drift vertical velocity must be 0, 1, or 2' )
171      ENDIF
172      ll_st_bv2014  = ( nn_sdrift==jp_breivik_2014 )
173      ll_st_li2017  = ( nn_sdrift==jp_li_2017 )
174      ll_st_bv_li   = ( ll_st_bv2014 .OR. ll_st_li2017 )
175      ll_st_peakfr  = ( nn_sdrift==jp_peakfr )
176      IF( ln_tauwoc .AND. ln_tauw ) &
177         CALL ctl_stop( 'More than one method for modifying the ocean stress has been selected ', &
178                                  '(ln_tauwoc=.true. and ln_tauw=.true.)' )
179      IF( ln_tauwoc ) &
180         CALL ctl_warn( 'You are subtracting the wave stress to the ocean (ln_tauwoc=.true.)' )
181      IF( ln_tauw ) &
182         CALL ctl_warn( 'The wave modified ocean stress components are used (ln_tauw=.true.) ', &
183                              'This will override any other specification of the ocean stress' )
184      !
185      IF( .NOT.ln_usr ) THEN     ! the model calendar needs some specificities (except in user defined case)
186         IF( MOD( rday , rdt ) /= 0. )   CALL ctl_stop( 'the time step must devide the number of second of in a day' )
187         IF( MOD( rday , 2.  ) /= 0. )   CALL ctl_stop( 'the number of second of in a day must be an even number'    )
188         IF( MOD( rdt  , 2.  ) /= 0. )   CALL ctl_stop( 'the time step (in second) must be an even number'           )
189      ENDIF
190      !                       !**  check option consistency
191      !
192      IF(lwp) WRITE(numout,*)       !* Single / Multi - executable (NEMO / OPA+SAS)
193      SELECT CASE( nn_components )
194      CASE( jp_iam_nemo )
195         IF(lwp) WRITE(numout,*) '   ==>>>   NEMO configured as a single executable (i.e. including both OPA and Surface module)'
196      CASE( jp_iam_opa  )
197         IF(lwp) WRITE(numout,*) '   ==>>>   Multi executable configuration. Here, OPA component'
198         IF( .NOT.lk_oasis )   CALL ctl_stop( 'sbc_init : OPA-SAS coupled via OASIS, but key_oasis3 disabled' )
199         IF( ln_cpl        )   CALL ctl_stop( 'sbc_init : OPA-SAS coupled via OASIS, but ln_cpl = T in OPA'   )
200         IF( ln_mixcpl     )   CALL ctl_stop( 'sbc_init : OPA-SAS coupled via OASIS, but ln_mixcpl = T in OPA' )
201      CASE( jp_iam_sas  )
202         IF(lwp) WRITE(numout,*) '   ==>>>   Multi executable configuration. Here, SAS component'
203         IF( .NOT.lk_oasis )   CALL ctl_stop( 'sbc_init : OPA-SAS coupled via OASIS, but key_oasis3 disabled' )
204         IF( ln_mixcpl     )   CALL ctl_stop( 'sbc_init : OPA-SAS coupled via OASIS, but ln_mixcpl = T in OPA' )
205      CASE DEFAULT
206         CALL ctl_stop( 'sbc_init : unsupported value for nn_components' )
207      END SELECT
208      !                             !* coupled options
209      IF( ln_cpl ) THEN
210         IF( .NOT. lk_oasis )   CALL ctl_stop( 'sbc_init : coupled mode with an atmosphere model (ln_cpl=T)',   &
211            &                                  '           required to defined key_oasis3' )
212      ENDIF
213      IF( ln_mixcpl ) THEN
214         IF( .NOT. lk_oasis )   CALL ctl_stop( 'sbc_init : mixed forced-coupled mode (ln_mixcpl=T) ',   &
215            &                                  '           required to defined key_oasis3' )
216         IF( .NOT.ln_cpl    )   CALL ctl_stop( 'sbc_init : mixed forced-coupled mode (ln_mixcpl=T) requires ln_cpl = T' )
217         IF( nn_components /= jp_iam_nemo )    &
218            &                   CALL ctl_stop( 'sbc_init : the mixed forced-coupled mode (ln_mixcpl=T) ',   &
219            &                                   '          not yet working with sas-opa coupling via oasis' )
220      ENDIF
221      !                             !* sea-ice
222      SELECT CASE( nn_ice )
223      CASE( 0 )                        !- no ice in the domain
224      CASE( 1 )                        !- Ice-cover climatology ("Ice-if" model) 
225      CASE( 2 )                        !- SI3  ice model
226      CASE( 3 )                        !- CICE ice model
227         IF( .NOT.( ln_blk .OR. ln_cpl ) )   CALL ctl_stop( 'sbc_init : CICE sea-ice model requires ln_blk or ln_cpl = T' )
228         IF( lk_agrif                    )   CALL ctl_stop( 'sbc_init : CICE sea-ice model not currently available with AGRIF' ) 
229      CASE DEFAULT                     !- not supported
230      END SELECT
231      !
232      !                       !**  allocate and set required variables
233      !
234      !                             !* allocate sbc arrays
235      IF( sbc_oce_alloc() /= 0 )   CALL ctl_stop( 'sbc_init : unable to allocate sbc_oce arrays' )
236#if ! defined key_si3 && ! defined key_cice
237      IF( sbc_ice_alloc() /= 0 )   CALL ctl_stop( 'sbc_init : unable to allocate sbc_ice arrays' )
238#endif
239      !
240      IF( .NOT.ln_isf ) THEN        !* No ice-shelf in the domain : allocate and set to zero
241         IF( sbc_isf_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'sbc_init : unable to allocate sbc_isf arrays' )
242         fwfisf  (:,:)   = 0._wp   ;   risf_tsc  (:,:,:) = 0._wp
243         fwfisf_b(:,:)   = 0._wp   ;   risf_tsc_b(:,:,:) = 0._wp
244      END IF
245      IF( nn_ice == 0 ) THEN        !* No sea-ice in the domain : ice fraction is always zero
246         IF( nn_components /= jp_iam_opa )   fr_i(:,:) = 0._wp    ! except for OPA in SAS-OPA coupled case
247      ENDIF
248      !
249      sfx   (:,:) = 0._wp           !* salt flux due to freezing/melting
250      fmmflx(:,:) = 0._wp           !* freezing minus melting flux
251
252      taum(:,:) = 0._wp             !* wind stress module (needed in GLS in case of reduced restart)
253
254      !                          ! Choice of the Surface Boudary Condition (set nsbc)
255      IF( ln_dm2dc ) THEN           !* daily mean to diurnal cycle
256         nday_qsr = -1   ! allow initialization at the 1st call
257         IF( .NOT.( ln_flx .OR. ln_blk ) .AND. nn_components /= jp_iam_opa )   &
258            &   CALL ctl_stop( 'qsr diurnal cycle from daily values requires a flux or bulk formulation' )
259      ENDIF
260      !                             !* Choice of the Surface Boudary Condition
261      !                             (set nsbc)
262      !
263      ll_purecpl  = ln_cpl .AND. .NOT.ln_mixcpl
264      ll_opa      = nn_components == jp_iam_opa
265      ll_not_nemo = nn_components /= jp_iam_nemo
266      icpt = 0
267      !
268      IF( ln_usr          ) THEN   ;   nsbc = jp_usr     ; icpt = icpt + 1   ;   ENDIF       ! user defined         formulation
269      IF( ln_flx          ) THEN   ;   nsbc = jp_flx     ; icpt = icpt + 1   ;   ENDIF       ! flux                 formulation
270      IF( ln_blk          ) THEN   ;   nsbc = jp_blk     ; icpt = icpt + 1   ;   ENDIF       ! bulk                 formulation
271      IF( ll_purecpl      ) THEN   ;   nsbc = jp_purecpl ; icpt = icpt + 1   ;   ENDIF       ! Pure Coupled         formulation
272      IF( ll_opa          ) THEN   ;   nsbc = jp_none    ; icpt = icpt + 1   ;   ENDIF       ! opa coupling via SAS module
273      !
274      IF( icpt /= 1 )    CALL ctl_stop( 'sbc_init : choose ONE and only ONE sbc option' )
275      !
276      IF(lwp) THEN                     !- print the choice of surface flux formulation
277         WRITE(numout,*)
278         SELECT CASE( nsbc )
279         CASE( jp_usr     )   ;   WRITE(numout,*) '   ==>>>   user defined forcing formulation'
280         CASE( jp_flx     )   ;   WRITE(numout,*) '   ==>>>   flux formulation'
281         CASE( jp_blk     )   ;   WRITE(numout,*) '   ==>>>   bulk formulation'
282         CASE( jp_purecpl )   ;   WRITE(numout,*) '   ==>>>   pure coupled formulation'
283!!gm abusive use of jp_none ??   ===>>> need to be check and changed by adding a jp_sas parameter
284         CASE( jp_none    )   ;   WRITE(numout,*) '   ==>>>   OPA coupled to SAS via oasis'
285            IF( ln_mixcpl )       WRITE(numout,*) '               + forced-coupled mixed formulation'
286         END SELECT
287         IF( ll_not_nemo  )       WRITE(numout,*) '               + OASIS coupled SAS'
288      ENDIF
289      !
290      !                             !* OASIS initialization
291      !
292      IF( lk_oasis )   CALL sbc_cpl_init( nn_ice )   ! Must be done before: (1) first time step
293      !                                              !                      (2) the use of nn_fsbc
294      !     nn_fsbc initialization if OPA-SAS coupling via OASIS
295      !     SAS time-step has to be declared in OASIS (mandatory) -> nn_fsbc has to be modified accordingly
296      IF( nn_components /= jp_iam_nemo ) THEN
297         IF( nn_components == jp_iam_opa )   nn_fsbc = cpl_freq('O_SFLX') / NINT(rdt)
298         IF( nn_components == jp_iam_sas )   nn_fsbc = cpl_freq('I_SFLX') / NINT(rdt)
299         !
300         IF(lwp)THEN
301            WRITE(numout,*)
302            WRITE(numout,*)"   OPA-SAS coupled via OASIS : nn_fsbc re-defined from OASIS namcouple ", nn_fsbc
303            WRITE(numout,*)
304         ENDIF
305      ENDIF
306      !
307      !                             !* check consistency between model timeline and nn_fsbc
308      IF( MOD( nitend - nit000 + 1, nn_fsbc) /= 0 .OR.   &
309          MOD( nstock             , nn_fsbc) /= 0 ) THEN
310         WRITE(ctmp1,*) 'sbc_init : experiment length (', nitend - nit000 + 1, ') or nstock (', nstock,   &
311            &           ' is NOT a multiple of nn_fsbc (', nn_fsbc, ')'
312         CALL ctl_stop( ctmp1, 'Impossible to properly do model restart' )
313      ENDIF
314      !
315      IF( MOD( rday, REAL(nn_fsbc, wp) * rdt ) /= 0 )   &
316         &  CALL ctl_warn( 'sbc_init : nn_fsbc is NOT a multiple of the number of time steps in a day' )
317      !
318      IF( ln_dm2dc .AND. NINT(rday) / ( nn_fsbc * NINT(rdt) ) < 8  )   &
319         &   CALL ctl_warn( 'sbc_init : diurnal cycle for qsr: the sampling of the diurnal cycle is too small...' )
320      !
321   
322      !                       !**  associated modules : initialization
323      !
324                          CALL sbc_ssm_init            ! Sea-surface mean fields initialization
325      !
326      IF( ln_blk      )   CALL sbc_blk_init            ! bulk formulae initialization
327
328      IF( ln_ssr      )   CALL sbc_ssr_init            ! Sea-Surface Restoring initialization
329      !
330      IF( ln_isf      )   CALL sbc_isf_init            ! Compute iceshelves
331      !
332                          CALL sbc_rnf_init            ! Runof initialization
333      !
334      IF( ln_apr_dyn )    CALL sbc_apr_init            ! Atmo Pressure Forcing initialization
335      !
336#if defined key_si3
337      IF( lk_agrif .AND. nn_ice == 0 ) THEN            ! allocate ice arrays in case agrif + ice-model + no-ice in child grid
338                          IF( sbc_ice_alloc() /= 0 )   CALL ctl_stop('STOP', 'sbc_ice_alloc : unable to allocate arrays' )
339      ELSEIF( nn_ice == 2 ) THEN
340                          CALL ice_init                ! ICE initialization
341      ENDIF
342#endif
343      IF( nn_ice == 3 )   CALL cice_sbc_init( nsbc )   ! CICE initialization
344      !
345      IF( ln_wave     )   CALL sbc_wave_init           ! surface wave initialisation
346      !
347      IF( lwxios ) THEN
348         CALL iom_set_rstw_var_active('utau_b')
349         CALL iom_set_rstw_var_active('vtau_b')
350         CALL iom_set_rstw_var_active('qns_b')
351         ! The 3D heat content due to qsr forcing is treated in traqsr
352         ! CALL iom_set_rstw_var_active('qsr_b')
353         CALL iom_set_rstw_var_active('emp_b')
354         CALL iom_set_rstw_var_active('sfx_b')
355      ENDIF
356
357   END SUBROUTINE sbc_init
358
359
360   SUBROUTINE sbc( kt )
361      !!---------------------------------------------------------------------
362      !!                    ***  ROUTINE sbc  ***
363      !!
364      !! ** Purpose :   provide at each time-step the ocean surface boundary
365      !!                condition (momentum, heat and freshwater fluxes)
366      !!
367      !! ** Method  :   blah blah  to be written ?????????
368      !!                CAUTION : never mask the surface stress field (tke sbc)
369      !!
370      !! ** Action  : - set the ocean surface boundary condition at before and now
371      !!                time step, i.e.
372      !!                utau_b, vtau_b, qns_b, qsr_b, emp_n, sfx_b, qrp_b, erp_b
373      !!                utau  , vtau  , qns  , qsr  , emp  , sfx  , qrp  , erp
374      !!              - updte the ice fraction : fr_i
375      !!----------------------------------------------------------------------
376      INTEGER, INTENT(in) ::   kt   ! ocean time step
377      !
378      LOGICAL ::   ll_sas, ll_opa   ! local logical
379      !!---------------------------------------------------------------------
380      !
381      IF( ln_timing )   CALL timing_start('sbc')
382      !
383      !                                            ! ---------------------------------------- !
384      IF( kt /= nit000 ) THEN                      !          Swap of forcing fields          !
385         !                                         ! ---------------------------------------- !
386         utau_b(:,:) = utau(:,:)                         ! Swap the ocean forcing fields
387         vtau_b(:,:) = vtau(:,:)                         ! (except at nit000 where before fields
388         qns_b (:,:) = qns (:,:)                         !  are set at the end of the routine)
389         emp_b (:,:) = emp (:,:)
390         sfx_b (:,:) = sfx (:,:)
391         IF ( ln_rnf ) THEN
392            rnf_b    (:,:  ) = rnf    (:,:  )
393            rnf_tsc_b(:,:,:) = rnf_tsc(:,:,:)
394         ENDIF
395         IF( ln_isf )  THEN
396            fwfisf_b  (:,:  ) = fwfisf  (:,:  )               
397            risf_tsc_b(:,:,:) = risf_tsc(:,:,:)             
398         ENDIF
399        !
400      ENDIF
401      !                                            ! ---------------------------------------- !
402      !                                            !        forcing field computation         !
403      !                                            ! ---------------------------------------- !
404      !
405      ll_sas = nn_components == jp_iam_sas               ! component flags
406      ll_opa = nn_components == jp_iam_opa
407      !
408      IF( .NOT.ll_sas )   CALL sbc_ssm ( kt )            ! mean ocean sea surface variables (sst_m, sss_m, ssu_m, ssv_m)
409      IF( ln_wave     )   CALL sbc_wave( kt )            ! surface waves
410
411      !
412      !                                            !==  sbc formulation  ==!
413      !                                                   
414      SELECT CASE( nsbc )                                ! Compute ocean surface boundary condition
415      !                                                  ! (i.e. utau,vtau, qns, qsr, emp, sfx)
416      CASE( jp_usr   )     ;   CALL usrdef_sbc_oce( kt )                    ! user defined formulation
417      CASE( jp_flx     )   ;   CALL sbc_flx       ( kt )                    ! flux formulation
418      CASE( jp_blk     )
419         IF( ll_sas    )       CALL sbc_cpl_rcv   ( kt, nn_fsbc, nn_ice )   ! OPA-SAS coupling: SAS receiving fields from OPA
420                               CALL sbc_blk       ( kt )                    ! bulk formulation for the ocean
421                               !
422      CASE( jp_purecpl )   ;   CALL sbc_cpl_rcv   ( kt, nn_fsbc, nn_ice )   ! pure coupled formulation
423      CASE( jp_none    )
424         IF( ll_opa    )       CALL sbc_cpl_rcv   ( kt, nn_fsbc, nn_ice )   ! OPA-SAS coupling: OPA receiving fields from SAS
425      END SELECT
426      !
427      IF( ln_mixcpl )          CALL sbc_cpl_rcv   ( kt, nn_fsbc, nn_ice )   ! forced-coupled mixed formulation after forcing
428      !
429      IF ( ln_wave .AND. (ln_tauwoc .OR. ln_tauw) ) CALL sbc_wstress( )      ! Wind stress provided by waves
430      !
431      !                                            !==  Misc. Options  ==!
432      !
433      SELECT CASE( nn_ice )                                       ! Update heat and freshwater fluxes over sea-ice areas
434      CASE(  1 )   ;         CALL sbc_ice_if   ( kt )             ! Ice-cover climatology ("Ice-if" model)
435#if defined key_si3
436      CASE(  2 )   ;         CALL ice_stp  ( kt, nsbc )           ! SI3 ice model
437#endif
438      CASE(  3 )   ;         CALL sbc_ice_cice ( kt, nsbc )       ! CICE ice model
439      END SELECT
440
441      IF( ln_icebergs    )   THEN
442                                     CALL icb_stp( kt )           ! compute icebergs
443         ! icebergs may advect into haloes during the icb step and alter emp.
444         ! A lbc_lnk is necessary here to ensure restartability (#2113)
445         IF( .NOT. ln_passive_mode ) CALL lbc_lnk( 'sbcmod', emp, 'T', 1. ) ! ensure restartability with icebergs
446      ENDIF
447
448      IF( ln_isf         )   CALL sbc_isf( kt )                   ! compute iceshelves
449
450      IF( ln_rnf         )   CALL sbc_rnf( kt )                   ! add runoffs to fresh water fluxes
451
452      IF( ln_ssr         )   CALL sbc_ssr( kt )                   ! add SST/SSS damping term
453
454      IF( nn_fwb    /= 0 )   CALL sbc_fwb( kt, nn_fwb, nn_fsbc )  ! control the freshwater budget
455
456      ! Special treatment of freshwater fluxes over closed seas in the model domain
457      ! Should not be run if ln_diurnal_only
458      IF( l_sbc_clo .AND. (.NOT. ln_diurnal_only) )   CALL sbc_clo( kt )   
459
460!!$!RBbug do not understand why see ticket 667
461!!$!clem: it looks like it is necessary for the north fold (in certain circumstances). Don't know why.
462!!$      CALL lbc_lnk( 'sbcmod', emp, 'T', 1. )
463      !
464      IF( kt == nit000 ) THEN                          !   set the forcing field at nit000 - 1    !
465         !                                             ! ---------------------------------------- !
466         IF( ln_rstart .AND.    &                               !* Restart: read in restart file
467            & iom_varid( numror, 'utau_b', ldstop = .FALSE. ) > 0 ) THEN
468            IF(lwp) WRITE(numout,*) '          nit000-1 surface forcing fields red in the restart file'
469            CALL iom_get( numror, jpdom_autoglo, 'utau_b', utau_b, ldxios = lrxios )   ! before i-stress  (U-point)
470            CALL iom_get( numror, jpdom_autoglo, 'vtau_b', vtau_b, ldxios = lrxios )   ! before j-stress  (V-point)
471            CALL iom_get( numror, jpdom_autoglo, 'qns_b' , qns_b, ldxios = lrxios  )   ! before non solar heat flux (T-point)
472            ! The 3D heat content due to qsr forcing is treated in traqsr
473            ! CALL iom_get( numror, jpdom_autoglo, 'qsr_b' , qsr_b, ldxios = lrxios  ) ! before     solar heat flux (T-point)
474            CALL iom_get( numror, jpdom_autoglo, 'emp_b', emp_b, ldxios = lrxios  )    ! before     freshwater flux (T-point)
475            ! To ensure restart capability with 3.3x/3.4 restart files    !! to be removed in v3.6
476            IF( iom_varid( numror, 'sfx_b', ldstop = .FALSE. ) > 0 ) THEN
477               CALL iom_get( numror, jpdom_autoglo, 'sfx_b', sfx_b, ldxios = lrxios )  ! before salt flux (T-point)
478            ELSE
479               sfx_b (:,:) = sfx(:,:)
480            ENDIF
481         ELSE                                                   !* no restart: set from nit000 values
482            IF(lwp) WRITE(numout,*) '          nit000-1 surface forcing fields set to nit000'
483            utau_b(:,:) = utau(:,:)
484            vtau_b(:,:) = vtau(:,:)
485            qns_b (:,:) = qns (:,:)
486            emp_b (:,:) = emp (:,:)
487            sfx_b (:,:) = sfx (:,:)
488         ENDIF
489      ENDIF
490      !                                                ! ---------------------------------------- !
491      IF( lrst_oce ) THEN                              !      Write in the ocean restart file     !
492         !                                             ! ---------------------------------------- !
493         IF(lwp) WRITE(numout,*)
494         IF(lwp) WRITE(numout,*) 'sbc : ocean surface forcing fields written in ocean restart file ',   &
495            &                    'at it= ', kt,' date= ', ndastp
496         IF(lwp) WRITE(numout,*) '~~~~'
497         IF( lwxios ) CALL iom_swap(      cwxios_context          )
498         CALL iom_rstput( kt, nitrst, numrow, 'utau_b' , utau, ldxios = lwxios )
499         CALL iom_rstput( kt, nitrst, numrow, 'vtau_b' , vtau, ldxios = lwxios )
500         CALL iom_rstput( kt, nitrst, numrow, 'qns_b'  , qns, ldxios = lwxios  )
501         ! The 3D heat content due to qsr forcing is treated in traqsr
502         ! CALL iom_rstput( kt, nitrst, numrow, 'qsr_b'  , qsr  )
503         CALL iom_rstput( kt, nitrst, numrow, 'emp_b'  , emp, ldxios = lwxios  )
504         CALL iom_rstput( kt, nitrst, numrow, 'sfx_b'  , sfx, ldxios = lwxios  )
505         IF( lwxios ) CALL iom_swap(      cxios_context          )
506      ENDIF
507      !                                                ! ---------------------------------------- !
508      !                                                !        Outputs and control print         !
509      !                                                ! ---------------------------------------- !
510      IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN
511         CALL iom_put( "empmr"  , emp    - rnf )                ! upward water flux
512         CALL iom_put( "empbmr" , emp_b  - rnf )                ! before upward water flux ( needed to recalculate the time evolution of ssh in offline )
513         CALL iom_put( "saltflx", sfx  )                        ! downward salt flux (includes virtual salt flux beneath ice in linear free surface case)
514         CALL iom_put( "fmmflx", fmmflx  )                      ! Freezing-melting water flux
515         CALL iom_put( "qt"    , qns  + qsr )                   ! total heat flux
516         CALL iom_put( "qns"   , qns        )                   ! solar heat flux
517         CALL iom_put( "qsr"   ,       qsr  )                   ! solar heat flux
518         IF( nn_ice > 0 .OR. ll_opa )   CALL iom_put( "ice_cover", fr_i )   ! ice fraction
519         CALL iom_put( "taum"  , taum       )                   ! wind stress module
520         CALL iom_put( "wspd"  , wndm       )                   ! wind speed  module over free ocean or leads in presence of sea-ice
521      ENDIF
522      !
523      CALL iom_put( "utau", utau )   ! i-wind stress   (stress can be updated at each time step in sea-ice)
524      CALL iom_put( "vtau", vtau )   ! j-wind stress
525      !
526      IF(ln_ctl) THEN         ! print mean trends (used for debugging)
527         CALL prt_ctl(tab2d_1=fr_i              , clinfo1=' fr_i    - : ', mask1=tmask )
528         CALL prt_ctl(tab2d_1=(emp-rnf + fwfisf), clinfo1=' emp-rnf - : ', mask1=tmask )
529         CALL prt_ctl(tab2d_1=(sfx-rnf + fwfisf), clinfo1=' sfx-rnf - : ', mask1=tmask )
530         CALL prt_ctl(tab2d_1=qns              , clinfo1=' qns      - : ', mask1=tmask )
531         CALL prt_ctl(tab2d_1=qsr              , clinfo1=' qsr      - : ', mask1=tmask )
532         CALL prt_ctl(tab3d_1=tmask            , clinfo1=' tmask    - : ', mask1=tmask, kdim=jpk )
533         CALL prt_ctl(tab3d_1=tsn(:,:,:,jp_tem), clinfo1=' sst      - : ', mask1=tmask, kdim=1   )
534         CALL prt_ctl(tab3d_1=tsn(:,:,:,jp_sal), clinfo1=' sss      - : ', mask1=tmask, kdim=1   )
535         CALL prt_ctl(tab2d_1=utau             , clinfo1=' utau     - : ', mask1=umask,                      &
536            &         tab2d_2=vtau             , clinfo2=' vtau     - : ', mask2=vmask )
537      ENDIF
538
539      IF( kt == nitend )   CALL sbc_final         ! Close down surface module if necessary
540      !
541      IF( ln_timing )   CALL timing_stop('sbc')
542      !
543   END SUBROUTINE sbc
544
545
546   SUBROUTINE sbc_final
547      !!---------------------------------------------------------------------
548      !!                    ***  ROUTINE sbc_final  ***
549      !!
550      !! ** Purpose :   Finalize CICE (if used)
551      !!---------------------------------------------------------------------
552      !
553      IF( nn_ice == 3 )   CALL cice_sbc_final
554      !
555   END SUBROUTINE sbc_final
556
557   !!======================================================================
558END MODULE sbcmod
Note: See TracBrowser for help on using the repository browser.