source: NEMO/trunk/src/OCE/TRA/traadv_fct.F90 @ 13295

Last change on this file since 13295 was 13295, checked in by acc, 9 months ago

Replace do-loop macros in the trunk with alternative forms with greater flexibility for extra halo applications. This alters a lot of routines but does not change any behaviour or results. do_loop_substitute.h90 is greatly simplified by this change. SETTE results are identical to those with the previous revision

  • Property svn:keywords set to Id
File size: 33.3 KB
Line 
1MODULE traadv_fct
2   !!==============================================================================
3   !!                       ***  MODULE  traadv_fct  ***
4   !! Ocean  tracers:  horizontal & vertical advective trend (2nd/4th order Flux Corrected Transport method)
5   !!==============================================================================
6   !! History :  3.7  !  2015-09  (L. Debreu, G. Madec)  original code (inspired from traadv_tvd.F90)
7   !!----------------------------------------------------------------------
8
9   !!----------------------------------------------------------------------
10   !!  tra_adv_fct    : update the tracer trend with a 3D advective trends using a 2nd or 4th order FCT scheme
11   !!                   with sub-time-stepping in the vertical direction
12   !!  nonosc         : compute monotonic tracer fluxes by a non-oscillatory algorithm
13   !!  interp_4th_cpt : 4th order compact scheme for the vertical component of the advection
14   !!----------------------------------------------------------------------
15   USE oce            ! ocean dynamics and active tracers
16   USE dom_oce        ! ocean space and time domain
17   USE trc_oce        ! share passive tracers/Ocean variables
18   USE trd_oce        ! trends: ocean variables
19   USE trdtra         ! tracers trends
20   USE diaptr         ! poleward transport diagnostics
21   USE diaar5         ! AR5 diagnostics
22   USE phycst  , ONLY : rho0_rcp
23   USE zdf_oce , ONLY : ln_zad_Aimp
24   !
25   USE in_out_manager ! I/O manager
26   USE iom            !
27   USE lib_mpp        ! MPP library
28   USE lbclnk         ! ocean lateral boundary condition (or mpp link)
29   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
30
31   IMPLICIT NONE
32   PRIVATE
33
34   PUBLIC   tra_adv_fct        ! called by traadv.F90
35   PUBLIC   interp_4th_cpt     ! called by traadv_cen.F90
36
37   LOGICAL  ::   l_trd   ! flag to compute trends
38   LOGICAL  ::   l_ptr   ! flag to compute poleward transport
39   LOGICAL  ::   l_hst   ! flag to compute heat/salt transport
40   REAL(wp) ::   r1_6 = 1._wp / 6._wp   ! =1/6
41
42   !                                        ! tridiag solver associated indices:
43   INTEGER, PARAMETER ::   np_NH   = 0   ! Neumann homogeneous boundary condition
44   INTEGER, PARAMETER ::   np_CEN2 = 1   ! 2nd order centered  boundary condition
45
46   !! * Substitutions
47#  include "do_loop_substitute.h90"
48#  include "domzgr_substitute.h90"
49   !!----------------------------------------------------------------------
50   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
51   !! $Id$
52   !! Software governed by the CeCILL license (see ./LICENSE)
53   !!----------------------------------------------------------------------
54CONTAINS
55
56   SUBROUTINE tra_adv_fct( kt, kit000, cdtype, p2dt, pU, pV, pW,       &
57      &                    Kbb, Kmm, pt, kjpt, Krhs, kn_fct_h, kn_fct_v )
58      !!----------------------------------------------------------------------
59      !!                  ***  ROUTINE tra_adv_fct  ***
60      !!
61      !! **  Purpose :   Compute the now trend due to total advection of tracers
62      !!               and add it to the general trend of tracer equations
63      !!
64      !! **  Method  : - 2nd or 4th FCT scheme on the horizontal direction
65      !!               (choice through the value of kn_fct)
66      !!               - on the vertical the 4th order is a compact scheme
67      !!               - corrected flux (monotonic correction)
68      !!
69      !! ** Action : - update pt(:,:,:,:,Krhs)  with the now advective tracer trends
70      !!             - send trends to trdtra module for further diagnostics (l_trdtra=T)
71      !!             - poleward advective heat and salt transport (ln_diaptr=T)
72      !!----------------------------------------------------------------------
73      INTEGER                                  , INTENT(in   ) ::   kt              ! ocean time-step index
74      INTEGER                                  , INTENT(in   ) ::   Kbb, Kmm, Krhs  ! ocean time level indices
75      INTEGER                                  , INTENT(in   ) ::   kit000          ! first time step index
76      CHARACTER(len=3)                         , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
77      INTEGER                                  , INTENT(in   ) ::   kjpt            ! number of tracers
78      INTEGER                                  , INTENT(in   ) ::   kn_fct_h        ! order of the FCT scheme (=2 or 4)
79      INTEGER                                  , INTENT(in   ) ::   kn_fct_v        ! order of the FCT scheme (=2 or 4)
80      REAL(wp)                                 , INTENT(in   ) ::   p2dt            ! tracer time-step
81      REAL(wp), DIMENSION(jpi,jpj,jpk         ), INTENT(in   ) ::   pU, pV, pW      ! 3 ocean volume flux components
82      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt,jpt), INTENT(inout) ::   pt              ! tracers and RHS of tracer equation
83      !
84      INTEGER  ::   ji, jj, jk, jn                           ! dummy loop indices 
85      REAL(wp) ::   ztra                                     ! local scalar
86      REAL(wp) ::   zfp_ui, zfp_vj, zfp_wk, zC2t_u, zC4t_u   !   -      -
87      REAL(wp) ::   zfm_ui, zfm_vj, zfm_wk, zC2t_v, zC4t_v   !   -      -
88      REAL(wp), DIMENSION(jpi,jpj,jpk)        ::   zwi, zwx, zwy, zwz, ztu, ztv, zltu, zltv, ztw
89      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::   ztrdx, ztrdy, ztrdz, zptry
90      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::   zwinf, zwdia, zwsup
91      LOGICAL  ::   ll_zAimp                                 ! flag to apply adaptive implicit vertical advection
92      !!----------------------------------------------------------------------
93      !
94      IF( kt == kit000 )  THEN
95         IF(lwp) WRITE(numout,*)
96         IF(lwp) WRITE(numout,*) 'tra_adv_fct : FCT advection scheme on ', cdtype
97         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
98      ENDIF
99      !! -- init to 0
100      zwi(:,:,:) = 0._wp
101      zwx(:,:,:) = 0._wp
102      zwy(:,:,:) = 0._wp
103      zwz(:,:,:) = 0._wp
104      ztu(:,:,:) = 0._wp
105      ztv(:,:,:) = 0._wp
106      zltu(:,:,:) = 0._wp
107      zltv(:,:,:) = 0._wp
108      ztw(:,:,:) = 0._wp
109      !
110      l_trd = .FALSE.            ! set local switches
111      l_hst = .FALSE.
112      l_ptr = .FALSE.
113      ll_zAimp = .FALSE.
114      IF( ( cdtype == 'TRA' .AND. l_trdtra  ) .OR. ( cdtype =='TRC' .AND. l_trdtrc ) )      l_trd = .TRUE.
115      IF(   cdtype == 'TRA' .AND. ( iom_use( 'sophtadv' ) .OR. iom_use( 'sophtadv' ) ) )    l_ptr = .TRUE. 
116      IF(   cdtype == 'TRA' .AND. ( iom_use("uadv_heattr") .OR. iom_use("vadv_heattr") .OR.  &
117         &                         iom_use("uadv_salttr") .OR. iom_use("vadv_salttr")  ) )  l_hst = .TRUE.
118      !
119      IF( l_trd .OR. l_hst )  THEN
120         ALLOCATE( ztrdx(jpi,jpj,jpk), ztrdy(jpi,jpj,jpk), ztrdz(jpi,jpj,jpk) )
121         ztrdx(:,:,:) = 0._wp   ;    ztrdy(:,:,:) = 0._wp   ;   ztrdz(:,:,:) = 0._wp
122      ENDIF
123      !
124      IF( l_ptr ) THEN 
125         ALLOCATE( zptry(jpi,jpj,jpk) )
126         zptry(:,:,:) = 0._wp
127      ENDIF
128      !                          ! surface & bottom value : flux set to zero one for all
129      zwz(:,:, 1 ) = 0._wp           
130      zwx(:,:,jpk) = 0._wp   ;   zwy(:,:,jpk) = 0._wp    ;    zwz(:,:,jpk) = 0._wp
131      !
132      zwi(:,:,:) = 0._wp       
133      !
134      ! If adaptive vertical advection, check if it is needed on this PE at this time
135      IF( ln_zad_Aimp ) THEN
136         IF( MAXVAL( ABS( wi(:,:,:) ) ) > 0._wp ) ll_zAimp = .TRUE.
137      END IF
138      ! If active adaptive vertical advection, build tridiagonal matrix
139      IF( ll_zAimp ) THEN
140         ALLOCATE(zwdia(jpi,jpj,jpk), zwinf(jpi,jpj,jpk),zwsup(jpi,jpj,jpk))
141         DO_3D( 0, 0, 0, 0, 1, jpkm1 )
142            zwdia(ji,jj,jk) =  1._wp + p2dt * ( MAX( wi(ji,jj,jk) , 0._wp ) - MIN( wi(ji,jj,jk+1) , 0._wp ) )   &
143            &                               / e3t(ji,jj,jk,Krhs)
144            zwinf(ji,jj,jk) =  p2dt * MIN( wi(ji,jj,jk  ) , 0._wp ) / e3t(ji,jj,jk,Krhs)
145            zwsup(ji,jj,jk) = -p2dt * MAX( wi(ji,jj,jk+1) , 0._wp ) / e3t(ji,jj,jk,Krhs)
146         END_3D
147      END IF
148      !
149      DO jn = 1, kjpt            !==  loop over the tracers  ==!
150         !
151         !        !==  upstream advection with initial mass fluxes & intermediate update  ==!
152         !                    !* upstream tracer flux in the i and j direction
153         DO_3D( 1, 0, 1, 0, 1, jpkm1 )
154            ! upstream scheme
155            zfp_ui = pU(ji,jj,jk) + ABS( pU(ji,jj,jk) )
156            zfm_ui = pU(ji,jj,jk) - ABS( pU(ji,jj,jk) )
157            zfp_vj = pV(ji,jj,jk) + ABS( pV(ji,jj,jk) )
158            zfm_vj = pV(ji,jj,jk) - ABS( pV(ji,jj,jk) )
159            zwx(ji,jj,jk) = 0.5 * ( zfp_ui * pt(ji,jj,jk,jn,Kbb) + zfm_ui * pt(ji+1,jj  ,jk,jn,Kbb) )
160            zwy(ji,jj,jk) = 0.5 * ( zfp_vj * pt(ji,jj,jk,jn,Kbb) + zfm_vj * pt(ji  ,jj+1,jk,jn,Kbb) )
161         END_3D
162         !                    !* upstream tracer flux in the k direction *!
163         DO_3D( 1, 1, 1, 1, 2, jpkm1 )
164            zfp_wk = pW(ji,jj,jk) + ABS( pW(ji,jj,jk) )
165            zfm_wk = pW(ji,jj,jk) - ABS( pW(ji,jj,jk) )
166            zwz(ji,jj,jk) = 0.5 * ( zfp_wk * pt(ji,jj,jk,jn,Kbb) + zfm_wk * pt(ji,jj,jk-1,jn,Kbb) ) * wmask(ji,jj,jk)
167         END_3D
168         IF( ln_linssh ) THEN    ! top ocean value (only in linear free surface as zwz has been w-masked)
169            IF( ln_isfcav ) THEN             ! top of the ice-shelf cavities and at the ocean surface
170               DO_2D( 1, 1, 1, 1 )
171                  zwz(ji,jj, mikt(ji,jj) ) = pW(ji,jj,mikt(ji,jj)) * pt(ji,jj,mikt(ji,jj),jn,Kbb)   ! linear free surface
172               END_2D
173            ELSE                             ! no cavities: only at the ocean surface
174               DO_2D( 1, 1, 1, 1 )
175                  zwz(ji,jj,1) = pW(ji,jj,1) * pt(ji,jj,1,jn,Kbb)
176               END_2D
177            ENDIF
178         ENDIF
179         !               
180         DO_3D( 0, 0, 0, 0, 1, jpkm1 )
181            !                             ! total intermediate advective trends
182            ztra = - (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
183               &      + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
184               &      + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) ) * r1_e1e2t(ji,jj)
185            !                             ! update and guess with monotonic sheme
186            pt(ji,jj,jk,jn,Krhs) =                   pt(ji,jj,jk,jn,Krhs) +       ztra   &
187               &                                  / e3t(ji,jj,jk,Kmm ) * tmask(ji,jj,jk)
188            zwi(ji,jj,jk)    = ( e3t(ji,jj,jk,Kbb) * pt(ji,jj,jk,jn,Kbb) + p2dt * ztra ) &
189               &                                  / e3t(ji,jj,jk,Krhs) * tmask(ji,jj,jk)
190         END_3D
191         
192         IF ( ll_zAimp ) THEN
193            CALL tridia_solver( zwdia, zwsup, zwinf, zwi, zwi , 0 )
194            !
195            ztw(:,:,1) = 0._wp ; ztw(:,:,jpk) = 0._wp ;
196            DO_3D( 0, 0, 0, 0, 2, jpkm1 )
197               zfp_wk = wi(ji,jj,jk) + ABS( wi(ji,jj,jk) )
198               zfm_wk = wi(ji,jj,jk) - ABS( wi(ji,jj,jk) )
199               ztw(ji,jj,jk) =  0.5 * e1e2t(ji,jj) * ( zfp_wk * zwi(ji,jj,jk) + zfm_wk * zwi(ji,jj,jk-1) ) * wmask(ji,jj,jk)
200               zwz(ji,jj,jk) = zwz(ji,jj,jk) + ztw(ji,jj,jk) ! update vertical fluxes
201            END_3D
202            DO_3D( 0, 0, 0, 0, 1, jpkm1 )
203               pt(ji,jj,jk,jn,Krhs) = pt(ji,jj,jk,jn,Krhs) - ( ztw(ji,jj,jk) - ztw(ji  ,jj  ,jk+1) ) &
204                  &                                        * r1_e1e2t(ji,jj) / e3t(ji,jj,jk,Kmm)
205            END_3D
206            !
207         END IF
208         !               
209         IF( l_trd .OR. l_hst )  THEN             ! trend diagnostics (contribution of upstream fluxes)
210            ztrdx(:,:,:) = zwx(:,:,:)   ;   ztrdy(:,:,:) = zwy(:,:,:)   ;   ztrdz(:,:,:) = zwz(:,:,:)
211         END IF
212         !                             ! "Poleward" heat and salt transports (contribution of upstream fluxes)
213         IF( l_ptr )   zptry(:,:,:) = zwy(:,:,:) 
214         !
215         !        !==  anti-diffusive flux : high order minus low order  ==!
216         !
217         SELECT CASE( kn_fct_h )    !* horizontal anti-diffusive fluxes
218         !
219         CASE(  2  )                   !- 2nd order centered
220            DO_3D( 1, 0, 1, 0, 1, jpkm1 )
221               zwx(ji,jj,jk) = 0.5_wp * pU(ji,jj,jk) * ( pt(ji,jj,jk,jn,Kmm) + pt(ji+1,jj,jk,jn,Kmm) ) - zwx(ji,jj,jk)
222               zwy(ji,jj,jk) = 0.5_wp * pV(ji,jj,jk) * ( pt(ji,jj,jk,jn,Kmm) + pt(ji,jj+1,jk,jn,Kmm) ) - zwy(ji,jj,jk)
223            END_3D
224            !
225         CASE(  4  )                   !- 4th order centered
226            zltu(:,:,jpk) = 0._wp            ! Bottom value : flux set to zero
227            zltv(:,:,jpk) = 0._wp
228            DO jk = 1, jpkm1                 ! Laplacian
229               DO_2D( 1, 0, 1, 0 )
230                  ztu(ji,jj,jk) = ( pt(ji+1,jj  ,jk,jn,Kmm) - pt(ji,jj,jk,jn,Kmm) ) * umask(ji,jj,jk)
231                  ztv(ji,jj,jk) = ( pt(ji  ,jj+1,jk,jn,Kmm) - pt(ji,jj,jk,jn,Kmm) ) * vmask(ji,jj,jk)
232               END_2D
233               DO_2D( 0, 0, 0, 0 )
234                  zltu(ji,jj,jk) = (  ztu(ji,jj,jk) + ztu(ji-1,jj,jk)  ) * r1_6
235                  zltv(ji,jj,jk) = (  ztv(ji,jj,jk) + ztv(ji,jj-1,jk)  ) * r1_6
236               END_2D
237            END DO
238            CALL lbc_lnk_multi( 'traadv_fct', zltu, 'T', 1.0_wp , zltv, 'T', 1.0_wp )   ! Lateral boundary cond. (unchanged sgn)
239            !
240            DO_3D( 1, 0, 1, 0, 1, jpkm1 )
241               zC2t_u = pt(ji,jj,jk,jn,Kmm) + pt(ji+1,jj  ,jk,jn,Kmm)   ! 2 x C2 interpolation of T at u- & v-points
242               zC2t_v = pt(ji,jj,jk,jn,Kmm) + pt(ji  ,jj+1,jk,jn,Kmm)
243               !                                                  ! C4 minus upstream advective fluxes
244               zwx(ji,jj,jk) =  0.5_wp * pU(ji,jj,jk) * ( zC2t_u + zltu(ji,jj,jk) - zltu(ji+1,jj,jk) ) - zwx(ji,jj,jk)
245               zwy(ji,jj,jk) =  0.5_wp * pV(ji,jj,jk) * ( zC2t_v + zltv(ji,jj,jk) - zltv(ji,jj+1,jk) ) - zwy(ji,jj,jk)
246            END_3D
247            !
248         CASE(  41 )                   !- 4th order centered       ==>>   !!gm coding attempt   need to be tested
249            ztu(:,:,jpk) = 0._wp             ! Bottom value : flux set to zero
250            ztv(:,:,jpk) = 0._wp
251            DO_3D( 1, 0, 1, 0, 1, jpkm1 )
252               ztu(ji,jj,jk) = ( pt(ji+1,jj  ,jk,jn,Kmm) - pt(ji,jj,jk,jn,Kmm) ) * umask(ji,jj,jk)
253               ztv(ji,jj,jk) = ( pt(ji  ,jj+1,jk,jn,Kmm) - pt(ji,jj,jk,jn,Kmm) ) * vmask(ji,jj,jk)
254            END_3D
255            CALL lbc_lnk_multi( 'traadv_fct', ztu, 'U', -1.0_wp , ztv, 'V', -1.0_wp )   ! Lateral boundary cond. (unchanged sgn)
256            !
257            DO_3D( 0, 0, 0, 0, 1, jpkm1 )
258               zC2t_u = pt(ji,jj,jk,jn,Kmm) + pt(ji+1,jj  ,jk,jn,Kmm)   ! 2 x C2 interpolation of T at u- & v-points (x2)
259               zC2t_v = pt(ji,jj,jk,jn,Kmm) + pt(ji  ,jj+1,jk,jn,Kmm)
260               !                                                  ! C4 interpolation of T at u- & v-points (x2)
261               zC4t_u =  zC2t_u + r1_6 * ( ztu(ji-1,jj  ,jk) - ztu(ji+1,jj  ,jk) )
262               zC4t_v =  zC2t_v + r1_6 * ( ztv(ji  ,jj-1,jk) - ztv(ji  ,jj+1,jk) )
263               !                                                  ! C4 minus upstream advective fluxes
264               zwx(ji,jj,jk) =  0.5_wp * pU(ji,jj,jk) * zC4t_u - zwx(ji,jj,jk)
265               zwy(ji,jj,jk) =  0.5_wp * pV(ji,jj,jk) * zC4t_v - zwy(ji,jj,jk)
266            END_3D
267            !
268         END SELECT
269         !                     
270         SELECT CASE( kn_fct_v )    !* vertical anti-diffusive fluxes (w-masked interior values)
271         !
272         CASE(  2  )                   !- 2nd order centered
273            DO_3D( 0, 0, 0, 0, 2, jpkm1 )
274               zwz(ji,jj,jk) =  (  pW(ji,jj,jk) * 0.5_wp * ( pt(ji,jj,jk,jn,Kmm) + pt(ji,jj,jk-1,jn,Kmm) )   &
275                  &              - zwz(ji,jj,jk)  ) * wmask(ji,jj,jk)
276            END_3D
277            !
278         CASE(  4  )                   !- 4th order COMPACT
279            CALL interp_4th_cpt( pt(:,:,:,jn,Kmm) , ztw )   ! zwt = COMPACT interpolation of T at w-point
280            DO_3D( 0, 0, 0, 0, 2, jpkm1 )
281               zwz(ji,jj,jk) = ( pW(ji,jj,jk) * ztw(ji,jj,jk) - zwz(ji,jj,jk) ) * wmask(ji,jj,jk)
282            END_3D
283            !
284         END SELECT
285         IF( ln_linssh ) THEN    ! top ocean value: high order = upstream  ==>>  zwz=0
286            zwz(:,:,1) = 0._wp   ! only ocean surface as interior zwz values have been w-masked
287         ENDIF
288         !         
289         IF ( ll_zAimp ) THEN
290            DO_3D( 0, 0, 0, 0, 1, jpkm1 )
291               !                             ! total intermediate advective trends
292               ztra = - (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
293                  &      + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
294                  &      + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) ) * r1_e1e2t(ji,jj)
295               ztw(ji,jj,jk)  = zwi(ji,jj,jk) + p2dt * ztra / e3t(ji,jj,jk,Krhs) * tmask(ji,jj,jk)
296            END_3D
297            !
298            CALL tridia_solver( zwdia, zwsup, zwinf, ztw, ztw , 0 )
299            !
300            DO_3D( 0, 0, 0, 0, 2, jpkm1 )
301               zfp_wk = wi(ji,jj,jk) + ABS( wi(ji,jj,jk) )
302               zfm_wk = wi(ji,jj,jk) - ABS( wi(ji,jj,jk) )
303               zwz(ji,jj,jk) =  zwz(ji,jj,jk) + 0.5 * e1e2t(ji,jj) * ( zfp_wk * ztw(ji,jj,jk) + zfm_wk * ztw(ji,jj,jk-1) ) * wmask(ji,jj,jk)
304            END_3D
305         END IF
306         !
307         CALL lbc_lnk_multi( 'traadv_fct', zwi, 'T', 1.0_wp, zwx, 'U', -1.0_wp , zwy, 'V', -1.0_wp,  zwz, 'W',  1.0_wp )
308         !
309         !        !==  monotonicity algorithm  ==!
310         !
311         CALL nonosc( Kmm, pt(:,:,:,jn,Kbb), zwx, zwy, zwz, zwi, p2dt )
312         !
313         !        !==  final trend with corrected fluxes  ==!
314         !
315         DO_3D( 0, 0, 0, 0, 1, jpkm1 )
316            ztra = - (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
317               &      + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
318               &      + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) ) * r1_e1e2t(ji,jj)
319            pt(ji,jj,jk,jn,Krhs) = pt(ji,jj,jk,jn,Krhs) + ztra / e3t(ji,jj,jk,Kmm)
320            zwi(ji,jj,jk) = zwi(ji,jj,jk) + p2dt * ztra / e3t(ji,jj,jk,Krhs) * tmask(ji,jj,jk)
321         END_3D
322         !
323         IF ( ll_zAimp ) THEN
324            !
325            ztw(:,:,1) = 0._wp ; ztw(:,:,jpk) = 0._wp
326            DO_3D( 0, 0, 0, 0, 2, jpkm1 )
327               zfp_wk = wi(ji,jj,jk) + ABS( wi(ji,jj,jk) )
328               zfm_wk = wi(ji,jj,jk) - ABS( wi(ji,jj,jk) )
329               ztw(ji,jj,jk) = - 0.5 * e1e2t(ji,jj) * ( zfp_wk * zwi(ji,jj,jk) + zfm_wk * zwi(ji,jj,jk-1) ) * wmask(ji,jj,jk)
330               zwz(ji,jj,jk) = zwz(ji,jj,jk) + ztw(ji,jj,jk) ! Update vertical fluxes for trend diagnostic
331            END_3D
332            DO_3D( 0, 0, 0, 0, 1, jpkm1 )
333               pt(ji,jj,jk,jn,Krhs) = pt(ji,jj,jk,jn,Krhs) - ( ztw(ji,jj,jk) - ztw(ji  ,jj  ,jk+1) ) &
334                  &                                        * r1_e1e2t(ji,jj) / e3t(ji,jj,jk,Kmm)
335            END_3D
336         END IF         
337         !
338         IF( l_trd .OR. l_hst ) THEN   ! trend diagnostics // heat/salt transport
339            ztrdx(:,:,:) = ztrdx(:,:,:) + zwx(:,:,:)  ! <<< add anti-diffusive fluxes
340            ztrdy(:,:,:) = ztrdy(:,:,:) + zwy(:,:,:)  !     to upstream fluxes
341            ztrdz(:,:,:) = ztrdz(:,:,:) + zwz(:,:,:)  !
342            !
343            IF( l_trd ) THEN              ! trend diagnostics
344               CALL trd_tra( kt, Kmm, Krhs, cdtype, jn, jptra_xad, ztrdx, pU, pt(:,:,:,jn,Kmm) )
345               CALL trd_tra( kt, Kmm, Krhs, cdtype, jn, jptra_yad, ztrdy, pV, pt(:,:,:,jn,Kmm) )
346               CALL trd_tra( kt, Kmm, Krhs, cdtype, jn, jptra_zad, ztrdz, pW, pt(:,:,:,jn,Kmm) )
347            ENDIF
348            !                             ! heat/salt transport
349            IF( l_hst )   CALL dia_ar5_hst( jn, 'adv', ztrdx(:,:,:), ztrdy(:,:,:) )
350            !
351         ENDIF
352         IF( l_ptr ) THEN              ! "Poleward" transports
353            zptry(:,:,:) = zptry(:,:,:) + zwy(:,:,:)  ! <<< add anti-diffusive fluxes
354            CALL dia_ptr_hst( jn, 'adv', zptry(:,:,:) )
355         ENDIF
356         !
357      END DO                     ! end of tracer loop
358      !
359      IF ( ll_zAimp ) THEN
360         DEALLOCATE( zwdia, zwinf, zwsup )
361      ENDIF
362      IF( l_trd .OR. l_hst ) THEN
363         DEALLOCATE( ztrdx, ztrdy, ztrdz )
364      ENDIF
365      IF( l_ptr ) THEN
366         DEALLOCATE( zptry )
367      ENDIF
368      !
369   END SUBROUTINE tra_adv_fct
370
371
372   SUBROUTINE nonosc( Kmm, pbef, paa, pbb, pcc, paft, p2dt )
373      !!---------------------------------------------------------------------
374      !!                    ***  ROUTINE nonosc  ***
375      !!     
376      !! **  Purpose :   compute monotonic tracer fluxes from the upstream
377      !!       scheme and the before field by a nonoscillatory algorithm
378      !!
379      !! **  Method  :   ... ???
380      !!       warning : pbef and paft must be masked, but the boundaries
381      !!       conditions on the fluxes are not necessary zalezak (1979)
382      !!       drange (1995) multi-dimensional forward-in-time and upstream-
383      !!       in-space based differencing for fluid
384      !!----------------------------------------------------------------------
385      INTEGER                          , INTENT(in   ) ::   Kmm             ! time level index
386      REAL(wp)                         , INTENT(in   ) ::   p2dt            ! tracer time-step
387      REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT(in   ) ::   pbef, paft      ! before & after field
388      REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT(inout) ::   paa, pbb, pcc   ! monotonic fluxes in the 3 directions
389      !
390      INTEGER  ::   ji, jj, jk   ! dummy loop indices
391      INTEGER  ::   ikm1         ! local integer
392      REAL(dp) ::   zpos, zneg, zbt, za, zb, zc, zbig, zrtrn    ! local scalars
393      REAL(dp) ::   zau, zbu, zcu, zav, zbv, zcv, zup, zdo            !   -      -
394      REAL(dp), DIMENSION(jpi,jpj,jpk) :: zbetup, zbetdo, zbup, zbdo
395      !!----------------------------------------------------------------------
396      !
397      zbig  = 1.e+40_dp
398      zrtrn = 1.e-15_dp
399      zbetup(:,:,:) = 0._dp   ;   zbetdo(:,:,:) = 0._dp
400
401      ! Search local extrema
402      ! --------------------
403      ! max/min of pbef & paft with large negative/positive value (-/+zbig) inside land
404      zbup = MAX( pbef * tmask - zbig * ( 1._wp - tmask ),   &
405         &        paft * tmask - zbig * ( 1._wp - tmask )  )
406      zbdo = MIN( pbef * tmask + zbig * ( 1._wp - tmask ),   &
407         &        paft * tmask + zbig * ( 1._wp - tmask )  )
408
409      DO jk = 1, jpkm1
410         ikm1 = MAX(jk-1,1)
411         DO_2D( 0, 0, 0, 0 )
412
413            ! search maximum in neighbourhood
414            zup = MAX(  zbup(ji  ,jj  ,jk  ),   &
415               &        zbup(ji-1,jj  ,jk  ), zbup(ji+1,jj  ,jk  ),   &
416               &        zbup(ji  ,jj-1,jk  ), zbup(ji  ,jj+1,jk  ),   &
417               &        zbup(ji  ,jj  ,ikm1), zbup(ji  ,jj  ,jk+1)  )
418
419            ! search minimum in neighbourhood
420            zdo = MIN(  zbdo(ji  ,jj  ,jk  ),   &
421               &        zbdo(ji-1,jj  ,jk  ), zbdo(ji+1,jj  ,jk  ),   &
422               &        zbdo(ji  ,jj-1,jk  ), zbdo(ji  ,jj+1,jk  ),   &
423               &        zbdo(ji  ,jj  ,ikm1), zbdo(ji  ,jj  ,jk+1)  )
424
425            ! positive part of the flux
426            zpos = MAX( 0., paa(ji-1,jj  ,jk  ) ) - MIN( 0., paa(ji  ,jj  ,jk  ) )   &
427               & + MAX( 0., pbb(ji  ,jj-1,jk  ) ) - MIN( 0., pbb(ji  ,jj  ,jk  ) )   &
428               & + MAX( 0., pcc(ji  ,jj  ,jk+1) ) - MIN( 0., pcc(ji  ,jj  ,jk  ) )
429
430            ! negative part of the flux
431            zneg = MAX( 0., paa(ji  ,jj  ,jk  ) ) - MIN( 0., paa(ji-1,jj  ,jk  ) )   &
432               & + MAX( 0., pbb(ji  ,jj  ,jk  ) ) - MIN( 0., pbb(ji  ,jj-1,jk  ) )   &
433               & + MAX( 0., pcc(ji  ,jj  ,jk  ) ) - MIN( 0., pcc(ji  ,jj  ,jk+1) )
434
435            ! up & down beta terms
436            zbt = e1e2t(ji,jj) * e3t(ji,jj,jk,Kmm) / p2dt
437            zbetup(ji,jj,jk) = ( zup            - paft(ji,jj,jk) ) / ( zpos + zrtrn ) * zbt
438            zbetdo(ji,jj,jk) = ( paft(ji,jj,jk) - zdo            ) / ( zneg + zrtrn ) * zbt
439         END_2D
440      END DO
441      CALL lbc_lnk_multi( 'traadv_fct', zbetup, 'T', 1.0_wp , zbetdo, 'T', 1.0_wp )   ! lateral boundary cond. (unchanged sign)
442
443      ! 3. monotonic flux in the i & j direction (paa & pbb)
444      ! ----------------------------------------
445      DO_3D( 0, 0, 0, 0, 1, jpkm1 )
446         zau = MIN( 1._wp, zbetdo(ji,jj,jk), zbetup(ji+1,jj,jk) )
447         zbu = MIN( 1._wp, zbetup(ji,jj,jk), zbetdo(ji+1,jj,jk) )
448         zcu =       ( 0.5  + SIGN( 0.5_wp , paa(ji,jj,jk) ) )
449         paa(ji,jj,jk) = paa(ji,jj,jk) * ( zcu * zau + ( 1._wp - zcu) * zbu )
450
451         zav = MIN( 1._wp, zbetdo(ji,jj,jk), zbetup(ji,jj+1,jk) )
452         zbv = MIN( 1._wp, zbetup(ji,jj,jk), zbetdo(ji,jj+1,jk) )
453         zcv =       ( 0.5  + SIGN( 0.5_wp , pbb(ji,jj,jk) ) )
454         pbb(ji,jj,jk) = pbb(ji,jj,jk) * ( zcv * zav + ( 1._wp - zcv) * zbv )
455
456! monotonic flux in the k direction, i.e. pcc
457! -------------------------------------------
458         za = MIN( 1., zbetdo(ji,jj,jk+1), zbetup(ji,jj,jk) )
459         zb = MIN( 1., zbetup(ji,jj,jk+1), zbetdo(ji,jj,jk) )
460         zc =       ( 0.5  + SIGN( 0.5_wp , pcc(ji,jj,jk+1) ) )
461         pcc(ji,jj,jk+1) = pcc(ji,jj,jk+1) * ( zc * za + ( 1._wp - zc) * zb )
462      END_3D
463      CALL lbc_lnk_multi( 'traadv_fct', paa, 'U', -1.0_wp , pbb, 'V', -1.0_wp )   ! lateral boundary condition (changed sign)
464      !
465   END SUBROUTINE nonosc
466
467
468   SUBROUTINE interp_4th_cpt_org( pt_in, pt_out )
469      !!----------------------------------------------------------------------
470      !!                  ***  ROUTINE interp_4th_cpt_org  ***
471      !!
472      !! **  Purpose :   Compute the interpolation of tracer at w-point
473      !!
474      !! **  Method  :   4th order compact interpolation
475      !!----------------------------------------------------------------------
476      REAL(wp),DIMENSION(jpi,jpj,jpk), INTENT(in   ) ::   pt_in    ! now tracer fields
477      REAL(wp),DIMENSION(jpi,jpj,jpk), INTENT(  out) ::   pt_out   ! now tracer field interpolated at w-pts
478      !
479      INTEGER :: ji, jj, jk   ! dummy loop integers
480      REAL(wp),DIMENSION(jpi,jpj,jpk) :: zwd, zwi, zws, zwrm, zwt
481      !!----------------------------------------------------------------------
482     
483      DO_3D( 1, 1, 1, 1, 3, jpkm1 )
484         zwd (ji,jj,jk) = 4._wp
485         zwi (ji,jj,jk) = 1._wp
486         zws (ji,jj,jk) = 1._wp
487         zwrm(ji,jj,jk) = 3._wp * ( pt_in(ji,jj,jk-1) + pt_in(ji,jj,jk) )
488         !
489         IF( tmask(ji,jj,jk+1) == 0._wp) THEN   ! Switch to second order centered at bottom
490            zwd (ji,jj,jk) = 1._wp
491            zwi (ji,jj,jk) = 0._wp
492            zws (ji,jj,jk) = 0._wp
493            zwrm(ji,jj,jk) = 0.5 * ( pt_in(ji,jj,jk-1) + pt_in(ji,jj,jk) )   
494         ENDIF
495      END_3D
496      !
497      jk = 2                                          ! Switch to second order centered at top
498      DO_2D( 1, 1, 1, 1 )
499         zwd (ji,jj,jk) = 1._wp
500         zwi (ji,jj,jk) = 0._wp
501         zws (ji,jj,jk) = 0._wp
502         zwrm(ji,jj,jk) = 0.5 * ( pt_in(ji,jj,jk-1) + pt_in(ji,jj,jk) )
503      END_2D
504      !
505      !                       !==  tridiagonal solve  ==!
506      DO_2D( 1, 1, 1, 1 )
507         zwt(ji,jj,2) = zwd(ji,jj,2)
508      END_2D
509      DO_3D( 1, 1, 1, 1, 3, jpkm1 )
510         zwt(ji,jj,jk) = zwd(ji,jj,jk) - zwi(ji,jj,jk) * zws(ji,jj,jk-1) /zwt(ji,jj,jk-1)
511      END_3D
512      !
513      DO_2D( 1, 1, 1, 1 )
514         pt_out(ji,jj,2) = zwrm(ji,jj,2)
515      END_2D
516      DO_3D( 1, 1, 1, 1, 3, jpkm1 )
517         pt_out(ji,jj,jk) = zwrm(ji,jj,jk) - zwi(ji,jj,jk) / zwt(ji,jj,jk-1) *pt_out(ji,jj,jk-1)             
518      END_3D
519
520      DO_2D( 1, 1, 1, 1 )
521         pt_out(ji,jj,jpkm1) = pt_out(ji,jj,jpkm1) / zwt(ji,jj,jpkm1)
522      END_2D
523      DO_3DS( 1, 1, 1, 1, jpk-2, 2, -1 )
524         pt_out(ji,jj,jk) = ( pt_out(ji,jj,jk) - zws(ji,jj,jk) * pt_out(ji,jj,jk+1) ) / zwt(ji,jj,jk)
525      END_3D
526      !   
527   END SUBROUTINE interp_4th_cpt_org
528   
529
530   SUBROUTINE interp_4th_cpt( pt_in, pt_out )
531      !!----------------------------------------------------------------------
532      !!                  ***  ROUTINE interp_4th_cpt  ***
533      !!
534      !! **  Purpose :   Compute the interpolation of tracer at w-point
535      !!
536      !! **  Method  :   4th order compact interpolation
537      !!----------------------------------------------------------------------
538      REAL(wp),DIMENSION(jpi,jpj,jpk), INTENT(in   ) ::   pt_in    ! field at t-point
539      REAL(wp),DIMENSION(jpi,jpj,jpk), INTENT(  out) ::   pt_out   ! field interpolated at w-point
540      !
541      INTEGER ::   ji, jj, jk   ! dummy loop integers
542      INTEGER ::   ikt, ikb     ! local integers
543      REAL(wp),DIMENSION(jpi,jpj,jpk) :: zwd, zwi, zws, zwrm, zwt
544      !!----------------------------------------------------------------------
545      !
546      !                      !==  build the three diagonal matrix & the RHS  ==!
547      !
548      DO_3D( 0, 0, 0, 0, 3, jpkm1 )
549         zwd (ji,jj,jk) = 3._wp * wmask(ji,jj,jk) + 1._wp                 !       diagonal
550         zwi (ji,jj,jk) =         wmask(ji,jj,jk)                         ! lower diagonal
551         zws (ji,jj,jk) =         wmask(ji,jj,jk)                         ! upper diagonal
552         zwrm(ji,jj,jk) = 3._wp * wmask(ji,jj,jk)                     &   ! RHS
553            &           *       ( pt_in(ji,jj,jk) + pt_in(ji,jj,jk-1) )
554      END_3D
555      !
556!!gm
557!      SELECT CASE( kbc )               !* boundary condition
558!      CASE( np_NH   )   ! Neumann homogeneous at top & bottom
559!      CASE( np_CEN2 )   ! 2nd order centered  at top & bottom
560!      END SELECT
561!!gm 
562      !
563      IF ( ln_isfcav ) THEN            ! set level two values which may not be set in ISF case
564         zwd(:,:,2) = 1._wp  ;  zwi(:,:,2) = 0._wp  ;  zws(:,:,2) = 0._wp  ;  zwrm(:,:,2) = 0._wp
565      END IF
566      !
567      DO_2D( 0, 0, 0, 0 )
568         ikt = mikt(ji,jj) + 1            ! w-point below the 1st  wet point
569         ikb = MAX(mbkt(ji,jj), 2)        !     -   above the last wet point
570         !
571         zwd (ji,jj,ikt) = 1._wp          ! top
572         zwi (ji,jj,ikt) = 0._wp
573         zws (ji,jj,ikt) = 0._wp
574         zwrm(ji,jj,ikt) = 0.5_wp * ( pt_in(ji,jj,ikt-1) + pt_in(ji,jj,ikt) )
575         !
576         zwd (ji,jj,ikb) = 1._wp          ! bottom
577         zwi (ji,jj,ikb) = 0._wp
578         zws (ji,jj,ikb) = 0._wp
579         zwrm(ji,jj,ikb) = 0.5_wp * ( pt_in(ji,jj,ikb-1) + pt_in(ji,jj,ikb) )           
580      END_2D
581      !
582      !                       !==  tridiagonal solver  ==!
583      !
584      DO_2D( 0, 0, 0, 0 )
585         zwt(ji,jj,2) = zwd(ji,jj,2)
586      END_2D
587      DO_3D( 0, 0, 0, 0, 3, jpkm1 )
588         zwt(ji,jj,jk) = zwd(ji,jj,jk) - zwi(ji,jj,jk) * zws(ji,jj,jk-1) /zwt(ji,jj,jk-1)
589      END_3D
590      !
591      DO_2D( 0, 0, 0, 0 )
592         pt_out(ji,jj,2) = zwrm(ji,jj,2)
593      END_2D
594      DO_3D( 0, 0, 0, 0, 3, jpkm1 )
595         pt_out(ji,jj,jk) = zwrm(ji,jj,jk) - zwi(ji,jj,jk) / zwt(ji,jj,jk-1) *pt_out(ji,jj,jk-1)             
596      END_3D
597
598      DO_2D( 0, 0, 0, 0 )
599         pt_out(ji,jj,jpkm1) = pt_out(ji,jj,jpkm1) / zwt(ji,jj,jpkm1)
600      END_2D
601      DO_3DS( 0, 0, 0, 0, jpk-2, 2, -1 )
602         pt_out(ji,jj,jk) = ( pt_out(ji,jj,jk) - zws(ji,jj,jk) * pt_out(ji,jj,jk+1) ) / zwt(ji,jj,jk)
603      END_3D
604      !   
605   END SUBROUTINE interp_4th_cpt
606
607
608   SUBROUTINE tridia_solver( pD, pU, pL, pRHS, pt_out , klev )
609      !!----------------------------------------------------------------------
610      !!                  ***  ROUTINE tridia_solver  ***
611      !!
612      !! **  Purpose :   solve a symmetric 3diagonal system
613      !!
614      !! **  Method  :   solve M.t_out = RHS(t)  where M is a tri diagonal matrix ( jpk*jpk )
615      !!     
616      !!             ( D_1 U_1  0   0   0  )( t_1 )   ( RHS_1 )
617      !!             ( L_2 D_2 U_2  0   0  )( t_2 )   ( RHS_2 )
618      !!             (  0  L_3 D_3 U_3  0  )( t_3 ) = ( RHS_3 )
619      !!             (        ...          )( ... )   ( ...  )
620      !!             (  0   0   0  L_k D_k )( t_k )   ( RHS_k )
621      !!     
622      !!        M is decomposed in the product of an upper and lower triangular matrix.
623      !!        The tri-diagonals matrix is given as input 3D arrays:   pD, pU, pL
624      !!        (i.e. the Diagonal, the Upper diagonal, and the Lower diagonal).
625      !!        The solution is pta.
626      !!        The 3d array zwt is used as a work space array.
627      !!----------------------------------------------------------------------
628      REAL(wp),DIMENSION(:,:,:), INTENT(in   ) ::   pD, pU, PL    ! 3-diagonal matrix
629      REAL(wp),DIMENSION(:,:,:), INTENT(in   ) ::   pRHS          ! Right-Hand-Side
630      REAL(wp),DIMENSION(:,:,:), INTENT(  out) ::   pt_out        !!gm field at level=F(klev)
631      INTEGER                  , INTENT(in   ) ::   klev          ! =1 pt_out at w-level
632      !                                                           ! =0 pt at t-level
633      INTEGER ::   ji, jj, jk   ! dummy loop integers
634      INTEGER ::   kstart       ! local indices
635      REAL(wp),DIMENSION(jpi,jpj,jpk) ::   zwt   ! 3D work array
636      !!----------------------------------------------------------------------
637      !
638      kstart =  1  + klev
639      !
640      DO_2D( 0, 0, 0, 0 )
641         zwt(ji,jj,kstart) = pD(ji,jj,kstart)
642      END_2D
643      DO_3D( 0, 0, 0, 0, kstart+1, jpkm1 )
644         zwt(ji,jj,jk) = pD(ji,jj,jk) - pL(ji,jj,jk) * pU(ji,jj,jk-1) /zwt(ji,jj,jk-1)
645      END_3D
646      !
647      DO_2D( 0, 0, 0, 0 )
648         pt_out(ji,jj,kstart) = pRHS(ji,jj,kstart)
649      END_2D
650      DO_3D( 0, 0, 0, 0, kstart+1, jpkm1 )
651         pt_out(ji,jj,jk) = pRHS(ji,jj,jk) - pL(ji,jj,jk) / zwt(ji,jj,jk-1) *pt_out(ji,jj,jk-1)             
652      END_3D
653
654      DO_2D( 0, 0, 0, 0 )
655         pt_out(ji,jj,jpkm1) = pt_out(ji,jj,jpkm1) / zwt(ji,jj,jpkm1)
656      END_2D
657      DO_3DS( 0, 0, 0, 0, jpk-2, kstart, -1 )
658         pt_out(ji,jj,jk) = ( pt_out(ji,jj,jk) - pU(ji,jj,jk) * pt_out(ji,jj,jk+1) ) / zwt(ji,jj,jk)
659      END_3D
660      !
661   END SUBROUTINE tridia_solver
662
663   !!======================================================================
664END MODULE traadv_fct
Note: See TracBrowser for help on using the repository browser.