| 1 | MODULE nemogcm |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE nemogcm *** |
|---|
| 4 | !! Ocean system : NEMO GCM (ocean dynamics, on-line tracers, biochemistry and sea-ice) |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : OPA ! 1990-10 (C. Levy, G. Madec) Original code |
|---|
| 7 | !! 7.0 ! 1991-11 (M. Imbard, C. Levy, G. Madec) |
|---|
| 8 | !! 7.1 ! 1993-03 (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar, |
|---|
| 9 | !! P. Delecluse, C. Perigaud, G. Caniaux, B. Colot, C. Maes) release 7.1 |
|---|
| 10 | !! - ! 1992-06 (L.Terray) coupling implementation |
|---|
| 11 | !! - ! 1993-11 (M.A. Filiberti) IGLOO sea-ice |
|---|
| 12 | !! 8.0 ! 1996-03 (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar, |
|---|
| 13 | !! P. Delecluse, L.Terray, M.A. Filiberti, J. Vialar, A.M. Treguier, M. Levy) release 8.0 |
|---|
| 14 | !! 8.1 ! 1997-06 (M. Imbard, G. Madec) |
|---|
| 15 | !! 8.2 ! 1999-11 (M. Imbard, H. Goosse) sea-ice model |
|---|
| 16 | !! ! 1999-12 (V. Thierry, A-M. Treguier, M. Imbard, M-A. Foujols) OPEN-MP |
|---|
| 17 | !! ! 2000-07 (J-M Molines, M. Imbard) Open Boundary Conditions (CLIPPER) |
|---|
| 18 | !! NEMO 1.0 ! 2002-08 (G. Madec) F90: Free form and modules |
|---|
| 19 | !! - ! 2004-06 (R. Redler, NEC CCRLE, Germany) add OASIS[3/4] coupled interfaces |
|---|
| 20 | !! - ! 2004-08 (C. Talandier) New trends organization |
|---|
| 21 | !! - ! 2005-06 (C. Ethe) Add the 1D configuration possibility |
|---|
| 22 | !! - ! 2005-11 (V. Garnier) Surface pressure gradient organization |
|---|
| 23 | !! - ! 2006-03 (L. Debreu, C. Mazauric) Agrif implementation |
|---|
| 24 | !! - ! 2006-04 (G. Madec, R. Benshila) Step reorganization |
|---|
| 25 | !! - ! 2007-07 (J. Chanut, A. Sellar) Unstructured open boundaries (BDY) |
|---|
| 26 | !! 3.2 ! 2009-08 (S. Masson) open/write in the listing file in mpp |
|---|
| 27 | !! 3.3 ! 2010-05 (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface |
|---|
| 28 | !! - ! 2010-10 (C. Ethe, G. Madec) reorganisation of initialisation phase |
|---|
| 29 | !! 3.3.1! 2011-01 (A. R. Porter, STFC Daresbury) dynamical allocation |
|---|
| 30 | !! - ! 2011-11 (C. Harris) decomposition changes for running with CICE |
|---|
| 31 | !! 3.6 ! 2012-05 (C. Calone, J. Simeon, G. Madec, C. Ethe) Add grid coarsening |
|---|
| 32 | !! - ! 2014-12 (G. Madec) remove KPP scheme and cross-land advection (cla) |
|---|
| 33 | !! 4.0 ! 2016-10 (G. Madec, S. Flavoni) domain configuration / user defined interface |
|---|
| 34 | !!---------------------------------------------------------------------- |
|---|
| 35 | |
|---|
| 36 | !!---------------------------------------------------------------------- |
|---|
| 37 | !! nemo_gcm : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice |
|---|
| 38 | !! nemo_init : initialization of the NEMO system |
|---|
| 39 | !! nemo_ctl : initialisation of the contol print |
|---|
| 40 | !! nemo_closefile: close remaining open files |
|---|
| 41 | !! nemo_alloc : dynamical allocation |
|---|
| 42 | !!---------------------------------------------------------------------- |
|---|
| 43 | USE step_oce ! module used in the ocean time stepping module (step.F90) |
|---|
| 44 | ! |
|---|
| 45 | USE phycst ! physical constant (par_cst routine) |
|---|
| 46 | USE domain ! domain initialization (dom_init & dom_cfg routines) |
|---|
| 47 | USE wet_dry ! Wetting and drying setting (wad_init routine) |
|---|
| 48 | USE usrdef_nam ! user defined configuration namelist |
|---|
| 49 | USE tide_mod, ONLY : tide_init ! tidal components initialization (tide_init routine) |
|---|
| 50 | USE bdyini , ONLY : bdy_init ! open boundary cond. setting (bdy_init routine) |
|---|
| 51 | USE istate ! initial state setting (istate_init routine) |
|---|
| 52 | USE trdini ! dyn/tra trends initialization (trd_init routine) |
|---|
| 53 | USE icbini ! handle bergs, initialisation |
|---|
| 54 | USE icbstp , ONLY : icb_end ! handle bergs, close iceberg files |
|---|
| 55 | USE cpl_oasis3 ! OASIS3 coupling |
|---|
| 56 | USE dyndmp ! Momentum damping (C1D only) |
|---|
| 57 | USE step_diu ! diurnal bulk SST timestepping (called from here if run offline) |
|---|
| 58 | USE crsini ! initialise grid coarsening utility |
|---|
| 59 | USE dia25h , ONLY : dia_25h_init ! 25h mean output (initialisation) |
|---|
| 60 | USE c1d ! 1D configuration |
|---|
| 61 | #if defined key_top |
|---|
| 62 | USE trcini ! passive tracer initialisation |
|---|
| 63 | #endif |
|---|
| 64 | #if defined key_nemocice_decomp |
|---|
| 65 | USE ice_domain_size, only: nx_global, ny_global |
|---|
| 66 | #endif |
|---|
| 67 | #if defined key_qco || defined key_linssh |
|---|
| 68 | USE stpmlf ! NEMO time-stepping (stp_MLF routine) |
|---|
| 69 | #else |
|---|
| 70 | USE step ! NEMO time-stepping (stp routine) |
|---|
| 71 | #endif |
|---|
| 72 | ! |
|---|
| 73 | USE lib_mpp ! distributed memory computing |
|---|
| 74 | USE mppini ! shared/distributed memory setting (mpp_init routine) |
|---|
| 75 | USE lib_fortran ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) |
|---|
| 76 | USE halo_mng ! halo manager |
|---|
| 77 | |
|---|
| 78 | IMPLICIT NONE |
|---|
| 79 | PRIVATE |
|---|
| 80 | |
|---|
| 81 | PUBLIC nemo_gcm ! called by model.F90 |
|---|
| 82 | PUBLIC nemo_init ! needed by AGRIF |
|---|
| 83 | PUBLIC nemo_alloc ! needed by TAM |
|---|
| 84 | |
|---|
| 85 | CHARACTER(lc) :: cform_aaa="( /, 'AAAAAAAA', / ) " ! flag for output listing |
|---|
| 86 | |
|---|
| 87 | #if ! defined key_mpi_off |
|---|
| 88 | ! need MPI_Wtime |
|---|
| 89 | INCLUDE 'mpif.h' |
|---|
| 90 | #endif |
|---|
| 91 | |
|---|
| 92 | !!---------------------------------------------------------------------- |
|---|
| 93 | !! NEMO/OCE 4.0 , NEMO Consortium (2018) |
|---|
| 94 | !! $Id$ |
|---|
| 95 | !! Software governed by the CeCILL license (see ./LICENSE) |
|---|
| 96 | !!---------------------------------------------------------------------- |
|---|
| 97 | CONTAINS |
|---|
| 98 | |
|---|
| 99 | SUBROUTINE nemo_gcm |
|---|
| 100 | !!---------------------------------------------------------------------- |
|---|
| 101 | !! *** ROUTINE nemo_gcm *** |
|---|
| 102 | !! |
|---|
| 103 | !! ** Purpose : NEMO solves the primitive equations on an orthogonal |
|---|
| 104 | !! curvilinear mesh on the sphere. |
|---|
| 105 | !! |
|---|
| 106 | !! ** Method : - model general initialization |
|---|
| 107 | !! - launch the time-stepping (stp routine) |
|---|
| 108 | !! - finalize the run by closing files and communications |
|---|
| 109 | !! |
|---|
| 110 | !! References : Madec, Delecluse, Imbard, and Levy, 1997: internal report, IPSL. |
|---|
| 111 | !! Madec, 2008, internal report, IPSL. |
|---|
| 112 | !!---------------------------------------------------------------------- |
|---|
| 113 | INTEGER :: istp ! time step index |
|---|
| 114 | REAL(wp):: zstptiming ! elapsed time for 1 time step |
|---|
| 115 | !!---------------------------------------------------------------------- |
|---|
| 116 | ! |
|---|
| 117 | #if defined key_agrif |
|---|
| 118 | CALL Agrif_Init_Grids() ! AGRIF: set the meshes |
|---|
| 119 | #endif |
|---|
| 120 | ! !-----------------------! |
|---|
| 121 | CALL nemo_init !== Initialisations ==! |
|---|
| 122 | ! !-----------------------! |
|---|
| 123 | #if defined key_agrif |
|---|
| 124 | Kbb_a = Nbb; Kmm_a = Nnn; Krhs_a = Nrhs ! agrif_oce module copies of time level indices |
|---|
| 125 | CALL Agrif_Declare_Var ! " " " " " DYN/TRA |
|---|
| 126 | # if defined key_top |
|---|
| 127 | CALL Agrif_Declare_Var_top ! " " " " " TOP |
|---|
| 128 | # endif |
|---|
| 129 | #endif |
|---|
| 130 | ! check that all process are still there... If some process have an error, |
|---|
| 131 | ! they will never enter in step and other processes will wait until the end of the cpu time! |
|---|
| 132 | CALL mpp_max( 'nemogcm', nstop ) |
|---|
| 133 | |
|---|
| 134 | IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA |
|---|
| 135 | |
|---|
| 136 | ! !-----------------------! |
|---|
| 137 | ! !== time stepping ==! |
|---|
| 138 | ! !-----------------------! |
|---|
| 139 | ! |
|---|
| 140 | ! !== set the model time-step ==! |
|---|
| 141 | ! |
|---|
| 142 | istp = nit000 |
|---|
| 143 | ! |
|---|
| 144 | # if defined key_agrif |
|---|
| 145 | ! !== AGRIF time-stepping ==! |
|---|
| 146 | CALL Agrif_Regrid() |
|---|
| 147 | ! |
|---|
| 148 | ! Recursive update from highest nested level to lowest: |
|---|
| 149 | Kbb_a = Nbb; Kmm_a = Nnn; Krhs_a = Nrhs ! agrif_oce module copies of time level indices |
|---|
| 150 | CALL Agrif_step_child_adj(Agrif_Update_All) |
|---|
| 151 | CALL Agrif_step_child_adj(Agrif_Check_parent_bat) |
|---|
| 152 | ! |
|---|
| 153 | DO WHILE( istp <= nitend .AND. nstop == 0 ) |
|---|
| 154 | ! |
|---|
| 155 | # if defined key_qco || defined key_linssh |
|---|
| 156 | CALL stp_MLF |
|---|
| 157 | # else |
|---|
| 158 | CALL stp |
|---|
| 159 | # endif |
|---|
| 160 | istp = istp + 1 |
|---|
| 161 | END DO |
|---|
| 162 | ! |
|---|
| 163 | # else |
|---|
| 164 | ! |
|---|
| 165 | IF( .NOT.ln_diurnal_only ) THEN !== Standard time-stepping ==! |
|---|
| 166 | ! |
|---|
| 167 | DO WHILE( istp <= nitend .AND. nstop == 0 ) |
|---|
| 168 | ! |
|---|
| 169 | ncom_stp = istp |
|---|
| 170 | IF( ln_timing ) THEN |
|---|
| 171 | zstptiming = MPI_Wtime() |
|---|
| 172 | IF ( istp == ( nit000 + 1 ) ) elapsed_time = zstptiming |
|---|
| 173 | IF ( istp == nitend ) elapsed_time = zstptiming - elapsed_time |
|---|
| 174 | ENDIF |
|---|
| 175 | ! |
|---|
| 176 | # if defined key_qco || defined key_linssh |
|---|
| 177 | CALL stp_MLF( istp ) |
|---|
| 178 | # else |
|---|
| 179 | CALL stp ( istp ) |
|---|
| 180 | # endif |
|---|
| 181 | istp = istp + 1 |
|---|
| 182 | ! |
|---|
| 183 | IF( lwp .AND. ln_timing ) WRITE(numtime,*) 'timing step ', istp-1, ' : ', MPI_Wtime() - zstptiming |
|---|
| 184 | ! |
|---|
| 185 | END DO |
|---|
| 186 | ! |
|---|
| 187 | ELSE !== diurnal SST time-steeping only ==! |
|---|
| 188 | ! |
|---|
| 189 | DO WHILE( istp <= nitend .AND. nstop == 0 ) |
|---|
| 190 | CALL stp_diurnal( istp ) ! time step only the diurnal SST |
|---|
| 191 | istp = istp + 1 |
|---|
| 192 | END DO |
|---|
| 193 | ! |
|---|
| 194 | ENDIF |
|---|
| 195 | ! |
|---|
| 196 | # endif |
|---|
| 197 | ! |
|---|
| 198 | IF( ln_diaobs ) CALL dia_obs_wri |
|---|
| 199 | ! |
|---|
| 200 | IF( ln_icebergs ) CALL icb_end( nitend ) |
|---|
| 201 | |
|---|
| 202 | ! !------------------------! |
|---|
| 203 | ! !== finalize the run ==! |
|---|
| 204 | ! !------------------------! |
|---|
| 205 | IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA |
|---|
| 206 | ! |
|---|
| 207 | IF( nstop /= 0 .AND. lwp ) THEN ! error print |
|---|
| 208 | WRITE(ctmp1,*) ' ==>>> nemo_gcm: a total of ', nstop, ' errors have been found' |
|---|
| 209 | IF( ngrdstop > 0 ) THEN |
|---|
| 210 | WRITE(ctmp9,'(i2)') ngrdstop |
|---|
| 211 | WRITE(ctmp2,*) ' E R R O R detected in Agrif grid '//TRIM(ctmp9) |
|---|
| 212 | WRITE(ctmp3,*) ' Look for "E R R O R" messages in all existing '//TRIM(ctmp9)//'_ocean_output* files' |
|---|
| 213 | CALL ctl_stop( ' ', ctmp1, ' ', ctmp2, ' ', ctmp3 ) |
|---|
| 214 | ELSE |
|---|
| 215 | WRITE(ctmp2,*) ' Look for "E R R O R" messages in all existing ocean_output* files' |
|---|
| 216 | CALL ctl_stop( ' ', ctmp1, ' ', ctmp2 ) |
|---|
| 217 | ENDIF |
|---|
| 218 | ENDIF |
|---|
| 219 | ! |
|---|
| 220 | IF( ln_timing ) CALL timing_finalize |
|---|
| 221 | ! |
|---|
| 222 | CALL nemo_closefile |
|---|
| 223 | ! |
|---|
| 224 | #if defined key_xios |
|---|
| 225 | CALL xios_finalize ! end mpp communications with xios |
|---|
| 226 | IF( lk_oasis ) CALL cpl_finalize ! end coupling and mpp communications with OASIS |
|---|
| 227 | #else |
|---|
| 228 | IF ( lk_oasis ) THEN ; CALL cpl_finalize ! end coupling and mpp communications with OASIS |
|---|
| 229 | ELSEIF( lk_mpp ) THEN ; CALL mppstop ! end mpp communications |
|---|
| 230 | ENDIF |
|---|
| 231 | #endif |
|---|
| 232 | ! |
|---|
| 233 | IF(lwm) THEN |
|---|
| 234 | IF( nstop == 0 ) THEN ; STOP 0 |
|---|
| 235 | ELSE ; STOP 123 |
|---|
| 236 | ENDIF |
|---|
| 237 | ENDIF |
|---|
| 238 | ! |
|---|
| 239 | END SUBROUTINE nemo_gcm |
|---|
| 240 | |
|---|
| 241 | |
|---|
| 242 | SUBROUTINE nemo_init |
|---|
| 243 | !!---------------------------------------------------------------------- |
|---|
| 244 | !! *** ROUTINE nemo_init *** |
|---|
| 245 | !! |
|---|
| 246 | !! ** Purpose : initialization of the NEMO GCM |
|---|
| 247 | !!---------------------------------------------------------------------- |
|---|
| 248 | INTEGER :: ios, ilocal_comm ! local integers |
|---|
| 249 | !! |
|---|
| 250 | NAMELIST/namctl/ sn_cfctl, ln_timing, ln_diacfl, nn_isplt, nn_jsplt , nn_ictls, & |
|---|
| 251 | & nn_ictle, nn_jctls , nn_jctle |
|---|
| 252 | NAMELIST/namcfg/ ln_read_cfg, cn_domcfg, ln_closea, ln_write_cfg, cn_domcfg_out, ln_use_jattr |
|---|
| 253 | !!---------------------------------------------------------------------- |
|---|
| 254 | ! |
|---|
| 255 | cxios_context = 'nemo' |
|---|
| 256 | ! |
|---|
| 257 | ! !-------------------------------------------------! |
|---|
| 258 | ! ! set communicator & select the local rank ! |
|---|
| 259 | ! ! must be done as soon as possible to get narea ! |
|---|
| 260 | ! !-------------------------------------------------! |
|---|
| 261 | ! |
|---|
| 262 | #if defined key_xios |
|---|
| 263 | IF( Agrif_Root() ) THEN |
|---|
| 264 | IF( lk_oasis ) THEN |
|---|
| 265 | CALL cpl_init( "oceanx", ilocal_comm ) ! nemo local communicator given by oasis |
|---|
| 266 | CALL xios_initialize( "not used" , local_comm =ilocal_comm ) ! send nemo communicator to xios |
|---|
| 267 | ELSE |
|---|
| 268 | CALL xios_initialize( "for_xios_mpi_id", return_comm=ilocal_comm ) ! nemo local communicator given by xios |
|---|
| 269 | ENDIF |
|---|
| 270 | ENDIF |
|---|
| 271 | CALL mpp_start( ilocal_comm ) |
|---|
| 272 | #else |
|---|
| 273 | IF( lk_oasis ) THEN |
|---|
| 274 | IF( Agrif_Root() ) THEN |
|---|
| 275 | CALL cpl_init( "oceanx", ilocal_comm ) ! nemo local communicator given by oasis |
|---|
| 276 | ENDIF |
|---|
| 277 | CALL mpp_start( ilocal_comm ) |
|---|
| 278 | ELSE |
|---|
| 279 | CALL mpp_start( ) |
|---|
| 280 | ENDIF |
|---|
| 281 | #endif |
|---|
| 282 | ! |
|---|
| 283 | narea = mpprank + 1 ! mpprank: the rank of proc (0 --> mppsize -1 ) |
|---|
| 284 | lwm = (narea == 1) ! control of output namelists |
|---|
| 285 | ! |
|---|
| 286 | ! !---------------------------------------------------------------! |
|---|
| 287 | ! ! Open output files, reference and configuration namelist files ! |
|---|
| 288 | ! !---------------------------------------------------------------! |
|---|
| 289 | ! |
|---|
| 290 | ! open ocean.output as soon as possible to get all output prints (including errors messages) |
|---|
| 291 | IF( lwm ) CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. ) |
|---|
| 292 | ! open reference and configuration namelist files |
|---|
| 293 | CALL load_nml( numnam_ref, 'namelist_ref', -1, lwm ) |
|---|
| 294 | CALL load_nml( numnam_cfg, 'namelist_cfg', -1, lwm ) |
|---|
| 295 | IF( lwm ) CALL ctl_opn( numond, 'output.namelist.dyn', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. ) |
|---|
| 296 | ! open /dev/null file to be able to supress output write easily |
|---|
| 297 | IF( Agrif_Root() ) THEN |
|---|
| 298 | CALL ctl_opn( numnul, '/dev/null', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. ) |
|---|
| 299 | #ifdef key_agrif |
|---|
| 300 | ELSE |
|---|
| 301 | numnul = Agrif_Parent(numnul) |
|---|
| 302 | #endif |
|---|
| 303 | ENDIF |
|---|
| 304 | ! !--------------------! |
|---|
| 305 | ! ! Open listing units ! -> need sn_cfctl from namctl to define lwp |
|---|
| 306 | ! !--------------------! |
|---|
| 307 | ! |
|---|
| 308 | READ ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 ) |
|---|
| 309 | 901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in reference namelist' ) |
|---|
| 310 | READ ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 ) |
|---|
| 311 | 902 IF( ios > 0 ) CALL ctl_nam ( ios , 'namctl in configuration namelist' ) |
|---|
| 312 | ! |
|---|
| 313 | ! finalize the definition of namctl variables |
|---|
| 314 | IF( narea < sn_cfctl%procmin .OR. narea > sn_cfctl%procmax .OR. MOD( narea - sn_cfctl%procmin, sn_cfctl%procincr ) /= 0 ) & |
|---|
| 315 | & CALL nemo_set_cfctl( sn_cfctl, .FALSE. ) |
|---|
| 316 | ! |
|---|
| 317 | lwp = (narea == 1) .OR. sn_cfctl%l_oceout ! control of all listing output print |
|---|
| 318 | ! |
|---|
| 319 | IF(lwp) THEN ! open listing units |
|---|
| 320 | ! |
|---|
| 321 | IF( .NOT. lwm ) & ! alreay opened for narea == 1 |
|---|
| 322 | & CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE., narea ) |
|---|
| 323 | ! |
|---|
| 324 | WRITE(numout,*) |
|---|
| 325 | WRITE(numout,*) ' CNRS - NERC - Met OFFICE - MERCATOR-ocean - CMCC' |
|---|
| 326 | WRITE(numout,*) ' NEMO team' |
|---|
| 327 | WRITE(numout,*) ' Ocean General Circulation Model' |
|---|
| 328 | WRITE(numout,*) ' NEMO version 4.0 (2020) ' |
|---|
| 329 | WRITE(numout,*) |
|---|
| 330 | WRITE(numout,*) " ._ ._ ._ ._ ._ " |
|---|
| 331 | WRITE(numout,*) " _.-._)`\_.-._)`\_.-._)`\_.-._)`\_.-._)`\_ " |
|---|
| 332 | WRITE(numout,*) |
|---|
| 333 | WRITE(numout,*) " o _, _, " |
|---|
| 334 | WRITE(numout,*) " o .' ( .-' / " |
|---|
| 335 | WRITE(numout,*) " o _/..._'. .' / " |
|---|
| 336 | WRITE(numout,*) " ( o .-'` ` '-./ _.' " |
|---|
| 337 | WRITE(numout,*) " ) ( o) ;= <_ ( " |
|---|
| 338 | WRITE(numout,*) " ( '-.,\\__ __.-;`\ '. ) " |
|---|
| 339 | WRITE(numout,*) " ) ) \) |`\ \) '. \ ( ( " |
|---|
| 340 | WRITE(numout,*) " ( ( \_/ '-._\ ) ) " |
|---|
| 341 | WRITE(numout,*) " ) ) jgs ` ( ( " |
|---|
| 342 | WRITE(numout,*) " ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^ " |
|---|
| 343 | WRITE(numout,*) |
|---|
| 344 | ! |
|---|
| 345 | WRITE(numout,cform_aaa) ! Flag AAAAAAA |
|---|
| 346 | ! |
|---|
| 347 | ! ! Control print of the working precision |
|---|
| 348 | WRITE(numout,*) |
|---|
| 349 | IF( wp == dp ) THEN ; WRITE(numout,*) "par_kind : wp = Working precision = dp = double-precision" |
|---|
| 350 | ELSE ; WRITE(numout,*) "par_kind : wp = Working precision = sp = single-precision" |
|---|
| 351 | ENDIF |
|---|
| 352 | WRITE(numout,*) "~~~~~~~~ ****************" |
|---|
| 353 | WRITE(numout,*) |
|---|
| 354 | ! |
|---|
| 355 | ENDIF |
|---|
| 356 | ! |
|---|
| 357 | IF(lwm) WRITE( numond, namctl ) |
|---|
| 358 | ! |
|---|
| 359 | ! !------------------------------------! |
|---|
| 360 | ! ! Set global domain size parameters ! |
|---|
| 361 | ! !------------------------------------! |
|---|
| 362 | ! |
|---|
| 363 | READ ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 ) |
|---|
| 364 | 903 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in reference namelist' ) |
|---|
| 365 | READ ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 ) |
|---|
| 366 | 904 IF( ios > 0 ) CALL ctl_nam ( ios , 'namcfg in configuration namelist' ) |
|---|
| 367 | ! |
|---|
| 368 | IF( ln_read_cfg ) THEN ! Read sizes in domain configuration file |
|---|
| 369 | CALL domain_cfg ( cn_cfg, nn_cfg, Ni0glo, Nj0glo, jpkglo, l_Iperio, l_Jperio, l_NFold, c_NFtype ) |
|---|
| 370 | ELSE ! user-defined namelist |
|---|
| 371 | CALL usr_def_nam( cn_cfg, nn_cfg, Ni0glo, Nj0glo, jpkglo, l_Iperio, l_Jperio, l_NFold, c_NFtype ) |
|---|
| 372 | ENDIF |
|---|
| 373 | ! |
|---|
| 374 | IF(lwm) WRITE( numond, namcfg ) |
|---|
| 375 | ! |
|---|
| 376 | ! !-----------------------------------------! |
|---|
| 377 | ! ! mpp parameters and domain decomposition ! |
|---|
| 378 | ! !-----------------------------------------! |
|---|
| 379 | CALL mpp_init |
|---|
| 380 | |
|---|
| 381 | #if defined key_loop_fusion |
|---|
| 382 | IF( nn_hls == 1 ) THEN |
|---|
| 383 | CALL ctl_stop( 'STOP', 'nemogcm : Loop fusion can be used only with extra-halo' ) |
|---|
| 384 | ENDIF |
|---|
| 385 | #endif |
|---|
| 386 | |
|---|
| 387 | CALL halo_mng_init() |
|---|
| 388 | ! Now we know the dimensions of the grid and numout has been set: we can allocate arrays |
|---|
| 389 | CALL nemo_alloc() |
|---|
| 390 | |
|---|
| 391 | ! Initialise time level indices |
|---|
| 392 | Nbb = 1 ; Nnn = 2 ; Naa = 3 ; Nrhs = Naa |
|---|
| 393 | #if defined key_agrif |
|---|
| 394 | Kbb_a = Nbb ; Kmm_a = Nnn ; Krhs_a = Nrhs ! agrif_oce module copies of time level indices |
|---|
| 395 | #endif |
|---|
| 396 | ! !-------------------------------! |
|---|
| 397 | ! ! NEMO general initialization ! |
|---|
| 398 | ! !-------------------------------! |
|---|
| 399 | |
|---|
| 400 | CALL nemo_ctl ! Control prints of namctl and namcfg |
|---|
| 401 | ! |
|---|
| 402 | ! ! General initialization |
|---|
| 403 | IF( ln_timing ) CALL timing_init ! timing |
|---|
| 404 | IF( ln_timing ) CALL timing_start( 'nemo_init') |
|---|
| 405 | ! |
|---|
| 406 | CALL phy_cst ! Physical constants |
|---|
| 407 | CALL eos_init ! Equation of state |
|---|
| 408 | CALL wad_init ! Wetting and drying options |
|---|
| 409 | |
|---|
| 410 | #if defined key_agrif |
|---|
| 411 | CALL Agrif_Declare_Var_ini ! " " " " " DOM |
|---|
| 412 | #endif |
|---|
| 413 | CALL dom_init( Nbb, Nnn, Naa ) ! Domain |
|---|
| 414 | IF( ln_crs ) CALL crs_init( Nnn ) ! coarsened grid: domain initialization |
|---|
| 415 | IF( sn_cfctl%l_prtctl ) & |
|---|
| 416 | & CALL prt_ctl_init ! Print control |
|---|
| 417 | |
|---|
| 418 | CALL diurnal_sst_bulk_init ! diurnal sst |
|---|
| 419 | IF( ln_diurnal ) CALL diurnal_sst_coolskin_init ! cool skin |
|---|
| 420 | ! |
|---|
| 421 | IF( ln_diurnal_only ) THEN ! diurnal only: a subset of the initialisation routines |
|---|
| 422 | CALL istate_init( Nbb, Nnn, Naa ) ! ocean initial state (Dynamics and tracers) |
|---|
| 423 | CALL sbc_init( Nbb, Nnn, Naa ) ! Forcings : surface module |
|---|
| 424 | CALL tra_qsr_init ! penetrative solar radiation qsr |
|---|
| 425 | IF( ln_diaobs ) THEN ! Observation & model comparison |
|---|
| 426 | CALL dia_obs_init( Nnn ) ! Initialize observational data |
|---|
| 427 | CALL dia_obs( nit000 - 1, Nnn ) ! Observation operator for restart |
|---|
| 428 | ENDIF |
|---|
| 429 | IF( lk_asminc ) CALL asm_inc_init( Nbb, Nnn, Nrhs ) ! Assimilation increments |
|---|
| 430 | ! |
|---|
| 431 | RETURN ! end of initialization |
|---|
| 432 | ENDIF |
|---|
| 433 | ! |
|---|
| 434 | |
|---|
| 435 | CALL istate_init( Nbb, Nnn, Naa ) ! ocean initial state (Dynamics and tracers) |
|---|
| 436 | |
|---|
| 437 | ! ! external forcing |
|---|
| 438 | CALL tide_init ! tidal harmonics |
|---|
| 439 | CALL sbc_init( Nbb, Nnn, Naa ) ! surface boundary conditions (including sea-ice) |
|---|
| 440 | CALL bdy_init ! Open boundaries initialisation |
|---|
| 441 | |
|---|
| 442 | ! ! Ocean physics |
|---|
| 443 | CALL zdf_phy_init( Nnn ) ! Vertical physics |
|---|
| 444 | |
|---|
| 445 | ! ! Lateral physics |
|---|
| 446 | CALL ldf_tra_init ! Lateral ocean tracer physics |
|---|
| 447 | CALL ldf_eiv_init ! eddy induced velocity param. must be done after ldf_tra_init |
|---|
| 448 | CALL ldf_dyn_init ! Lateral ocean momentum physics |
|---|
| 449 | |
|---|
| 450 | ! ! Active tracers |
|---|
| 451 | IF( ln_traqsr ) CALL tra_qsr_init ! penetrative solar radiation qsr |
|---|
| 452 | CALL tra_bbc_init ! bottom heat flux |
|---|
| 453 | CALL tra_bbl_init ! advective (and/or diffusive) bottom boundary layer scheme |
|---|
| 454 | CALL tra_dmp_init ! internal tracer damping |
|---|
| 455 | CALL tra_adv_init ! horizontal & vertical advection |
|---|
| 456 | CALL tra_ldf_init ! lateral mixing |
|---|
| 457 | |
|---|
| 458 | ! ! Dynamics |
|---|
| 459 | IF( ln_c1d ) CALL dyn_dmp_init ! internal momentum damping |
|---|
| 460 | CALL dyn_adv_init ! advection (vector or flux form) |
|---|
| 461 | CALL dyn_vor_init ! vorticity term including Coriolis |
|---|
| 462 | CALL dyn_ldf_init ! lateral mixing |
|---|
| 463 | CALL dyn_hpg_init( Nnn ) ! horizontal gradient of Hydrostatic pressure |
|---|
| 464 | CALL dyn_spg_init ! surface pressure gradient |
|---|
| 465 | |
|---|
| 466 | ! ! Icebergs |
|---|
| 467 | CALL icb_init( rn_Dt, nit000) ! initialise icebergs instance |
|---|
| 468 | |
|---|
| 469 | ! ice shelf |
|---|
| 470 | CALL isf_init( Nbb, Nnn, Naa ) |
|---|
| 471 | #if defined key_top |
|---|
| 472 | ! ! Passive tracers |
|---|
| 473 | CALL trc_init( Nbb, Nnn, Naa ) |
|---|
| 474 | #endif |
|---|
| 475 | IF( l_ldfslp ) CALL ldf_slp_init ! slope of lateral mixing |
|---|
| 476 | |
|---|
| 477 | ! ! Misc. options |
|---|
| 478 | CALL sto_par_init ! Stochastic parametrization |
|---|
| 479 | IF( ln_sto_eos ) CALL sto_pts_init ! RRandom T/S fluctuations |
|---|
| 480 | |
|---|
| 481 | ! ! Diagnostics |
|---|
| 482 | CALL flo_init( Nnn ) ! drifting Floats |
|---|
| 483 | IF( ln_diacfl ) CALL dia_cfl_init ! Initialise CFL diagnostics |
|---|
| 484 | CALL dia_dct_init ! Sections tranports |
|---|
| 485 | CALL dia_hsb_init( Nnn ) ! heat content, salt content and volume budgets |
|---|
| 486 | CALL trd_init( Nnn ) ! Mixed-layer/Vorticity/Integral constraints trends |
|---|
| 487 | CALL dia_obs_init( Nnn ) ! Initialize observational data |
|---|
| 488 | CALL dia_25h_init( Nbb ) ! 25h mean outputs |
|---|
| 489 | CALL dia_detide_init ! Weights computation for daily detiding of model diagnostics |
|---|
| 490 | IF( ln_diaobs ) CALL dia_obs( nit000-1, Nnn ) ! Observation operator for restart |
|---|
| 491 | CALL dia_mlr_init ! Initialisation of IOM context management for multiple-linear-regression analysis |
|---|
| 492 | |
|---|
| 493 | ! ! Assimilation increments |
|---|
| 494 | IF( lk_asminc ) CALL asm_inc_init( Nbb, Nnn, Nrhs ) ! Initialize assimilation increments |
|---|
| 495 | ! |
|---|
| 496 | IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA |
|---|
| 497 | ! |
|---|
| 498 | IF( ln_timing ) CALL timing_stop( 'nemo_init') |
|---|
| 499 | ! |
|---|
| 500 | END SUBROUTINE nemo_init |
|---|
| 501 | |
|---|
| 502 | |
|---|
| 503 | SUBROUTINE nemo_ctl |
|---|
| 504 | !!---------------------------------------------------------------------- |
|---|
| 505 | !! *** ROUTINE nemo_ctl *** |
|---|
| 506 | !! |
|---|
| 507 | !! ** Purpose : control print setting |
|---|
| 508 | !! |
|---|
| 509 | !! ** Method : - print namctl and namcfg information and check some consistencies |
|---|
| 510 | !!---------------------------------------------------------------------- |
|---|
| 511 | ! |
|---|
| 512 | IF(lwp) THEN ! control print |
|---|
| 513 | WRITE(numout,*) |
|---|
| 514 | WRITE(numout,*) 'nemo_ctl: Control prints' |
|---|
| 515 | WRITE(numout,*) '~~~~~~~~' |
|---|
| 516 | WRITE(numout,*) ' Namelist namctl' |
|---|
| 517 | WRITE(numout,*) ' sn_cfctl%l_runstat = ', sn_cfctl%l_runstat |
|---|
| 518 | WRITE(numout,*) ' sn_cfctl%l_trcstat = ', sn_cfctl%l_trcstat |
|---|
| 519 | WRITE(numout,*) ' sn_cfctl%l_oceout = ', sn_cfctl%l_oceout |
|---|
| 520 | WRITE(numout,*) ' sn_cfctl%l_layout = ', sn_cfctl%l_layout |
|---|
| 521 | WRITE(numout,*) ' sn_cfctl%l_prtctl = ', sn_cfctl%l_prtctl |
|---|
| 522 | WRITE(numout,*) ' sn_cfctl%l_prttrc = ', sn_cfctl%l_prttrc |
|---|
| 523 | WRITE(numout,*) ' sn_cfctl%l_oasout = ', sn_cfctl%l_oasout |
|---|
| 524 | WRITE(numout,*) ' sn_cfctl%procmin = ', sn_cfctl%procmin |
|---|
| 525 | WRITE(numout,*) ' sn_cfctl%procmax = ', sn_cfctl%procmax |
|---|
| 526 | WRITE(numout,*) ' sn_cfctl%procincr = ', sn_cfctl%procincr |
|---|
| 527 | WRITE(numout,*) ' sn_cfctl%ptimincr = ', sn_cfctl%ptimincr |
|---|
| 528 | WRITE(numout,*) ' timing by routine ln_timing = ', ln_timing |
|---|
| 529 | WRITE(numout,*) ' CFL diagnostics ln_diacfl = ', ln_diacfl |
|---|
| 530 | ENDIF |
|---|
| 531 | ! |
|---|
| 532 | IF( .NOT.ln_read_cfg ) ln_closea = .false. ! dealing possible only with a domcfg file |
|---|
| 533 | IF(lwp) THEN ! control print |
|---|
| 534 | WRITE(numout,*) |
|---|
| 535 | WRITE(numout,*) ' Namelist namcfg' |
|---|
| 536 | WRITE(numout,*) ' read domain configuration file ln_read_cfg = ', ln_read_cfg |
|---|
| 537 | WRITE(numout,*) ' filename to be read cn_domcfg = ', TRIM(cn_domcfg) |
|---|
| 538 | WRITE(numout,*) ' keep closed seas in the domain (if exist) ln_closea = ', ln_closea |
|---|
| 539 | WRITE(numout,*) ' create a configuration definition file ln_write_cfg = ', ln_write_cfg |
|---|
| 540 | WRITE(numout,*) ' filename to be written cn_domcfg_out = ', TRIM(cn_domcfg_out) |
|---|
| 541 | WRITE(numout,*) ' use file attribute if exists as i/p j-start ln_use_jattr = ', ln_use_jattr |
|---|
| 542 | ENDIF |
|---|
| 543 | ! |
|---|
| 544 | IF( 1._wp /= SIGN(1._wp,-0._wp) ) CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows f2003 standard.', & |
|---|
| 545 | & 'Compile with key_nosignedzero enabled:', & |
|---|
| 546 | & '--> add -Dkey_nosignedzero to the definition of %CPP in your arch file' ) |
|---|
| 547 | ! |
|---|
| 548 | #if defined key_agrif |
|---|
| 549 | IF( ln_timing ) CALL ctl_stop( 'AGRIF not implemented with ln_timing = true') |
|---|
| 550 | #endif |
|---|
| 551 | ! |
|---|
| 552 | END SUBROUTINE nemo_ctl |
|---|
| 553 | |
|---|
| 554 | |
|---|
| 555 | SUBROUTINE nemo_closefile |
|---|
| 556 | !!---------------------------------------------------------------------- |
|---|
| 557 | !! *** ROUTINE nemo_closefile *** |
|---|
| 558 | !! |
|---|
| 559 | !! ** Purpose : Close the files |
|---|
| 560 | !!---------------------------------------------------------------------- |
|---|
| 561 | ! |
|---|
| 562 | IF( lk_mpp ) CALL mppsync |
|---|
| 563 | ! |
|---|
| 564 | CALL iom_close ! close all input/output files managed by iom_* |
|---|
| 565 | ! |
|---|
| 566 | IF( numstp /= -1 ) CLOSE( numstp ) ! time-step file |
|---|
| 567 | IF( numrun /= -1 ) CLOSE( numrun ) ! run statistics file |
|---|
| 568 | IF( lwm.AND.numond /= -1 ) CLOSE( numond ) ! oce output namelist |
|---|
| 569 | IF( lwm.AND.numoni /= -1 ) CLOSE( numoni ) ! ice output namelist |
|---|
| 570 | IF( numevo_ice /= -1 ) CLOSE( numevo_ice ) ! ice variables (temp. evolution) |
|---|
| 571 | IF( numout /= 6 ) CLOSE( numout ) ! standard model output file |
|---|
| 572 | IF( numdct_vol /= -1 ) CLOSE( numdct_vol ) ! volume transports |
|---|
| 573 | IF( numdct_heat /= -1 ) CLOSE( numdct_heat ) ! heat transports |
|---|
| 574 | IF( numdct_salt /= -1 ) CLOSE( numdct_salt ) ! salt transports |
|---|
| 575 | ! |
|---|
| 576 | numout = 6 ! redefine numout in case it is used after this point... |
|---|
| 577 | ! |
|---|
| 578 | END SUBROUTINE nemo_closefile |
|---|
| 579 | |
|---|
| 580 | |
|---|
| 581 | SUBROUTINE nemo_alloc |
|---|
| 582 | !!---------------------------------------------------------------------- |
|---|
| 583 | !! *** ROUTINE nemo_alloc *** |
|---|
| 584 | !! |
|---|
| 585 | !! ** Purpose : Allocate all the dynamic arrays of the OCE modules |
|---|
| 586 | !! |
|---|
| 587 | !! ** Method : |
|---|
| 588 | !!---------------------------------------------------------------------- |
|---|
| 589 | USE diawri , ONLY : dia_wri_alloc |
|---|
| 590 | USE dom_oce , ONLY : dom_oce_alloc |
|---|
| 591 | USE trc_oce , ONLY : trc_oce_alloc |
|---|
| 592 | USE bdy_oce , ONLY : bdy_oce_alloc |
|---|
| 593 | ! |
|---|
| 594 | INTEGER :: ierr |
|---|
| 595 | !!---------------------------------------------------------------------- |
|---|
| 596 | ! |
|---|
| 597 | ierr = oce_alloc () ! ocean |
|---|
| 598 | ierr = ierr + dia_wri_alloc() |
|---|
| 599 | ierr = ierr + dom_oce_alloc() ! ocean domain |
|---|
| 600 | ierr = ierr + zdf_oce_alloc() ! ocean vertical physics |
|---|
| 601 | ierr = ierr + trc_oce_alloc() ! shared TRC / TRA arrays |
|---|
| 602 | ierr = ierr + bdy_oce_alloc() ! bdy masks (incl. initialization) |
|---|
| 603 | ! |
|---|
| 604 | CALL mpp_sum( 'nemogcm', ierr ) |
|---|
| 605 | IF( ierr /= 0 ) CALL ctl_stop( 'STOP', 'nemo_alloc: unable to allocate standard ocean arrays' ) |
|---|
| 606 | ! |
|---|
| 607 | END SUBROUTINE nemo_alloc |
|---|
| 608 | |
|---|
| 609 | |
|---|
| 610 | SUBROUTINE nemo_set_cfctl(sn_cfctl, setto ) |
|---|
| 611 | !!---------------------------------------------------------------------- |
|---|
| 612 | !! *** ROUTINE nemo_set_cfctl *** |
|---|
| 613 | !! |
|---|
| 614 | !! ** Purpose : Set elements of the output control structure to setto. |
|---|
| 615 | !! |
|---|
| 616 | !! ** Method : Note this routine can be used to switch on/off some |
|---|
| 617 | !! types of output for selected areas. |
|---|
| 618 | !!---------------------------------------------------------------------- |
|---|
| 619 | TYPE(sn_ctl), INTENT(inout) :: sn_cfctl |
|---|
| 620 | LOGICAL , INTENT(in ) :: setto |
|---|
| 621 | !!---------------------------------------------------------------------- |
|---|
| 622 | sn_cfctl%l_runstat = setto |
|---|
| 623 | sn_cfctl%l_trcstat = setto |
|---|
| 624 | sn_cfctl%l_oceout = setto |
|---|
| 625 | sn_cfctl%l_layout = setto |
|---|
| 626 | sn_cfctl%l_prtctl = setto |
|---|
| 627 | sn_cfctl%l_prttrc = setto |
|---|
| 628 | sn_cfctl%l_oasout = setto |
|---|
| 629 | END SUBROUTINE nemo_set_cfctl |
|---|
| 630 | |
|---|
| 631 | !!====================================================================== |
|---|
| 632 | END MODULE nemogcm |
|---|
