1 | MODULE trazdf |
---|
2 | !!============================================================================== |
---|
3 | !! *** MODULE trazdf *** |
---|
4 | !! Ocean active tracers: vertical component of the tracer mixing trend |
---|
5 | !!============================================================================== |
---|
6 | !! History : 1.0 ! 2005-11 (G. Madec) Original code |
---|
7 | !! 3.0 ! 2008-01 (C. Ethe, G. Madec) merge TRC-TRA |
---|
8 | !! 4.0 ! 2017-06 (G. Madec) remove explict time-stepping option |
---|
9 | !!---------------------------------------------------------------------- |
---|
10 | |
---|
11 | !!---------------------------------------------------------------------- |
---|
12 | !! tra_zdf : Update the tracer trend with the vertical diffusion |
---|
13 | !!---------------------------------------------------------------------- |
---|
14 | USE oce ! ocean dynamics and tracers variables |
---|
15 | USE dom_oce ! ocean space and time domain variables |
---|
16 | USE domvvl ! variable volume |
---|
17 | USE phycst ! physical constant |
---|
18 | USE zdf_oce ! ocean vertical physics variables |
---|
19 | USE sbc_oce ! surface boundary condition: ocean |
---|
20 | USE ldftra ! lateral diffusion: eddy diffusivity |
---|
21 | USE ldfslp ! lateral diffusion: iso-neutral slope |
---|
22 | USE trd_oce ! trends: ocean variables |
---|
23 | USE trdtra ! trends: tracer trend manager |
---|
24 | ! |
---|
25 | USE in_out_manager ! I/O manager |
---|
26 | USE prtctl ! Print control |
---|
27 | USE lbclnk ! ocean lateral boundary conditions (or mpp link) |
---|
28 | USE lib_mpp ! MPP library |
---|
29 | USE timing ! Timing |
---|
30 | |
---|
31 | IMPLICIT NONE |
---|
32 | PRIVATE |
---|
33 | |
---|
34 | PUBLIC tra_zdf ! called by step.F90 |
---|
35 | PUBLIC tra_zdf_imp ! called by trczdf.F90 |
---|
36 | |
---|
37 | !! * Substitutions |
---|
38 | # include "do_loop_substitute.h90" |
---|
39 | !!---------------------------------------------------------------------- |
---|
40 | !! NEMO/OCE 4.0 , NEMO Consortium (2018) |
---|
41 | !! $Id$ |
---|
42 | !! Software governed by the CeCILL license (see ./LICENSE) |
---|
43 | !!---------------------------------------------------------------------- |
---|
44 | CONTAINS |
---|
45 | |
---|
46 | SUBROUTINE tra_zdf( kt, Kbb, Kmm, Krhs, pts, Kaa ) |
---|
47 | !!---------------------------------------------------------------------- |
---|
48 | !! *** ROUTINE tra_zdf *** |
---|
49 | !! |
---|
50 | !! ** Purpose : compute the vertical ocean tracer physics. |
---|
51 | !!--------------------------------------------------------------------- |
---|
52 | INTEGER , INTENT(in) :: kt ! ocean time-step index |
---|
53 | INTEGER , INTENT(in) :: Kbb, Kmm, Krhs, Kaa ! time level indices |
---|
54 | REAL(wp), DIMENSION(jpi,jpj,jpk,jpts,jpt), INTENT(inout) :: pts ! active tracers and RHS of tracer equation |
---|
55 | ! |
---|
56 | INTEGER :: jk ! Dummy loop indices |
---|
57 | REAL(wp), DIMENSION(:,:,:), ALLOCATABLE :: ztrdt, ztrds ! 3D workspace |
---|
58 | !!--------------------------------------------------------------------- |
---|
59 | ! |
---|
60 | IF( ln_timing ) CALL timing_start('tra_zdf') |
---|
61 | ! |
---|
62 | IF( kt == nit000 ) THEN |
---|
63 | IF(lwp)WRITE(numout,*) |
---|
64 | IF(lwp)WRITE(numout,*) 'tra_zdf : implicit vertical mixing on T & S' |
---|
65 | IF(lwp)WRITE(numout,*) '~~~~~~~ ' |
---|
66 | ENDIF |
---|
67 | ! |
---|
68 | IF( l_trdtra ) THEN !* Save ta and sa trends |
---|
69 | ALLOCATE( ztrdt(jpi,jpj,jpk) , ztrds(jpi,jpj,jpk) ) |
---|
70 | ztrdt(:,:,:) = pts(:,:,:,jp_tem,Kaa) |
---|
71 | ztrds(:,:,:) = pts(:,:,:,jp_sal,Kaa) |
---|
72 | ENDIF |
---|
73 | ! |
---|
74 | ! !* compute lateral mixing trend and add it to the general trend |
---|
75 | CALL tra_zdf_imp( kt, nit000, 'TRA', rDt, Kbb, Kmm, Krhs, pts, Kaa, jpts ) |
---|
76 | |
---|
77 | !!gm WHY here ! and I don't like that ! |
---|
78 | ! DRAKKAR SSS control { |
---|
79 | ! JMM avoid negative salinities near river outlet ! Ugly fix |
---|
80 | ! JMM : restore negative salinities to small salinities: |
---|
81 | WHERE( pts(:,:,:,jp_sal,Kaa) < 0._wp ) pts(:,:,:,jp_sal,Kaa) = 0.1_wp |
---|
82 | !!gm |
---|
83 | |
---|
84 | IF( l_trdtra ) THEN ! save the vertical diffusive trends for further diagnostics |
---|
85 | DO jk = 1, jpkm1 |
---|
86 | ztrdt(:,:,jk) = ( ( pts(:,:,jk,jp_tem,Kaa)*e3t(:,:,jk,Kaa) - pts(:,:,jk,jp_tem,Kbb)*e3t(:,:,jk,Kbb) ) & |
---|
87 | & / (e3t(:,:,jk,Kmm)*rDt) ) - ztrdt(:,:,jk) |
---|
88 | ztrds(:,:,jk) = ( ( pts(:,:,jk,jp_sal,Kaa)*e3t(:,:,jk,Kaa) - pts(:,:,jk,jp_sal,Kbb)*e3t(:,:,jk,Kbb) ) & |
---|
89 | & / (e3t(:,:,jk,Kmm)*rDt) ) - ztrds(:,:,jk) |
---|
90 | END DO |
---|
91 | !!gm this should be moved in trdtra.F90 and done on all trends |
---|
92 | CALL lbc_lnk_multi( 'trazdf', ztrdt, 'T', 1.0_wp , ztrds, 'T', 1.0_wp ) |
---|
93 | !!gm |
---|
94 | CALL trd_tra( kt, Kmm, Krhs, 'TRA', jp_tem, jptra_zdf, ztrdt ) |
---|
95 | CALL trd_tra( kt, Kmm, Krhs, 'TRA', jp_sal, jptra_zdf, ztrds ) |
---|
96 | DEALLOCATE( ztrdt , ztrds ) |
---|
97 | ENDIF |
---|
98 | ! ! print mean trends (used for debugging) |
---|
99 | IF(sn_cfctl%l_prtctl) CALL prt_ctl( tab3d_1=pts(:,:,:,jp_tem,Kaa), clinfo1=' zdf - Ta: ', mask1=tmask, & |
---|
100 | & tab3d_2=pts(:,:,:,jp_sal,Kaa), clinfo2= ' Sa: ', mask2=tmask, clinfo3='tra' ) |
---|
101 | ! |
---|
102 | IF( ln_timing ) CALL timing_stop('tra_zdf') |
---|
103 | ! |
---|
104 | END SUBROUTINE tra_zdf |
---|
105 | |
---|
106 | |
---|
107 | SUBROUTINE tra_zdf_imp( kt, kit000, cdtype, p2dt, Kbb, Kmm, Krhs, pt, Kaa, kjpt ) |
---|
108 | !!---------------------------------------------------------------------- |
---|
109 | !! *** ROUTINE tra_zdf_imp *** |
---|
110 | !! |
---|
111 | !! ** Purpose : Compute the after tracer through a implicit computation |
---|
112 | !! of the vertical tracer diffusion (including the vertical component |
---|
113 | !! of lateral mixing (only for 2nd order operator, for fourth order |
---|
114 | !! it is already computed and add to the general trend in traldf) |
---|
115 | !! |
---|
116 | !! ** Method : The vertical diffusion of a tracer ,t , is given by: |
---|
117 | !! difft = dz( avt dz(t) ) = 1/e3t dk+1( avt/e3w dk(t) ) |
---|
118 | !! It is computed using a backward time scheme (t=after field) |
---|
119 | !! which provide directly the after tracer field. |
---|
120 | !! If ln_zdfddm=T, use avs for salinity or for passive tracers |
---|
121 | !! Surface and bottom boundary conditions: no diffusive flux on |
---|
122 | !! both tracers (bottom, applied through the masked field avt). |
---|
123 | !! If iso-neutral mixing, add to avt the contribution due to lateral mixing. |
---|
124 | !! |
---|
125 | !! ** Action : - pt(:,:,:,:,Kaa) becomes the after tracer |
---|
126 | !!--------------------------------------------------------------------- |
---|
127 | INTEGER , INTENT(in ) :: kt ! ocean time-step index |
---|
128 | INTEGER , INTENT(in ) :: Kbb, Kmm, Krhs, Kaa ! ocean time level indices |
---|
129 | INTEGER , INTENT(in ) :: kit000 ! first time step index |
---|
130 | CHARACTER(len=3) , INTENT(in ) :: cdtype ! =TRA or TRC (tracer indicator) |
---|
131 | INTEGER , INTENT(in ) :: kjpt ! number of tracers |
---|
132 | REAL(wp) , INTENT(in ) :: p2dt ! tracer time-step |
---|
133 | REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt,jpt), INTENT(inout) :: pt ! tracers and RHS of tracer equation |
---|
134 | ! |
---|
135 | INTEGER :: ji, jj, jk, jn ! dummy loop indices |
---|
136 | REAL(wp) :: zrhs, zzwi, zzws ! local scalars |
---|
137 | REAL(wp), DIMENSION(jpi,jpj,jpk) :: zwi, zwt, zwd, zws |
---|
138 | !!--------------------------------------------------------------------- |
---|
139 | ! |
---|
140 | ! ! ============= ! |
---|
141 | DO jn = 1, kjpt ! tracer loop ! |
---|
142 | ! ! ============= ! |
---|
143 | ! Matrix construction |
---|
144 | ! -------------------- |
---|
145 | ! Build matrix if temperature or salinity (only in double diffusion case) or first passive tracer |
---|
146 | ! |
---|
147 | IF( ( cdtype == 'TRA' .AND. ( jn == jp_tem .OR. ( jn == jp_sal .AND. ln_zdfddm ) ) ) .OR. & |
---|
148 | & ( cdtype == 'TRC' .AND. jn == 1 ) ) THEN |
---|
149 | ! |
---|
150 | ! vertical mixing coef.: avt for temperature, avs for salinity and passive tracers |
---|
151 | IF( cdtype == 'TRA' .AND. jn == jp_tem ) THEN ; zwt(:,:,2:jpk) = avt(:,:,2:jpk) |
---|
152 | ELSE ; zwt(:,:,2:jpk) = avs(:,:,2:jpk) |
---|
153 | ENDIF |
---|
154 | zwt(:,:,1) = 0._wp |
---|
155 | ! |
---|
156 | IF( l_ldfslp ) THEN ! isoneutral diffusion: add the contribution |
---|
157 | IF( ln_traldf_msc ) THEN ! MSC iso-neutral operator |
---|
158 | DO_3D_00_00( 2, jpkm1 ) |
---|
159 | zwt(ji,jj,jk) = zwt(ji,jj,jk) + akz(ji,jj,jk) |
---|
160 | END_3D |
---|
161 | ELSE ! standard or triad iso-neutral operator |
---|
162 | DO_3D_00_00( 2, jpkm1 ) |
---|
163 | zwt(ji,jj,jk) = zwt(ji,jj,jk) + ah_wslp2(ji,jj,jk) |
---|
164 | END_3D |
---|
165 | ENDIF |
---|
166 | ENDIF |
---|
167 | ! |
---|
168 | ! Diagonal, lower (i), upper (s) (including the bottom boundary condition since avt is masked) |
---|
169 | IF( ln_zad_Aimp ) THEN ! Adaptive implicit vertical advection |
---|
170 | DO_3D_00_00( 1, jpkm1 ) |
---|
171 | zzwi = - p2dt * zwt(ji,jj,jk ) / e3w(ji,jj,jk ,Kmm) |
---|
172 | zzws = - p2dt * zwt(ji,jj,jk+1) / e3w(ji,jj,jk+1,Kmm) |
---|
173 | zwd(ji,jj,jk) = e3t(ji,jj,jk,Kaa) - zzwi - zzws & |
---|
174 | & + p2dt * ( MAX( wi(ji,jj,jk ) , 0._wp ) - MIN( wi(ji,jj,jk+1) , 0._wp ) ) |
---|
175 | zwi(ji,jj,jk) = zzwi + p2dt * MIN( wi(ji,jj,jk ) , 0._wp ) |
---|
176 | zws(ji,jj,jk) = zzws - p2dt * MAX( wi(ji,jj,jk+1) , 0._wp ) |
---|
177 | END_3D |
---|
178 | ELSE |
---|
179 | DO_3D_00_00( 1, jpkm1 ) |
---|
180 | zwi(ji,jj,jk) = - p2dt * zwt(ji,jj,jk ) / e3w(ji,jj,jk,Kmm) |
---|
181 | zws(ji,jj,jk) = - p2dt * zwt(ji,jj,jk+1) / e3w(ji,jj,jk+1,Kmm) |
---|
182 | zwd(ji,jj,jk) = e3t(ji,jj,jk,Kaa) - zwi(ji,jj,jk) - zws(ji,jj,jk) |
---|
183 | END_3D |
---|
184 | ENDIF |
---|
185 | ! |
---|
186 | !! Matrix inversion from the first level |
---|
187 | !!---------------------------------------------------------------------- |
---|
188 | ! solve m.x = y where m is a tri diagonal matrix ( jpk*jpk ) |
---|
189 | ! |
---|
190 | ! ( zwd1 zws1 0 0 0 )( zwx1 ) ( zwy1 ) |
---|
191 | ! ( zwi2 zwd2 zws2 0 0 )( zwx2 ) ( zwy2 ) |
---|
192 | ! ( 0 zwi3 zwd3 zws3 0 )( zwx3 )=( zwy3 ) |
---|
193 | ! ( ... )( ... ) ( ... ) |
---|
194 | ! ( 0 0 0 zwik zwdk )( zwxk ) ( zwyk ) |
---|
195 | ! |
---|
196 | ! m is decomposed in the product of an upper and lower triangular matrix. |
---|
197 | ! The 3 diagonal terms are in 3d arrays: zwd, zws, zwi. |
---|
198 | ! Suffices i,s and d indicate "inferior" (below diagonal), diagonal |
---|
199 | ! and "superior" (above diagonal) components of the tridiagonal system. |
---|
200 | ! The solution will be in the 4d array pta. |
---|
201 | ! The 3d array zwt is used as a work space array. |
---|
202 | ! En route to the solution pt(:,:,:,:,Kaa) is used a to evaluate the rhs and then |
---|
203 | ! used as a work space array: its value is modified. |
---|
204 | ! |
---|
205 | DO_2D_00_00 |
---|
206 | zwt(ji,jj,1) = zwd(ji,jj,1) |
---|
207 | END_2D |
---|
208 | DO_3D_00_00( 2, jpkm1 ) |
---|
209 | zwt(ji,jj,jk) = zwd(ji,jj,jk) - zwi(ji,jj,jk) * zws(ji,jj,jk-1) / zwt(ji,jj,jk-1) |
---|
210 | END_3D |
---|
211 | ! |
---|
212 | ENDIF |
---|
213 | ! |
---|
214 | DO_2D_00_00 |
---|
215 | pt(ji,jj,1,jn,Kaa) = e3t(ji,jj,1,Kbb) * pt(ji,jj,1,jn,Kbb) + p2dt * e3t(ji,jj,1,Kmm) * pt(ji,jj,1,jn,Krhs) |
---|
216 | END_2D |
---|
217 | DO_3D_00_00( 2, jpkm1 ) |
---|
218 | zrhs = e3t(ji,jj,jk,Kbb) * pt(ji,jj,jk,jn,Kbb) + p2dt * e3t(ji,jj,jk,Kmm) * pt(ji,jj,jk,jn,Krhs) ! zrhs=right hand side |
---|
219 | pt(ji,jj,jk,jn,Kaa) = zrhs - zwi(ji,jj,jk) / zwt(ji,jj,jk-1) * pt(ji,jj,jk-1,jn,Kaa) |
---|
220 | END_3D |
---|
221 | ! |
---|
222 | DO_2D_00_00 |
---|
223 | pt(ji,jj,jpkm1,jn,Kaa) = pt(ji,jj,jpkm1,jn,Kaa) / zwt(ji,jj,jpkm1) * tmask(ji,jj,jpkm1) |
---|
224 | END_2D |
---|
225 | DO_3DS_00_00( jpk-2, 1, -1 ) |
---|
226 | pt(ji,jj,jk,jn,Kaa) = ( pt(ji,jj,jk,jn,Kaa) - zws(ji,jj,jk) * pt(ji,jj,jk+1,jn,Kaa) ) & |
---|
227 | & / zwt(ji,jj,jk) * tmask(ji,jj,jk) |
---|
228 | END_3D |
---|
229 | ! ! ================= ! |
---|
230 | END DO ! end tracer loop ! |
---|
231 | ! ! ================= ! |
---|
232 | END SUBROUTINE tra_zdf_imp |
---|
233 | |
---|
234 | !!============================================================================== |
---|
235 | END MODULE trazdf |
---|