1 | MODULE nemogcm |
---|
2 | !!====================================================================== |
---|
3 | !! *** MODULE nemogcm *** |
---|
4 | !! Off-line Ocean : passive tracer evolution, dynamics read in files |
---|
5 | !!====================================================================== |
---|
6 | !! History : 3.3 ! 2010-05 (C. Ethe) Full reorganization of the off-line: phasing with the on-line |
---|
7 | !! 3.4 ! 2011-01 (C. Ethe, A. R. Porter, STFC Daresbury) dynamical allocation |
---|
8 | !! 4.0 ! 2016-10 (C. Ethe, G. Madec, S. Flavoni) domain configuration / user defined interface |
---|
9 | !! 4.1 ! 2019-08 (A. Coward, D. Storkey) rewrite in preparation for new timestepping scheme |
---|
10 | !!---------------------------------------------------------------------- |
---|
11 | |
---|
12 | !!---------------------------------------------------------------------- |
---|
13 | !! nemo_gcm : off-line: solve ocean tracer only |
---|
14 | !! nemo_gcm : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice |
---|
15 | !! nemo_init : initialization of the NEMO system |
---|
16 | !! nemo_ctl : initialisation of the contol print |
---|
17 | !! nemo_closefile: close remaining open files |
---|
18 | !! nemo_alloc : dynamical allocation |
---|
19 | !! istate_init : simple initialization to zero of ocean fields |
---|
20 | !! stp_ctl : reduced step control (no dynamics in off-line) |
---|
21 | !!---------------------------------------------------------------------- |
---|
22 | USE dom_oce ! ocean space domain variables |
---|
23 | USE oce ! dynamics and tracers variables |
---|
24 | USE trc_oce ! Shared ocean/passive tracers variables |
---|
25 | USE c1d ! 1D configuration |
---|
26 | USE domain ! domain initialization from coordinate & bathymetry (dom_init routine) |
---|
27 | USE closea ! treatment of closed seas (for ln_closea) |
---|
28 | USE usrdef_nam ! user defined configuration |
---|
29 | USE eosbn2 ! equation of state (eos bn2 routine) |
---|
30 | #if defined key_qco |
---|
31 | USE domqco ! tools for scale factor (dom_qco_r3c routine) |
---|
32 | #endif |
---|
33 | USE bdyini ! open boundary cond. setting (bdy_init routine) |
---|
34 | ! ! ocean physics |
---|
35 | USE ldftra ! lateral diffusivity setting (ldf_tra_init routine) |
---|
36 | USE ldfslp ! slopes of neutral surfaces (ldf_slp_init routine) |
---|
37 | USE traqsr ! solar radiation penetration (tra_qsr_init routine) |
---|
38 | USE trabbl ! bottom boundary layer (tra_bbl_init routine) |
---|
39 | USE traldf ! lateral physics (tra_ldf_init routine) |
---|
40 | USE sbcmod ! surface boundary condition (sbc_init routine) |
---|
41 | USE phycst ! physical constant (par_cst routine) |
---|
42 | USE zdfphy ! vertical physics manager (zdf_phy_init routine) |
---|
43 | USE dtadyn ! Lecture and Interpolation of the dynamical fields |
---|
44 | USE trcini ! Initilization of the passive tracers |
---|
45 | USE daymod ! calendar (day routine) |
---|
46 | USE trcstp ! passive tracer time-stepping (trc_stp routine) |
---|
47 | USE dtadyn ! Lecture and interpolation of the dynamical fields |
---|
48 | ! ! Passive tracers needs |
---|
49 | USE trc ! passive tracer : variables |
---|
50 | USE trcnam ! passive tracer : namelist |
---|
51 | USE trcrst ! passive tracer restart |
---|
52 | USE sbc_oce , ONLY : ln_rnf |
---|
53 | USE sbcrnf ! surface boundary condition : runoffs |
---|
54 | ! ! I/O & MPP |
---|
55 | USE iom ! I/O library |
---|
56 | USE in_out_manager ! I/O manager |
---|
57 | USE mppini ! shared/distributed memory setting (mpp_init routine) |
---|
58 | USE lib_mpp ! distributed memory computing |
---|
59 | #if defined key_xios |
---|
60 | USE xios ! xIOserver |
---|
61 | #endif |
---|
62 | USE prtctl ! Print control (prt_ctl_init routine) |
---|
63 | USE timing ! Timing |
---|
64 | USE lib_fortran ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) |
---|
65 | #if defined key_qco |
---|
66 | USE stpmlf , ONLY : Nbb, Nnn, Naa, Nrhs ! time level indices |
---|
67 | #else |
---|
68 | USE step , ONLY : Nbb, Nnn, Naa, Nrhs ! time level indices |
---|
69 | #endif |
---|
70 | USE halo_mng |
---|
71 | |
---|
72 | IMPLICIT NONE |
---|
73 | PRIVATE |
---|
74 | |
---|
75 | PUBLIC nemo_gcm ! called by nemo.F90 |
---|
76 | |
---|
77 | CHARACTER (len=64) :: cform_aaa="( /, 'AAAAAAAA', / ) " ! flag for output listing |
---|
78 | #if ! defined key_mpi_off |
---|
79 | ! need MPI_Wtime |
---|
80 | INCLUDE 'mpif.h' |
---|
81 | #endif |
---|
82 | |
---|
83 | !!---------------------------------------------------------------------- |
---|
84 | !! NEMO/OFF 4.0 , NEMO Consortium (2018) |
---|
85 | !! $Id$ |
---|
86 | !! Software governed by the CeCILL license (see ./LICENSE) |
---|
87 | !!---------------------------------------------------------------------- |
---|
88 | CONTAINS |
---|
89 | |
---|
90 | SUBROUTINE nemo_gcm |
---|
91 | !!---------------------------------------------------------------------- |
---|
92 | !! *** ROUTINE nemo_gcm *** |
---|
93 | !! |
---|
94 | !! ** Purpose : NEMO solves the primitive equations on an orthogonal |
---|
95 | !! curvilinear mesh on the sphere. |
---|
96 | !! |
---|
97 | !! ** Method : - model general initialization |
---|
98 | !! - launch the time-stepping (dta_dyn and trc_stp) |
---|
99 | !! - finalize the run by closing files and communications |
---|
100 | !! |
---|
101 | !! References : Madec, Delecluse,Imbard, and Levy, 1997: internal report, IPSL. |
---|
102 | !! Madec, 2008, internal report, IPSL. |
---|
103 | !!---------------------------------------------------------------------- |
---|
104 | INTEGER :: istp ! time step index |
---|
105 | REAL(wp):: zstptiming ! elapsed time for 1 time step |
---|
106 | !!---------------------------------------------------------------------- |
---|
107 | |
---|
108 | CALL nemo_init ! Initializations |
---|
109 | |
---|
110 | ! check that all process are still there... If some process have an error, |
---|
111 | ! they will never enter in step and other processes will wait until the end of the cpu time! |
---|
112 | CALL mpp_max( 'nemogcm', nstop ) |
---|
113 | |
---|
114 | ! !-----------------------! |
---|
115 | ! !== time stepping ==! |
---|
116 | ! !-----------------------! |
---|
117 | istp = nit000 |
---|
118 | ! |
---|
119 | IF( ln_rnf ) CALL sbc_rnf(istp) ! runoffs initialization |
---|
120 | ! |
---|
121 | CALL iom_init( cxios_context ) ! iom_put initialization (must be done after nemo_init for AGRIF+XIOS+OASIS) |
---|
122 | ! |
---|
123 | DO WHILE ( istp <= nitend .AND. nstop == 0 ) !== OFF time-stepping ==! |
---|
124 | IF( ln_timing ) THEN |
---|
125 | zstptiming = MPI_Wtime() |
---|
126 | IF ( istp == ( nit000 + 1 ) ) elapsed_time = zstptiming |
---|
127 | IF ( istp == nitend ) elapsed_time = zstptiming - elapsed_time |
---|
128 | ENDIF |
---|
129 | ! |
---|
130 | IF((istp == nitrst) .AND. lwxios) THEN |
---|
131 | CALL iom_swap( cw_toprst_cxt ) |
---|
132 | CALL iom_init_closedef(cw_toprst_cxt) |
---|
133 | CALL iom_setkt( istp - nit000 + 1, cw_toprst_cxt ) |
---|
134 | ENDIF |
---|
135 | |
---|
136 | IF( istp /= nit000 ) CALL day ( istp ) ! Calendar (day was already called at nit000 in day_init) |
---|
137 | CALL iom_setkt ( istp - nit000 + 1, cxios_context ) ! say to iom that we are at time step kstp |
---|
138 | #if ! defined key_sed_off |
---|
139 | CALL dta_dyn ( istp, Nbb, Nnn, Naa ) ! Interpolation of the dynamical fields |
---|
140 | IF( .NOT.ln_linssh ) THEN |
---|
141 | CALL dta_dyn_atf( istp, Nbb, Nnn, Naa ) ! time filter of sea surface height and vertical scale factors |
---|
142 | # if defined key_qco |
---|
143 | CALL dom_qco_r3c( ssh(:,:,Nnn), r3t_f, r3u_f, r3v_f ) |
---|
144 | # endif |
---|
145 | ENDIF |
---|
146 | CALL trc_stp ( istp, Nbb, Nnn, Nrhs, Naa ) ! time-stepping |
---|
147 | ! Swap time levels |
---|
148 | Nrhs = Nbb |
---|
149 | Nbb = Nnn |
---|
150 | Nnn = Naa |
---|
151 | Naa = Nrhs |
---|
152 | ! |
---|
153 | # if ! defined key_qco |
---|
154 | IF( .NOT.ln_linssh ) CALL dta_dyn_sf_interp( istp, Nnn ) ! calculate now grid parameters |
---|
155 | # endif |
---|
156 | |
---|
157 | #else |
---|
158 | CALL dta_dyn_sed( istp, Nnn ) ! Interpolation of the dynamical fields |
---|
159 | CALL trc_stp ( istp, Nbb, Nnn, Nrhs, Naa ) ! time-stepping |
---|
160 | ! Swap time levels |
---|
161 | Nnn = Nbb |
---|
162 | Naa = Nbb |
---|
163 | #endif |
---|
164 | CALL stp_ctl ( istp ) ! Time loop: control and print |
---|
165 | istp = istp + 1 |
---|
166 | |
---|
167 | IF( lwp .AND. ln_timing ) WRITE(numtime,*) 'timing step ', istp-1, ' : ', MPI_Wtime() - zstptiming |
---|
168 | |
---|
169 | END DO |
---|
170 | ! |
---|
171 | #if defined key_xios |
---|
172 | CALL iom_context_finalize( cxios_context ) ! needed for XIOS+AGRIF |
---|
173 | #endif |
---|
174 | |
---|
175 | ! !------------------------! |
---|
176 | ! !== finalize the run ==! |
---|
177 | ! !------------------------! |
---|
178 | IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA |
---|
179 | |
---|
180 | IF( nstop /= 0 .AND. lwp ) THEN ! error print |
---|
181 | WRITE(ctmp1,*) ' ==>>> nemo_gcm: a total of ', nstop, ' errors have been found' |
---|
182 | WRITE(ctmp2,*) ' Look for "E R R O R" messages in all existing ocean_output* files' |
---|
183 | CALL ctl_stop( ' ', ctmp1, ' ', ctmp2 ) |
---|
184 | ENDIF |
---|
185 | ! |
---|
186 | IF( ln_timing ) CALL timing_finalize |
---|
187 | ! |
---|
188 | CALL nemo_closefile |
---|
189 | ! |
---|
190 | #if defined key_xios |
---|
191 | CALL xios_finalize ! end mpp communications with xios |
---|
192 | #else |
---|
193 | IF( lk_mpp ) CALL mppstop ! end mpp communications |
---|
194 | #endif |
---|
195 | ! |
---|
196 | IF(lwm) THEN |
---|
197 | IF( nstop == 0 ) THEN ; STOP 0 |
---|
198 | ELSE ; STOP 123 |
---|
199 | ENDIF |
---|
200 | ENDIF |
---|
201 | ! |
---|
202 | END SUBROUTINE nemo_gcm |
---|
203 | |
---|
204 | |
---|
205 | SUBROUTINE nemo_init |
---|
206 | !!---------------------------------------------------------------------- |
---|
207 | !! *** ROUTINE nemo_init *** |
---|
208 | !! |
---|
209 | !! ** Purpose : initialization of the nemo model in off-line mode |
---|
210 | !!---------------------------------------------------------------------- |
---|
211 | INTEGER :: ios, ilocal_comm ! local integers |
---|
212 | !! |
---|
213 | NAMELIST/namctl/ sn_cfctl, ln_timing, ln_diacfl, & |
---|
214 | & nn_isplt, nn_jsplt, nn_ictls, nn_ictle, nn_jctls, nn_jctle |
---|
215 | NAMELIST/namcfg/ ln_read_cfg, cn_domcfg, ln_closea, ln_write_cfg, cn_domcfg_out, ln_use_jattr |
---|
216 | !!---------------------------------------------------------------------- |
---|
217 | ! |
---|
218 | cxios_context = 'nemo' |
---|
219 | nn_hls = 1 |
---|
220 | ! |
---|
221 | ! !-------------------------------------------------! |
---|
222 | ! ! set communicator & select the local rank ! |
---|
223 | ! ! must be done as soon as possible to get narea ! |
---|
224 | ! !-------------------------------------------------! |
---|
225 | ! |
---|
226 | #if defined key_xios |
---|
227 | CALL xios_initialize( "for_xios_mpi_id", return_comm=ilocal_comm ) ! nemo local communicator given by xios |
---|
228 | CALL mpp_start( ilocal_comm ) |
---|
229 | #else |
---|
230 | CALL mpp_start( ) |
---|
231 | #endif |
---|
232 | ! |
---|
233 | narea = mpprank + 1 ! mpprank: the rank of proc (0 --> mppsize -1 ) |
---|
234 | lwm = (narea == 1) ! control of output namelists |
---|
235 | ! |
---|
236 | ! !---------------------------------------------------------------! |
---|
237 | ! ! Open output files, reference and configuration namelist files ! |
---|
238 | ! !---------------------------------------------------------------! |
---|
239 | ! |
---|
240 | ! open ocean.output as soon as possible to get all output prints (including errors messages) |
---|
241 | IF( lwm ) CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. ) |
---|
242 | ! open reference and configuration namelist files |
---|
243 | CALL load_nml( numnam_ref, 'namelist_ref', -1, lwm ) |
---|
244 | CALL load_nml( numnam_cfg, 'namelist_cfg', -1, lwm ) |
---|
245 | IF( lwm ) CALL ctl_opn( numond, 'output.namelist.dyn', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. ) |
---|
246 | ! open /dev/null file to be able to supress output write easily |
---|
247 | IF( Agrif_Root() ) THEN |
---|
248 | CALL ctl_opn( numnul, '/dev/null', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. ) |
---|
249 | #ifdef key_agrif |
---|
250 | ELSE |
---|
251 | numnul = Agrif_Parent(numnul) |
---|
252 | #endif |
---|
253 | ENDIF |
---|
254 | ! |
---|
255 | ! !--------------------! |
---|
256 | ! ! Open listing units ! -> need sn_cfctl from namctl to define lwp |
---|
257 | ! !--------------------! |
---|
258 | ! |
---|
259 | READ ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 ) |
---|
260 | 901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in reference namelist' ) |
---|
261 | READ ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 ) |
---|
262 | 902 IF( ios > 0 ) CALL ctl_nam ( ios , 'namctl in configuration namelist' ) |
---|
263 | ! |
---|
264 | ! finalize the definition of namctl variables |
---|
265 | IF( narea < sn_cfctl%procmin .OR. narea > sn_cfctl%procmax .OR. MOD( narea - sn_cfctl%procmin, sn_cfctl%procincr ) /= 0 ) & |
---|
266 | & CALL nemo_set_cfctl( sn_cfctl, .FALSE. ) |
---|
267 | ! |
---|
268 | lwp = (narea == 1) .OR. sn_cfctl%l_oceout ! control of all listing output print |
---|
269 | ! |
---|
270 | IF(lwp) THEN ! open listing units |
---|
271 | ! |
---|
272 | IF( .NOT. lwm ) & ! alreay opened for narea == 1 |
---|
273 | & CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE., narea ) |
---|
274 | ! |
---|
275 | WRITE(numout,*) |
---|
276 | WRITE(numout,*) ' CNRS - NERC - Met OFFICE - MERCATOR-ocean - CMCC' |
---|
277 | WRITE(numout,*) ' NEMO team' |
---|
278 | WRITE(numout,*) ' Off-line TOP Model' |
---|
279 | WRITE(numout,*) ' NEMO version 4.0 (2019) ' |
---|
280 | WRITE(numout,*) |
---|
281 | WRITE(numout,*) " ._ ._ ._ ._ ._ " |
---|
282 | WRITE(numout,*) " _.-._)`\_.-._)`\_.-._)`\_.-._)`\_.-._)`\_ " |
---|
283 | WRITE(numout,*) |
---|
284 | WRITE(numout,*) " o _, _, " |
---|
285 | WRITE(numout,*) " o .' ( .-' / " |
---|
286 | WRITE(numout,*) " o _/..._'. .' / " |
---|
287 | WRITE(numout,*) " ( o .-'` ` '-./ _.' " |
---|
288 | WRITE(numout,*) " ) ( o) ;= <_ ( " |
---|
289 | WRITE(numout,*) " ( '-.,\\__ __.-;`\ '. ) " |
---|
290 | WRITE(numout,*) " ) ) \) |`\ \) '. \ ( ( " |
---|
291 | WRITE(numout,*) " ( ( \_/ '-._\ ) ) " |
---|
292 | WRITE(numout,*) " ) ) ` ( ( " |
---|
293 | WRITE(numout,*) " ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^ " |
---|
294 | WRITE(numout,*) |
---|
295 | ! |
---|
296 | WRITE(numout,cform_aaa) ! Flag AAAAAAA |
---|
297 | ! |
---|
298 | ENDIF |
---|
299 | ! |
---|
300 | IF(lwm) WRITE( numond, namctl ) |
---|
301 | ! |
---|
302 | ! !------------------------------------! |
---|
303 | ! ! Set global domain size parameters ! |
---|
304 | ! !------------------------------------! |
---|
305 | ! |
---|
306 | READ ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 ) |
---|
307 | 903 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in reference namelist' ) |
---|
308 | READ ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 ) |
---|
309 | 904 IF( ios > 0 ) CALL ctl_nam ( ios , 'namcfg in configuration namelist' ) |
---|
310 | ! |
---|
311 | IF( ln_read_cfg ) THEN ! Read sizes in domain configuration file |
---|
312 | CALL domain_cfg ( cn_cfg, nn_cfg, Ni0glo, Nj0glo, jpkglo, l_Iperio, l_Jperio, l_NFold, c_NFtype ) |
---|
313 | ELSE ! user-defined namelist |
---|
314 | CALL usr_def_nam( cn_cfg, nn_cfg, Ni0glo, Nj0glo, jpkglo, l_Iperio, l_Jperio, l_NFold, c_NFtype ) |
---|
315 | ENDIF |
---|
316 | ! |
---|
317 | IF(lwm) WRITE( numond, namcfg ) |
---|
318 | l_offline = .true. ! passive tracers are run offline |
---|
319 | ! |
---|
320 | ! !-----------------------------------------! |
---|
321 | ! ! mpp parameters and domain decomposition ! |
---|
322 | ! !-----------------------------------------! |
---|
323 | ! |
---|
324 | CALL mpp_init |
---|
325 | |
---|
326 | #if defined key_loop_fusion |
---|
327 | IF( nn_hls == 1 ) THEN |
---|
328 | CALL ctl_stop( 'STOP', 'nemogcm : Loop fusion can be used only with extra-halo' ) |
---|
329 | ENDIF |
---|
330 | #endif |
---|
331 | |
---|
332 | CALL halo_mng_init() |
---|
333 | ! Now we know the dimensions of the grid and numout has been set: we can allocate arrays |
---|
334 | CALL nemo_alloc() |
---|
335 | |
---|
336 | ! Initialise time level indices |
---|
337 | Nbb = 1; Nnn = 2; Naa = 3; Nrhs = Naa |
---|
338 | |
---|
339 | ! !-------------------------------! |
---|
340 | ! ! NEMO general initialization ! |
---|
341 | ! !-------------------------------! |
---|
342 | |
---|
343 | CALL nemo_ctl ! Control prints |
---|
344 | ! |
---|
345 | ! ! General initialization |
---|
346 | IF( ln_timing ) CALL timing_init |
---|
347 | IF( ln_timing ) CALL timing_start( 'nemo_init') |
---|
348 | ! |
---|
349 | CALL phy_cst ! Physical constants |
---|
350 | CALL eos_init ! Equation of state |
---|
351 | IF( ln_c1d ) CALL c1d_init ! 1D column configuration |
---|
352 | CALL dom_init( Nbb, Nnn, Naa ) ! Domain |
---|
353 | IF( sn_cfctl%l_prtctl ) & |
---|
354 | & CALL prt_ctl_init ! Print control |
---|
355 | |
---|
356 | CALL istate_init( Nnn, Naa ) ! ocean initial state (Dynamics and tracers) |
---|
357 | |
---|
358 | CALL sbc_init( Nbb, Nnn, Naa ) ! Forcings : surface module |
---|
359 | CALL bdy_init ! Open boundaries initialisation |
---|
360 | |
---|
361 | CALL zdf_phy_init( Nnn ) ! Vertical physics |
---|
362 | |
---|
363 | ! ! Tracer physics |
---|
364 | CALL ldf_tra_init ! Lateral ocean tracer physics |
---|
365 | CALL ldf_eiv_init ! Eddy induced velocity param. must be done after ldf_tra_init |
---|
366 | CALL tra_ldf_init ! lateral mixing |
---|
367 | IF( l_ldfslp ) CALL ldf_slp_init ! slope of lateral mixing |
---|
368 | IF( ln_traqsr ) CALL tra_qsr_init ! penetrative solar radiation |
---|
369 | IF( ln_trabbl ) CALL tra_bbl_init ! advective (and/or diffusive) bottom boundary layer scheme |
---|
370 | |
---|
371 | ! ! Passive tracers |
---|
372 | CALL trc_nam_run ! Needed to get restart parameters for passive tracers |
---|
373 | CALL trc_rst_cal( nit000, 'READ' ) ! calendar |
---|
374 | #if defined key_sed_off |
---|
375 | CALL dta_dyn_sed_init( Nnn ) ! Initialization for the dynamics |
---|
376 | #else |
---|
377 | CALL dta_dyn_init( Nbb, Nnn, Naa ) ! Initialization for the dynamics |
---|
378 | #endif |
---|
379 | CALL trc_init( Nbb, Nnn, Naa ) ! Passive tracers initialization |
---|
380 | |
---|
381 | IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA |
---|
382 | ! |
---|
383 | IF( ln_timing ) CALL timing_stop( 'nemo_init') |
---|
384 | ! |
---|
385 | END SUBROUTINE nemo_init |
---|
386 | |
---|
387 | |
---|
388 | SUBROUTINE nemo_ctl |
---|
389 | !!---------------------------------------------------------------------- |
---|
390 | !! *** ROUTINE nemo_ctl *** |
---|
391 | !! |
---|
392 | !! ** Purpose : control print setting |
---|
393 | !! |
---|
394 | !! ** Method : - print namctl and namcfg information and check some consistencies |
---|
395 | !!---------------------------------------------------------------------- |
---|
396 | ! |
---|
397 | IF(lwp) THEN ! control print |
---|
398 | WRITE(numout,*) |
---|
399 | WRITE(numout,*) 'nemo_ctl: Control prints' |
---|
400 | WRITE(numout,*) '~~~~~~~~' |
---|
401 | WRITE(numout,*) ' Namelist namctl' |
---|
402 | WRITE(numout,*) ' sn_cfctl%l_runstat = ', sn_cfctl%l_runstat |
---|
403 | WRITE(numout,*) ' sn_cfctl%l_trcstat = ', sn_cfctl%l_trcstat |
---|
404 | WRITE(numout,*) ' sn_cfctl%l_oceout = ', sn_cfctl%l_oceout |
---|
405 | WRITE(numout,*) ' sn_cfctl%l_layout = ', sn_cfctl%l_layout |
---|
406 | WRITE(numout,*) ' sn_cfctl%l_prtctl = ', sn_cfctl%l_prtctl |
---|
407 | WRITE(numout,*) ' sn_cfctl%l_prttrc = ', sn_cfctl%l_prttrc |
---|
408 | WRITE(numout,*) ' sn_cfctl%l_oasout = ', sn_cfctl%l_oasout |
---|
409 | WRITE(numout,*) ' sn_cfctl%procmin = ', sn_cfctl%procmin |
---|
410 | WRITE(numout,*) ' sn_cfctl%procmax = ', sn_cfctl%procmax |
---|
411 | WRITE(numout,*) ' sn_cfctl%procincr = ', sn_cfctl%procincr |
---|
412 | WRITE(numout,*) ' sn_cfctl%ptimincr = ', sn_cfctl%ptimincr |
---|
413 | WRITE(numout,*) ' timing by routine ln_timing = ', ln_timing |
---|
414 | WRITE(numout,*) ' CFL diagnostics ln_diacfl = ', ln_diacfl |
---|
415 | ENDIF |
---|
416 | |
---|
417 | IF( .NOT.ln_read_cfg ) ln_closea = .false. ! dealing possible only with a domcfg file |
---|
418 | IF(lwp) THEN ! control print |
---|
419 | WRITE(numout,*) |
---|
420 | WRITE(numout,*) ' Namelist namcfg' |
---|
421 | WRITE(numout,*) ' read domain configuration file ln_read_cfg = ', ln_read_cfg |
---|
422 | WRITE(numout,*) ' filename to be read cn_domcfg = ', TRIM(cn_domcfg) |
---|
423 | WRITE(numout,*) ' keep closed seas in the domain (if exist) ln_closea = ', ln_closea |
---|
424 | WRITE(numout,*) ' create a configuration definition file ln_write_cfg = ', ln_write_cfg |
---|
425 | WRITE(numout,*) ' filename to be written cn_domcfg_out = ', TRIM(cn_domcfg_out) |
---|
426 | WRITE(numout,*) ' use file attribute if exists as i/p j-start ln_use_jattr = ', ln_use_jattr |
---|
427 | ENDIF |
---|
428 | ! |
---|
429 | IF( 1._wp /= SIGN(1._wp,-0._wp) ) CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows f2003 standard.', & |
---|
430 | & 'Compile with key_nosignedzero enabled' ) |
---|
431 | ! |
---|
432 | END SUBROUTINE nemo_ctl |
---|
433 | |
---|
434 | |
---|
435 | SUBROUTINE nemo_closefile |
---|
436 | !!---------------------------------------------------------------------- |
---|
437 | !! *** ROUTINE nemo_closefile *** |
---|
438 | !! |
---|
439 | !! ** Purpose : Close the files |
---|
440 | !!---------------------------------------------------------------------- |
---|
441 | ! |
---|
442 | IF( lk_mpp ) CALL mppsync |
---|
443 | ! |
---|
444 | CALL iom_close ! close all input/output files managed by iom_* |
---|
445 | ! |
---|
446 | IF( numstp /= -1 ) CLOSE( numstp ) ! time-step file |
---|
447 | IF( lwm.AND.numond /= -1 ) CLOSE( numond ) ! oce output namelist |
---|
448 | ! |
---|
449 | numout = 6 ! redefine numout in case it is used after this point... |
---|
450 | ! |
---|
451 | END SUBROUTINE nemo_closefile |
---|
452 | |
---|
453 | |
---|
454 | SUBROUTINE nemo_alloc |
---|
455 | !!---------------------------------------------------------------------- |
---|
456 | !! *** ROUTINE nemo_alloc *** |
---|
457 | !! |
---|
458 | !! ** Purpose : Allocate all the dynamic arrays of the OCE modules |
---|
459 | !! |
---|
460 | !! ** Method : |
---|
461 | !!---------------------------------------------------------------------- |
---|
462 | USE diawri , ONLY : dia_wri_alloc |
---|
463 | USE dom_oce, ONLY : dom_oce_alloc |
---|
464 | USE zdf_oce, ONLY : zdf_oce_alloc |
---|
465 | USE trc_oce, ONLY : trc_oce_alloc |
---|
466 | USE bdy_oce, ONLY : bdy_oce_alloc |
---|
467 | ! |
---|
468 | INTEGER :: ierr |
---|
469 | !!---------------------------------------------------------------------- |
---|
470 | ! |
---|
471 | ierr = oce_alloc () ! ocean |
---|
472 | ierr = ierr + dia_wri_alloc() |
---|
473 | ierr = ierr + dom_oce_alloc() ! ocean domain |
---|
474 | ierr = ierr + zdf_oce_alloc() ! ocean vertical physics |
---|
475 | ierr = ierr + trc_oce_alloc() ! shared TRC / TRA arrays |
---|
476 | ierr = ierr + bdy_oce_alloc() ! bdy masks (incl. initialization) |
---|
477 | ! |
---|
478 | CALL mpp_sum( 'nemogcm', ierr ) |
---|
479 | IF( ierr /= 0 ) CALL ctl_stop( 'STOP', 'nemo_alloc: unable to allocate standard ocean arrays' ) |
---|
480 | ! |
---|
481 | END SUBROUTINE nemo_alloc |
---|
482 | |
---|
483 | SUBROUTINE nemo_set_cfctl(sn_cfctl, setto ) |
---|
484 | !!---------------------------------------------------------------------- |
---|
485 | !! *** ROUTINE nemo_set_cfctl *** |
---|
486 | !! |
---|
487 | !! ** Purpose : Set elements of the output control structure to setto. |
---|
488 | !! |
---|
489 | !! ** Method : Note this routine can be used to switch on/off some |
---|
490 | !! types of output for selected areas. |
---|
491 | !!---------------------------------------------------------------------- |
---|
492 | TYPE(sn_ctl), INTENT(inout) :: sn_cfctl |
---|
493 | LOGICAL , INTENT(in ) :: setto |
---|
494 | !!---------------------------------------------------------------------- |
---|
495 | sn_cfctl%l_runstat = setto |
---|
496 | sn_cfctl%l_trcstat = setto |
---|
497 | sn_cfctl%l_oceout = setto |
---|
498 | sn_cfctl%l_layout = setto |
---|
499 | sn_cfctl%l_prtctl = setto |
---|
500 | sn_cfctl%l_prttrc = setto |
---|
501 | sn_cfctl%l_oasout = setto |
---|
502 | END SUBROUTINE nemo_set_cfctl |
---|
503 | |
---|
504 | SUBROUTINE istate_init( Kmm, Kaa ) |
---|
505 | !!---------------------------------------------------------------------- |
---|
506 | !! *** ROUTINE istate_init *** |
---|
507 | !! |
---|
508 | !! ** Purpose : Initialization to zero of the dynamics and tracers. |
---|
509 | !!---------------------------------------------------------------------- |
---|
510 | INTEGER, INTENT(in) :: Kmm, Kaa ! ocean time level indices |
---|
511 | ! |
---|
512 | ! now fields ! after fields ! |
---|
513 | uu (:,:,:,Kmm) = 0._wp ; uu(:,:,:,Kaa) = 0._wp ! |
---|
514 | vv (:,:,:,Kmm) = 0._wp ; vv(:,:,:,Kaa) = 0._wp ! |
---|
515 | ww (:,:,:) = 0._wp ! ! |
---|
516 | hdiv (:,:,:) = 0._wp ! ! |
---|
517 | ts (:,:,:,:,Kmm) = 0._wp ! ! |
---|
518 | ! |
---|
519 | rhd (:,:,:) = 0.e0 |
---|
520 | rhop (:,:,:) = 0.e0 |
---|
521 | rn2 (:,:,:) = 0.e0 |
---|
522 | ! |
---|
523 | END SUBROUTINE istate_init |
---|
524 | |
---|
525 | |
---|
526 | SUBROUTINE stp_ctl( kt ) |
---|
527 | !!---------------------------------------------------------------------- |
---|
528 | !! *** ROUTINE stp_ctl *** |
---|
529 | !! |
---|
530 | !! ** Purpose : Control the run |
---|
531 | !! |
---|
532 | !! ** Method : - Save the time step in numstp |
---|
533 | !! |
---|
534 | !! ** Actions : 'time.step' file containing the last ocean time-step |
---|
535 | !!---------------------------------------------------------------------- |
---|
536 | INTEGER, INTENT(in ) :: kt ! ocean time-step index |
---|
537 | !!---------------------------------------------------------------------- |
---|
538 | ! |
---|
539 | IF( kt == nit000 .AND. lwm ) THEN |
---|
540 | WRITE(numout,*) |
---|
541 | WRITE(numout,*) 'stp_ctl : time-stepping control' |
---|
542 | WRITE(numout,*) '~~~~~~~' |
---|
543 | ! open time.step file |
---|
544 | CALL ctl_opn( numstp, 'time.step', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp, narea ) |
---|
545 | ENDIF |
---|
546 | ! |
---|
547 | IF(lwm) WRITE ( numstp, '(1x, i8)' ) kt !* save the current time step in numstp |
---|
548 | IF(lwm) REWIND( numstp ) ! -------------------------- |
---|
549 | ! |
---|
550 | END SUBROUTINE stp_ctl |
---|
551 | !!====================================================================== |
---|
552 | END MODULE nemogcm |
---|