1 | MODULE diaar5 |
---|
2 | !!====================================================================== |
---|
3 | !! *** MODULE diaar5 *** |
---|
4 | !! AR5 diagnostics |
---|
5 | !!====================================================================== |
---|
6 | !! History : 3.2 ! 2009-11 (S. Masson) Original code |
---|
7 | !! 3.3 ! 2010-10 (C. Ethe, G. Madec) reorganisation of initialisation phase + merge TRC-TRA |
---|
8 | !!---------------------------------------------------------------------- |
---|
9 | #if defined key_diaar5 || defined key_esopa |
---|
10 | !!---------------------------------------------------------------------- |
---|
11 | !! 'key_diaar5' : activate ar5 diagnotics |
---|
12 | !!---------------------------------------------------------------------- |
---|
13 | !! dia_ar5 : AR5 diagnostics |
---|
14 | !! dia_ar5_init : initialisation of AR5 diagnostics |
---|
15 | !!---------------------------------------------------------------------- |
---|
16 | USE oce ! ocean dynamics and active tracers |
---|
17 | USE dom_oce ! ocean space and time domain |
---|
18 | USE eosbn2 ! equation of state (eos_bn2 routine) |
---|
19 | USE lib_mpp ! distribued memory computing library |
---|
20 | USE iom ! I/O manager library |
---|
21 | |
---|
22 | IMPLICIT NONE |
---|
23 | PRIVATE |
---|
24 | |
---|
25 | PUBLIC dia_ar5 ! routine called in step.F90 module |
---|
26 | PUBLIC dia_ar5_init ! routine called in opa.F90 module |
---|
27 | PUBLIC dia_ar5_alloc ! routine called in nemogcm.F90 module |
---|
28 | |
---|
29 | LOGICAL, PUBLIC, PARAMETER :: lk_diaar5 = .TRUE. ! coupled flag |
---|
30 | |
---|
31 | REAL(wp) :: vol0 ! ocean volume (interior domain) |
---|
32 | REAL(wp) :: area_tot ! total ocean surface (interior domain) |
---|
33 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,: ) :: area ! cell surface (interior domain) |
---|
34 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,: ) :: thick0 ! ocean thickness (interior domain) |
---|
35 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: sn0 ! initial salinity |
---|
36 | |
---|
37 | !! * Substitutions |
---|
38 | # include "domzgr_substitute.h90" |
---|
39 | !!---------------------------------------------------------------------- |
---|
40 | !! NEMO/OPA 3.3 , NEMO Consortium (2010) |
---|
41 | !! $Id$ |
---|
42 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
---|
43 | !!---------------------------------------------------------------------- |
---|
44 | CONTAINS |
---|
45 | |
---|
46 | FUNCTION dia_ar5_alloc() |
---|
47 | !!---------------------------------------------------------------------- |
---|
48 | !! *** ROUTINE dia_ar5_alloc *** |
---|
49 | !!---------------------------------------------------------------------- |
---|
50 | INTEGER :: dia_ar5_alloc |
---|
51 | !!---------------------------------------------------------------------- |
---|
52 | ! |
---|
53 | ALLOCATE( area(jpi,jpj), thick0(jpi,jpj) , sn0(jpi,jpj,jpk) , STAT=dia_ar5_alloc ) |
---|
54 | ! |
---|
55 | IF( lk_mpp ) CALL mpp_sum ( dia_ar5_alloc ) |
---|
56 | IF( dia_ar5_alloc /= 0 ) CALL ctl_warn('dia_ar5_alloc: failed to allocate arrays') |
---|
57 | ! |
---|
58 | END FUNCTION dia_ar5_alloc |
---|
59 | |
---|
60 | |
---|
61 | SUBROUTINE dia_ar5( kt ) |
---|
62 | !!---------------------------------------------------------------------- |
---|
63 | !! *** ROUTINE dia_ar5 *** |
---|
64 | !! |
---|
65 | !! ** Purpose : compute and output some AR5 diagnostics |
---|
66 | !!---------------------------------------------------------------------- |
---|
67 | USE wrk_nemo, ONLY: wrk_in_use, wrk_not_released |
---|
68 | USE wrk_nemo, ONLY: zarea_ssh => wrk_2d_1 , zbotpres => wrk_2d_2 ! 2D workspace |
---|
69 | USE wrk_nemo, ONLY: zrhd => wrk_3d_1 , zrhop => wrk_3d_2 ! 3D - |
---|
70 | USE wrk_nemo, ONLY: ztsn => wrk_4d_1 ! 4D - |
---|
71 | ! |
---|
72 | INTEGER, INTENT( in ) :: kt ! ocean time-step index |
---|
73 | ! |
---|
74 | INTEGER :: ji, jj, jk ! dummy loop arguments |
---|
75 | REAL(wp) :: zvolssh, zvol, zssh_steric, zztmp, zarho, ztemp, zsal, zmass |
---|
76 | !!-------------------------------------------------------------------- |
---|
77 | |
---|
78 | IF( wrk_in_use(2, 1,2) .OR. & |
---|
79 | wrk_in_use(3, 1,2) .OR. & |
---|
80 | wrk_in_use(4, 1) ) THEN |
---|
81 | CALL ctl_stop('dia_ar5: requested workspace arrays unavailable') ; RETURN |
---|
82 | ENDIF |
---|
83 | |
---|
84 | CALL iom_put( 'cellthc', fse3t(:,:,:) ) |
---|
85 | |
---|
86 | zarea_ssh(:,:) = area(:,:) * sshn(:,:) |
---|
87 | |
---|
88 | ! ! total volume of liquid seawater |
---|
89 | zvolssh = SUM( zarea_ssh(:,:) ) |
---|
90 | IF( lk_mpp ) CALL mpp_sum( zvolssh ) |
---|
91 | zvol = vol0 + zvolssh |
---|
92 | |
---|
93 | CALL iom_put( 'voltot', zvol ) |
---|
94 | CALL iom_put( 'sshtot', zvolssh / area_tot ) |
---|
95 | |
---|
96 | ! ! thermosteric ssh |
---|
97 | ztsn(:,:,:,jp_tem) = tn (:,:,:) |
---|
98 | ztsn(:,:,:,jp_sal) = sn0(:,:,:) |
---|
99 | CALL eos( ztsn, zrhd ) ! now in situ density using initial salinity |
---|
100 | ! |
---|
101 | zbotpres(:,:) = 0._wp ! no atmospheric surface pressure, levitating sea-ice |
---|
102 | DO jk = 1, jpkm1 |
---|
103 | zbotpres(:,:) = zbotpres(:,:) + fse3t(:,:,jk) * zrhd(:,:,jk) |
---|
104 | END DO |
---|
105 | IF( .NOT.lk_vvl ) zbotpres(:,:) = zbotpres(:,:) + sshn(:,:) * zrhd(:,:,1) |
---|
106 | ! |
---|
107 | zarho = SUM( area(:,:) * zbotpres(:,:) ) |
---|
108 | IF( lk_mpp ) CALL mpp_sum( zarho ) |
---|
109 | zssh_steric = - zarho / area_tot |
---|
110 | CALL iom_put( 'sshthster', zssh_steric ) |
---|
111 | |
---|
112 | ! ! steric sea surface height |
---|
113 | CALL eos( tsn, zrhd, zrhop ) ! now in situ and potential density |
---|
114 | zrhop(:,:,jpk) = 0._wp |
---|
115 | CALL iom_put( 'rhop', zrhop ) |
---|
116 | ! |
---|
117 | zbotpres(:,:) = 0._wp ! no atmospheric surface pressure, levitating sea-ice |
---|
118 | DO jk = 1, jpkm1 |
---|
119 | zbotpres(:,:) = zbotpres(:,:) + fse3t(:,:,jk) * zrhd(:,:,jk) |
---|
120 | END DO |
---|
121 | IF( .NOT.lk_vvl ) zbotpres(:,:) = zbotpres(:,:) + sshn(:,:) * zrhd(:,:,1) |
---|
122 | ! |
---|
123 | zarho = SUM( area(:,:) * zbotpres(:,:) ) |
---|
124 | IF( lk_mpp ) CALL mpp_sum( zarho ) |
---|
125 | zssh_steric = - zarho / area_tot |
---|
126 | CALL iom_put( 'sshsteric', zssh_steric ) |
---|
127 | |
---|
128 | ! ! ocean bottom pressure |
---|
129 | zztmp = rau0 * grav * 1.e-4_wp ! recover pressure from pressure anomaly and cover to dbar = 1.e4 Pa |
---|
130 | zbotpres(:,:) = zztmp * ( zbotpres(:,:) + sshn(:,:) + thick0(:,:) ) |
---|
131 | CALL iom_put( 'botpres', zbotpres ) |
---|
132 | |
---|
133 | ! ! Mean density anomalie, temperature and salinity |
---|
134 | ztemp = 0._wp |
---|
135 | zsal = 0._wp |
---|
136 | DO jk = 1, jpkm1 |
---|
137 | DO jj = 1, jpj |
---|
138 | DO ji = 1, jpi |
---|
139 | zztmp = area(ji,jj) * fse3t(ji,jj,jk) |
---|
140 | ztemp = ztemp + zztmp * tn(ji,jj,jk) |
---|
141 | zsal = zsal + zztmp * sn(ji,jj,jk) |
---|
142 | END DO |
---|
143 | END DO |
---|
144 | END DO |
---|
145 | IF( .NOT.lk_vvl ) THEN |
---|
146 | ztemp = ztemp + SUM( zarea_ssh(:,:) * tn(:,:,1) ) |
---|
147 | zsal = zsal + SUM( zarea_ssh(:,:) * sn(:,:,1) ) |
---|
148 | ENDIF |
---|
149 | IF( lk_mpp ) THEN |
---|
150 | CALL mpp_sum( ztemp ) |
---|
151 | CALL mpp_sum( zsal ) |
---|
152 | END IF |
---|
153 | ! |
---|
154 | zmass = rau0 * ( zarho + zvol ) ! total mass of liquid seawater |
---|
155 | ztemp = ztemp / zvol ! potential temperature in liquid seawater |
---|
156 | zsal = zsal / zvol ! Salinity of liquid seawater |
---|
157 | ! |
---|
158 | CALL iom_put( 'masstot', zmass ) |
---|
159 | CALL iom_put( 'temptot', ztemp ) |
---|
160 | CALL iom_put( 'saltot' , zsal ) |
---|
161 | ! |
---|
162 | IF( wrk_not_released(2, 1,2) .OR. & |
---|
163 | wrk_not_released(3, 1,2) .OR. & |
---|
164 | wrk_not_released(4, 1) ) CALL ctl_stop('dia_ar5: failed to release workspace arrays') |
---|
165 | ! |
---|
166 | END SUBROUTINE dia_ar5 |
---|
167 | |
---|
168 | |
---|
169 | SUBROUTINE dia_ar5_init |
---|
170 | !!---------------------------------------------------------------------- |
---|
171 | !! *** ROUTINE dia_ar5_init *** |
---|
172 | !! |
---|
173 | !! ** Purpose : initialization for AR5 diagnostic computation |
---|
174 | !!---------------------------------------------------------------------- |
---|
175 | USE wrk_nemo, ONLY: wrk_in_use, wrk_not_released |
---|
176 | USE wrk_nemo, ONLY: wrk_4d_1 ! 4D workspace |
---|
177 | ! |
---|
178 | INTEGER :: inum |
---|
179 | INTEGER :: ik |
---|
180 | INTEGER :: ji, jj, jk ! dummy loop indices |
---|
181 | REAL(wp) :: zztmp |
---|
182 | REAL(wp), POINTER, DIMENSION(:,:,:,:) :: zsaldta ! Jan/Dec levitus salinity |
---|
183 | !!---------------------------------------------------------------------- |
---|
184 | ! |
---|
185 | IF(wrk_in_use(4, 1) ) THEN |
---|
186 | CALL ctl_stop('dia_ar5_init: requested workspace array unavailable.') ; RETURN |
---|
187 | ENDIF |
---|
188 | zsaldta => wrk_4d_1(:,:,:,1:2) |
---|
189 | |
---|
190 | ! ! allocate dia_ar5 arrays |
---|
191 | IF( dia_ar5_alloc() /= 0 ) CALL ctl_stop( 'STOP', 'dia_ar5_init : unable to allocate arrays' ) |
---|
192 | |
---|
193 | area(:,:) = e1t(:,:) * e2t(:,:) * tmask_i(:,:) |
---|
194 | |
---|
195 | area_tot = SUM( area(:,:) ) ; IF( lk_mpp ) CALL mpp_sum( area_tot ) |
---|
196 | |
---|
197 | vol0 = 0._wp |
---|
198 | thick0(:,:) = 0._wp |
---|
199 | DO jk = 1, jpkm1 |
---|
200 | vol0 = vol0 + SUM( area (:,:) * tmask(:,:,jk) * fse3t_0(:,:,jk) ) |
---|
201 | thick0(:,:) = thick0(:,:) + tmask_i(:,:) * tmask(:,:,jk) * fse3t_0(:,:,jk) |
---|
202 | END DO |
---|
203 | IF( lk_mpp ) CALL mpp_sum( vol0 ) |
---|
204 | |
---|
205 | CALL iom_open ( 'data_1m_salinity_nomask', inum ) |
---|
206 | CALL iom_get ( inum, jpdom_data, 'vosaline', zsaldta(:,:,:,1), 1 ) |
---|
207 | CALL iom_get ( inum, jpdom_data, 'vosaline', zsaldta(:,:,:,2), 12 ) |
---|
208 | CALL iom_close( inum ) |
---|
209 | sn0(:,:,:) = 0.5_wp * ( zsaldta(:,:,:,1) + zsaldta(:,:,:,2) ) |
---|
210 | sn0(:,:,:) = sn0(:,:,:) * tmask(:,:,:) |
---|
211 | IF( ln_zps ) THEN ! z-coord. partial steps |
---|
212 | DO jj = 1, jpj ! interpolation of salinity at the last ocean level (i.e. the partial step) |
---|
213 | DO ji = 1, jpi |
---|
214 | ik = mbkt(ji,jj) |
---|
215 | IF( ik > 1 ) THEN |
---|
216 | zztmp = ( gdept_0(ik) - fsdept_0(ji,jj,ik) ) / ( gdept_0(ik) - gdept_0(ik-1) ) |
---|
217 | sn0(ji,jj,ik) = ( 1._wp - zztmp ) * sn0(ji,jj,ik) + zztmp * sn0(ji,jj,ik-1) |
---|
218 | ENDIF |
---|
219 | END DO |
---|
220 | END DO |
---|
221 | ENDIF |
---|
222 | ! |
---|
223 | IF( wrk_not_released(4, 1) ) CALL ctl_stop('dia_ar5_init: failed to release workspace array') |
---|
224 | ! |
---|
225 | END SUBROUTINE dia_ar5_init |
---|
226 | |
---|
227 | #else |
---|
228 | !!---------------------------------------------------------------------- |
---|
229 | !! Default option : NO diaar5 |
---|
230 | !!---------------------------------------------------------------------- |
---|
231 | LOGICAL, PUBLIC, PARAMETER :: lk_diaar5 = .FALSE. ! coupled flag |
---|
232 | CONTAINS |
---|
233 | SUBROUTINE dia_ar5_init ! Dummy routine |
---|
234 | END SUBROUTINE dia_ar5_init |
---|
235 | SUBROUTINE dia_ar5( kt ) ! Empty routine |
---|
236 | INTEGER :: kt |
---|
237 | WRITE(*,*) 'dia_ar5: You should not have seen this print! error?', kt |
---|
238 | END SUBROUTINE dia_ar5 |
---|
239 | #endif |
---|
240 | |
---|
241 | !!====================================================================== |
---|
242 | END MODULE diaar5 |
---|