1 | MODULE ldfeiv |
---|
2 | !!====================================================================== |
---|
3 | !! *** MODULE ldfeiv *** |
---|
4 | !! Ocean physics: variable eddy induced velocity coefficients |
---|
5 | !!====================================================================== |
---|
6 | !! History : OPA ! 1999-03 (G. Madec, A. Jouzeau) Original code |
---|
7 | !! NEMO 1.0 ! 2002-06 (G. Madec) Free form, F90 |
---|
8 | !!---------------------------------------------------------------------- |
---|
9 | #if defined key_traldf_eiv && defined key_traldf_c2d |
---|
10 | !!---------------------------------------------------------------------- |
---|
11 | !! 'key_traldf_eiv' and eddy induced velocity |
---|
12 | !! 'key_traldf_c2d' 2D tracer lateral mixing coef. |
---|
13 | !!---------------------------------------------------------------------- |
---|
14 | !! ldf_eiv : compute the eddy induced velocity coefficients |
---|
15 | !!---------------------------------------------------------------------- |
---|
16 | USE oce ! ocean dynamics and tracers |
---|
17 | USE dom_oce ! ocean space and time domain |
---|
18 | USE sbc_oce ! surface boundary condition: ocean |
---|
19 | USE sbcrnf ! river runoffs |
---|
20 | USE ldftra_oce ! ocean tracer lateral physics |
---|
21 | USE phycst ! physical constants |
---|
22 | USE ldfslp ! iso-neutral slopes |
---|
23 | USE in_out_manager ! I/O manager |
---|
24 | USE lbclnk ! ocean lateral boundary conditions (or mpp link) |
---|
25 | USE prtctl ! Print control |
---|
26 | USE iom ! I/O library |
---|
27 | |
---|
28 | IMPLICIT NONE |
---|
29 | PRIVATE |
---|
30 | |
---|
31 | PUBLIC ldf_eiv ! routine called by step.F90 |
---|
32 | |
---|
33 | !! * Substitutions |
---|
34 | # include "domzgr_substitute.h90" |
---|
35 | # include "vectopt_loop_substitute.h90" |
---|
36 | !!---------------------------------------------------------------------- |
---|
37 | !! NEMO/OPA 3.3 , NEMO Consortium (2010) |
---|
38 | !! $Id$ |
---|
39 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
---|
40 | !!---------------------------------------------------------------------- |
---|
41 | CONTAINS |
---|
42 | |
---|
43 | SUBROUTINE ldf_eiv( kt ) |
---|
44 | !!---------------------------------------------------------------------- |
---|
45 | !! *** ROUTINE ldf_eiv *** |
---|
46 | !! |
---|
47 | !! ** Purpose : Compute the eddy induced velocity coefficient from the |
---|
48 | !! growth rate of baroclinic instability. |
---|
49 | !! |
---|
50 | !! ** Method : |
---|
51 | !! |
---|
52 | !! ** Action : - uslp , vslp : i- and j-slopes of neutral surfaces at u- & v-points |
---|
53 | !! - wslpi, wslpj : i- and j-slopes of neutral surfaces at w-points. |
---|
54 | !!---------------------------------------------------------------------- |
---|
55 | USE wrk_nemo, ONLY: wrk_in_use, wrk_not_released |
---|
56 | USE wrk_nemo, ONLY: zn => wrk_2d_1 , zah => wrk_2d_2 ! 2D workspace |
---|
57 | USE wrk_nemo, ONLY: zhw => wrk_2d_3 , zross => wrk_2d_4 |
---|
58 | ! |
---|
59 | INTEGER, INTENT(in) :: kt ! ocean time-step inedx |
---|
60 | ! |
---|
61 | INTEGER :: ji, jj, jk ! dummy loop indices |
---|
62 | REAL(wp) :: zfw, ze3w, zn2, zf20, zaht, zaht_min ! temporary scalars |
---|
63 | !!---------------------------------------------------------------------- |
---|
64 | |
---|
65 | IF( wrk_in_use(2, 1,2,3,4) ) THEN |
---|
66 | CALL ctl_stop('ldf_eiv: requested workspace arrays are unavailable.') ; RETURN |
---|
67 | ENDIF |
---|
68 | |
---|
69 | IF( kt == nit000 ) THEN |
---|
70 | IF(lwp) WRITE(numout,*) |
---|
71 | IF(lwp) WRITE(numout,*) 'ldf_eiv : eddy induced velocity coefficients' |
---|
72 | IF(lwp) WRITE(numout,*) '~~~~~~~' |
---|
73 | ENDIF |
---|
74 | |
---|
75 | ! 0. Local initialization |
---|
76 | ! ----------------------- |
---|
77 | zn (:,:) = 0._wp |
---|
78 | zhw (:,:) = 5._wp |
---|
79 | zah (:,:) = 0._wp |
---|
80 | zross(:,:) = 0._wp |
---|
81 | |
---|
82 | |
---|
83 | ! 1. Compute lateral diffusive coefficient |
---|
84 | ! ---------------------------------------- |
---|
85 | IF( ln_traldf_grif ) THEN |
---|
86 | DO jk = 1, jpk |
---|
87 | # if defined key_vectopt_loop |
---|
88 | !CDIR NOVERRCHK |
---|
89 | DO ji = 1, jpij ! vector opt. |
---|
90 | ! Take the max of N^2 and zero then take the vertical sum |
---|
91 | ! of the square root of the resulting N^2 ( required to compute |
---|
92 | ! internal Rossby radius Ro = .5 * sum_jpk(N) / f |
---|
93 | zn2 = MAX( rn2b(ji,1,jk), 0._wp ) |
---|
94 | zn(ji,1) = zn(ji,1) + SQRT( zn2 ) * fse3w(ji,1,jk) |
---|
95 | ! Compute elements required for the inverse time scale of baroclinic |
---|
96 | ! eddies using the isopycnal slopes calculated in ldfslp.F : |
---|
97 | ! T^-1 = sqrt(m_jpk(N^2*(r1^2+r2^2)*e3w)) |
---|
98 | ze3w = fse3w(ji,1,jk) * tmask(ji,1,jk) |
---|
99 | zah(ji,1) = zah(ji,1) + zn2 * wslp2(ji,1,jk) * ze3w |
---|
100 | zhw(ji,1) = zhw(ji,1) + ze3w |
---|
101 | END DO |
---|
102 | # else |
---|
103 | DO jj = 2, jpjm1 |
---|
104 | !CDIR NOVERRCHK |
---|
105 | DO ji = 2, jpim1 |
---|
106 | ! Take the max of N^2 and zero then take the vertical sum |
---|
107 | ! of the square root of the resulting N^2 ( required to compute |
---|
108 | ! internal Rossby radius Ro = .5 * sum_jpk(N) / f |
---|
109 | zn2 = MAX( rn2b(ji,jj,jk), 0._wp ) |
---|
110 | zn(ji,jj) = zn(ji,jj) + SQRT( zn2 ) * fse3w(ji,jj,jk) |
---|
111 | ! Compute elements required for the inverse time scale of baroclinic |
---|
112 | ! eddies using the isopycnal slopes calculated in ldfslp.F : |
---|
113 | ! T^-1 = sqrt(m_jpk(N^2*(r1^2+r2^2)*e3w)) |
---|
114 | ze3w = fse3w(ji,jj,jk) * tmask(ji,jj,jk) |
---|
115 | zah(ji,jj) = zah(ji,jj) + zn2 * wslp2(ji,jj,jk) * ze3w |
---|
116 | zhw(ji,jj) = zhw(ji,jj) + ze3w |
---|
117 | END DO |
---|
118 | END DO |
---|
119 | # endif |
---|
120 | END DO |
---|
121 | ELSE |
---|
122 | DO jk = 1, jpk |
---|
123 | # if defined key_vectopt_loop |
---|
124 | !CDIR NOVERRCHK |
---|
125 | DO ji = 1, jpij ! vector opt. |
---|
126 | ! Take the max of N^2 and zero then take the vertical sum |
---|
127 | ! of the square root of the resulting N^2 ( required to compute |
---|
128 | ! internal Rossby radius Ro = .5 * sum_jpk(N) / f |
---|
129 | zn2 = MAX( rn2b(ji,1,jk), 0._wp ) |
---|
130 | zn(ji,1) = zn(ji,1) + SQRT( zn2 ) * fse3w(ji,1,jk) |
---|
131 | ! Compute elements required for the inverse time scale of baroclinic |
---|
132 | ! eddies using the isopycnal slopes calculated in ldfslp.F : |
---|
133 | ! T^-1 = sqrt(m_jpk(N^2*(r1^2+r2^2)*e3w)) |
---|
134 | ze3w = fse3w(ji,1,jk) * tmask(ji,1,jk) |
---|
135 | zah(ji,1) = zah(ji,1) + zn2 * ( wslpi(ji,1,jk) * wslpi(ji,1,jk) & |
---|
136 | & + wslpj(ji,1,jk) * wslpj(ji,1,jk) ) * ze3w |
---|
137 | zhw(ji,1) = zhw(ji,1) + ze3w |
---|
138 | END DO |
---|
139 | # else |
---|
140 | DO jj = 2, jpjm1 |
---|
141 | !CDIR NOVERRCHK |
---|
142 | DO ji = 2, jpim1 |
---|
143 | ! Take the max of N^2 and zero then take the vertical sum |
---|
144 | ! of the square root of the resulting N^2 ( required to compute |
---|
145 | ! internal Rossby radius Ro = .5 * sum_jpk(N) / f |
---|
146 | zn2 = MAX( rn2b(ji,jj,jk), 0._wp ) |
---|
147 | zn(ji,jj) = zn(ji,jj) + SQRT( zn2 ) * fse3w(ji,jj,jk) |
---|
148 | ! Compute elements required for the inverse time scale of baroclinic |
---|
149 | ! eddies using the isopycnal slopes calculated in ldfslp.F : |
---|
150 | ! T^-1 = sqrt(m_jpk(N^2*(r1^2+r2^2)*e3w)) |
---|
151 | ze3w = fse3w(ji,jj,jk) * tmask(ji,jj,jk) |
---|
152 | zah(ji,jj) = zah(ji,jj) + zn2 * ( wslpi(ji,jj,jk) * wslpi(ji,jj,jk) & |
---|
153 | & + wslpj(ji,jj,jk) * wslpj(ji,jj,jk) ) * ze3w |
---|
154 | zhw(ji,jj) = zhw(ji,jj) + ze3w |
---|
155 | END DO |
---|
156 | END DO |
---|
157 | # endif |
---|
158 | END DO |
---|
159 | END IF |
---|
160 | |
---|
161 | DO jj = 2, jpjm1 |
---|
162 | !CDIR NOVERRCHK |
---|
163 | DO ji = fs_2, fs_jpim1 ! vector opt. |
---|
164 | zfw = MAX( ABS( 2. * omega * SIN( rad * gphit(ji,jj) ) ) , 1.e-10 ) |
---|
165 | ! Rossby radius at w-point taken < 40km and > 2km |
---|
166 | zross(ji,jj) = MAX( MIN( .4 * zn(ji,jj) / zfw, 40.e3 ), 2.e3 ) |
---|
167 | ! Compute aeiw by multiplying Ro^2 and T^-1 |
---|
168 | aeiw(ji,jj) = zross(ji,jj) * zross(ji,jj) * SQRT( zah(ji,jj) / zhw(ji,jj) ) * tmask(ji,jj,1) |
---|
169 | END DO |
---|
170 | END DO |
---|
171 | |
---|
172 | IF( cp_cfg == "orca" .AND. jp_cfg == 2 ) THEN ! ORCA R2 |
---|
173 | DO jj = 2, jpjm1 |
---|
174 | !CDIR NOVERRCHK |
---|
175 | DO ji = fs_2, fs_jpim1 ! vector opt. |
---|
176 | ! Take the minimum between aeiw and 1000 m2/s over shelves (depth shallower than 650 m) |
---|
177 | IF( mbkt(ji,jj) <= 20 ) aeiw(ji,jj) = MIN( aeiw(ji,jj), 1000. ) |
---|
178 | END DO |
---|
179 | END DO |
---|
180 | ENDIF |
---|
181 | |
---|
182 | ! Decrease the coefficient in the tropics (20N-20S) |
---|
183 | zf20 = 2._wp * omega * sin( rad * 20._wp ) |
---|
184 | DO jj = 2, jpjm1 |
---|
185 | DO ji = fs_2, fs_jpim1 ! vector opt. |
---|
186 | aeiw(ji,jj) = MIN( 1., ABS( ff(ji,jj) / zf20 ) ) * aeiw(ji,jj) |
---|
187 | END DO |
---|
188 | END DO |
---|
189 | |
---|
190 | ! ORCA R05: Take the minimum between aeiw and aeiv0 |
---|
191 | IF( cp_cfg == "orca" .AND. jp_cfg == 05 ) THEN |
---|
192 | DO jj = 2, jpjm1 |
---|
193 | DO ji = fs_2, fs_jpim1 ! vector opt. |
---|
194 | aeiw(ji,jj) = MIN( aeiw(ji,jj), aeiv0 ) |
---|
195 | END DO |
---|
196 | END DO |
---|
197 | ENDIF |
---|
198 | CALL lbc_lnk( aeiw, 'W', 1. ) ! lateral boundary condition on aeiw |
---|
199 | |
---|
200 | |
---|
201 | ! Average the diffusive coefficient at u- v- points |
---|
202 | DO jj = 2, jpjm1 |
---|
203 | DO ji = fs_2, fs_jpim1 ! vector opt. |
---|
204 | aeiu(ji,jj) = 0.5_wp * ( aeiw(ji,jj) + aeiw(ji+1,jj ) ) |
---|
205 | aeiv(ji,jj) = 0.5_wp * ( aeiw(ji,jj) + aeiw(ji ,jj+1) ) |
---|
206 | END DO |
---|
207 | END DO |
---|
208 | CALL lbc_lnk( aeiu, 'U', 1. ) ; CALL lbc_lnk( aeiv, 'V', 1. ) ! lateral boundary condition |
---|
209 | |
---|
210 | |
---|
211 | IF(ln_ctl) THEN |
---|
212 | CALL prt_ctl(tab2d_1=aeiu, clinfo1=' eiv - u: ', ovlap=1) |
---|
213 | CALL prt_ctl(tab2d_1=aeiv, clinfo1=' eiv - v: ', ovlap=1) |
---|
214 | ENDIF |
---|
215 | |
---|
216 | ! ORCA R05: add a space variation on aht (=aeiv except at the equator and river mouth) |
---|
217 | IF( cp_cfg == "orca" .AND. jp_cfg == 05 ) THEN |
---|
218 | zf20 = 2._wp * omega * SIN( rad * 20._wp ) |
---|
219 | zaht_min = 100._wp ! minimum value for aht |
---|
220 | DO jj = 1, jpj |
---|
221 | DO ji = 1, jpi |
---|
222 | zaht = ( 1._wp - MIN( 1._wp , ABS( ff(ji,jj) / zf20 ) ) ) * ( aht0 - zaht_min ) & |
---|
223 | & + aht0 * rnfmsk(ji,jj) ! enhanced near river mouths |
---|
224 | ahtu(ji,jj) = MAX( MAX( zaht_min, aeiu(ji,jj) ) + zaht, aht0 ) |
---|
225 | ahtv(ji,jj) = MAX( MAX( zaht_min, aeiv(ji,jj) ) + zaht, aht0 ) |
---|
226 | ahtw(ji,jj) = MAX( MAX( zaht_min, aeiw(ji,jj) ) + zaht, aht0 ) |
---|
227 | END DO |
---|
228 | END DO |
---|
229 | IF(ln_ctl) THEN |
---|
230 | CALL prt_ctl(tab2d_1=ahtu, clinfo1=' aht - u: ', ovlap=1) |
---|
231 | CALL prt_ctl(tab2d_1=ahtv, clinfo1=' aht - v: ', ovlap=1) |
---|
232 | CALL prt_ctl(tab2d_1=ahtw, clinfo1=' aht - w: ', ovlap=1) |
---|
233 | ENDIF |
---|
234 | ENDIF |
---|
235 | |
---|
236 | IF( aeiv0 == 0._wp ) THEN |
---|
237 | aeiu(:,:) = 0._wp |
---|
238 | aeiv(:,:) = 0._wp |
---|
239 | aeiw(:,:) = 0._wp |
---|
240 | ENDIF |
---|
241 | |
---|
242 | CALL iom_put( "aht2d" , ahtw ) ! lateral eddy diffusivity |
---|
243 | CALL iom_put( "aht2d_eiv", aeiw ) ! EIV lateral eddy diffusivity |
---|
244 | ! |
---|
245 | IF( wrk_not_released(2, 1,2,3,4) ) CALL ctl_stop('ldf_eiv: failed to release workspace arrays') |
---|
246 | ! |
---|
247 | END SUBROUTINE ldf_eiv |
---|
248 | |
---|
249 | #else |
---|
250 | !!---------------------------------------------------------------------- |
---|
251 | !! Default option Dummy module |
---|
252 | !!---------------------------------------------------------------------- |
---|
253 | CONTAINS |
---|
254 | SUBROUTINE ldf_eiv( kt ) ! Empty routine |
---|
255 | INTEGER :: kt |
---|
256 | WRITE(*,*) 'ldf_eiv: You should not have seen this print! error?', kt |
---|
257 | END SUBROUTINE ldf_eiv |
---|
258 | #endif |
---|
259 | |
---|
260 | !!====================================================================== |
---|
261 | END MODULE ldfeiv |
---|