| 1 | MODULE sbcrnf |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE sbcrnf *** |
|---|
| 4 | !! Ocean forcing: river runoff |
|---|
| 5 | !!===================================================================== |
|---|
| 6 | !! History : OPA ! 2000-11 (R. Hordoir, E. Durand) NetCDF FORMAT |
|---|
| 7 | !! NEMO 1.0 ! 2002-09 (G. Madec) F90: Free form and module |
|---|
| 8 | !! 3.0 ! 2006-07 (G. Madec) Surface module |
|---|
| 9 | !! 3.2 ! 2009-04 (B. Lemaire) Introduce iom_put |
|---|
| 10 | !! 3.3 ! 2010-10 (R. Furner, G. Madec) runoff distributed over ocean levels |
|---|
| 11 | !!---------------------------------------------------------------------- |
|---|
| 12 | |
|---|
| 13 | !!---------------------------------------------------------------------- |
|---|
| 14 | !! sbc_rnf : monthly runoffs read in a NetCDF file |
|---|
| 15 | !! sbc_rnf_init : runoffs initialisation |
|---|
| 16 | !! rnf_mouth : set river mouth mask |
|---|
| 17 | !!---------------------------------------------------------------------- |
|---|
| 18 | USE dom_oce ! ocean space and time domain |
|---|
| 19 | USE phycst ! physical constants |
|---|
| 20 | USE sbc_oce ! surface boundary condition variables |
|---|
| 21 | USE closea ! closed seas |
|---|
| 22 | USE fldread ! read input field at current time step |
|---|
| 23 | USE in_out_manager ! I/O manager |
|---|
| 24 | USE iom ! I/O module |
|---|
| 25 | USE lib_mpp ! MPP library |
|---|
| 26 | |
|---|
| 27 | IMPLICIT NONE |
|---|
| 28 | PRIVATE |
|---|
| 29 | |
|---|
| 30 | PUBLIC sbc_rnf ! routine call in sbcmod module |
|---|
| 31 | PUBLIC sbc_rnf_div ! routine called in sshwzv module |
|---|
| 32 | PUBLIC sbc_rnf_alloc ! routine call in sbcmod module |
|---|
| 33 | PUBLIC sbc_rnf_init ! (PUBLIC for TAM) |
|---|
| 34 | ! !!* namsbc_rnf namelist * |
|---|
| 35 | CHARACTER(len=100), PUBLIC :: cn_dir = './' !: Root directory for location of ssr files |
|---|
| 36 | LOGICAL , PUBLIC :: ln_rnf_depth = .false. !: depth river runoffs attribute specified in a file |
|---|
| 37 | LOGICAL , PUBLIC :: ln_rnf_tem = .false. !: temperature river runoffs attribute specified in a file |
|---|
| 38 | LOGICAL , PUBLIC :: ln_rnf_sal = .false. !: salinity river runoffs attribute specified in a file |
|---|
| 39 | LOGICAL , PUBLIC :: ln_rnf_emp = .false. !: runoffs into a file to be read or already into precipitation |
|---|
| 40 | TYPE(FLD_N) , PUBLIC :: sn_rnf !: information about the runoff file to be read |
|---|
| 41 | TYPE(FLD_N) , PUBLIC :: sn_cnf !: information about the runoff mouth file to be read |
|---|
| 42 | TYPE(FLD_N) :: sn_s_rnf !: information about the salinities of runoff file to be read |
|---|
| 43 | TYPE(FLD_N) :: sn_t_rnf !: information about the temperatures of runoff file to be read |
|---|
| 44 | TYPE(FLD_N) :: sn_dep_rnf !: information about the depth which river inflow affects |
|---|
| 45 | LOGICAL , PUBLIC :: ln_rnf_mouth = .false. !: specific treatment in mouths vicinity |
|---|
| 46 | REAL(wp) , PUBLIC :: rn_hrnf = 0._wp !: runoffs, depth over which enhanced vertical mixing is used |
|---|
| 47 | REAL(wp) , PUBLIC :: rn_avt_rnf = 0._wp !: runoffs, value of the additional vertical mixing coef. [m2/s] |
|---|
| 48 | REAL(wp) , PUBLIC :: rn_rfact = 1._wp !: multiplicative factor for runoff |
|---|
| 49 | |
|---|
| 50 | INTEGER , PUBLIC :: nkrnf = 0 !: nb of levels over which Kz is increased at river mouths |
|---|
| 51 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) :: rnfmsk !: river mouth mask (hori.) |
|---|
| 52 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:) :: rnfmsk_z !: river mouth mask (vert.) |
|---|
| 53 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) :: h_rnf !: depth of runoff in m |
|---|
| 54 | INTEGER, PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) :: nk_rnf !: depth of runoff in model levels |
|---|
| 55 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: rnf_tsc_b, rnf_tsc !: before and now T & S runoff contents [K.m/s & PSU.m/s] |
|---|
| 56 | |
|---|
| 57 | TYPE(FLD), PUBLIC, ALLOCATABLE, DIMENSION(:) :: sf_rnf ! structure: river runoff (file information, fields read) |
|---|
| 58 | TYPE(FLD), PUBLIC, ALLOCATABLE, DIMENSION(:) :: sf_s_rnf ! structure: river runoff salinity (file information, fields read) |
|---|
| 59 | TYPE(FLD), PUBLIC, ALLOCATABLE, DIMENSION(:) :: sf_t_rnf ! structure: river runoff temperature (file information, fields read) |
|---|
| 60 | |
|---|
| 61 | !! * Substitutions |
|---|
| 62 | # include "domzgr_substitute.h90" |
|---|
| 63 | !!---------------------------------------------------------------------- |
|---|
| 64 | !! NEMO/OPA 3.3 , NEMO Consortium (2010) |
|---|
| 65 | !! $Id$ |
|---|
| 66 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 67 | !!---------------------------------------------------------------------- |
|---|
| 68 | CONTAINS |
|---|
| 69 | |
|---|
| 70 | INTEGER FUNCTION sbc_rnf_alloc() |
|---|
| 71 | !!---------------------------------------------------------------------- |
|---|
| 72 | !! *** ROUTINE sbc_rnf_alloc *** |
|---|
| 73 | !!---------------------------------------------------------------------- |
|---|
| 74 | ALLOCATE( rnfmsk(jpi,jpj) , rnfmsk_z(jpk) , & |
|---|
| 75 | & h_rnf (jpi,jpj) , nk_rnf (jpi,jpj) , & |
|---|
| 76 | & rnf_tsc_b(jpi,jpj,jpts) , rnf_tsc (jpi,jpj,jpts) , STAT=sbc_rnf_alloc ) |
|---|
| 77 | ! |
|---|
| 78 | IF( lk_mpp ) CALL mpp_sum ( sbc_rnf_alloc ) |
|---|
| 79 | IF( sbc_rnf_alloc > 0 ) CALL ctl_warn('sbc_rnf_alloc: allocation of arrays failed') |
|---|
| 80 | END FUNCTION sbc_rnf_alloc |
|---|
| 81 | |
|---|
| 82 | |
|---|
| 83 | SUBROUTINE sbc_rnf( kt ) |
|---|
| 84 | !!---------------------------------------------------------------------- |
|---|
| 85 | !! *** ROUTINE sbc_rnf *** |
|---|
| 86 | !! |
|---|
| 87 | !! ** Purpose : Introduce a climatological run off forcing |
|---|
| 88 | !! |
|---|
| 89 | !! ** Method : Set each river mouth with a monthly climatology |
|---|
| 90 | !! provided from different data. |
|---|
| 91 | !! CAUTION : upward water flux, runoff forced to be < 0 |
|---|
| 92 | !! |
|---|
| 93 | !! ** Action : runoff updated runoff field at time-step kt |
|---|
| 94 | !!---------------------------------------------------------------------- |
|---|
| 95 | INTEGER, INTENT(in) :: kt ! ocean time step |
|---|
| 96 | ! |
|---|
| 97 | INTEGER :: ji, jj ! dummy loop indices |
|---|
| 98 | !!---------------------------------------------------------------------- |
|---|
| 99 | ! |
|---|
| 100 | IF( kt == nit000 ) CALL sbc_rnf_init ! Read namelist and allocate structures |
|---|
| 101 | |
|---|
| 102 | ! ! ---------------------------------------- ! |
|---|
| 103 | IF( kt /= nit000 ) THEN ! Swap of forcing fields ! |
|---|
| 104 | ! ! ---------------------------------------- ! |
|---|
| 105 | rnf_b (:,: ) = rnf (:,: ) ! Swap the ocean forcing fields except at nit000 |
|---|
| 106 | rnf_tsc_b(:,:,:) = rnf_tsc(:,:,:) ! where before fields are set at the end of the routine |
|---|
| 107 | ! |
|---|
| 108 | ENDIF |
|---|
| 109 | |
|---|
| 110 | ! !-------------------! |
|---|
| 111 | IF( .NOT. ln_rnf_emp ) THEN ! Update runoff ! |
|---|
| 112 | ! !-------------------! |
|---|
| 113 | ! |
|---|
| 114 | CALL fld_read ( kt, nn_fsbc, sf_rnf ) ! Read Runoffs data and provide it at kt |
|---|
| 115 | IF( ln_rnf_tem ) CALL fld_read ( kt, nn_fsbc, sf_t_rnf ) ! idem for runoffs temperature if required |
|---|
| 116 | IF( ln_rnf_sal ) CALL fld_read ( kt, nn_fsbc, sf_s_rnf ) ! idem for runoffs salinity if required |
|---|
| 117 | ! |
|---|
| 118 | ! Runoff reduction only associated to the ORCA2_LIM configuration |
|---|
| 119 | ! when reading the NetCDF file runoff_1m_nomask.nc |
|---|
| 120 | IF( cp_cfg == 'orca' .AND. jp_cfg == 2 ) THEN |
|---|
| 121 | WHERE( 40._wp < gphit(:,:) .AND. gphit(:,:) < 65._wp ) |
|---|
| 122 | sf_rnf(1)%fnow(:,:,1) = 0.85 * sf_rnf(1)%fnow(:,:,1) |
|---|
| 123 | END WHERE |
|---|
| 124 | ENDIF |
|---|
| 125 | ! |
|---|
| 126 | IF( MOD( kt - 1, nn_fsbc ) == 0 ) THEN |
|---|
| 127 | ! |
|---|
| 128 | rnf(:,:) = rn_rfact * ( sf_rnf(1)%fnow(:,:,1) ) ! updated runoff value at time step kt |
|---|
| 129 | ! |
|---|
| 130 | ! ! set temperature & salinity content of runoffs |
|---|
| 131 | IF( ln_rnf_tem ) THEN ! use runoffs temperature data |
|---|
| 132 | rnf_tsc(:,:,jp_tem) = ( sf_t_rnf(1)%fnow(:,:,1) ) * rnf(:,:) * r1_rau0 |
|---|
| 133 | WHERE( sf_t_rnf(1)%fnow(:,:,1) == -999 ) ! if missing data value use SST as runoffs temperature |
|---|
| 134 | rnf_tsc(:,:,jp_tem) = sst_m(:,:) * rnf(:,:) * r1_rau0 |
|---|
| 135 | END WHERE |
|---|
| 136 | ELSE ! use SST as runoffs temperature |
|---|
| 137 | rnf_tsc(:,:,jp_tem) = sst_m(:,:) * rnf(:,:) * r1_rau0 |
|---|
| 138 | ENDIF |
|---|
| 139 | ! ! use runoffs salinity data |
|---|
| 140 | IF( ln_rnf_sal ) rnf_tsc(:,:,jp_sal) = ( sf_s_rnf(1)%fnow(:,:,1) ) * rnf(:,:) * r1_rau0 |
|---|
| 141 | ! ! else use S=0 for runoffs (done one for all in the init) |
|---|
| 142 | ! |
|---|
| 143 | IF( ln_rnf_tem .OR. ln_rnf_sal ) THEN ! runoffs as outflow: use ocean SST and SSS |
|---|
| 144 | WHERE( rnf(:,:) < 0._wp ) ! example baltic model when flow is out of domain |
|---|
| 145 | rnf_tsc(:,:,jp_tem) = sst_m(:,:) * rnf(:,:) * r1_rau0 |
|---|
| 146 | rnf_tsc(:,:,jp_sal) = sss_m(:,:) * rnf(:,:) * r1_rau0 |
|---|
| 147 | END WHERE |
|---|
| 148 | ENDIF |
|---|
| 149 | ! |
|---|
| 150 | CALL iom_put( "runoffs", rnf ) ! output runoffs arrays |
|---|
| 151 | ENDIF |
|---|
| 152 | ! |
|---|
| 153 | ENDIF |
|---|
| 154 | ! |
|---|
| 155 | IF( kt == nit000 ) THEN ! set the forcing field at nit000 - 1 ! |
|---|
| 156 | ! ! ---------------------------------------- ! |
|---|
| 157 | IF( ln_rstart .AND. & !* Restart: read in restart file |
|---|
| 158 | & iom_varid( numror, 'rnf_b', ldstop = .FALSE. ) > 0 ) THEN |
|---|
| 159 | IF(lwp) WRITE(numout,*) ' nit000-1 runoff forcing fields red in the restart file' |
|---|
| 160 | CALL iom_get( numror, jpdom_autoglo, 'rnf_b', rnf_b ) ! before runoff |
|---|
| 161 | CALL iom_get( numror, jpdom_autoglo, 'rnf_hc_b', rnf_tsc_b(:,:,jp_tem) ) ! before heat content of runoff |
|---|
| 162 | CALL iom_get( numror, jpdom_autoglo, 'rnf_sc_b', rnf_tsc_b(:,:,jp_sal) ) ! before salinity content of runoff |
|---|
| 163 | ELSE !* no restart: set from nit000 values |
|---|
| 164 | IF(lwp) WRITE(numout,*) ' nit000-1 runoff forcing fields set to nit000' |
|---|
| 165 | rnf_b (:,: ) = rnf (:,: ) |
|---|
| 166 | rnf_tsc_b(:,:,:) = rnf_tsc(:,:,:) |
|---|
| 167 | ENDIF |
|---|
| 168 | ENDIF |
|---|
| 169 | ! ! ---------------------------------------- ! |
|---|
| 170 | IF( lrst_oce ) THEN ! Write in the ocean restart file ! |
|---|
| 171 | ! ! ---------------------------------------- ! |
|---|
| 172 | IF(lwp) WRITE(numout,*) |
|---|
| 173 | IF(lwp) WRITE(numout,*) 'sbcrnf : runoff forcing fields written in ocean restart file ', & |
|---|
| 174 | & 'at it= ', kt,' date= ', ndastp |
|---|
| 175 | IF(lwp) WRITE(numout,*) '~~~~' |
|---|
| 176 | CALL iom_rstput( kt, nitrst, numrow, 'rnf_b' , rnf ) |
|---|
| 177 | CALL iom_rstput( kt, nitrst, numrow, 'rnf_hc_b', rnf_tsc(:,:,jp_tem) ) |
|---|
| 178 | CALL iom_rstput( kt, nitrst, numrow, 'rnf_sc_b', rnf_tsc(:,:,jp_sal) ) |
|---|
| 179 | ENDIF |
|---|
| 180 | ! |
|---|
| 181 | END SUBROUTINE sbc_rnf |
|---|
| 182 | |
|---|
| 183 | |
|---|
| 184 | SUBROUTINE sbc_rnf_div( phdivn ) |
|---|
| 185 | !!---------------------------------------------------------------------- |
|---|
| 186 | !! *** ROUTINE sbc_rnf *** |
|---|
| 187 | !! |
|---|
| 188 | !! ** Purpose : update the horizontal divergence with the runoff inflow |
|---|
| 189 | !! |
|---|
| 190 | !! ** Method : |
|---|
| 191 | !! CAUTION : rnf is positive (inflow) decreasing the |
|---|
| 192 | !! divergence and expressed in m/s |
|---|
| 193 | !! |
|---|
| 194 | !! ** Action : phdivn decreased by the runoff inflow |
|---|
| 195 | !!---------------------------------------------------------------------- |
|---|
| 196 | REAL(wp), DIMENSION(:,:,:), INTENT(inout) :: phdivn ! horizontal divergence |
|---|
| 197 | !! |
|---|
| 198 | INTEGER :: ji, jj, jk ! dummy loop indices |
|---|
| 199 | REAL(wp) :: zfact ! local scalar |
|---|
| 200 | !!---------------------------------------------------------------------- |
|---|
| 201 | ! |
|---|
| 202 | zfact = 0.5_wp |
|---|
| 203 | ! |
|---|
| 204 | IF( ln_rnf_depth ) THEN !== runoff distributed over several levels ==! |
|---|
| 205 | IF( lk_vvl ) THEN ! variable volume case |
|---|
| 206 | DO jj = 1, jpj ! update the depth over which runoffs are distributed |
|---|
| 207 | DO ji = 1, jpi |
|---|
| 208 | h_rnf(ji,jj) = 0._wp |
|---|
| 209 | DO jk = 1, nk_rnf(ji,jj) ! recalculates h_rnf to be the depth in metres |
|---|
| 210 | h_rnf(ji,jj) = h_rnf(ji,jj) + fse3t(ji,jj,jk) ! to the bottom of the relevant grid box |
|---|
| 211 | END DO |
|---|
| 212 | ! ! apply the runoff input flow |
|---|
| 213 | DO jk = 1, nk_rnf(ji,jj) |
|---|
| 214 | phdivn(ji,jj,jk) = phdivn(ji,jj,jk) - ( rnf(ji,jj) + rnf_b(ji,jj) ) * zfact * r1_rau0 / h_rnf(ji,jj) |
|---|
| 215 | END DO |
|---|
| 216 | END DO |
|---|
| 217 | END DO |
|---|
| 218 | ELSE ! constant volume case : just apply the runoff input flow |
|---|
| 219 | DO jj = 1, jpj |
|---|
| 220 | DO ji = 1, jpi |
|---|
| 221 | DO jk = 1, nk_rnf(ji,jj) |
|---|
| 222 | phdivn(ji,jj,jk) = phdivn(ji,jj,jk) - ( rnf(ji,jj) + rnf_b(ji,jj) ) * zfact * r1_rau0 / h_rnf(ji,jj) |
|---|
| 223 | END DO |
|---|
| 224 | END DO |
|---|
| 225 | END DO |
|---|
| 226 | ENDIF |
|---|
| 227 | ELSE !== runoff put only at the surface ==! |
|---|
| 228 | IF( lk_vvl ) THEN ! variable volume case |
|---|
| 229 | h_rnf(:,:) = fse3t(:,:,1) ! recalculate h_rnf to be depth of top box |
|---|
| 230 | ENDIF |
|---|
| 231 | phdivn(:,:,1) = phdivn(:,:,1) - ( rnf(:,:) + rnf_b(:,:) ) * zfact * r1_rau0 / fse3t(:,:,1) |
|---|
| 232 | ENDIF |
|---|
| 233 | ! |
|---|
| 234 | END SUBROUTINE sbc_rnf_div |
|---|
| 235 | |
|---|
| 236 | |
|---|
| 237 | SUBROUTINE sbc_rnf_init |
|---|
| 238 | !!---------------------------------------------------------------------- |
|---|
| 239 | !! *** ROUTINE sbc_rnf_init *** |
|---|
| 240 | !! |
|---|
| 241 | !! ** Purpose : Initialisation of the runoffs if (ln_rnf=T) |
|---|
| 242 | !! |
|---|
| 243 | !! ** Method : - read the runoff namsbc_rnf namelist |
|---|
| 244 | !! |
|---|
| 245 | !! ** Action : - read parameters |
|---|
| 246 | !!---------------------------------------------------------------------- |
|---|
| 247 | CHARACTER(len=32) :: rn_dep_file ! runoff file name |
|---|
| 248 | INTEGER :: ji, jj, jk ! dummy loop indices |
|---|
| 249 | INTEGER :: ierror, inum ! temporary integer |
|---|
| 250 | ! |
|---|
| 251 | NAMELIST/namsbc_rnf/ cn_dir, ln_rnf_emp, ln_rnf_depth, ln_rnf_tem, ln_rnf_sal, & |
|---|
| 252 | & sn_rnf, sn_cnf , sn_s_rnf , sn_t_rnf , sn_dep_rnf, & |
|---|
| 253 | & ln_rnf_mouth , rn_hrnf , rn_avt_rnf, rn_rfact |
|---|
| 254 | !!---------------------------------------------------------------------- |
|---|
| 255 | ! |
|---|
| 256 | ! ! ============ |
|---|
| 257 | ! ! Namelist |
|---|
| 258 | ! ! ============ |
|---|
| 259 | ! (NB: frequency positive => hours, negative => months) |
|---|
| 260 | ! ! file ! frequency ! variable ! time intep ! clim ! 'yearly' or ! weights ! rotation ! |
|---|
| 261 | ! ! name ! (hours) ! name ! (T/F) ! (T/F) ! 'monthly' ! filename ! pairs ! |
|---|
| 262 | sn_rnf = FLD_N( 'runoffs', -1 , 'sorunoff' , .TRUE. , .true. , 'yearly' , '' , '' ) |
|---|
| 263 | sn_cnf = FLD_N( 'runoffs', 0 , 'sorunoff' , .FALSE. , .true. , 'yearly' , '' , '' ) |
|---|
| 264 | |
|---|
| 265 | sn_s_rnf = FLD_N( 'runoffs', 24. , 'rosaline' , .TRUE. , .true. , 'yearly' , '' , '' ) |
|---|
| 266 | sn_t_rnf = FLD_N( 'runoffs', 24. , 'rotemper' , .TRUE. , .true. , 'yearly' , '' , '' ) |
|---|
| 267 | sn_dep_rnf = FLD_N( 'runoffs', 0. , 'rodepth' , .FALSE. , .true. , 'yearly' , '' , '' ) |
|---|
| 268 | ! |
|---|
| 269 | REWIND ( numnam ) ! Read Namelist namsbc_rnf |
|---|
| 270 | READ ( numnam, namsbc_rnf ) |
|---|
| 271 | ! |
|---|
| 272 | ! ! Control print |
|---|
| 273 | IF(lwp) THEN |
|---|
| 274 | WRITE(numout,*) |
|---|
| 275 | WRITE(numout,*) 'sbc_rnf : runoff ' |
|---|
| 276 | WRITE(numout,*) '~~~~~~~ ' |
|---|
| 277 | WRITE(numout,*) ' Namelist namsbc_rnf' |
|---|
| 278 | WRITE(numout,*) ' runoff in a file to be read ln_rnf_emp = ', ln_rnf_emp |
|---|
| 279 | WRITE(numout,*) ' specific river mouths treatment ln_rnf_mouth = ', ln_rnf_mouth |
|---|
| 280 | WRITE(numout,*) ' river mouth additional Kz rn_avt_rnf = ', rn_avt_rnf |
|---|
| 281 | WRITE(numout,*) ' depth of river mouth additional mixing rn_hrnf = ', rn_hrnf |
|---|
| 282 | WRITE(numout,*) ' multiplicative factor for runoff rn_rfact = ', rn_rfact |
|---|
| 283 | ENDIF |
|---|
| 284 | ! |
|---|
| 285 | ! ! ================== |
|---|
| 286 | ! ! Type of runoff |
|---|
| 287 | ! ! ================== |
|---|
| 288 | ! !== allocate runoff arrays |
|---|
| 289 | IF( sbc_rnf_alloc() /= 0 ) CALL ctl_stop( 'STOP', 'sbc_rnf_alloc : unable to allocate arrays' ) |
|---|
| 290 | ! |
|---|
| 291 | IF( ln_rnf_emp ) THEN !== runoffs directly provided in the precipitations ==! |
|---|
| 292 | IF(lwp) WRITE(numout,*) |
|---|
| 293 | IF(lwp) WRITE(numout,*) ' runoffs directly provided in the precipitations' |
|---|
| 294 | IF( ln_rnf_depth .OR. ln_rnf_tem .OR. ln_rnf_sal ) THEN |
|---|
| 295 | CALL ctl_warn( 'runoffs already included in precipitations, so runoff (T,S, depth) attributes will not be used' ) |
|---|
| 296 | ln_rnf_depth = .FALSE. ; ln_rnf_tem = .FALSE. ; ln_rnf_sal = .FALSE. |
|---|
| 297 | ENDIF |
|---|
| 298 | ! |
|---|
| 299 | ELSE !== runoffs read in a file : set sf_rnf structure ==! |
|---|
| 300 | ! |
|---|
| 301 | ALLOCATE( sf_rnf(1), STAT=ierror ) ! Create sf_rnf structure (runoff inflow) |
|---|
| 302 | IF(lwp) WRITE(numout,*) |
|---|
| 303 | IF(lwp) WRITE(numout,*) ' runoffs inflow read in a file' |
|---|
| 304 | IF( ierror > 0 ) THEN |
|---|
| 305 | CALL ctl_stop( 'sbc_rnf: unable to allocate sf_rnf structure' ) ; RETURN |
|---|
| 306 | ENDIF |
|---|
| 307 | ALLOCATE( sf_rnf(1)%fnow(jpi,jpj,1) ) |
|---|
| 308 | IF( sn_rnf%ln_tint ) ALLOCATE( sf_rnf(1)%fdta(jpi,jpj,1,2) ) |
|---|
| 309 | ! ! fill sf_rnf with the namelist (sn_rnf) and control print |
|---|
| 310 | CALL fld_fill( sf_rnf, (/ sn_rnf /), cn_dir, 'sbc_rnf_init', 'read runoffs data', 'namsbc_rnf' ) |
|---|
| 311 | ! |
|---|
| 312 | IF( ln_rnf_tem ) THEN ! Create (if required) sf_t_rnf structure |
|---|
| 313 | IF(lwp) WRITE(numout,*) |
|---|
| 314 | IF(lwp) WRITE(numout,*) ' runoffs temperatures read in a file' |
|---|
| 315 | ALLOCATE( sf_t_rnf(1), STAT=ierror ) |
|---|
| 316 | IF( ierror > 0 ) THEN |
|---|
| 317 | CALL ctl_stop( 'sbc_rnf_init: unable to allocate sf_t_rnf structure' ) ; RETURN |
|---|
| 318 | ENDIF |
|---|
| 319 | ALLOCATE( sf_t_rnf(1)%fnow(jpi,jpj,1) ) |
|---|
| 320 | IF( sn_t_rnf%ln_tint ) ALLOCATE( sf_t_rnf(1)%fdta(jpi,jpj,1,2) ) |
|---|
| 321 | CALL fld_fill (sf_t_rnf, (/ sn_t_rnf /), cn_dir, 'sbc_rnf_init', 'read runoff temperature data', 'namsbc_rnf' ) |
|---|
| 322 | ENDIF |
|---|
| 323 | ! |
|---|
| 324 | IF( ln_rnf_sal ) THEN ! Create (if required) sf_s_rnf and sf_t_rnf structures |
|---|
| 325 | IF(lwp) WRITE(numout,*) |
|---|
| 326 | IF(lwp) WRITE(numout,*) ' runoffs salinities read in a file' |
|---|
| 327 | ALLOCATE( sf_s_rnf(1), STAT=ierror ) |
|---|
| 328 | IF( ierror > 0 ) THEN |
|---|
| 329 | CALL ctl_stop( 'sbc_rnf_init: unable to allocate sf_s_rnf structure' ) ; RETURN |
|---|
| 330 | ENDIF |
|---|
| 331 | ALLOCATE( sf_s_rnf(1)%fnow(jpi,jpj,1) ) |
|---|
| 332 | IF( sn_s_rnf%ln_tint ) ALLOCATE( sf_s_rnf(1)%fdta(jpi,jpj,1,2) ) |
|---|
| 333 | CALL fld_fill (sf_s_rnf, (/ sn_s_rnf /), cn_dir, 'sbc_rnf_init', 'read runoff salinity data', 'namsbc_rnf' ) |
|---|
| 334 | ENDIF |
|---|
| 335 | ! |
|---|
| 336 | IF( ln_rnf_depth ) THEN ! depth of runoffs set from a file |
|---|
| 337 | IF(lwp) WRITE(numout,*) |
|---|
| 338 | IF(lwp) WRITE(numout,*) ' runoffs depth read in a file' |
|---|
| 339 | rn_dep_file = TRIM( cn_dir )//TRIM( sn_dep_rnf%clname ) |
|---|
| 340 | CALL iom_open ( rn_dep_file, inum ) ! open file |
|---|
| 341 | CALL iom_get ( inum, jpdom_data, sn_dep_rnf%clvar, h_rnf ) ! read the river mouth array |
|---|
| 342 | CALL iom_close( inum ) ! close file |
|---|
| 343 | ! |
|---|
| 344 | nk_rnf(:,:) = 0 ! set the number of level over which river runoffs are applied |
|---|
| 345 | DO jj = 1, jpj |
|---|
| 346 | DO ji = 1, jpi |
|---|
| 347 | IF( h_rnf(ji,jj) > 0._wp ) THEN |
|---|
| 348 | jk = 2 |
|---|
| 349 | DO WHILE ( jk /= mbkt(ji,jj) .AND. fsdept(ji,jj,jk) < h_rnf(ji,jj) ) ; jk = jk + 1 ; END DO |
|---|
| 350 | nk_rnf(ji,jj) = jk |
|---|
| 351 | ELSEIF( h_rnf(ji,jj) == -1._wp ) THEN ; nk_rnf(ji,jj) = 1 |
|---|
| 352 | ELSEIF( h_rnf(ji,jj) == -999._wp ) THEN ; nk_rnf(ji,jj) = mbkt(ji,jj) |
|---|
| 353 | ELSE |
|---|
| 354 | CALL ctl_stop( 'runoff depth not positive, and not -999 or -1, rnf value in file fort.999' ) |
|---|
| 355 | WRITE(999,*) 'ji, jj, rnf(ji,jj) :', ji, jj, rnf(ji,jj) |
|---|
| 356 | ENDIF |
|---|
| 357 | END DO |
|---|
| 358 | END DO |
|---|
| 359 | DO jj = 1, jpj ! set the associated depth |
|---|
| 360 | DO ji = 1, jpi |
|---|
| 361 | h_rnf(ji,jj) = 0._wp |
|---|
| 362 | DO jk = 1, nk_rnf(ji,jj) |
|---|
| 363 | h_rnf(ji,jj) = h_rnf(ji,jj) + fse3t(ji,jj,jk) |
|---|
| 364 | END DO |
|---|
| 365 | END DO |
|---|
| 366 | END DO |
|---|
| 367 | ELSE ! runoffs applied at the surface |
|---|
| 368 | nk_rnf(:,:) = 1 |
|---|
| 369 | h_rnf (:,:) = fse3t(:,:,1) |
|---|
| 370 | ENDIF |
|---|
| 371 | ! |
|---|
| 372 | ENDIF |
|---|
| 373 | ! |
|---|
| 374 | rnf(:,:) = 0._wp ! runoff initialisation |
|---|
| 375 | rnf_tsc(:,:,:) = 0._wp ! runoffs temperature & salinty contents initilisation |
|---|
| 376 | ! |
|---|
| 377 | ! ! ======================== |
|---|
| 378 | ! ! River mouth vicinity |
|---|
| 379 | ! ! ======================== |
|---|
| 380 | ! |
|---|
| 381 | IF( ln_rnf_mouth ) THEN ! Specific treatment in vicinity of river mouths : |
|---|
| 382 | ! ! - Increase Kz in surface layers ( rn_hrnf > 0 ) |
|---|
| 383 | ! ! - set to zero SSS damping (ln_ssr=T) |
|---|
| 384 | ! ! - mixed upstream-centered (ln_traadv_cen2=T) |
|---|
| 385 | ! |
|---|
| 386 | IF ( ln_rnf_depth ) CALL ctl_warn( 'sbc_rnf_init: increased mixing turned on but effects may already', & |
|---|
| 387 | & 'be spread through depth by ln_rnf_depth' ) |
|---|
| 388 | ! |
|---|
| 389 | nkrnf = 0 ! Number of level over which Kz increase |
|---|
| 390 | IF( rn_hrnf > 0._wp ) THEN |
|---|
| 391 | nkrnf = 2 |
|---|
| 392 | DO WHILE( nkrnf /= jpkm1 .AND. gdepw_0(nkrnf+1) < rn_hrnf ) ; nkrnf = nkrnf + 1 ; END DO |
|---|
| 393 | IF( ln_sco ) CALL ctl_warn( 'sbc_rnf: number of levels over which Kz is increased is computed for zco...' ) |
|---|
| 394 | ENDIF |
|---|
| 395 | IF(lwp) WRITE(numout,*) |
|---|
| 396 | IF(lwp) WRITE(numout,*) ' Specific treatment used in vicinity of river mouths :' |
|---|
| 397 | IF(lwp) WRITE(numout,*) ' - Increase Kz in surface layers (if rn_hrnf > 0 )' |
|---|
| 398 | IF(lwp) WRITE(numout,*) ' by ', rn_avt_rnf,' m2/s over ', nkrnf, ' w-levels' |
|---|
| 399 | IF(lwp) WRITE(numout,*) ' - set to zero SSS damping (if ln_ssr=T)' |
|---|
| 400 | IF(lwp) WRITE(numout,*) ' - mixed upstream-centered (if ln_traadv_cen2=T)' |
|---|
| 401 | ! |
|---|
| 402 | CALL rnf_mouth ! set river mouth mask |
|---|
| 403 | ! |
|---|
| 404 | ELSE ! No treatment at river mouths |
|---|
| 405 | IF(lwp) WRITE(numout,*) |
|---|
| 406 | IF(lwp) WRITE(numout,*) ' No specific treatment at river mouths' |
|---|
| 407 | rnfmsk (:,:) = 0._wp |
|---|
| 408 | rnfmsk_z(:) = 0._wp |
|---|
| 409 | nkrnf = 0 |
|---|
| 410 | ENDIF |
|---|
| 411 | ! |
|---|
| 412 | END SUBROUTINE sbc_rnf_init |
|---|
| 413 | |
|---|
| 414 | |
|---|
| 415 | SUBROUTINE rnf_mouth |
|---|
| 416 | !!---------------------------------------------------------------------- |
|---|
| 417 | !! *** ROUTINE rnf_mouth *** |
|---|
| 418 | !! |
|---|
| 419 | !! ** Purpose : define the river mouths mask |
|---|
| 420 | !! |
|---|
| 421 | !! ** Method : read the river mouth mask (=0/1) in the river runoff |
|---|
| 422 | !! climatological file. Defined a given vertical structure. |
|---|
| 423 | !! CAUTION, the vertical structure is hard coded on the |
|---|
| 424 | !! first 5 levels. |
|---|
| 425 | !! This fields can be used to: |
|---|
| 426 | !! - set an upstream advection scheme |
|---|
| 427 | !! (ln_rnf_mouth=T and ln_traadv_cen2=T) |
|---|
| 428 | !! - increase vertical on the top nn_krnf vertical levels |
|---|
| 429 | !! at river runoff input grid point (nn_krnf>=2, see step.F90) |
|---|
| 430 | !! - set to zero SSS restoring flux at river mouth grid points |
|---|
| 431 | !! |
|---|
| 432 | !! ** Action : rnfmsk set to 1 at river runoff input, 0 elsewhere |
|---|
| 433 | !! rnfmsk_z vertical structure |
|---|
| 434 | !!---------------------------------------------------------------------- |
|---|
| 435 | INTEGER :: inum ! temporary integers |
|---|
| 436 | CHARACTER(len=140) :: cl_rnfile ! runoff file name |
|---|
| 437 | !!---------------------------------------------------------------------- |
|---|
| 438 | ! |
|---|
| 439 | IF(lwp) WRITE(numout,*) |
|---|
| 440 | IF(lwp) WRITE(numout,*) 'rnf_mouth : river mouth mask' |
|---|
| 441 | IF(lwp) WRITE(numout,*) '~~~~~~~~~ ' |
|---|
| 442 | ! |
|---|
| 443 | cl_rnfile = TRIM( cn_dir )//TRIM( sn_cnf%clname ) |
|---|
| 444 | IF( .NOT. sn_cnf%ln_clim ) THEN ; WRITE(cl_rnfile, '(a,"_y",i4)' ) TRIM( cl_rnfile ), nyear ! add year |
|---|
| 445 | IF( sn_cnf%cltype == 'monthly' ) WRITE(cl_rnfile, '(a,"m",i2)' ) TRIM( cl_rnfile ), nmonth ! add month |
|---|
| 446 | ENDIF |
|---|
| 447 | ! |
|---|
| 448 | ! horizontal mask (read in NetCDF file) |
|---|
| 449 | CALL iom_open ( cl_rnfile, inum ) ! open file |
|---|
| 450 | CALL iom_get ( inum, jpdom_data, sn_cnf%clvar, rnfmsk ) ! read the river mouth array |
|---|
| 451 | CALL iom_close( inum ) ! close file |
|---|
| 452 | ! |
|---|
| 453 | IF( nn_closea == 1 ) CALL clo_rnf( rnfmsk ) ! closed sea inflow set as ruver mouth |
|---|
| 454 | ! |
|---|
| 455 | rnfmsk_z(:) = 0._wp ! vertical structure |
|---|
| 456 | rnfmsk_z(1) = 1.0 |
|---|
| 457 | rnfmsk_z(2) = 1.0 ! ********** |
|---|
| 458 | rnfmsk_z(3) = 0.5 ! HARD CODED on the 5 first levels |
|---|
| 459 | rnfmsk_z(4) = 0.25 ! ********** |
|---|
| 460 | rnfmsk_z(5) = 0.125 |
|---|
| 461 | ! |
|---|
| 462 | END SUBROUTINE rnf_mouth |
|---|
| 463 | |
|---|
| 464 | !!====================================================================== |
|---|
| 465 | END MODULE sbcrnf |
|---|
