| 1 | MODULE daymod |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE daymod *** |
|---|
| 4 | !! Ocean : calendar |
|---|
| 5 | !!===================================================================== |
|---|
| 6 | !! History : OPA ! 1994-09 (M. Pontaud M. Imbard) Original code |
|---|
| 7 | !! ! 1997-03 (O. Marti) |
|---|
| 8 | !! ! 1997-05 (G. Madec) |
|---|
| 9 | !! ! 1997-08 (M. Imbard) |
|---|
| 10 | !! NEMO 1.0 ! 2003-09 (G. Madec) F90 + nyear, nmonth, nday |
|---|
| 11 | !! ! 2004-01 (A.M. Treguier) new calculation based on adatrj |
|---|
| 12 | !! ! 2006-08 (G. Madec) surface module major update |
|---|
| 13 | !!---------------------------------------------------------------------- |
|---|
| 14 | |
|---|
| 15 | !!---------------------------------------------------------------------- |
|---|
| 16 | !! day : calendar |
|---|
| 17 | !! |
|---|
| 18 | !! ------------------------------- |
|---|
| 19 | !! ----------- WARNING ----------- |
|---|
| 20 | !! |
|---|
| 21 | !! we suppose that the time step is deviding the number of second of in a day |
|---|
| 22 | !! ---> MOD( rday, rdttra(1) ) == 0 |
|---|
| 23 | !! |
|---|
| 24 | !! ----------- WARNING ----------- |
|---|
| 25 | !! ------------------------------- |
|---|
| 26 | !! |
|---|
| 27 | !!---------------------------------------------------------------------- |
|---|
| 28 | USE dom_oce ! ocean space and time domain |
|---|
| 29 | USE phycst ! physical constants |
|---|
| 30 | USE in_out_manager ! I/O manager |
|---|
| 31 | USE iom ! |
|---|
| 32 | USE ioipsl, ONLY : ymds2ju ! for calendar |
|---|
| 33 | USE prtctl ! Print control |
|---|
| 34 | USE restart ! |
|---|
| 35 | USE trc_oce, ONLY : lk_offline ! offline flag |
|---|
| 36 | |
|---|
| 37 | IMPLICIT NONE |
|---|
| 38 | PRIVATE |
|---|
| 39 | |
|---|
| 40 | PUBLIC day ! called by step.F90 |
|---|
| 41 | PUBLIC day_init ! called by istate.F90 |
|---|
| 42 | |
|---|
| 43 | INTEGER :: nsecd, nsecd05, ndt, ndt05 |
|---|
| 44 | |
|---|
| 45 | !! * Control permutation of array indices |
|---|
| 46 | # include "dom_oce_ftrans.h90" |
|---|
| 47 | |
|---|
| 48 | !!---------------------------------------------------------------------- |
|---|
| 49 | !! NEMO/OPA 3.3 , NEMO Consortium (2010) |
|---|
| 50 | !! $Id$ |
|---|
| 51 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 52 | !!---------------------------------------------------------------------- |
|---|
| 53 | CONTAINS |
|---|
| 54 | |
|---|
| 55 | SUBROUTINE day_init |
|---|
| 56 | !!---------------------------------------------------------------------- |
|---|
| 57 | !! *** ROUTINE day_init *** |
|---|
| 58 | !! |
|---|
| 59 | !! ** Purpose : Initialization of the calendar values to their values 1 time step before nit000 |
|---|
| 60 | !! because day will be called at the beginning of step |
|---|
| 61 | !! |
|---|
| 62 | !! ** Action : - nyear : current year |
|---|
| 63 | !! - nmonth : current month of the year nyear |
|---|
| 64 | !! - nday : current day of the month nmonth |
|---|
| 65 | !! - nday_year : current day of the year nyear |
|---|
| 66 | !! - nsec_year : current time step counted in second since 00h jan 1st of the current year |
|---|
| 67 | !! - nsec_month : current time step counted in second since 00h 1st day of the current month |
|---|
| 68 | !! - nsec_day : current time step counted in second since 00h of the current day |
|---|
| 69 | !! - nsec1jan000 : second since Jan. 1st 00h of nit000 year and Jan. 1st 00h of the current year |
|---|
| 70 | !! - nmonth_len, nyear_len, nmonth_half, nmonth_end through day_mth |
|---|
| 71 | !!---------------------------------------------------------------------- |
|---|
| 72 | INTEGER :: inbday, idweek |
|---|
| 73 | REAL(wp) :: zjul |
|---|
| 74 | !!---------------------------------------------------------------------- |
|---|
| 75 | |
|---|
| 76 | ! all calendar staff is based on the fact that MOD( rday, rdttra(1) ) == 0 |
|---|
| 77 | IF( MOD( rday , rdttra(1) ) /= 0. ) CALL ctl_stop( 'the time step must devide the number of second of in a day' ) |
|---|
| 78 | IF( MOD( rday , 2. ) /= 0. ) CALL ctl_stop( 'the number of second of in a day must be an even number' ) |
|---|
| 79 | IF( MOD( rdttra(1), 2. ) /= 0. ) CALL ctl_stop( 'the time step (in second) must be an even number' ) |
|---|
| 80 | nsecd = NINT(rday ) |
|---|
| 81 | nsecd05 = NINT(0.5 * rday ) |
|---|
| 82 | ndt = NINT( rdttra(1)) |
|---|
| 83 | ndt05 = NINT(0.5 * rdttra(1)) |
|---|
| 84 | |
|---|
| 85 | IF( .NOT. lk_offline ) CALL day_rst( nit000, 'READ' ) |
|---|
| 86 | |
|---|
| 87 | ! set the calandar from ndastp (read in restart file and namelist) |
|---|
| 88 | |
|---|
| 89 | nyear = ndastp / 10000 |
|---|
| 90 | nmonth = ( ndastp - (nyear * 10000) ) / 100 |
|---|
| 91 | nday = ndastp - (nyear * 10000) - ( nmonth * 100 ) |
|---|
| 92 | |
|---|
| 93 | CALL ymds2ju( nyear, nmonth, nday, 0.0, fjulday ) ! we assume that we start run at 00:00 |
|---|
| 94 | IF( ABS(fjulday - REAL(NINT(fjulday),wp)) < 0.1 / rday ) fjulday = REAL(NINT(fjulday),wp) ! avoid truncation error |
|---|
| 95 | fjulday = fjulday + 1. ! move back to the day at nit000 (and not at nit000 - 1) |
|---|
| 96 | |
|---|
| 97 | nsec1jan000 = 0 |
|---|
| 98 | CALL day_mth |
|---|
| 99 | |
|---|
| 100 | IF ( nday == 0 ) THEN ! for ex if ndastp = ndate0 - 1 |
|---|
| 101 | nmonth = nmonth - 1 |
|---|
| 102 | nday = nmonth_len(nmonth) |
|---|
| 103 | ENDIF |
|---|
| 104 | IF ( nmonth == 0 ) THEN ! go at the end of previous year |
|---|
| 105 | nmonth = 12 |
|---|
| 106 | nyear = nyear - 1 |
|---|
| 107 | nsec1jan000 = nsec1jan000 - nsecd * nyear_len(0) |
|---|
| 108 | IF( nleapy == 1 ) CALL day_mth |
|---|
| 109 | ENDIF |
|---|
| 110 | |
|---|
| 111 | ! day since january 1st |
|---|
| 112 | nday_year = nday + SUM( nmonth_len(1:nmonth - 1) ) |
|---|
| 113 | |
|---|
| 114 | !compute number of days between last monday and today |
|---|
| 115 | CALL ymds2ju( 1900, 01, 01, 0.0, zjul ) ! compute julian day value of 01.01.1900 (our reference that was a Monday) |
|---|
| 116 | inbday = NINT(fjulday - zjul) ! compute nb day between 01.01.1900 and current day |
|---|
| 117 | idweek = MOD(inbday, 7) ! compute nb day between last monday and current day |
|---|
| 118 | |
|---|
| 119 | ! number of seconds since the beginning of current year/month/week/day at the middle of the time-step |
|---|
| 120 | nsec_year = nday_year * nsecd - ndt05 ! 1 time step before the middle of the first time step |
|---|
| 121 | nsec_month = nday * nsecd - ndt05 ! because day will be called at the beginning of step |
|---|
| 122 | nsec_week = idweek * nsecd - ndt05 |
|---|
| 123 | nsec_day = nsecd - ndt05 |
|---|
| 124 | |
|---|
| 125 | ! control print |
|---|
| 126 | IF(lwp) WRITE(numout, "((A), i6,'/',i2,'/',i2,' nsec_day:',i6,' nsec_week:',I8)") & |
|---|
| 127 | ' ==============>> 1/2 time step before the start of the run DATE Y/M/D = ', & |
|---|
| 128 | nyear, nmonth, nday, nsec_day, nsec_week |
|---|
| 129 | |
|---|
| 130 | ! Up to now, calendar parameters are related to the end of previous run (nit000-1) |
|---|
| 131 | ! call day to set the calendar parameters at the begining of the current simulaton. needed by iom_init |
|---|
| 132 | CALL day( nit000 ) |
|---|
| 133 | |
|---|
| 134 | END SUBROUTINE day_init |
|---|
| 135 | |
|---|
| 136 | |
|---|
| 137 | SUBROUTINE day_mth |
|---|
| 138 | !!---------------------------------------------------------------------- |
|---|
| 139 | !! *** ROUTINE day_init *** |
|---|
| 140 | !! |
|---|
| 141 | !! ** Purpose : calendar values related to the months |
|---|
| 142 | !! |
|---|
| 143 | !! ** Action : - nmonth_len : length in days of the months of the current year |
|---|
| 144 | !! - nyear_len : length in days of the previous/current year |
|---|
| 145 | !! - nmonth_half : second since the beginning of the year and the halft of the months |
|---|
| 146 | !! - nmonth_end : second since the beginning of the year and the end of the months |
|---|
| 147 | !!---------------------------------------------------------------------- |
|---|
| 148 | INTEGER :: jm ! dummy loop indice |
|---|
| 149 | !!---------------------------------------------------------------------- |
|---|
| 150 | |
|---|
| 151 | ! length of the month of the current year (from nleapy, read in namelist) |
|---|
| 152 | IF ( nleapy < 2 ) THEN |
|---|
| 153 | nmonth_len(:) = (/ 31, 31, 28, 31, 30, 31, 30, 31, 31, 30, 31, 30, 31, 31 /) |
|---|
| 154 | nyear_len(:) = 365 |
|---|
| 155 | IF ( nleapy == 1 ) THEN ! we are using calandar with leap years |
|---|
| 156 | IF ( MOD(nyear-1, 4) == 0 .AND. ( MOD(nyear-1, 400) == 0 .OR. MOD(nyear-1, 100) /= 0 ) ) THEN |
|---|
| 157 | nyear_len(0) = 366 |
|---|
| 158 | ENDIF |
|---|
| 159 | IF ( MOD(nyear, 4) == 0 .AND. ( MOD(nyear, 400) == 0 .OR. MOD(nyear, 100) /= 0 ) ) THEN |
|---|
| 160 | nmonth_len(2) = 29 |
|---|
| 161 | nyear_len(1) = 366 |
|---|
| 162 | ENDIF |
|---|
| 163 | ENDIF |
|---|
| 164 | ELSE |
|---|
| 165 | nmonth_len(:) = nleapy ! all months with nleapy days per year |
|---|
| 166 | nyear_len(:) = 12 * nleapy |
|---|
| 167 | ENDIF |
|---|
| 168 | |
|---|
| 169 | ! half month in second since the begining of the year: |
|---|
| 170 | ! time since Jan 1st 0 1 2 ... 11 12 13 |
|---|
| 171 | ! ---------*--|--*--|--*--| ... |--*--|--*--|--*--|-------------------------------------- |
|---|
| 172 | ! <---> <---> <---> ... <---> <---> <---> |
|---|
| 173 | ! month number 0 1 2 ... 11 12 13 |
|---|
| 174 | ! |
|---|
| 175 | ! nmonth_half(jm) = rday * REAL( 0.5 * nmonth_len(jm) + SUM(nmonth_len(1:jm-1)) ) |
|---|
| 176 | nmonth_half(0) = - nsecd05 * nmonth_len(0) |
|---|
| 177 | DO jm = 1, 13 |
|---|
| 178 | nmonth_half(jm) = nmonth_half(jm-1) + nsecd05 * ( nmonth_len(jm-1) + nmonth_len(jm) ) |
|---|
| 179 | END DO |
|---|
| 180 | |
|---|
| 181 | nmonth_end(0) = 0 |
|---|
| 182 | DO jm = 1, 13 |
|---|
| 183 | nmonth_end(jm) = nmonth_end(jm-1) + nsecd * nmonth_len(jm) |
|---|
| 184 | END DO |
|---|
| 185 | ! |
|---|
| 186 | END SUBROUTINE |
|---|
| 187 | |
|---|
| 188 | |
|---|
| 189 | SUBROUTINE day( kt ) |
|---|
| 190 | !!---------------------------------------------------------------------- |
|---|
| 191 | !! *** ROUTINE day *** |
|---|
| 192 | !! |
|---|
| 193 | !! ** Purpose : Compute the date with a day iteration IF necessary. |
|---|
| 194 | !! |
|---|
| 195 | !! ** Method : - ??? |
|---|
| 196 | !! |
|---|
| 197 | !! ** Action : - nyear : current year |
|---|
| 198 | !! - nmonth : current month of the year nyear |
|---|
| 199 | !! - nday : current day of the month nmonth |
|---|
| 200 | !! - nday_year : current day of the year nyear |
|---|
| 201 | !! - ndastp : = nyear*10000 + nmonth*100 + nday |
|---|
| 202 | !! - adatrj : date in days since the beginning of the run |
|---|
| 203 | !! - nsec_year : current time of the year (in second since 00h, jan 1st) |
|---|
| 204 | !!---------------------------------------------------------------------- |
|---|
| 205 | INTEGER, INTENT(in) :: kt ! ocean time-step indices |
|---|
| 206 | ! |
|---|
| 207 | CHARACTER (len=25) :: charout |
|---|
| 208 | REAL(wp) :: zprec ! fraction of day corresponding to 0.1 second |
|---|
| 209 | !!---------------------------------------------------------------------- |
|---|
| 210 | zprec = 0.1 / rday |
|---|
| 211 | ! ! New time-step |
|---|
| 212 | nsec_year = nsec_year + ndt |
|---|
| 213 | nsec_month = nsec_month + ndt |
|---|
| 214 | nsec_week = nsec_week + ndt |
|---|
| 215 | nsec_day = nsec_day + ndt |
|---|
| 216 | adatrj = adatrj + rdttra(1) / rday |
|---|
| 217 | fjulday = fjulday + rdttra(1) / rday |
|---|
| 218 | IF( ABS(fjulday - REAL(NINT(fjulday),wp)) < zprec ) fjulday = REAL(NINT(fjulday),wp) ! avoid truncation error |
|---|
| 219 | IF( ABS(adatrj - REAL(NINT(adatrj ),wp)) < zprec ) adatrj = REAL(NINT(adatrj ),wp) ! avoid truncation error |
|---|
| 220 | |
|---|
| 221 | IF( nsec_day > nsecd ) THEN ! New day |
|---|
| 222 | ! |
|---|
| 223 | nday = nday + 1 |
|---|
| 224 | nday_year = nday_year + 1 |
|---|
| 225 | nsec_day = ndt05 |
|---|
| 226 | ! |
|---|
| 227 | IF( nday == nmonth_len(nmonth) + 1 ) THEN ! New month |
|---|
| 228 | nday = 1 |
|---|
| 229 | nmonth = nmonth + 1 |
|---|
| 230 | nsec_month = ndt05 |
|---|
| 231 | IF( nmonth == 13 ) THEN ! New year |
|---|
| 232 | nyear = nyear + 1 |
|---|
| 233 | nmonth = 1 |
|---|
| 234 | nday_year = 1 |
|---|
| 235 | nsec_year = ndt05 |
|---|
| 236 | nsec1jan000 = nsec1jan000 + nsecd * nyear_len(1) |
|---|
| 237 | IF( nleapy == 1 ) CALL day_mth |
|---|
| 238 | ENDIF |
|---|
| 239 | ENDIF |
|---|
| 240 | ! |
|---|
| 241 | ndastp = nyear * 10000 + nmonth * 100 + nday ! New date |
|---|
| 242 | ! |
|---|
| 243 | !compute first day of the year in julian days |
|---|
| 244 | CALL ymds2ju( nyear, 01, 01, 0.0, fjulstartyear ) |
|---|
| 245 | ! |
|---|
| 246 | IF(lwp) WRITE(numout,'(a,i8,a,i4.4,a,i2.2,a,i2.2,a,i3.3)') '======>> time-step =', kt, & |
|---|
| 247 | & ' New day, DATE Y/M/D = ', nyear, '/', nmonth, '/', nday, ' nday_year = ', nday_year |
|---|
| 248 | IF(lwp) WRITE(numout,'(a,i8,a,i7,a,i5)') ' nsec_year = ', nsec_year, & |
|---|
| 249 | & ' nsec_month = ', nsec_month, ' nsec_day = ', nsec_day, ' nsec_week = ', nsec_week |
|---|
| 250 | ENDIF |
|---|
| 251 | |
|---|
| 252 | IF( nsec_week > 7*nsecd ) nsec_week = ndt05 ! New week |
|---|
| 253 | |
|---|
| 254 | IF(ln_ctl) THEN |
|---|
| 255 | WRITE(charout,FMT="('kt =', I4,' d/m/y =',I2,I2,I4)") kt, nday, nmonth, nyear |
|---|
| 256 | CALL prt_ctl_info(charout) |
|---|
| 257 | ENDIF |
|---|
| 258 | |
|---|
| 259 | IF( .NOT. lk_offline ) CALL rst_opn( kt ) ! Open the restart file if needed and control lrst_oce |
|---|
| 260 | IF( lrst_oce ) CALL day_rst( kt, 'WRITE' ) ! write day restart information |
|---|
| 261 | ! |
|---|
| 262 | END SUBROUTINE day |
|---|
| 263 | |
|---|
| 264 | |
|---|
| 265 | SUBROUTINE day_rst( kt, cdrw ) |
|---|
| 266 | !!--------------------------------------------------------------------- |
|---|
| 267 | !! *** ROUTINE ts_rst *** |
|---|
| 268 | !! |
|---|
| 269 | !! ** Purpose : Read or write calendar in restart file: |
|---|
| 270 | !! |
|---|
| 271 | !! WRITE(READ) mode: |
|---|
| 272 | !! kt : number of time step since the begining of the experiment at the |
|---|
| 273 | !! end of the current(previous) run |
|---|
| 274 | !! adatrj(0) : number of elapsed days since the begining of the experiment at the |
|---|
| 275 | !! end of the current(previous) run (REAL -> keep fractions of day) |
|---|
| 276 | !! ndastp : date at the end of the current(previous) run (coded as yyyymmdd integer) |
|---|
| 277 | !! |
|---|
| 278 | !! According to namelist parameter nrstdt, |
|---|
| 279 | !! nrstdt = 0 no control on the date (nit000 is arbitrary). |
|---|
| 280 | !! nrstdt = 1 we verify that nit000 is equal to the last |
|---|
| 281 | !! time step of previous run + 1. |
|---|
| 282 | !! In both those options, the exact duration of the experiment |
|---|
| 283 | !! since the beginning (cumulated duration of all previous restart runs) |
|---|
| 284 | !! is not stored in the restart and is assumed to be (nit000-1)*rdt. |
|---|
| 285 | !! This is valid is the time step has remained constant. |
|---|
| 286 | !! |
|---|
| 287 | !! nrstdt = 2 the duration of the experiment in days (adatrj) |
|---|
| 288 | !! has been stored in the restart file. |
|---|
| 289 | !!---------------------------------------------------------------------- |
|---|
| 290 | INTEGER , INTENT(in) :: kt ! ocean time-step |
|---|
| 291 | CHARACTER(len=*), INTENT(in) :: cdrw ! "READ"/"WRITE" flag |
|---|
| 292 | ! |
|---|
| 293 | REAL(wp) :: zkt, zndastp |
|---|
| 294 | !!---------------------------------------------------------------------- |
|---|
| 295 | |
|---|
| 296 | IF( TRIM(cdrw) == 'READ' ) THEN |
|---|
| 297 | |
|---|
| 298 | IF( iom_varid( numror, 'kt', ldstop = .FALSE. ) > 0 ) THEN |
|---|
| 299 | ! Get Calendar informations |
|---|
| 300 | CALL iom_get( numror, 'kt', zkt ) ! last time-step of previous run |
|---|
| 301 | IF(lwp) THEN |
|---|
| 302 | WRITE(numout,*) ' *** Info read in restart : ' |
|---|
| 303 | WRITE(numout,*) ' previous time-step : ', NINT( zkt ) |
|---|
| 304 | WRITE(numout,*) ' *** restart option' |
|---|
| 305 | SELECT CASE ( nrstdt ) |
|---|
| 306 | CASE ( 0 ) ; WRITE(numout,*) ' nrstdt = 0 : no control of nit000' |
|---|
| 307 | CASE ( 1 ) ; WRITE(numout,*) ' nrstdt = 1 : no control the date at nit000 (use ndate0 read in the namelist)' |
|---|
| 308 | CASE ( 2 ) ; WRITE(numout,*) ' nrstdt = 2 : calendar parameters read in restart' |
|---|
| 309 | END SELECT |
|---|
| 310 | WRITE(numout,*) |
|---|
| 311 | ENDIF |
|---|
| 312 | ! Control of date |
|---|
| 313 | IF( nit000 - NINT( zkt ) /= 1 .AND. nrstdt /= 0 ) & |
|---|
| 314 | & CALL ctl_stop( ' ===>>>> : problem with nit000 for the restart', & |
|---|
| 315 | & ' verify the restart file or rerun with nrstdt = 0 (namelist)' ) |
|---|
| 316 | ! define ndastp and adatrj |
|---|
| 317 | IF ( nrstdt == 2 ) THEN |
|---|
| 318 | ! read the parameters correspondting to nit000 - 1 (last time step of previous run) |
|---|
| 319 | CALL iom_get( numror, 'ndastp', zndastp ) |
|---|
| 320 | ndastp = NINT( zndastp ) |
|---|
| 321 | CALL iom_get( numror, 'adatrj', adatrj ) |
|---|
| 322 | ELSE |
|---|
| 323 | ! parameters correspondting to nit000 - 1 (as we start the step loop with a call to day) |
|---|
| 324 | ndastp = ndate0 - 1 ! ndate0 read in the namelist in dom_nam, we assume that we start run at 00:00 |
|---|
| 325 | adatrj = ( REAL( nit000-1, wp ) * rdttra(1) ) / rday |
|---|
| 326 | ! note this is wrong if time step has changed during run |
|---|
| 327 | ENDIF |
|---|
| 328 | ELSE |
|---|
| 329 | ! parameters correspondting to nit000 - 1 (as we start the step loop with a call to day) |
|---|
| 330 | ndastp = ndate0 - 1 ! ndate0 read in the namelist in dom_nam, we assume that we start run at 00:00 |
|---|
| 331 | adatrj = ( REAL( nit000-1, wp ) * rdttra(1) ) / rday |
|---|
| 332 | ENDIF |
|---|
| 333 | IF( ABS(adatrj - REAL(NINT(adatrj),wp)) < 0.1 / rday ) adatrj = REAL(NINT(adatrj),wp) ! avoid truncation error |
|---|
| 334 | ! |
|---|
| 335 | IF(lwp) THEN |
|---|
| 336 | WRITE(numout,*) ' *** Info used values : ' |
|---|
| 337 | WRITE(numout,*) ' date ndastp : ', ndastp |
|---|
| 338 | WRITE(numout,*) ' number of elapsed days since the begining of run : ', adatrj |
|---|
| 339 | WRITE(numout,*) |
|---|
| 340 | ENDIF |
|---|
| 341 | ! |
|---|
| 342 | ELSEIF( TRIM(cdrw) == 'WRITE' ) THEN |
|---|
| 343 | ! |
|---|
| 344 | IF( kt == nitrst ) THEN |
|---|
| 345 | IF(lwp) WRITE(numout,*) |
|---|
| 346 | IF(lwp) WRITE(numout,*) 'rst_write : write oce restart file kt =', kt |
|---|
| 347 | IF(lwp) WRITE(numout,*) '~~~~~~~' |
|---|
| 348 | ENDIF |
|---|
| 349 | ! calendar control |
|---|
| 350 | CALL iom_rstput( kt, nitrst, numrow, 'kt' , REAL( kt , wp) ) ! time-step |
|---|
| 351 | CALL iom_rstput( kt, nitrst, numrow, 'ndastp' , REAL( ndastp, wp) ) ! date |
|---|
| 352 | CALL iom_rstput( kt, nitrst, numrow, 'adatrj' , adatrj ) ! number of elapsed days since |
|---|
| 353 | ! ! the begining of the run [s] |
|---|
| 354 | ENDIF |
|---|
| 355 | ! |
|---|
| 356 | END SUBROUTINE day_rst |
|---|
| 357 | |
|---|
| 358 | !!====================================================================== |
|---|
| 359 | END MODULE daymod |
|---|
