New URL for NEMO forge! http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.

nemogcm.F90 in branches/2011/dev_NEMO_MERGE_2011/NEMOGCM/NEMO/OPA_SRC – NEMO

Context Navigation

source: branches/2011/dev_NEMO_MERGE_2011/NEMOGCM/NEMO/OPA_SRC/nemogcm.F90 @ 3140

Last change on this file since 3140 was 3139, checked in by rblod, 13 years ago
Add timing module see ticket #829
Property svn:keywords set to `Id`
File size: 35.9 KB

Line
1	MODULE nemogcm
2	!!======================================================================
3	!! * MODULE nemogcm *
4	!! Ocean system : NEMO GCM (ocean dynamics, on-line tracers, biochemistry and sea-ice)
5	!!======================================================================
6	!! History : OPA ! 1990-10 (C. Levy, G. Madec) Original code
7	!! 7.0 ! 1991-11 (M. Imbard, C. Levy, G. Madec)
8	!! 7.1 ! 1993-03 (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
9	!! P. Delecluse, C. Perigaud, G. Caniaux, B. Colot, C. Maes) release 7.1
10	!! - ! 1992-06 (L.Terray) coupling implementation
11	!! - ! 1993-11 (M.A. Filiberti) IGLOO sea-ice
12	!! 8.0 ! 1996-03 (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
13	!! P. Delecluse, L.Terray, M.A. Filiberti, J. Vialar, A.M. Treguier, M. Levy) release 8.0
14	!! 8.1 ! 1997-06 (M. Imbard, G. Madec)
15	!! 8.2 ! 1999-11 (M. Imbard, H. Goosse) LIM sea-ice model
16	!! ! 1999-12 (V. Thierry, A-M. Treguier, M. Imbard, M-A. Foujols) OPEN-MP
17	!! ! 2000-07 (J-M Molines, M. Imbard) Open Boundary Conditions (CLIPPER)
18	!! NEMO 1.0 ! 2002-08 (G. Madec) F90: Free form and modules
19	!! - ! 2004-06 (R. Redler, NEC CCRLE, Germany) add OASIS[3/4] coupled interfaces
20	!! - ! 2004-08 (C. Talandier) New trends organization
21	!! - ! 2005-06 (C. Ethe) Add the 1D configuration possibility
22	!! - ! 2005-11 (V. Garnier) Surface pressure gradient organization
23	!! - ! 2006-03 (L. Debreu, C. Mazauric) Agrif implementation
24	!! - ! 2006-04 (G. Madec, R. Benshila) Step reorganization
25	!! - ! 2007-07 (J. Chanut, A. Sellar) Unstructured open boundaries (BDY)
26	!! 3.2 ! 2009-08 (S. Masson) open/write in the listing file in mpp
27	!! 3.3 ! 2010-05 (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
28	!! - ! 2010-10 (C. Ethe, G. Madec) reorganisation of initialisation phase
29	!! 3.3.1! 2011-01 (A. R. Porter, STFC Daresbury) dynamical allocation
30	!! 3.4 ! 2011-11 (C. Harris) decomposition changes for running with CICE
31	!!----------------------------------------------------------------------
32
33	!!----------------------------------------------------------------------
34	!! nemo_gcm : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
35	!! nemo_init : initialization of the NEMO system
36	!! nemo_ctl : initialisation of the contol print
37	!! nemo_closefile : close remaining open files
38	!! nemo_alloc : dynamical allocation
39	!! nemo_partition : calculate MPP domain decomposition
40	!! factorise : calculate the factors of the no. of MPI processes
41	!!----------------------------------------------------------------------
42	USE step_oce ! module used in the ocean time stepping module
43	USE sbc_oce ! surface boundary condition: ocean
44	USE cla ! cross land advection (tra_cla routine)
45	USE domcfg ! domain configuration (dom_cfg routine)
46	USE mppini ! shared/distributed memory setting (mpp_init routine)
47	USE domain ! domain initialization (dom_init routine)
48	USE obcini ! open boundary cond. initialization (obc_ini routine)
49	USE bdyini ! open boundary cond. initialization (bdy_init routine)
50	USE bdydta ! open boundary cond. initialization (bdy_dta_init routine)
51	USE bdytides ! open boundary cond. initialization (tide_init routine)
52	USE istate ! initial state setting (istate_init routine)
53	USE ldfdyn ! lateral viscosity setting (ldfdyn_init routine)
54	USE ldftra ! lateral diffusivity setting (ldftra_init routine)
55	USE zdfini ! vertical physics setting (zdf_init routine)
56	USE phycst ! physical constant (par_cst routine)
57	USE trdmod ! momentum/tracers trends (trd_mod_init routine)
58	USE asminc ! assimilation increments (asm_inc_init routine)
59	USE asmtrj ! writing out state trajectory
60	USE sshwzv ! vertical velocity used in asm
61	USE diaptr ! poleward transports (dia_ptr_init routine)
62	USE diadct ! sections transports (dia_dct_init routine)
63	USE diaobs ! Observation diagnostics (dia_obs_init routine)
64	USE step ! NEMO time-stepping (stp routine)
65	#if defined key_oasis3
66	USE cpl_oasis3 ! OASIS3 coupling
67	#elif defined key_oasis4
68	USE cpl_oasis4 ! OASIS4 coupling (not working)
69	#endif
70	USE c1d ! 1D configuration
71	USE step_c1d ! Time stepping loop for the 1D configuration
72	USE dynnept ! simplified form of Neptune effect
73	#if defined key_top
74	USE trcini ! passive tracer initialisation
75	#endif
76	USE lib_mpp ! distributed memory computing
77	#if defined key_iomput
78	USE mod_ioclient
79	#endif
80
81	IMPLICIT NONE
82	PRIVATE
83
84	PUBLIC nemo_gcm ! called by model.F90
85	PUBLIC nemo_init ! needed by AGRIF
86
87	CHARACTER(lc) :: cform_aaa="( /, 'AAAAAAAA', / ) " ! flag for output listing
88
89	!!----------------------------------------------------------------------
90	!! NEMO/OPA 4.0 , NEMO Consortium (2011)
91	!! $Id$
92	!! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
93	!!----------------------------------------------------------------------
94	CONTAINS
95
96	SUBROUTINE nemo_gcm
97	!!----------------------------------------------------------------------
98	!! * ROUTINE nemo_gcm *
99	!!
100	!! ** Purpose : NEMO solves the primitive equations on an orthogonal
101	!! curvilinear mesh on the sphere.
102	!!
103	!! ** Method : - model general initialization
104	!! - launch the time-stepping (stp routine)
105	!! - finalize the run by closing files and communications
106	!!
107	!! References : Madec, Delecluse, Imbard, and Levy, 1997: internal report, IPSL.
108	!! Madec, 2008, internal report, IPSL.
109	!!----------------------------------------------------------------------
110	INTEGER :: istp ! time step index
111	!!----------------------------------------------------------------------
112	!
113	#if defined key_agrif
114	CALL Agrif_Init_Grids() ! AGRIF: set the meshes
115	#endif
116
117	! !-----------------------!
118	CALL nemo_init !== Initialisations ==!
119	! !-----------------------!
120	#if defined key_agrif
121	CALL Agrif_Declare_Var ! AGRIF: set the meshes
122	# if defined key_top
123	CALL Agrif_Declare_Var_Top ! AGRIF: set the meshes
124	# endif
125	#endif
126	! check that all process are still there... If some process have an error,
127	! they will never enter in step and other processes will wait until the end of the cpu time!
128	IF( lk_mpp ) CALL mpp_max( nstop )
129
130	IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA
131
132	! !-----------------------!
133	! !== time stepping ==!
134	! !-----------------------!
135	istp = nit000
136	#if defined key_c1d
137	DO WHILE ( istp <= nitend .AND. nstop == 0 )
138	CALL stp_c1d( istp )
139	istp = istp + 1
140	END DO
141	#else
142	IF( lk_asminc ) THEN
143	IF( ln_bkgwri ) CALL asm_bkg_wri( nit000 - 1 ) ! Output background fields
144	IF( ln_trjwri ) CALL asm_trj_wri( nit000 - 1 ) ! Output trajectory fields
145	IF( ln_asmdin ) THEN ! Direct initialization
146	IF( ln_trainc ) CALL tra_asm_inc( nit000 - 1 ) ! Tracers
147	IF( ln_dyninc ) THEN
148	CALL dyn_asm_inc( nit000 - 1 ) ! Dynamics
149	IF ( ln_asmdin ) CALL ssh_wzv ( nit000 - 1 ) ! update vertical velocity
150	ENDIF
151	IF( ln_sshinc ) CALL ssh_asm_inc( nit000 - 1 ) ! SSH
152	ENDIF
153	ENDIF
154
155	DO WHILE ( istp <= nitend .AND. nstop == 0 )
156	#if defined key_agrif
157	CALL Agrif_Step( stp ) ! AGRIF: time stepping
158	#else
159	CALL stp( istp ) ! standard time stepping
160	#endif
161	istp = istp + 1
162	IF( lk_mpp ) CALL mpp_max( nstop )
163	END DO
164	#endif
165
166	IF( lk_diaobs ) CALL dia_obs_wri
167
168	! !------------------------!
169	! !== finalize the run ==!
170	! !------------------------!
171	IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA
172	!
173	IF( nstop /= 0 .AND. lwp ) THEN ! error print
174	WRITE(numout,cform_err)
175	WRITE(numout,*) nstop, ' error have been found'
176	ENDIF
177	!
178	IF( nn_timing == 1 ) CALL timing_finalize
179	!
180	CALL nemo_closefile
181	#if defined key_oasis3 \|\| defined key_oasis4
182	CALL cpl_prism_finalize ! end coupling and mpp communications with OASIS
183	#else
184	IF( lk_mpp ) CALL mppstop ! end mpp communications
185	#endif
186	!
187	END SUBROUTINE nemo_gcm
188
189
190	SUBROUTINE nemo_init
191	!!----------------------------------------------------------------------
192	!! * ROUTINE nemo_init *
193	!!
194	!! ** Purpose : initialization of the NEMO GCM
195	!!----------------------------------------------------------------------
196	INTEGER :: ji ! dummy loop indices
197	INTEGER :: ilocal_comm ! local integer
198	CHARACTER(len=80), DIMENSION(16) :: cltxt
199	!!
200	NAMELIST/namctl/ ln_ctl , nn_print, nn_ictls, nn_ictle, &
201	& nn_isplt, nn_jsplt, nn_jctls, nn_jctle, &
202	& nn_bench, nn_timing
203	!!----------------------------------------------------------------------
204	!
205	cltxt = ''
206	!
207	! ! open Namelist file
208	CALL ctl_opn( numnam, 'namelist', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
209	!
210	READ( numnam, namctl ) ! Namelist namctl : Control prints & Benchmark
211	!
212	! !--------------------------------------------!
213	! ! set communicator & select the local node !
214	! !--------------------------------------------!
215	#if defined key_iomput
216	IF( Agrif_Root() ) THEN
217	# if defined key_oasis3 \|\| defined key_oasis4
218	CALL cpl_prism_init( ilocal_comm ) ! nemo local communicator given by oasis
219	# endif
220	CALL init_ioclient( ilocal_comm ) ! exchange io_server nemo local communicator with the io_server
221	ENDIF
222	narea = mynode( cltxt, numnam, nstop, ilocal_comm ) ! Nodes selection
223	#else
224	# if defined key_oasis3 \|\| defined key_oasis4
225	IF( Agrif_Root() ) THEN
226	CALL cpl_prism_init( ilocal_comm ) ! nemo local communicator given by oasis
227	ENDIF
228	narea = mynode( cltxt, numnam, nstop, ilocal_comm ) ! Nodes selection (control print return in cltxt)
229	# else
230	ilocal_comm = 0
231	narea = mynode( cltxt, numnam, nstop ) ! Nodes selection (control print return in cltxt)
232	# endif
233	#endif
234	narea = narea + 1 ! mynode return the rank of proc (0 --> jpnij -1 )
235
236	lwp = (narea == 1) .OR. ln_ctl ! control of all listing output print
237
238	! If dimensions of processor grid weren't specified in the namelist file
239	! then we calculate them here now that we have our communicator size
240	IF( (jpni < 1) .OR. (jpnj < 1) )THEN
241	#if defined key_mpp_mpi
242	IF( Agrif_Root() ) CALL nemo_partition(mppsize)
243	#else
244	jpni = 1
245	jpnj = 1
246	jpnij = jpni*jpnj
247	#endif
248	END IF
249
250	! Calculate domain dimensions given calculated jpni and jpnj
251	! This used to be done in par_oce.F90 when they were parameters rather
252	! than variables
253	IF( Agrif_Root() ) THEN
254	jpi = ( jpiglo-2jpreci + (jpni-1) ) / jpni + 2jpreci ! first dim.
255	#if defined key_nemocice_decomp
256	jpj = ( jpjglo+1-2jprecj + (jpnj-1) ) / jpnj + 2jprecj ! second dim.
257	#else
258	jpj = ( jpjglo-2jprecj + (jpnj-1) ) / jpnj + 2jprecj ! second dim.
259	#endif
260	jpk = jpkdta ! third dim
261	jpim1 = jpi-1 ! inner domain indices
262	jpjm1 = jpj-1 ! " "
263	jpkm1 = jpk-1 ! " "
264	jpij = jpi*jpj ! jpi x j
265	ENDIF
266
267	IF(lwp) THEN ! open listing units
268	!
269	CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
270	!
271	WRITE(numout,*)
272	WRITE(numout,*) ' CNRS - NERC - Met OFFICE - MERCATOR-ocean'
273	WRITE(numout,*) ' NEMO team'
274	WRITE(numout,*) ' Ocean General Circulation Model'
275	WRITE(numout,*) ' version 3.3 (2010) '
276	WRITE(numout,*)
277	WRITE(numout,*)
278	DO ji = 1, SIZE(cltxt)
279	IF( TRIM(cltxt(ji)) /= '' ) WRITE(numout,*) cltxt(ji) ! control print of mynode
280	END DO
281	WRITE(numout,cform_aaa) ! Flag AAAAAAA
282	!
283	ENDIF
284
285	! Now we know the dimensions of the grid and numout has been set we can
286	! allocate arrays
287	CALL nemo_alloc()
288
289	! !-------------------------------!
290	! ! NEMO general initialization !
291	! !-------------------------------!
292
293	CALL nemo_ctl ! Control prints & Benchmark
294
295	! ! Domain decomposition
296	IF( jpni*jpnj == jpnij ) THEN ; CALL mpp_init ! standard cutting out
297	ELSE ; CALL mpp_init2 ! eliminate land processors
298	ENDIF
299	!
300	IF( nn_timing == 1 ) CALL timing_init
301	!
302	! ! General initialization
303	CALL phy_cst ! Physical constants
304	CALL eos_init ! Equation of state
305	CALL dom_cfg ! Domain configuration
306	CALL dom_init ! Domain
307
308	IF( ln_nnogather ) CALL nemo_northcomms ! Initialise the northfold neighbour lists (must be done after the masks are defined)
309
310	IF( ln_ctl ) CALL prt_ctl_init ! Print control
311
312	IF( lk_obc ) CALL obc_init ! Open boundaries
313	IF( lk_bdy ) CALL bdy_init ! Open boundaries initialisation
314	IF( lk_bdy ) CALL bdy_dta_init ! Open boundaries initialisation of external data arrays
315	IF( lk_bdy ) CALL tide_init ! Open boundaries initialisation of tidal harmonic forcing
316
317	CALL flush(numout)
318	CALL dyn_nept_init ! simplified form of Neptune effect
319	CALL flush(numout)
320
321	CALL istate_init ! ocean initial state (Dynamics and tracers)
322
323	! ! Ocean physics
324	CALL sbc_init ! Forcings : surface module
325	! ! Vertical physics
326	CALL zdf_init ! namelist read
327	CALL zdf_bfr_init ! bottom friction
328	IF( lk_zdfric ) CALL zdf_ric_init ! Richardson number dependent Kz
329	IF( lk_zdftke ) CALL zdf_tke_init ! TKE closure scheme
330	IF( lk_zdfgls ) CALL zdf_gls_init ! GLS closure scheme
331	IF( lk_zdfkpp ) CALL zdf_kpp_init ! KPP closure scheme
332	IF( lk_zdftmx ) CALL zdf_tmx_init ! tidal vertical mixing
333	IF( lk_zdfddm .AND. .NOT. lk_zdfkpp ) &
334	& CALL zdf_ddm_init ! double diffusive mixing
335	! ! Lateral physics
336	CALL ldf_tra_init ! Lateral ocean tracer physics
337	CALL ldf_dyn_init ! Lateral ocean momentum physics
338	IF( lk_ldfslp ) CALL ldf_slp_init ! slope of lateral mixing
339
340	! ! Active tracers
341	CALL tra_qsr_init ! penetrative solar radiation qsr
342	CALL tra_bbc_init ! bottom heat flux
343	IF( lk_trabbl ) CALL tra_bbl_init ! advective (and/or diffusive) bottom boundary layer scheme
344	IF( ln_tradmp ) CALL tra_dmp_init ! internal damping trends
345	CALL tra_adv_init ! horizontal & vertical advection
346	CALL tra_ldf_init ! lateral mixing
347	CALL tra_zdf_init ! vertical mixing and after tracer fields
348
349	! ! Dynamics
350	CALL dyn_adv_init ! advection (vector or flux form)
351	CALL dyn_vor_init ! vorticity term including Coriolis
352	CALL dyn_ldf_init ! lateral mixing
353	CALL dyn_hpg_init ! horizontal gradient of Hydrostatic pressure
354	CALL dyn_zdf_init ! vertical diffusion
355	CALL dyn_spg_init ! surface pressure gradient
356
357	! ! Misc. options
358	IF( nn_cla == 1 ) CALL cla_init ! Cross Land Advection
359
360	#if defined key_top
361	! ! Passive tracers
362	CALL trc_init
363	#endif
364	! ! Diagnostics
365	IF( lk_floats ) CALL flo_init ! drifting Floats
366	CALL iom_init ! iom_put initialization
367	IF( lk_diaar5 ) CALL dia_ar5_init ! ar5 diag
368	CALL dia_ptr_init ! Poleward TRansports initialization
369	IF( lk_diadct ) CALL dia_dct_init ! Sections tranports
370	CALL dia_hsb_init ! heat content, salt content and volume budgets
371	CALL trd_mod_init ! Mixed-layer/Vorticity/Integral constraints trends
372	IF( lk_diaobs ) THEN ! Observation & model comparison
373	CALL dia_obs_init ! Initialize observational data
374	CALL dia_obs( nit000 - 1 ) ! Observation operator for restart
375	ENDIF
376	! ! Assimilation increments
377	IF( lk_asminc ) CALL asm_inc_init ! Initialize assimilation increments
378	IF(lwp) WRITE(numout,*) 'Euler time step switch is ', neuler
379	!
380	END SUBROUTINE nemo_init
381
382
383	SUBROUTINE nemo_ctl
384	!!----------------------------------------------------------------------
385	!! * ROUTINE nemo_ctl *
386	!!
387	!! ** Purpose : control print setting
388	!!
389	!! ** Method : - print namctl information and check some consistencies
390	!!----------------------------------------------------------------------
391	!
392	IF(lwp) THEN ! control print
393	WRITE(numout,*)
394	WRITE(numout,*) 'nemo_ctl: Control prints & Benchmark'
395	WRITE(numout,*) '~~~~~~~ '
396	WRITE(numout,*) ' Namelist namctl'
397	WRITE(numout,*) ' run control (for debugging) ln_ctl = ', ln_ctl
398	WRITE(numout,*) ' level of print nn_print = ', nn_print
399	WRITE(numout,*) ' Start i indice for SUM control nn_ictls = ', nn_ictls
400	WRITE(numout,*) ' End i indice for SUM control nn_ictle = ', nn_ictle
401	WRITE(numout,*) ' Start j indice for SUM control nn_jctls = ', nn_jctls
402	WRITE(numout,*) ' End j indice for SUM control nn_jctle = ', nn_jctle
403	WRITE(numout,*) ' number of proc. following i nn_isplt = ', nn_isplt
404	WRITE(numout,*) ' number of proc. following j nn_jsplt = ', nn_jsplt
405	WRITE(numout,*) ' benchmark parameter (0/1) nn_bench = ', nn_bench
406	ENDIF
407	!
408	nprint = nn_print ! convert DOCTOR namelist names into OLD names
409	nictls = nn_ictls
410	nictle = nn_ictle
411	njctls = nn_jctls
412	njctle = nn_jctle
413	isplt = nn_isplt
414	jsplt = nn_jsplt
415	nbench = nn_bench
416	! ! Parameter control
417	!
418	IF( ln_ctl ) THEN ! sub-domain area indices for the control prints
419	IF( lk_mpp ) THEN
420	isplt = jpni ; jsplt = jpnj ; ijsplt = jpni*jpnj ! the domain is forced to the real split domain
421	ELSE
422	IF( isplt == 1 .AND. jsplt == 1 ) THEN
423	CALL ctl_warn( ' - isplt & jsplt are equal to 1', &
424	& ' - the print control will be done over the whole domain' )
425	ENDIF
426	ijsplt = isplt * jsplt ! total number of processors ijsplt
427	ENDIF
428	IF(lwp) WRITE(numout,*)' - The total number of processors over which the'
429	IF(lwp) WRITE(numout,*)' print control will be done is ijsplt : ', ijsplt
430	!
431	! ! indices used for the SUM control
432	IF( nictls+nictle+njctls+njctle == 0 ) THEN ! print control done over the default area
433	lsp_area = .FALSE.
434	ELSE ! print control done over a specific area
435	lsp_area = .TRUE.
436	IF( nictls < 1 .OR. nictls > jpiglo ) THEN
437	CALL ctl_warn( ' - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
438	nictls = 1
439	ENDIF
440	IF( nictle < 1 .OR. nictle > jpiglo ) THEN
441	CALL ctl_warn( ' - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
442	nictle = jpiglo
443	ENDIF
444	IF( njctls < 1 .OR. njctls > jpjglo ) THEN
445	CALL ctl_warn( ' - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
446	njctls = 1
447	ENDIF
448	IF( njctle < 1 .OR. njctle > jpjglo ) THEN
449	CALL ctl_warn( ' - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
450	njctle = jpjglo
451	ENDIF
452	ENDIF
453	ENDIF
454	!
455	IF( nbench == 1 ) THEN ! Benchmark
456	SELECT CASE ( cp_cfg )
457	CASE ( 'gyre' ) ; CALL ctl_warn( ' The Benchmark is activated ' )
458	CASE DEFAULT ; CALL ctl_stop( ' The Benchmark is based on the GYRE configuration:', &
459	& ' key_gyre must be used or set nbench = 0' )
460	END SELECT
461	ENDIF
462	!
463	IF( lk_c1d .AND. .NOT.lk_iomput ) CALL ctl_stop( 'nemo_ctl: The 1D configuration must be used ', &
464	& 'with the IOM Input/Output manager. ' , &
465	& 'Compile with key_iomput enabled' )
466	!
467	END SUBROUTINE nemo_ctl
468
469
470	SUBROUTINE nemo_closefile
471	!!----------------------------------------------------------------------
472	!! * ROUTINE nemo_closefile *
473	!!
474	!! ** Purpose : Close the files
475	!!----------------------------------------------------------------------
476	!
477	IF( lk_mpp ) CALL mppsync
478	!
479	CALL iom_close ! close all input/output files managed by iom_*
480	!
481	IF( numstp /= -1 ) CLOSE( numstp ) ! time-step file
482	IF( numsol /= -1 ) CLOSE( numsol ) ! solver file
483	IF( numnam /= -1 ) CLOSE( numnam ) ! oce namelist
484	IF( numnam_ice /= -1 ) CLOSE( numnam_ice ) ! ice namelist
485	IF( numevo_ice /= -1 ) CLOSE( numevo_ice ) ! ice variables (temp. evolution)
486	IF( numout /= 6 ) CLOSE( numout ) ! standard model output file
487	IF( numdct_vol /= -1 ) CLOSE( numdct_vol ) ! volume transports
488	IF( numdct_heat /= -1 ) CLOSE( numdct_heat ) ! heat transports
489	IF( numdct_salt /= -1 ) CLOSE( numdct_salt ) ! salt transports
490
491	!
492	numout = 6 ! redefine numout in case it is used after this point...
493	!
494	END SUBROUTINE nemo_closefile
495
496
497	SUBROUTINE nemo_alloc
498	!!----------------------------------------------------------------------
499	!! * ROUTINE nemo_alloc *
500	!!
501	!! ** Purpose : Allocate all the dynamic arrays of the OPA modules
502	!!
503	!! ** Method :
504	!!----------------------------------------------------------------------
505	USE diawri , ONLY: dia_wri_alloc
506	USE dom_oce , ONLY: dom_oce_alloc
507	USE ldfdyn_oce, ONLY: ldfdyn_oce_alloc
508	USE ldftra_oce, ONLY: ldftra_oce_alloc
509	USE trc_oce , ONLY: trc_oce_alloc
510	USE wrk_nemo , ONLY: wrk_alloc
511	!
512	INTEGER :: ierr
513	!!----------------------------------------------------------------------
514	!
515	ierr = oce_alloc () ! ocean
516	ierr = ierr + dia_wri_alloc ()
517	ierr = ierr + dom_oce_alloc () ! ocean domain
518	ierr = ierr + ldfdyn_oce_alloc() ! ocean lateral physics : dynamics
519	ierr = ierr + ldftra_oce_alloc() ! ocean lateral physics : tracers
520	ierr = ierr + zdf_oce_alloc () ! ocean vertical physics
521	!
522	ierr = ierr + lib_mpp_alloc (numout) ! mpp exchanges
523	ierr = ierr + trc_oce_alloc () ! shared TRC / TRA arrays
524	!
525	ierr = ierr + wrk_alloc(numout, lwp) ! workspace
526	!
527	IF( lk_mpp ) CALL mpp_sum( ierr )
528	IF( ierr /= 0 ) CALL ctl_stop( 'STOP', 'nemo_alloc : unable to allocate standard ocean arrays' )
529	!
530	END SUBROUTINE nemo_alloc
531
532
533	SUBROUTINE nemo_partition( num_pes )
534	!!----------------------------------------------------------------------
535	!! * ROUTINE nemo_partition *
536	!!
537	!! ** Purpose :
538	!!
539	!! ** Method :
540	!!----------------------------------------------------------------------
541	INTEGER, INTENT(in) :: num_pes ! The number of MPI processes we have
542	!
543	INTEGER, PARAMETER :: nfactmax = 20
544	INTEGER :: nfact ! The no. of factors returned
545	INTEGER :: ierr ! Error flag
546	INTEGER :: ji
547	INTEGER :: idiff, mindiff, imin ! For choosing pair of factors that are closest in value
548	INTEGER, DIMENSION(nfactmax) :: ifact ! Array of factors
549	!!----------------------------------------------------------------------
550
551	ierr = 0
552
553	CALL factorise( ifact, nfactmax, nfact, num_pes, ierr )
554
555	IF( nfact <= 1 ) THEN
556	WRITE (numout, *) 'WARNING: factorisation of number of PEs failed'
557	WRITE (numout, *) ' : using grid of ',num_pes,' x 1'
558	jpnj = 1
559	jpni = num_pes
560	ELSE
561	! Search through factors for the pair that are closest in value
562	mindiff = 1000000
563	imin = 1
564	DO ji = 1, nfact-1, 2
565	idiff = ABS( ifact(ji) - ifact(ji+1) )
566	IF( idiff < mindiff ) THEN
567	mindiff = idiff
568	imin = ji
569	ENDIF
570	END DO
571	jpnj = ifact(imin)
572	jpni = ifact(imin + 1)
573	ENDIF
574	!
575	jpnij = jpni*jpnj
576	!
577	END SUBROUTINE nemo_partition
578
579
580	SUBROUTINE factorise( kfax, kmaxfax, knfax, kn, kerr )
581	!!----------------------------------------------------------------------
582	!! * ROUTINE factorise *
583	!!
584	!! ** Purpose : return the prime factors of n.
585	!! knfax factors are returned in array kfax which is of
586	!! maximum dimension kmaxfax.
587	!! ** Method :
588	!!----------------------------------------------------------------------
589	INTEGER , INTENT(in ) :: kn, kmaxfax
590	INTEGER , INTENT( out) :: kerr, knfax
591	INTEGER, DIMENSION(kmaxfax), INTENT( out) :: kfax
592	!
593	INTEGER :: ifac, jl, inu
594	INTEGER, PARAMETER :: ntest = 14
595	INTEGER :: ilfax(ntest)
596
597	! lfax contains the set of allowed factors.
598	data (ilfax(jl),jl=1,ntest) / 16384, 8192, 4096, 2048, 1024, 512, 256, &
599	& 128, 64, 32, 16, 8, 4, 2 /
600	!!----------------------------------------------------------------------
601
602	! Clear the error flag and initialise output vars
603	kerr = 0
604	kfax = 1
605	knfax = 0
606
607	! Find the factors of n.
608	IF( kn == 1 ) GOTO 20
609
610	! nu holds the unfactorised part of the number.
611	! knfax holds the number of factors found.
612	! l points to the allowed factor list.
613	! ifac holds the current factor.
614
615	inu = kn
616	knfax = 0
617
618	DO jl = ntest, 1, -1
619	!
620	ifac = ilfax(jl)
621	IF( ifac > inu ) CYCLE
622
623	! Test whether the factor will divide.
624
625	IF( MOD(inu,ifac) == 0 ) THEN
626	!
627	knfax = knfax + 1 ! Add the factor to the list
628	IF( knfax > kmaxfax ) THEN
629	kerr = 6
630	write (,) 'FACTOR: insufficient space in factor array ', knfax
631	return
632	ENDIF
633	kfax(knfax) = ifac
634	! Store the other factor that goes with this one
635	knfax = knfax + 1
636	kfax(knfax) = inu / ifac
637	!WRITE (,) 'ARPDBG, factors ',knfax-1,' & ',knfax,' are ', kfax(knfax-1),' and ',kfax(knfax)
638	ENDIF
639	!
640	END DO
641
642	20 CONTINUE ! Label 20 is the exit point from the factor search loop.
643	!
644	END SUBROUTINE factorise
645
646	#if defined key_mpp_mpi
647	SUBROUTINE nemo_northcomms
648	!!======================================================================
649	!! * ROUTINE nemo_northcomms *
650	!! nemo_northcomms : Setup for north fold exchanges with explicit peer to peer messaging
651	!!=====================================================================
652	!!----------------------------------------------------------------------
653	!!
654	!! ** Purpose : Initialization of the northern neighbours lists.
655	!!----------------------------------------------------------------------
656	!! 1.0 ! 2011-10 (A. C. Coward, NOCS & J. Donners, PRACE)
657	!!----------------------------------------------------------------------
658
659	INTEGER :: ji, jj, jk, ij, jtyp ! dummy loop indices
660	INTEGER :: ijpj ! number of rows involved in north-fold exchange
661	INTEGER :: northcomms_alloc ! allocate return status
662	REAL(wp), ALLOCATABLE, DIMENSION ( :,: ) :: znnbrs ! workspace
663	LOGICAL, ALLOCATABLE, DIMENSION ( : ) :: lrankset ! workspace
664
665	IF(lwp) WRITE(numout,*)
666	IF(lwp) WRITE(numout,*) 'nemo_northcomms : Initialization of the northern neighbours lists'
667	IF(lwp) WRITE(numout,*) '~~~~~~~~~~'
668
669	!!----------------------------------------------------------------------
670	ALLOCATE( znnbrs(jpi,jpj), stat = northcomms_alloc )
671	ALLOCATE( lrankset(jpnij), stat = northcomms_alloc )
672	IF( northcomms_alloc /= 0 ) THEN
673	WRITE(numout,cform_war)
674	WRITE(numout,*) 'northcomms_alloc : failed to allocate arrays'
675	CALL ctl_stop( 'STOP', 'nemo_northcomms : unable to allocate temporary arrays' )
676	ENDIF
677	nsndto = 0
678	isendto = -1
679	ijpj = 4
680	!
681	! This routine has been called because ln_nnogather has been set true ( nammpp )
682	! However, these first few exchanges have to use the mpi_allgather method to
683	! establish the neighbour lists to use in subsequent peer to peer exchanges.
684	! Consequently, set l_north_nogather to be false here and set it true only after
685	! the lists have been established.
686	!
687	l_north_nogather = .FALSE.
688	!
689	! Exchange and store ranks on northern rows
690
691	DO jtyp = 1,4
692
693	lrankset = .FALSE.
694	znnbrs = narea
695	SELECT CASE (jtyp)
696	CASE(1)
697	CALL lbc_lnk( znnbrs, 'T', 1. ) ! Type 1: T,W-points
698	CASE(2)
699	CALL lbc_lnk( znnbrs, 'U', 1. ) ! Type 2: U-point
700	CASE(3)
701	CALL lbc_lnk( znnbrs, 'V', 1. ) ! Type 3: V-point
702	CASE(4)
703	CALL lbc_lnk( znnbrs, 'F', 1. ) ! Type 4: F-point
704	END SELECT
705
706	IF ( njmppt(narea) .EQ. MAXVAL( njmppt ) ) THEN
707	DO jj = nlcj-ijpj+1, nlcj
708	ij = jj - nlcj + ijpj
709	DO ji = 1,jpi
710	IF ( INT(znnbrs(ji,jj)) .NE. 0 .AND. INT(znnbrs(ji,jj)) .NE. narea ) &
711	& lrankset(INT(znnbrs(ji,jj))) = .true.
712	END DO
713	END DO
714
715	DO jj = 1,jpnij
716	IF ( lrankset(jj) ) THEN
717	nsndto(jtyp) = nsndto(jtyp) + 1
718	IF ( nsndto(jtyp) .GT. jpmaxngh ) THEN
719	CALL ctl_stop( ' Too many neighbours in nemo_northcomms ', &
720	& ' jpmaxngh will need to be increased ')
721	ENDIF
722	isendto(nsndto(jtyp),jtyp) = jj-1 ! narea converted to MPI rank
723	ENDIF
724	END DO
725	ENDIF
726
727	END DO
728
729	!
730	! Type 5: I-point
731	!
732	! ICE point exchanges may involve some averaging. The neighbours list is
733	! built up using two exchanges to ensure that the whole stencil is covered.
734	! lrankset should not be reset between these 'J' and 'K' point exchanges
735
736	jtyp = 5
737	lrankset = .FALSE.
738	znnbrs = narea
739	CALL lbc_lnk( znnbrs, 'J', 1. ) ! first ice U-V point
740
741	IF ( njmppt(narea) .EQ. MAXVAL( njmppt ) ) THEN
742	DO jj = nlcj-ijpj+1, nlcj
743	ij = jj - nlcj + ijpj
744	DO ji = 1,jpi
745	IF ( INT(znnbrs(ji,jj)) .NE. 0 .AND. INT(znnbrs(ji,jj)) .NE. narea ) &
746	& lrankset(INT(znnbrs(ji,jj))) = .true.
747	END DO
748	END DO
749	ENDIF
750
751	znnbrs = narea
752	CALL lbc_lnk( znnbrs, 'K', 1. ) ! second ice U-V point
753
754	IF ( njmppt(narea) .EQ. MAXVAL( njmppt )) THEN
755	DO jj = nlcj-ijpj+1, nlcj
756	ij = jj - nlcj + ijpj
757	DO ji = 1,jpi
758	IF ( INT(znnbrs(ji,jj)) .NE. 0 .AND. INT(znnbrs(ji,jj)) .NE. narea ) &
759	& lrankset( INT(znnbrs(ji,jj))) = .true.
760	END DO
761	END DO
762
763	DO jj = 1,jpnij
764	IF ( lrankset(jj) ) THEN
765	nsndto(jtyp) = nsndto(jtyp) + 1
766	IF ( nsndto(jtyp) .GT. jpmaxngh ) THEN
767	CALL ctl_stop( ' Too many neighbours in nemo_northcomms ', &
768	& ' jpmaxngh will need to be increased ')
769	ENDIF
770	isendto(nsndto(jtyp),jtyp) = jj-1 ! narea converted to MPI rank
771	ENDIF
772	END DO
773	!
774	! For northern row areas, set l_north_nogather so that all subsequent exchanges
775	! can use peer to peer communications at the north fold
776	!
777	l_north_nogather = .TRUE.
778	!
779	ENDIF
780	DEALLOCATE( znnbrs )
781	DEALLOCATE( lrankset )
782
783	END SUBROUTINE nemo_northcomms
784	#else
785	SUBROUTINE nemo_northcomms ! Dummy routine
786	WRITE(,) 'nemo_northcomms: You should not have seen this print! error?'
787	END SUBROUTINE nemo_northcomms
788	#endif
789	!!======================================================================
790	END MODULE nemogcm

Note: See TracBrowser for help on using the repository browser.

Download in other formats: