| 1 | MODULE sbcmod |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE sbcmod *** |
|---|
| 4 | !! Surface module : provide to the ocean its surface boundary condition |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : 3.0 ! 2006-07 (G. Madec) Original code |
|---|
| 7 | !! 3.1 ! 2008-08 (S. Masson, A. Caubel, E. Maisonnave, G. Madec) coupled interface |
|---|
| 8 | !! 3.3 ! 2010-04 (M. Leclair, G. Madec) Forcing averaged over 2 time steps |
|---|
| 9 | !! 3.3 ! 2010-10 (S. Masson) add diurnal cycle |
|---|
| 10 | !! 3.3 ! 2010-09 (D. Storkey) add ice boundary conditions (BDY) |
|---|
| 11 | !! - ! 2010-11 (G. Madec) ice-ocean stress always computed at each ocean time-step |
|---|
| 12 | !! - ! 2010-10 (J. Chanut, C. Bricaud, G. Madec) add the surface pressure forcing |
|---|
| 13 | !! 3.4 ! 2011-11 (C. Harris) CICE added as an option |
|---|
| 14 | !! 3.5 ! 2012-11 (A. Coward, G. Madec) Rethink of heat, mass and salt surface fluxes |
|---|
| 15 | !!---------------------------------------------------------------------- |
|---|
| 16 | |
|---|
| 17 | !!---------------------------------------------------------------------- |
|---|
| 18 | !! sbc_init : read namsbc namelist |
|---|
| 19 | !! sbc : surface ocean momentum, heat and freshwater boundary conditions |
|---|
| 20 | !!---------------------------------------------------------------------- |
|---|
| 21 | USE oce ! ocean dynamics and tracers |
|---|
| 22 | USE dom_oce ! ocean space and time domain |
|---|
| 23 | USE phycst ! physical constants |
|---|
| 24 | USE sbc_oce ! Surface boundary condition: ocean fields |
|---|
| 25 | USE sbc_ice ! Surface boundary condition: ice fields |
|---|
| 26 | USE sbcdcy ! surface boundary condition: diurnal cycle |
|---|
| 27 | USE sbcssm ! surface boundary condition: sea-surface mean variables |
|---|
| 28 | USE sbcapr ! surface boundary condition: atmospheric pressure |
|---|
| 29 | USE sbcana ! surface boundary condition: analytical formulation |
|---|
| 30 | USE sbcflx ! surface boundary condition: flux formulation |
|---|
| 31 | USE sbcblk_clio ! surface boundary condition: bulk formulation : CLIO |
|---|
| 32 | USE sbcblk_core ! surface boundary condition: bulk formulation : CORE |
|---|
| 33 | USE sbcblk_mfs ! surface boundary condition: bulk formulation : MFS |
|---|
| 34 | USE sbcice_if ! surface boundary condition: ice-if sea-ice model |
|---|
| 35 | USE sbcice_lim ! surface boundary condition: LIM 3.0 sea-ice model |
|---|
| 36 | USE sbcice_lim_2 ! surface boundary condition: LIM 2.0 sea-ice model |
|---|
| 37 | USE sbcice_cice ! surface boundary condition: CICE sea-ice model |
|---|
| 38 | USE sbccpl ! surface boundary condition: coupled florulation |
|---|
| 39 | USE cpl_oasis3, ONLY:lk_cpl ! are we in coupled mode? |
|---|
| 40 | USE sbcssr ! surface boundary condition: sea surface restoring |
|---|
| 41 | USE sbcrnf ! surface boundary condition: runoffs |
|---|
| 42 | USE sbcfwb ! surface boundary condition: freshwater budget |
|---|
| 43 | USE closea ! closed sea |
|---|
| 44 | USE icbstp ! Icebergs! |
|---|
| 45 | |
|---|
| 46 | USE prtctl ! Print control (prt_ctl routine) |
|---|
| 47 | USE iom ! IOM library |
|---|
| 48 | USE in_out_manager ! I/O manager |
|---|
| 49 | USE lib_mpp ! MPP library |
|---|
| 50 | USE timing ! Timing |
|---|
| 51 | USE sbcwave ! Wave module |
|---|
| 52 | |
|---|
| 53 | IMPLICIT NONE |
|---|
| 54 | PRIVATE |
|---|
| 55 | |
|---|
| 56 | PUBLIC sbc ! routine called by step.F90 |
|---|
| 57 | PUBLIC sbc_init ! routine called by opa.F90 |
|---|
| 58 | |
|---|
| 59 | INTEGER :: nsbc ! type of surface boundary condition (deduced from namsbc informations) |
|---|
| 60 | |
|---|
| 61 | !! * Substitutions |
|---|
| 62 | # include "domzgr_substitute.h90" |
|---|
| 63 | !!---------------------------------------------------------------------- |
|---|
| 64 | !! NEMO/OPA 4.0 , NEMO-consortium (2011) |
|---|
| 65 | !! $Id$ |
|---|
| 66 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 67 | !!---------------------------------------------------------------------- |
|---|
| 68 | CONTAINS |
|---|
| 69 | |
|---|
| 70 | SUBROUTINE sbc_init |
|---|
| 71 | !!--------------------------------------------------------------------- |
|---|
| 72 | !! *** ROUTINE sbc_init *** |
|---|
| 73 | !! |
|---|
| 74 | !! ** Purpose : Initialisation of the ocean surface boundary computation |
|---|
| 75 | !! |
|---|
| 76 | !! ** Method : Read the namsbc namelist and set derived parameters |
|---|
| 77 | !! Call init routines for all other SBC modules that have one |
|---|
| 78 | !! |
|---|
| 79 | !! ** Action : - read namsbc parameters |
|---|
| 80 | !! - nsbc: type of sbc |
|---|
| 81 | !!---------------------------------------------------------------------- |
|---|
| 82 | INTEGER :: icpt ! local integer |
|---|
| 83 | !! |
|---|
| 84 | NAMELIST/namsbc/ nn_fsbc , ln_ana , ln_flx, ln_blk_clio, ln_blk_core, ln_cpl, & |
|---|
| 85 | & ln_blk_mfs, ln_apr_dyn, nn_ice, nn_ice_embd, ln_dm2dc , ln_rnf, & |
|---|
| 86 | & ln_ssr , nn_fwb , ln_cdgw , ln_wave , ln_sdw |
|---|
| 87 | !!---------------------------------------------------------------------- |
|---|
| 88 | |
|---|
| 89 | IF(lwp) THEN |
|---|
| 90 | WRITE(numout,*) |
|---|
| 91 | WRITE(numout,*) 'sbc_init : surface boundary condition setting' |
|---|
| 92 | WRITE(numout,*) '~~~~~~~~ ' |
|---|
| 93 | ENDIF |
|---|
| 94 | |
|---|
| 95 | REWIND( numnam ) ! Read Namelist namsbc |
|---|
| 96 | READ ( numnam, namsbc ) |
|---|
| 97 | |
|---|
| 98 | ! ! overwrite namelist parameter using CPP key information |
|---|
| 99 | IF( Agrif_Root() ) THEN ! AGRIF zoom |
|---|
| 100 | IF( lk_lim2 ) nn_ice = 2 |
|---|
| 101 | IF( lk_lim3 ) nn_ice = 3 |
|---|
| 102 | IF( lk_cice ) nn_ice = 4 |
|---|
| 103 | ENDIF |
|---|
| 104 | IF( cp_cfg == 'gyre' ) THEN ! GYRE configuration |
|---|
| 105 | ln_ana = .TRUE. |
|---|
| 106 | nn_ice = 0 |
|---|
| 107 | ENDIF |
|---|
| 108 | |
|---|
| 109 | IF(lwp) THEN ! Control print |
|---|
| 110 | WRITE(numout,*) ' Namelist namsbc (partly overwritten with CPP key setting)' |
|---|
| 111 | WRITE(numout,*) ' frequency update of sbc (and ice) nn_fsbc = ', nn_fsbc |
|---|
| 112 | WRITE(numout,*) ' Type of sbc : ' |
|---|
| 113 | WRITE(numout,*) ' analytical formulation ln_ana = ', ln_ana |
|---|
| 114 | WRITE(numout,*) ' flux formulation ln_flx = ', ln_flx |
|---|
| 115 | WRITE(numout,*) ' CLIO bulk formulation ln_blk_clio = ', ln_blk_clio |
|---|
| 116 | WRITE(numout,*) ' CORE bulk formulation ln_blk_core = ', ln_blk_core |
|---|
| 117 | WRITE(numout,*) ' MFS bulk formulation ln_blk_mfs = ', ln_blk_mfs |
|---|
| 118 | WRITE(numout,*) ' coupled formulation (T if key_sbc_cpl) ln_cpl = ', ln_cpl |
|---|
| 119 | WRITE(numout,*) ' Misc. options of sbc : ' |
|---|
| 120 | WRITE(numout,*) ' Patm gradient added in ocean & ice Eqs. ln_apr_dyn = ', ln_apr_dyn |
|---|
| 121 | WRITE(numout,*) ' ice management in the sbc (=0/1/2/3) nn_ice = ', nn_ice |
|---|
| 122 | WRITE(numout,*) ' ice-ocean embedded/levitating (=0/1/2) nn_ice_embd = ', nn_ice_embd |
|---|
| 123 | WRITE(numout,*) ' daily mean to diurnal cycle qsr ln_dm2dc = ', ln_dm2dc |
|---|
| 124 | WRITE(numout,*) ' runoff / runoff mouths ln_rnf = ', ln_rnf |
|---|
| 125 | WRITE(numout,*) ' Sea Surface Restoring on SST and/or SSS ln_ssr = ', ln_ssr |
|---|
| 126 | WRITE(numout,*) ' FreshWater Budget control (=0/1/2) nn_fwb = ', nn_fwb |
|---|
| 127 | WRITE(numout,*) ' closed sea (=0/1) (set in namdom) nn_closea = ', nn_closea |
|---|
| 128 | ENDIF |
|---|
| 129 | |
|---|
| 130 | ! ! allocate sbc arrays |
|---|
| 131 | IF( sbc_oce_alloc() /= 0 ) CALL ctl_stop( 'STOP', 'sbc_init : unable to allocate sbc_oce arrays' ) |
|---|
| 132 | |
|---|
| 133 | ! ! Checks: |
|---|
| 134 | IF( .NOT. ln_rnf ) THEN ! no specific treatment in vicinity of river mouths |
|---|
| 135 | ln_rnf_mouth = .false. |
|---|
| 136 | IF( sbc_rnf_alloc() /= 0 ) CALL ctl_stop( 'STOP', 'sbc_init : unable to allocate sbc_rnf arrays' ) |
|---|
| 137 | nkrnf = 0 |
|---|
| 138 | rnf (:,:) = 0.0_wp |
|---|
| 139 | rnfmsk (:,:) = 0.0_wp |
|---|
| 140 | rnfmsk_z(:) = 0.0_wp |
|---|
| 141 | ENDIF |
|---|
| 142 | IF( nn_ice == 0 ) fr_i(:,:) = 0.e0 ! no ice in the domain, ice fraction is always zero |
|---|
| 143 | |
|---|
| 144 | sfx(:,:) = 0.0_wp ! the salt flux due to freezing/melting will be computed (i.e. will be non-zero) |
|---|
| 145 | ! only if sea-ice is present |
|---|
| 146 | |
|---|
| 147 | fmmflx(:,:) = 0.0_wp ! freezing-melting array initialisation |
|---|
| 148 | |
|---|
| 149 | ! ! restartability |
|---|
| 150 | IF( MOD( nitend - nit000 + 1, nn_fsbc) /= 0 .OR. & |
|---|
| 151 | MOD( nstock , nn_fsbc) /= 0 ) THEN |
|---|
| 152 | WRITE(ctmp1,*) 'experiment length (', nitend - nit000 + 1, ') or nstock (', nstock, & |
|---|
| 153 | & ' is NOT a multiple of nn_fsbc (', nn_fsbc, ')' |
|---|
| 154 | CALL ctl_stop( ctmp1, 'Impossible to properly do model restart' ) |
|---|
| 155 | ENDIF |
|---|
| 156 | ! |
|---|
| 157 | IF( MOD( rday, REAL(nn_fsbc, wp) * rdt ) /= 0 ) & |
|---|
| 158 | & CALL ctl_warn( 'nn_fsbc is NOT a multiple of the number of time steps in a day' ) |
|---|
| 159 | ! |
|---|
| 160 | IF( ( nn_ice == 2 .OR. nn_ice ==3 ) .AND. .NOT.( ln_blk_clio .OR. ln_blk_core .OR. lk_cpl ) ) & |
|---|
| 161 | & CALL ctl_stop( 'LIM sea-ice model requires a bulk formulation or coupled configuration' ) |
|---|
| 162 | IF( nn_ice == 4 .AND. .NOT.( ln_blk_core .OR. lk_cpl ) ) & |
|---|
| 163 | & CALL ctl_stop( 'CICE sea-ice model requires ln_blk_core or lk_cpl' ) |
|---|
| 164 | IF( nn_ice == 4 .AND. lk_agrif ) & |
|---|
| 165 | & CALL ctl_stop( 'CICE sea-ice model not currently available with AGRIF' ) |
|---|
| 166 | IF( ( nn_ice == 3 .OR. nn_ice == 4 ) .AND. nn_ice_embd == 0 ) & |
|---|
| 167 | & CALL ctl_stop( 'LIM3 and CICE sea-ice models require nn_ice_embd = 1 or 2' ) |
|---|
| 168 | |
|---|
| 169 | IF( ln_dm2dc ) nday_qsr = -1 ! initialisation flag |
|---|
| 170 | |
|---|
| 171 | IF( ln_dm2dc .AND. .NOT.( ln_flx .OR. ln_blk_core ) ) & |
|---|
| 172 | & CALL ctl_stop( 'diurnal cycle into qsr field from daily values requires a flux or core-bulk formulation' ) |
|---|
| 173 | |
|---|
| 174 | IF( ln_dm2dc .AND. ( ( NINT(rday) / ( nn_fsbc * NINT(rdt) ) ) < 8 ) ) & |
|---|
| 175 | & CALL ctl_warn( 'diurnal cycle for qsr: the sampling of the diurnal cycle is too small...' ) |
|---|
| 176 | |
|---|
| 177 | IF ( ln_wave ) THEN |
|---|
| 178 | !Activated wave module but neither drag nor stokes drift activated |
|---|
| 179 | IF ( .NOT.(ln_cdgw .OR. ln_sdw) ) THEN |
|---|
| 180 | CALL ctl_warn( 'Ask for wave coupling but nor drag coefficient (ln_cdgw=F) neither stokes drift activated (ln_sdw=F)' ) |
|---|
| 181 | !drag coefficient read from wave model definable only with mfs bulk formulae and core |
|---|
| 182 | ELSEIF (ln_cdgw .AND. .NOT.(ln_blk_mfs .OR. ln_blk_core) ) THEN |
|---|
| 183 | CALL ctl_stop( 'drag coefficient read from wave model definable only with mfs bulk formulae and core') |
|---|
| 184 | ENDIF |
|---|
| 185 | ELSE |
|---|
| 186 | IF ( ln_cdgw .OR. ln_sdw ) & |
|---|
| 187 | & CALL ctl_stop('Not Activated Wave Module (ln_wave=F) but & |
|---|
| 188 | & asked coupling with drag coefficient (ln_cdgw =T) or Stokes drift (ln_sdw=T) ') |
|---|
| 189 | ENDIF |
|---|
| 190 | |
|---|
| 191 | ! ! Choice of the Surface Boudary Condition (set nsbc) |
|---|
| 192 | icpt = 0 |
|---|
| 193 | IF( ln_ana ) THEN ; nsbc = 1 ; icpt = icpt + 1 ; ENDIF ! analytical formulation |
|---|
| 194 | IF( ln_flx ) THEN ; nsbc = 2 ; icpt = icpt + 1 ; ENDIF ! flux formulation |
|---|
| 195 | IF( ln_blk_clio ) THEN ; nsbc = 3 ; icpt = icpt + 1 ; ENDIF ! CLIO bulk formulation |
|---|
| 196 | IF( ln_blk_core ) THEN ; nsbc = 4 ; icpt = icpt + 1 ; ENDIF ! CORE bulk formulation |
|---|
| 197 | IF( ln_blk_mfs ) THEN ; nsbc = 6 ; icpt = icpt + 1 ; ENDIF ! MFS bulk formulation |
|---|
| 198 | IF( ln_cpl ) THEN ; nsbc = 5 ; icpt = icpt + 1 ; ENDIF ! Coupled formulation |
|---|
| 199 | IF( cp_cfg == 'gyre') THEN ; nsbc = 0 ; ENDIF ! GYRE analytical formulation |
|---|
| 200 | IF( lk_esopa ) nsbc = -1 ! esopa test, ALL formulations |
|---|
| 201 | ! |
|---|
| 202 | IF( icpt /= 1 .AND. .NOT.lk_esopa ) THEN |
|---|
| 203 | WRITE(numout,*) |
|---|
| 204 | WRITE(numout,*) ' E R R O R in setting the sbc, one and only one namelist/CPP key option ' |
|---|
| 205 | WRITE(numout,*) ' must be choosen. You choose ', icpt, ' option(s)' |
|---|
| 206 | WRITE(numout,*) ' We stop' |
|---|
| 207 | nstop = nstop + 1 |
|---|
| 208 | ENDIF |
|---|
| 209 | IF(lwp) THEN |
|---|
| 210 | WRITE(numout,*) |
|---|
| 211 | IF( nsbc == -1 ) WRITE(numout,*) ' ESOPA test All surface boundary conditions' |
|---|
| 212 | IF( nsbc == 0 ) WRITE(numout,*) ' GYRE analytical formulation' |
|---|
| 213 | IF( nsbc == 1 ) WRITE(numout,*) ' analytical formulation' |
|---|
| 214 | IF( nsbc == 2 ) WRITE(numout,*) ' flux formulation' |
|---|
| 215 | IF( nsbc == 3 ) WRITE(numout,*) ' CLIO bulk formulation' |
|---|
| 216 | IF( nsbc == 4 ) WRITE(numout,*) ' CORE bulk formulation' |
|---|
| 217 | IF( nsbc == 5 ) WRITE(numout,*) ' coupled formulation' |
|---|
| 218 | IF( nsbc == 6 ) WRITE(numout,*) ' MFS Bulk formulation' |
|---|
| 219 | ENDIF |
|---|
| 220 | ! |
|---|
| 221 | IF( ln_ssr ) CALL sbc_ssr_init ! Sea-Surface Restoring initialisation |
|---|
| 222 | ! |
|---|
| 223 | IF( nn_ice == 4 ) CALL cice_sbc_init( nsbc ) ! CICE initialisation |
|---|
| 224 | ! |
|---|
| 225 | END SUBROUTINE sbc_init |
|---|
| 226 | |
|---|
| 227 | |
|---|
| 228 | SUBROUTINE sbc( kt ) |
|---|
| 229 | !!--------------------------------------------------------------------- |
|---|
| 230 | !! *** ROUTINE sbc *** |
|---|
| 231 | !! |
|---|
| 232 | !! ** Purpose : provide at each time-step the ocean surface boundary |
|---|
| 233 | !! condition (momentum, heat and freshwater fluxes) |
|---|
| 234 | !! |
|---|
| 235 | !! ** Method : blah blah to be written ????????? |
|---|
| 236 | !! CAUTION : never mask the surface stress field (tke sbc) |
|---|
| 237 | !! |
|---|
| 238 | !! ** Action : - set the ocean surface boundary condition at before and now |
|---|
| 239 | !! time step, i.e. |
|---|
| 240 | !! utau_b, vtau_b, qns_b, qsr_b, emp_n, sfx_b, qrp_b, erp_b |
|---|
| 241 | !! utau , vtau , qns , qsr , emp , sfx , qrp , erp |
|---|
| 242 | !! - updte the ice fraction : fr_i |
|---|
| 243 | !!---------------------------------------------------------------------- |
|---|
| 244 | INTEGER, INTENT(in) :: kt ! ocean time step |
|---|
| 245 | !!--------------------------------------------------------------------- |
|---|
| 246 | ! |
|---|
| 247 | IF( nn_timing == 1 ) CALL timing_start('sbc') |
|---|
| 248 | ! |
|---|
| 249 | ! ! ---------------------------------------- ! |
|---|
| 250 | IF( kt /= nit000 ) THEN ! Swap of forcing fields ! |
|---|
| 251 | ! ! ---------------------------------------- ! |
|---|
| 252 | utau_b(:,:) = utau(:,:) ! Swap the ocean forcing fields |
|---|
| 253 | vtau_b(:,:) = vtau(:,:) ! (except at nit000 where before fields |
|---|
| 254 | qns_b (:,:) = qns (:,:) ! are set at the end of the routine) |
|---|
| 255 | ! The 3D heat content due to qsr forcing is treated in traqsr |
|---|
| 256 | ! qsr_b (:,:) = qsr (:,:) |
|---|
| 257 | emp_b(:,:) = emp(:,:) |
|---|
| 258 | sfx_b(:,:) = sfx(:,:) |
|---|
| 259 | ENDIF |
|---|
| 260 | ! ! ---------------------------------------- ! |
|---|
| 261 | ! ! forcing field computation ! |
|---|
| 262 | ! ! ---------------------------------------- ! |
|---|
| 263 | ! |
|---|
| 264 | IF( ln_apr_dyn ) CALL sbc_apr( kt ) ! atmospheric pressure provided at kt+0.5*nn_fsbc |
|---|
| 265 | ! (caution called before sbc_ssm) |
|---|
| 266 | ! |
|---|
| 267 | CALL sbc_ssm( kt ) ! ocean sea surface variables (sst_m, sss_m, ssu_m, ssv_m) |
|---|
| 268 | ! ! averaged over nf_sbc time-step |
|---|
| 269 | |
|---|
| 270 | IF (ln_wave) CALL sbc_wave( kt ) |
|---|
| 271 | !== sbc formulation ==! |
|---|
| 272 | |
|---|
| 273 | SELECT CASE( nsbc ) ! Compute ocean surface boundary condition |
|---|
| 274 | ! ! (i.e. utau,vtau, qns, qsr, emp, sfx) |
|---|
| 275 | CASE( 0 ) ; CALL sbc_gyre ( kt ) ! analytical formulation : GYRE configuration |
|---|
| 276 | CASE( 1 ) ; CALL sbc_ana ( kt ) ! analytical formulation : uniform sbc |
|---|
| 277 | CASE( 2 ) ; CALL sbc_flx ( kt ) ! flux formulation |
|---|
| 278 | CASE( 3 ) ; CALL sbc_blk_clio( kt ) ! bulk formulation : CLIO for the ocean |
|---|
| 279 | CASE( 4 ) ; CALL sbc_blk_core( kt ) ! bulk formulation : CORE for the ocean |
|---|
| 280 | CASE( 5 ) ; CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice ) ! coupled formulation |
|---|
| 281 | CASE( 6 ) ; CALL sbc_blk_mfs ( kt ) ! bulk formulation : MFS for the ocean |
|---|
| 282 | CASE( -1 ) |
|---|
| 283 | CALL sbc_ana ( kt ) ! ESOPA, test ALL the formulations |
|---|
| 284 | CALL sbc_gyre ( kt ) ! |
|---|
| 285 | CALL sbc_flx ( kt ) ! |
|---|
| 286 | CALL sbc_blk_clio( kt ) ! |
|---|
| 287 | CALL sbc_blk_core( kt ) ! |
|---|
| 288 | CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice ) ! |
|---|
| 289 | END SELECT |
|---|
| 290 | |
|---|
| 291 | ! !== Misc. Options ==! |
|---|
| 292 | |
|---|
| 293 | SELECT CASE( nn_ice ) ! Update heat and freshwater fluxes over sea-ice areas |
|---|
| 294 | CASE( 1 ) ; CALL sbc_ice_if ( kt ) ! Ice-cover climatology ("Ice-if" model) |
|---|
| 295 | CASE( 2 ) ; CALL sbc_ice_lim_2( kt, nsbc ) ! LIM-2 ice model |
|---|
| 296 | CASE( 3 ) ; CALL sbc_ice_lim ( kt, nsbc ) ! LIM-3 ice model |
|---|
| 297 | END SELECT |
|---|
| 298 | |
|---|
| 299 | IF( ln_icebergs ) CALL icb_stp( kt ) ! compute icebergs |
|---|
| 300 | |
|---|
| 301 | IF( ln_rnf ) CALL sbc_rnf( kt ) ! add runoffs to fresh water fluxes |
|---|
| 302 | |
|---|
| 303 | IF( ln_ssr ) CALL sbc_ssr( kt ) ! add SST/SSS damping term |
|---|
| 304 | |
|---|
| 305 | IF( nn_fwb /= 0 ) CALL sbc_fwb( kt, nn_fwb, nn_fsbc ) ! control the freshwater budget |
|---|
| 306 | |
|---|
| 307 | IF( nn_closea == 1 ) CALL sbc_clo( kt ) ! treatment of closed sea in the model domain |
|---|
| 308 | ! ! (update freshwater fluxes) |
|---|
| 309 | !RBbug do not understand why see ticket 667 |
|---|
| 310 | CALL lbc_lnk( emp, 'T', 1. ) |
|---|
| 311 | ! |
|---|
| 312 | IF( kt == nit000 ) THEN ! set the forcing field at nit000 - 1 ! |
|---|
| 313 | ! ! ---------------------------------------- ! |
|---|
| 314 | IF( ln_rstart .AND. & !* Restart: read in restart file |
|---|
| 315 | & iom_varid( numror, 'utau_b', ldstop = .FALSE. ) > 0 ) THEN |
|---|
| 316 | IF(lwp) WRITE(numout,*) ' nit000-1 surface forcing fields red in the restart file' |
|---|
| 317 | CALL iom_get( numror, jpdom_autoglo, 'utau_b', utau_b ) ! before i-stress (U-point) |
|---|
| 318 | CALL iom_get( numror, jpdom_autoglo, 'vtau_b', vtau_b ) ! before j-stress (V-point) |
|---|
| 319 | CALL iom_get( numror, jpdom_autoglo, 'qns_b' , qns_b ) ! before non solar heat flux (T-point) |
|---|
| 320 | ! The 3D heat content due to qsr forcing is treated in traqsr |
|---|
| 321 | ! CALL iom_get( numror, jpdom_autoglo, 'qsr_b' , qsr_b ) ! before solar heat flux (T-point) |
|---|
| 322 | CALL iom_get( numror, jpdom_autoglo, 'emp_b', emp_b ) ! before freshwater flux (T-point) |
|---|
| 323 | ! To ensure restart capability with 3.3x/3.4 restart files !! to be removed in v3.6 |
|---|
| 324 | IF( iom_varid( numror, 'sfx_b', ldstop = .FALSE. ) > 0 ) THEN |
|---|
| 325 | CALL iom_get( numror, jpdom_autoglo, 'sfx_b', sfx_b ) ! before salt flux (T-point) |
|---|
| 326 | ELSE |
|---|
| 327 | sfx_b (:,:) = sfx(:,:) |
|---|
| 328 | ENDIF |
|---|
| 329 | ELSE !* no restart: set from nit000 values |
|---|
| 330 | IF(lwp) WRITE(numout,*) ' nit000-1 surface forcing fields set to nit000' |
|---|
| 331 | utau_b(:,:) = utau(:,:) |
|---|
| 332 | vtau_b(:,:) = vtau(:,:) |
|---|
| 333 | qns_b (:,:) = qns (:,:) |
|---|
| 334 | emp_b (:,:) = emp(:,:) |
|---|
| 335 | sfx_b (:,:) = sfx(:,:) |
|---|
| 336 | ENDIF |
|---|
| 337 | ENDIF |
|---|
| 338 | ! ! ---------------------------------------- ! |
|---|
| 339 | IF( lrst_oce ) THEN ! Write in the ocean restart file ! |
|---|
| 340 | ! ! ---------------------------------------- ! |
|---|
| 341 | IF(lwp) WRITE(numout,*) |
|---|
| 342 | IF(lwp) WRITE(numout,*) 'sbc : ocean surface forcing fields written in ocean restart file ', & |
|---|
| 343 | & 'at it= ', kt,' date= ', ndastp |
|---|
| 344 | IF(lwp) WRITE(numout,*) '~~~~' |
|---|
| 345 | CALL iom_rstput( kt, nitrst, numrow, 'utau_b' , utau ) |
|---|
| 346 | CALL iom_rstput( kt, nitrst, numrow, 'vtau_b' , vtau ) |
|---|
| 347 | CALL iom_rstput( kt, nitrst, numrow, 'qns_b' , qns ) |
|---|
| 348 | ! The 3D heat content due to qsr forcing is treated in traqsr |
|---|
| 349 | ! CALL iom_rstput( kt, nitrst, numrow, 'qsr_b' , qsr ) |
|---|
| 350 | CALL iom_rstput( kt, nitrst, numrow, 'emp_b' , emp ) |
|---|
| 351 | CALL iom_rstput( kt, nitrst, numrow, 'sfx_b' , sfx ) |
|---|
| 352 | ENDIF |
|---|
| 353 | |
|---|
| 354 | ! ! ---------------------------------------- ! |
|---|
| 355 | ! ! Outputs and control print ! |
|---|
| 356 | ! ! ---------------------------------------- ! |
|---|
| 357 | IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN |
|---|
| 358 | CALL iom_put( "empmr" , emp - rnf ) ! upward water flux |
|---|
| 359 | CALL iom_put( "saltflx", sfx ) ! downward salt flux |
|---|
| 360 | ! (includes virtual salt flux beneath ice |
|---|
| 361 | ! in linear free surface case) |
|---|
| 362 | CALL iom_put( "fmmflx", fmmflx ) ! Freezing-melting water flux |
|---|
| 363 | CALL iom_put( "qt" , qns + qsr ) ! total heat flux |
|---|
| 364 | CALL iom_put( "qns" , qns ) ! solar heat flux |
|---|
| 365 | CALL iom_put( "qsr" , qsr ) ! solar heat flux |
|---|
| 366 | IF( nn_ice > 0 ) CALL iom_put( "ice_cover", fr_i ) ! ice fraction |
|---|
| 367 | ENDIF |
|---|
| 368 | ! |
|---|
| 369 | CALL iom_put( "utau", utau ) ! i-wind stress (stress can be updated at |
|---|
| 370 | CALL iom_put( "vtau", vtau ) ! j-wind stress each time step in sea-ice) |
|---|
| 371 | CALL iom_put( "taum", taum ) ! wind stress module |
|---|
| 372 | CALL iom_put( "wspd", wndm ) ! wind speed module |
|---|
| 373 | ! |
|---|
| 374 | IF(ln_ctl) THEN ! print mean trends (used for debugging) |
|---|
| 375 | CALL prt_ctl(tab2d_1=fr_i , clinfo1=' fr_i - : ', mask1=tmask, ovlap=1 ) |
|---|
| 376 | CALL prt_ctl(tab2d_1=(emp-rnf) , clinfo1=' emp-rnf - : ', mask1=tmask, ovlap=1 ) |
|---|
| 377 | CALL prt_ctl(tab2d_1=(sfx-rnf) , clinfo1=' sfx-rnf - : ', mask1=tmask, ovlap=1 ) |
|---|
| 378 | CALL prt_ctl(tab2d_1=qns , clinfo1=' qns - : ', mask1=tmask, ovlap=1 ) |
|---|
| 379 | CALL prt_ctl(tab2d_1=qsr , clinfo1=' qsr - : ', mask1=tmask, ovlap=1 ) |
|---|
| 380 | CALL prt_ctl(tab3d_1=tmask , clinfo1=' tmask - : ', mask1=tmask, ovlap=1, kdim=jpk ) |
|---|
| 381 | CALL prt_ctl(tab3d_1=tsn(:,:,:,jp_tem), clinfo1=' sst - : ', mask1=tmask, ovlap=1, kdim=1 ) |
|---|
| 382 | CALL prt_ctl(tab3d_1=tsn(:,:,:,jp_sal), clinfo1=' sss - : ', mask1=tmask, ovlap=1, kdim=1 ) |
|---|
| 383 | CALL prt_ctl(tab2d_1=utau , clinfo1=' utau - : ', mask1=umask, & |
|---|
| 384 | & tab2d_2=vtau , clinfo2=' vtau - : ', mask2=vmask, ovlap=1 ) |
|---|
| 385 | ENDIF |
|---|
| 386 | |
|---|
| 387 | IF( kt == nitend ) CALL sbc_final ! Close down surface module if necessary |
|---|
| 388 | ! |
|---|
| 389 | IF( nn_timing == 1 ) CALL timing_stop('sbc') |
|---|
| 390 | ! |
|---|
| 391 | END SUBROUTINE sbc |
|---|
| 392 | |
|---|
| 393 | |
|---|
| 394 | SUBROUTINE sbc_final |
|---|
| 395 | !!--------------------------------------------------------------------- |
|---|
| 396 | !! *** ROUTINE sbc_final *** |
|---|
| 397 | !! |
|---|
| 398 | !! ** Purpose : Finalize CICE (if used) |
|---|
| 399 | !!--------------------------------------------------------------------- |
|---|
| 400 | ! |
|---|
| 401 | IF( nn_ice == 4 ) CALL cice_sbc_final |
|---|
| 402 | ! |
|---|
| 403 | END SUBROUTINE sbc_final |
|---|
| 404 | |
|---|
| 405 | !!====================================================================== |
|---|
| 406 | END MODULE sbcmod |
|---|
